$$$$ PASAPAS
* PASAPAS   PROCEDUR  SP204843  26/04/22    21:15:02     12521          

'DEBP' PASAPAS  PRECED*'TABLE';
'SAUT' 1 'LIGNE';
'MESS'
'------------------ DEBUT DE LA PROCEDURE PASAPAS --------------------';
************************************************************************
*                                                                      *
*   PRECED      objet de type TABLE                                    *
*               C'est une table donnant , les arguments d'entrees, les *
*               options, puis les  resultats des pas precedents        *
*                                                                      *
* champs de materiaux :                                                *
*     WTAB.'MAT_REF' materiau etat a la temperature de REFERENCE       *
*     WTAB.'MAT0'    materiau etat debut de calcul                     *
*     WTAB.'MAT1'    materiau fin du pas de temps                      *
*                                                                      *
************************************************************************

****************   I PARTIE   ******************************************
* Verifications des infos transmises et valeurs par defaut
PAS_DEFA PRECED ;
* Creation des tables de sortie et initialisations
PAS_INIT PRECED ;

WTAB  = PRECED.'WTABLE'      ;
conti = PRECED.'CONTINUATION';
estim = PRECED.'ESTIMATION'  ;
*-----------------------------------------------------------------------
*              Appel aux procedures utilisateurs
*-----------------------------------------------------------------------
'SI' WTAB.'PROCEDURE_PERSO1';
  PRECED.'PERSO1_APPEL' = 1 ;
  PERSO1 PRECED ;
  'SI' ('EXIS' PRECED 'ARRET') ;
    WTAB.'ARRET' = PRECED.'ARRET' ;
  'FINSI' ;
'FINSI';
*
'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  REEV_MEC PRECED 0 ;
'FINSI' ;
*
'SI' WTAB.'PROCEDURE_REEV_THE' ;
  REEV_THE PRECED 0 ;
'FINSI' ;
*-----------------------------------------------------------------------
*              Initialisation ETAT et MATERIAUX
*-----------------------------------------------------------------------
TEMP0       = conti.'TEMPS';
ETAT0       = PAS_ETAT PRECED TEMP0 ;
WTAB.'MAT0' = PAS_MATE PRECED ETAT0 ;
WTAB.'MAT1' = WTAB.'MAT0' ;
*
*---------   initialisation deformation thermique de reference
'SI' WTAB.'FOR_MECA' ;
  'SI' WTAB.'ITHER' ;
    'SI' ('EGA' WTAB.'ETREF' 'INCONNU');
      WTAB.'ETAT_REF' = PAS_ETAT PRECED TEMP0 'T_REFERENCE';
      WTAB.'MAT_REF'  = PAS_MATE PRECED WTAB.'ETAT_REF'  ;
      WTAB.'ETREF'    = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
    'FINS' ;
*
    TET1 = WTAB.'TET1' ;
    'SI' ('EGA' ('TYPE' TET1) 'CHPOINT');
      TET1 ='CHAN' 'CHAM' TET1 WTAB.'MO_TOT' 'STRESSES' 'TEMPERATURES' ;
    'FINS';
    ETT0  = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
    WTAB.'ETHER1' = ETT0 - WTAB.'ETREF' ;
*
    'SI' WTAB.'POR1';
      WTAB.'MSRTHER1'= PAS_EPTH PRECED WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
    'FINS' ;
  'FINS' ;
'FINS' ;

**************************   II PARTIE  *************************
******************************************************************
******************* boucle sur les pas de temps  *****************
******************************************************************
* ------------quelques initialisations de l'algorithme
IPAS  = 0 ;
IAUTO = 1 ;
ISAUV = VRAI;
DTV   = ('EXTR' WTAB.'TEMPS_CALCULES' 1) - TEMP0 ;
'SI' ( DTV '<' 1.e-15 );
  'SI' WTAB.'FREQUENTIEL' ;
    DTV = 1.e-14 ;
  'SINON' ;
    DTV =('EXTR' WTAB.'TEMPS_CALCULES' 2) - TEMP0 ;
  'FINSI';
'FINSI';
* Pour l'option PAS_AJUSTE
DT_AVANT = DTV ;
IREREDU  = VRAI;
PASFINAL = 0 ;
*-----------------------------------------------------------------------
*              Debut de la boucle sur les pas de temps
*-----------------------------------------------------------------------
'REPETER' BEXTERN  ;
*
* ----- Determiner le nouvel instant a calculer TI
*
  TEMP0 = conti.'TEMPS' ;
  NPAS  = 'DIME' WTAB.'TEMPS_CALCULES';
  ICHG  = WTAB.'ICHG'; ICHG = ICHG + 1; WTAB.'ICHG' = ICHG;
  'SI' ( ICHG '>' NPAS) ; 'QUITTER' BEXTERN; 'FINSI';
  TI = 'EXTRAIRE'  WTAB.'TEMPS_CALCULES' ICHG ;
  ITERTPS = (TI '<' TEMP0 ) ;
  'SI' ('NON' WTAB.'FREQUENTIEL') ;
    ITERTPS = ITERTPS 'OU' (TI 'EGA' PRECED.'TEMPS'. 0) ;
    'SI' ('NON' WTAB.'REEQUILIBRAGE') ;
      ITERTPS = ITERTPS 'OU' ('EGA' TI TEMP0) ;
    'FINSI';
  'FINSI';
  'SI' ITERTPS ;
    'ITERER' BEXTERN ;
  'FINSI';
*
* ----- Ajustement du pas en fonction du nb d iteration du pas precedent
*
  'SI' WTAB.'PAS_AJUSTE';
    PASFINAL=PASFINAL+1;
    TIV=TI;
    DTV=DT_AVANT;
    'SI' WTAB.'CONV';
      'SI' (WTAB.'NOMBRE_ITERATIONS' > 20);
        DTV=DTV'/' (2. ** 0.5);
      'FINSI';
      'SI' (WTAB.'NOMBRE_ITERATIONS' <  7);
        'SI' IREREDU;
          DTV=DTV '*' (2. ** 0.5);
        'FINSI';
      'FINSI';
      DT_AVANT= DTV;
      IREREDU=VRAI;
    'SINON';
      DTV=0.0000000001D0* DT_AVANT;
      DT_AVANT= DT_AVANT /2.;
      IREREDU=FAUX;
    'FINSI';
    TTI = DTV* 1.0000000001 + TEMP0;
    'SI' ( TTI '<EG' TIV );
      TI=TTI;
      PASFINAL=0;
    'FINSI';
    'SI' (PASFINAL '>EG' 1.5) ; 
      DT_AVANT = TI-TEMP0; 
    'FINSI';
  'FINSI';
*
  estim.'TEMPS' = TI;
  WTAB.'DT'     = TI '-' TEMP0 ;
  'SI'((WTAB.'CONSOLIDATION' 'OU' WTAB.'DYNAMIQUE') 'ET' (WTAB.'DT' 'EGA' 0.));
    WTAB.'DT' = WTAB.'DTPREC' ;
    'ITERER' BEXTERN;
  'FINSI';
*
* ----- Compteur IPAS des pas de temps calcules
  IPAS = IPAS + 1;
  WTAB.'PAS'=IPAS;

* ----- Mise a jour du modele si chargement de type MODE :
  'SI' WTAB.'CHAR_MODE' ;
    MOD1P     =  WTAB.'MODELE' ;
    MODEVOL1  = 'TIRE' PRECED.'MODELE' 'MODE' TI ;
    WTAB.'MODELE' = MODEVOL1 ;

    'SI' WTAB.'CHAR_MATE' ;
      MATEVOL1  = 'TIRE' PRECED.'CARACTERISTIQUES' 'MATE' TI ;
      WTAB.'CARACTERISTIQUES' = MATEVOL1 ;
    'FINSI' ;

    PAS_MODL PRECED ;

*   MaJ table rayonnement :
    'SI' WTAB.'RAYO' ;
      WTAB.'RAYONNEMENT' = 'PRRA' WTAB.'MOD_RAY' ;
    'FINSI' ;

*   On sauvegarde les modeles successifs pour analyse resultats :
    ESTIM.'MODELES' = WTAB.'MODELE' ;

*   Initialisation TINI si thermique :
    'SI' WTAB.'THE1' ;
      MODX      = WTAB.'MOD_COND' ;
      MODXP     = MOD1P 'EXTR' 'MATE' 'CONDUCTION' ;
      GEO1      = MODX  'EXTR' 'MAIL' ;
      GEO1P     = MODXP 'EXTR' 'MAIL' ;
      DGEO1     = GEO1  'DIFF' GEO1P ;

*     Adapation du modele : transport de la solution
      'SI' ((WTAB.'ADAP_MODE') 'ET' ('NON' (TI '<' (WTAB.'TPS1_ADAP')))) ;
        mess '*****  Transport solution adaptation' ;
        IADAP1    = (WTAB.'INDI_ADAP') + 1 ;
        'SI' (IADAP1 '<EG' ('DIME' (WTAB.'LTPS_ADAP'))) ;
          WTAB.'TPS1_ADAP' = WTAB.'LTPS_ADAP' 'EXTR' IADAP1 ;
          WTAB.'INDI_ADAP' = IADAP1 ;
        'SINON' ;
          WTAB.'TPS1_ADAP' = 'MAXI' WTAB.'TEMPS_CALCULES' + 1. ;
        'FINSI' ;

*       Projection du champ de temperature sur la partie adaptee :
        DGEO1P    = DGEO1 'INTE' GEO1P ;
        DGEO2P    = (DGEO1 'INTE' GEO1) 'INCLU' DGEO1P 'VOLU' 'BARY'  ;
        CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
        CHAMT1P   = 'CHAN' 'CHAM' DGEO1P CHT1P ;
        CHT2P     = 'PROI' CHAMT1P  DGEO2P ;
        CHT1P     = ('REDU' CHT1P (GEO1P 'DIFF' DGEO1P)) 'ET' CHT2P ;
        CONTI.'TEMPERATURES' = CHT1P ;

*       Calcul de la capacite courante sur la partie adaptee :
        DMODX     = 'REDU' MODX DGEO2P ;
        DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
        DMATX     = 'VARI' 'NUAG' DMODX DMATX CHT2P ;
        CAPAX     = 'CAPA' DMODX DMATX ;
        CAPA1P    = ('REDU' (WTAB.'CAPA_COURANTE') (GEO1P 'DIFF' DGEO1P)) 'ET' CAPAX ;
        WTAB.'CAPA_COURANTE' = CAPA1P ;
             
        DGEO1     = (DGEO1 'INTE' GEO1) 'DIFF' DGEO2P ;
      'FINSI' ;

*     Calcul temperature dans partie apportee du modele :
      'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
*       Quantite de chaleur sur geometrie GEO1P :
        CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
        CAPA1P    = WTAB.'CAPA_COURANTE' 'LUMP' ;
        CHQ1P     = CAPA1P * CHT1P ;
*       Quantite de chaleur dans apport :
        DMODX     = 'REDU' MODX DGEO1 ;
        DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
        CHTINIX   = DMATX 'EXCO' 'TINI' 'T' ;
        CHTINIX   = 'CHAN' 'CHPO' CHTINIX DMODX 'MOYE' ;
        DMATX     = 'VARI' 'NUAG' DMODX DMATX CHTINIX ;
        CAPAX     = ('CAPA' DMODX DMATX) lump ;
        CHQX      = CAPAX * CHTINIX ;
*       Calcul T sur GEO1 :
        CAPA1     = CAPA1P et CAPAX ;
        CHTX1     = 'MANU' 'CHPO' GEO1 1 'T' 1. 'NATURE' 'DIFFUS' ;
        CHQX1     = CAPA1 * CHTX1;
        CHT1      = (CHQ1P + CHQX) * ('INVE' CHQX1) ('MOTS' 'Q') ('MOTS' 'Q') ('MOTS' 'T') ;
        CHT1      = CHT1 'CHAN' 'ATTRIBUT' 'NATURE' 'DIFFUS' ;
*        CHT1      = reso CAPA1 (CHQ1P + CHQX) ; comm plus lent avec RESO ;
        CONTI.'TEMPERATURES' = CHT1 ;

        CHTAPP1  = CHT1 'EXCO' 'T' 'TAPP' ;
        IND1     = 'DIME' PRECED.'TEMPERATURES_APPORT' ;
        ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
      'SINON' ;
        IND1     = 'DIME' PRECED.'TEMPERATURES_APPORT' ;
        CHTAPP1  = PRECED.'TEMPERATURES_APPORT' . (IND1 - 1) ;
        ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
      'FINSI' ;

*   Finsi formulation thermiquue
    'FINSI' ;

*   Initialisation PROPORTIONS_PHASES si metallurgie :
    'SI' WTAB.'FOR_METALLU' ;
      MODX      = WTAB.'MODELE' 'EXTR' 'FORM' 'METALLURGIE' ;
      MODXP     = MOD1P         'EXTR' 'FORM' 'METALLURGIE' ;
      GEO1      = MODX  'EXTR' 'MAIL' ;
      GEO1P     = MODXP 'EXTR' 'MAIL' ;
      DGEO1     = GEO1 'DIFF' GEO1P ;
      'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
        CHMET0    = CONTI.'PROPORTIONS_PHASES' ;
        DMODX     = 'REDU' MODX DGEO1 ;
        CHMET1    = 'ZERO' DMODX 'VARINTER' ;
        LISCO     = 'EXTR' DMODX 'VARI' ;
        CMP1      = 'EXCO' CHMET1 ('EXTR' LISCO 1) ('EXTR' LISCO 1) ;
        CHMET1    = CHMET1 + (CMP1 + 1.D0);
        CHMET1    = CHMET0 'ET' CHMET1 ;
        CONTI.'PROPORTIONS_PHASES' = CHMET1 'REDU' MODX ;
      'FINSI' ;
    'FINS' ;

*   Initialisation MECA si besoin :
    'SI' WTAB.'FOR_MECA' ;
      MODM1    = 'VIDE' 'MMODEL' ;
      MODM1P   = 'VIDE' 'MMODEL' ;
      'SI'  WTAB.'MEC1' ;
        MODM1    = MODM1 'ET' WTAB.'MOD_MEC' ;
        MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'MECANIQUE') ;
      'FINSI' ;
      'SI'  WTAB.'POR1' ;
        MODM1    = MODM1 'ET' WTAB.'MOD_POR' ;
        MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'POREUX') ;
      'FINSI' ;
      'SI' ('NON' ('VIDE' MODM1)) ;
        GEOM1    = 'EXTR' MODM1  'MAIL' ;
        GEOM1P   = 'EXTR' MODM1P 'MAIL' ;
        DGEOM1   = GEOM1 'DIFF' GEOM1P ;
        'SI' ('NON' (('VIDE' DGEOM1) 'OU' ('VIDE' (DGEOM1 'INTE' GEOM1)))) ;
          DMODM1   = 'REDU' MODM1 DGEOM1 ;

*         Mise a jour ETREF :
          TREF1    = 'EXCO' WTAB.'CARACTERISTIQUES' 'TREF' 'T' ;
          WTAB.'TEMPERATURE_REFERENCE' = 'CHAN' 'STRESSES' MODM1 TREF1 'TEMPERATURES' ;
          WTAB.'ETAT_REF'= PAS_ETAT PRECED TEMP0 'T_REFERENCE' ;
          WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF'   ;
          DETREF1  = 'EPTH' DMODM1 WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
          WTAB.'ETREF' = WTAB.'ETREF' 'ET' DETREF1 ;

*         Mise a jour ETHER1 :
          'SI' ('NON' ('EXIS' PRECED.'CHARGEMENT' 'TAPP')) ;
            'ERREUR' '***** Il manque la donnee du chargement TAPP !' ;
          'FINSI' ;
          TET1     = ('TIRE' PRECED.'CHARGEMENT' 'TAPP' TI) 'EXCO' 'TAPP' 'T' ;
          ETAT1    = PAS_ETAT PRECED TI ;
          MAT1     = PAS_MATE PRECED ETAT1 ;
          DETHER1  = ('EPTH' DMODM1 MAT1 TET1) - DETREF1 ;
          WTAB.'ETHER1' = WTAB.'ETHER1' 'ET' DETHER1 ;

*         Mise a jour deplacements et deformations :
          DEPDGEO1 = ('EXCO' ETAT1 ('EXTR' DMODM1 'DEPL')) 'CHAN' 'CHPO' DMODM1 ;
          DEPSL1   = ('EPSI' DMODM1 DEPDGEO1) - DETHER1 ;

*         Mise a jour table estimation :
          estim.DEPLACEMENTS               = conti.DEPLACEMENTS 'ET' DEPDGEO1 ;
          estim.CONTRAINTES                = conti.CONTRAINTES  'ET' ('ZERO' DMODM1 'CONTRAIN') ;
          estim.VARIABLES_INTERNES         = conti.VARIABLES_INTERNES  'ET' ('ZERO' DMODM1 'VARINTER') ;
          estim.DEFORMATIONS_INELASTIQUES  = conti.DEFORMATIONS_INELASTIQUES  'ET' ('ZERO' DMODM1 'DEFINELA') ;
          estim.DEFORMATIONS               = conti.DEFORMATIONS 'ET' ('ZERO' DMODM1 'DEFORMAT') ;
          estim.DEFORMATIONS_APPORT        = conti.DEFORMATIONS_APPORT 'ET' DEPSL1 ;

*         Correction deformation apport avec CHAR_DEFI :
          CGDEFAP1 = 'CHAR' 'DEFI' (-1. * (estim.DEFORMATIONS_APPORT)) ;
          WTAB . 'CHARGEMENT' = WTAB . 'CHARGEMENT_I' 'ET' CGDEFAP1 ;
          'SI' ('NON' WTAB.CHAR_DEFI) ;
            WTAB.CHAR_DEFI = VRAI ;
            WTAB.DEFOR1    = 'ZERO' MODM1 'DEFORMAT' ;
          'FINSI' ;
        'FINSI' ;

      'SINON' ;
          estim.DEFORMATIONS_APPORT      = conti.DEFORMATIONS_APPORT ;

      'FINSI' ;
    'FINSI' ;

* Fin traitement CHAR_MODE
  'FINSI' ;
*
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  I_BOTH = 0 ;
  'REPETER' BO_BOTH WTAB.'BOU_METH' ;
    I_BOTH = I_BOTH + 1 ;
*
*   Re-initialisation de WTAB.'CHARGEMENT' en tete de boucle mec-ther
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
      WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT_I' ;
    'FINSI';
*
*   ####################################################################
*   ########### RESOLUTION D'UN PAS SI THERMIQUE/DIFFUSION #############
*   ####################################################################
    'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF') ;
*
*     Se placer dans la configuration adequate
      'SI' WTAB.'FOR_MECA' ;
        'SI' (I_BOTH > 1) ;
          'SI' WTAB.'GRANDS_DEPLACEMENTS' ;
            WTAB.'RECARI'   = VRAI ;
            WTAB.'REA_GEOM' = VRAI ;
            'FORM' WTAB.'FOR' ;
          'FINSI';
        'SINON' ;
          'FORM' WTAB.'GE0_DEB' ;
        'FINSI' ;
      'FINSI' ;
*
      'SI' (TI 'NEG' TEMP0);
        WTAB.'TEM_CALC' = 'PROG' TI;
        'SI' ('EXISTE' PRECED 'PAS_MAX');
          'SI' ((TEMP0 + PRECED.'PAS_MAX') '<' TI);
            WTAB.'TEM_CALC' = 'PROG' TEMP0 'PAS' PRECED.'PAS_MAX' TI ;
            WTAB.'TEM_CALC' = 'ENLE' WTAB.'TEM_CALC' 1;
          'FINSI';
        'FINSI';

*       Mise a jour blocages passes dans chargement
*       -> ISO AVANT MAIS A FAIRE A CHAQUE FOIS SI DEPEND DE LA MECA ??
        'SI' ('EGA' I_BOTH 1) ;
*         Cas BLOCAGES_THERMIQUES (BLOT) :
          'SI' WTAB.'CHAR_BLOT' ;
            BLOT1 = 'TIRE' PRECED.'BLOCAGES_THERMIQUES' 'BLOT' TI ;
            WTAB.'BLOCAGES_THERMIQUES' = BLOT1 ;
          'FINSI' ;
*
*         Cas BLOCAGES_DIFFUSIONS (BLOD) :
          'SI' WTAB.'CHAR_BLOD' ;
            BLOD1 = 'TIRE' PRECED.'BLOCAGES_DIFFUSIONS' 'BLOD' TI ;
            WTAB.'BLOCAGES_DIFFUSIONS' = BLOD1 ;
          'FINSI' ;
        'FINSI' ;
*
* ----- Appel a la procedure thermique (lineaire ou nonlineaire) ----
*
        'SI' ('NON' WTAB.'COUPLAGE'); 'MENAGE'; 'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'NONLINEAIRE');
          CHTER = TRANSNON PRECED;
        'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'LINEAIRE');
          CHTER = TRANSLIN PRECED;
        'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
          WTAB.'NOUV_PAS' = ('EXTR' WTAB.'TEM_CALC' 1) - TEMP0;
          CHTER = DUPONT2 PRECED;
        'FINSI';
*
*       Verification d'une erreur en sortie
        'SI' CHTER.'ERREUR';
          'ERREUR' ' ';
        'FINSI';
*
*       Se placer sur la configuration de reference (appel proc ut.)
        'FORM' WTAB.'FOR0' ;
*
*        Reevaluation des donnees du calcul dependant de la temperature
        'SI' WTAB.'PROCEDURE_REEV_THE' ;
          REEV_THE PRECED  1 ;
        'FINSI' ;
      'FINS';
*
    'FINSI' ;
*   ####################################################################
*   ###### RESOLUTION D'UN PAS SI MECANIQUE/MECANIQUE DES FLUIDES ######
*   ####################################################################
    'SI' (WTAB.'FOR_MECA' 'OU' WTAB .'NVSTNL') ;
      'SAUT' 1 'LIGN';
      'MESSAGE' ' Numero du pas : ' IPAS '  Indice d evolution : ' ICHG ' -> temps :' TI;
*
*     Se placer sur la configuration de debut de pas
      'FORM' WTAB.'GE0_DEB' ;
*
      'MENA' ;
      IERRMEC = UNPAS PRECED;
*
*     Se placer sur la configuration de reference
      'FORM' WTAB.'FOR0' ;
*
*     Test si on a converge
      'SI' IERRMEC ;
        'ERREUR' 997 ;
      'FINSI';
*
*     Reevaluation des donnees du calcul dependant de la mecanique
      'SI' WTAB.'PROCEDURE_REEV_MEC' ;
        REEV_MEC PRECED 1;
      'FINSI' ;
*
    'FINSI';
*   ####################################################################
*   ############ TEST DE LA CONVERGENCE MECANIQUE THERMIQUE ############
*   ####################################################################
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
*      je cherche la convergence thermo-mecanique : je dois au moins
*      calculer deux fois mon probleme
      WTAB.'CONV_THMEC' = FAUX ;
      'SI' (I_BOTH > 1) ;
*       Test sur toutes les composantes (notamment, si DIFFUSION)
        CHT1     = WTAB.'THER_COURANT' ;
        DUABS2   = 'ABS' (WTAB.'THER_COURANTP' - CHT1) ;
        CRICOH1  = 0. ;
        NBINCO1  = 'DIME' WTAB.'PRIM_TOT' ;
        'REPE' BINCO1 NBINCO1 ;
          LINCOI1  = 'MOTS' ('EXTR' WTAB.'PRIM_TOT' &BINCO1) ;
          MDUABSI1 = 'MAXI' DUABS2 'AVEC' LINCOI1 ;
          NORMI1   = 'MAXI' 'ABS' CHT1 'AVEC' LINCOI1 ;
          'SI' (NORMI1 '<EG' (1.E-14 * MDUABSI1)) ;
            NORMI1 = 1. ;
          'FINS' ;
          CRICOHI1 = MDUABSI1 / NORMI1 ;
          'SI' (CRICOHI1 '>' CRICOH1) ;
            CRICOH1  = CRICOHI1 ;
         'FINS' ;
        'FIN' BINCO1 ;
        
        WTAB.'CONV_THMEC' = CRICOH1 '<' (WTAB . 'CRITERE_COHERENCE') ;
*       Fin de boucle Si ne converge Pas
        'SI'('NON' WTAB.'CONV_THMEC') ;
          'SI' (I_BOTH >EG WTAB.'BOU_METH');
            'MESS' 'PAS DE COHERENCE TROUVEE MECANIQUE THERMIQUE' ;
            'ERREUR' 999;
          'FINSI' ;
        'FINSI' ;
      'FINSI' ;
*     THER_COURANTPrecedent dans WTAB pour test CONVERGENCE_MEC_THE
      WTAB.'THER_COURANTP' = WTAB.'THER_COURANT' ;
    'FINSI' ;
*
    'SI' WTAB.'CONV_THMEC' ;
      'QUITTER' BO_BOTH ;
    'FINSI' ;
*
  'FIN' BO_BOTH ;
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
* ----------------------------------------------------------------------
*       Mise a jour de quantites de WTAB a partir de celles a TI
* ----------------------------------------------------------------------
*
* Formulation THERMIQUE
  'SI' WTAB.'FOR_THER';
    'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
      WTAB.'TET0'              = estim.'TEMPERATURES' ;
      WTAB.'VIEUXPAS'          = WTAB.'NOUV_PAS' ;
      WTAB.'RELAXATION_DUPONT' = CHTER.'RELAXATION_DUPONT';
    'FINSI';
  'FINSI' ;

* Cas du modele THERMOHYDRIQUE BETON_THM (Sciume) : mise a jour des variables internes
  ITHM1=WTAB.'THM1';
  'SI' ITHM1;
         'SI' ('EXIS' WTAB 'VAR_THM1') ;
         WTAB . 'VAR_THM1' = WTAB . 'VAR_THM2' ; 
         'FINS';
  'FINS';  
  
*
* Formulation MECANIQUE
  'SI' WTAB.'FOR_MECA' ;
*
    'SI' WTAB.'ITHER' ;
      WTAB.'TET1'   = WTAB.'TET2';
      WTAB.'ETHER1' = WTAB.'ETHER2';
      'SI' WTAB.'POR1';
        WTAB.'MSRTHER1'= WTAB.'MSRTHER2';
      'FINSI';
    'FINSI' ;
*       
* Cas du modle VISCOPLASTIQUE BETON_THM (Sciume)
    'SI' WTAB.'BETON_THM';
       WTAB.'BETON_MCR1' =  WTAB.'BETON_MCR2';
    'FINS' ; 
*
    'SI' WTAB.'CHAR_DEFI' ; 
      WTAB.'DEFOR1' = WTAB.'DEFOR2';
    'FINSI';
*
    'SI' WTAB.'DYNAMIQUE' ;
      'SI' ('NON' WTAB.'LIAISON_PERSISTANTE') ;
        WTAB.'FREA1' = WTAB.'FOPL' ;
      'FINSI';
      WTAB.'REAPREC' = estim.'REACTIONS';
    'FINSI';
*
*   Actualiser la configuration de debut de pas
    'SI' ( WTAB.'GRANDS_DEPLACEMENTS' 'OU'
          (WTAB.'FEFP_FORMULATION' 'ET' WTAB.'UPDATE_LAGRANGIAN')) ;
      WTAB.'GE0_DEB' = WTAB.'FOR' ;
    'FINSI';
*
  'FINSI';
*
* Option AUTOMATIQUE : temps effectivement calcule
  'SI' (WTAB.'AUTOMATIQUE' 'OU' ('NON' WTAB.'CONV'));
    TEMP0 = (TI '-' TEMP0) '*' WTAB.'AUTOCOEF' '+' TEMP0;
    estim.'TEMPS' = TEMP0 ;
    MSGZ = 'CHAI' ' Temps effectivement calcule';
    'SI' ('NON' WTAB.'CONV');
      MSGZ = 'CHAI' MSGZ ' et non converge';
    'FINSI';
    'MESS' MSGZ ' : 'TEMP0;
  'FINSI';

* Procedure utilisateur
  'SI' WTAB.'FOR_MECA' ;
    'SI' WTAB.'PROCEDURE_PERSO1' ;
      PRECED.'PERSO1_APPEL' = 2 ;
      PERSO1 PRECED;
      'SI' ('EXIS' PRECED 'ARRET') ;
        WTAB.'ARRET' = PRECED.'ARRET' ;
      'FINSI' ;
    'FINSI';
*
*   Redefinir WTAB.'CHARGEMENT_I'
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
      WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT' ;
    'FINSI';
  'FINSI';
*
* pour ne pas sauvegarder la matrice de raideur si on doit la recalculer
  'SI' ('EXIS' WTAB 'RRRR') ;
    'SI' WTAB.'RECARI' ;
      'OUBL' WTAB 'RRRR' ;
    'FINSI';
  'FINSI';
*
* ----------------------------------------------------------------------
*        Remplir CONTINUATION et table de resultats + sauvegarde
* ----------------------------------------------------------------------
  ISAUV = PAS_RESU iauto PRECED ;
*
* Option AUTOMATIQUE
  'SI' WTAB.'AUTOMATIQUE'; 
    'SI' ((WTAB.'AUTOCOEF' 'EGA'  0.9999999D0) 'OU' (TEMP0 '>EG' TI)) ;
      'MESS' ' Objectif atteint '; 'MESS' ' ';
      WTAB.'AUTODEUX' = FAUX ;
      WTAB.'AUTORED1' = 0 ;
      WTAB.'AUTOREDU' = 1. ;
      IAUTO = 1;
    'SINON';
      'MESS' ' Objectif non atteint: On recommence'; 'MESS' '  ';
      IAUTO = IAUTO+1;
      'SI' (IAUTO >EG WTAB.'AUTOPAS');
        'ERREUR' 1000;
*       'MESS' 'Pilotage non converge  apres ' IAUTO ' pas.';
      'FINSI';
      WTAB.'AUTODEUX'=VRAI;
      ICHG=ICHG - 1; WTAB.'ICHG' = ICHG ;
    'FINSI';
  'FINSI';
*
* Option PAS_AJUSTE
  'SI' WTAB.'PAS_AJUSTE';
    'SI' ((TI < TIV) 'OU' ('NON' WTAB.'CONV')); 
      ICHG=ICHG-1; WTAB.'ICHG' = ICHG ;
    'FINSI';
  'FINSI';
*
  'SI' WTAB.'ARRET';
    'QUITTER' BEXTERN;
  'FINSI';
*
'FIN' BEXTERN;
*-----------------------------------------------------------------------
*              Fin de la boucle sur les pas de temps
*-----------------------------------------------------------------------
'SI' ('NEG' WTAB.'AMORTISSEMENT' 'INCONNU');
  WTAB.'AMORTISSEMENT' = TOTO ;
'FINSI';
*
'SI' ('NEG' ('TYPE'  WTAB.'GE0_DEB') 'MOT') ;
  'OUBL' WTAB 'GE0_DEB' ;
'FINSI' ;
*
* pour forcer le calcul de la rigidite si on  rappele  pasapas
'SI' ('EXIS' WTAB 'RRRR') ;
  'OUBL' WTAB 'RRRR';
'FINSI';
*
* on tue WTAB.'MAT1' s'il existe car il peut etre tres gourmand en place
WTAB.'MAT1' = 'MOT' 'INCONNU';
*
'MESS' ' ';
'MESS'
'------------------- FIN DE LA PROCEDURE PASAPAS ---------------------';
'SAUT' 1 'LIGNE';
************************************************************************
'FINPROC' PRECED ;