Sources Esope | Cast3M

tcoq8
C TCOQ8     SOURCE    OF166741  23/12/04    21:15:10     11800          
 
C=======================================================================
C=                            T C O Q 8                                =
C=                            ---------                                =
C=                                                                     =
C=  Fonction :                                                         =
C=  ----------                                                         =
C=   Acquisition des caracteristiques d'integration aux noeuds, aux    =
C=   points d'integration (Gauss) ou au centre de gravite pour         =
C=   l'element thermique coque COQ8.                                   =
C=                                                                     =
C=  Parametres :  (E)=Entree  (S)=Sortie                               =
C=  ------------                                                       =
C=   ISUPTH  (E)   Indique le support d'integration demande            =
C=   IPINTE  (S)   Pointeur sur le segment MINTE associe (ACTIF en S)  =
C=======================================================================
 
      SUBROUTINE TCOQ8 (ISUPTH,IPINTE)
 
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8 (A-H,O-Z)
 
-INC SMINTE
 
      PARAMETER ( O0 = 0.D0, O1 = 1.D0, O5 = 0.5D0, O25 = 0.25D0 )
      PARAMETER ( XE  = 0.577350269189625764509148780501957D0 )
      PARAMETER ( XI  = 0.774596669241483377035853079956479D0 )
      PARAMETER ( XI2 = 0.55555555555555555555555555555555D0 )
      PARAMETER ( ETE = 0.88888888888888888888888888888888D0 )
      PARAMETER ( XI3 = XI2*XI2 )
      PARAMETER ( ET2 = ETE*ETE )
      PARAMETER ( XIET = XI2*ETE )
 
      NBNO = 8                                                                 
      IF      (ISUPTH.EQ.1) THEN
        NBPGAU = 8
      ELSE IF (ISUPTH.EQ.2) THEN
        NBPGAU = 18
      ELSE IF (ISUPTH.EQ.3) THEN
        NBPGAU = 1
      ELSE
        CALL ERREUR(5)
        RETURN
      ENDIF
      SEGINI,MINTE
 
C POIDS ET COORDONNEES DES 8 NOEUDS
      IF (ISUPTH.EQ.1) THEN
        QSIGAU(1) =  O1
        QSIGAU(2) =  O0
        QSIGAU(3) = -O1
        QSIGAU(4) = -O1
        QSIGAU(5) = -O1
        QSIGAU(6) =  O0
        QSIGAU(7) =  O1
        QSIGAU(8) =  O1
 
        ETAGAU(1) =  O1
        ETAGAU(2) =  O1
        ETAGAU(3) =  O1
        ETAGAU(4) =  O0
        ETAGAU(5) = -O1
        ETAGAU(6) = -O1
        ETAGAU(7) = -O1
        ETAGAU(8) =  O0
 
        POIGAU(1) = O5
        POIGAU(2) = O5
        POIGAU(3) = O5
        POIGAU(4) = O5
        POIGAU(5) = O5
        POIGAU(6) = O5
        POIGAU(7) = O5
        POIGAU(8) = O5
 
C POIDS ET COORDONNEES DES 18 POINTS DE GAUSS
C 2 NAPPES DE 9 POINTS DE GAUSS
      ELSE IF (ISUPTH.EQ.2) THEN
        QSIGAU(1) = -XI
        QSIGAU(2) =  O0
        QSIGAU(3) =  XI
        QSIGAU(4) = -XI
        QSIGAU(5) =  O0
        QSIGAU(6) =  XI
        QSIGAU(7) = -XI
        QSIGAU(8) =  O0
        QSIGAU(9) =  XI
 
        ETAGAU(1) = -XI
        ETAGAU(2) = -XI
        ETAGAU(3) = -XI
        ETAGAU(4) =  O0
        ETAGAU(5) =  O0
        ETAGAU(6) =  O0
        ETAGAU(7) =  XI
        ETAGAU(8) =  XI
        ETAGAU(9) =  XI
 
        POIGAU(1) = XI3
        POIGAU(2) = XIET
        POIGAU(3) = XI3
        POIGAU(4) = XIET
        POIGAU(5) = ET2
        POIGAU(6) = XIET
        POIGAU(7) = XI3
        POIGAU(8) = XIET
        POIGAU(9) = XI3
 
        DO I = 1, 9
          QSIGAU(I+9) = QSIGAU(I)
          ETAGAU(I+9) = ETAGAU(I)
          DZEGAU(I)   = -XE
          DZEGAU(I+9) =  XE
          POIGAU(I+9) = POIGAU(I)
        ENDDO
 
* POIDS ET COORDONNEES DU CENTRE DE GRAVITE
      ELSE IF (ISUPTH.EQ.3) THEN
        QSIGAU(1) = O0
        ETAGAU(1) = O0
        DZEGAU(1) = O0
        POIGAU(1) = O4
      ENDIF
 
C FONCTIONS DE FORME ET LEURS DERIVEES AU(X) NBPGAU POINT(S)
      DO I = 1, NBPGAU
        X = QSIGAU(I)
        Y = ETAGAU(I)
 
        SHPTOT(1,1,I) = -O25*(O1+X+Y)*(O1-X)*(O1-Y)
        SHPTOT(1,2,I) = O5*(O1-X*X)*(O1-Y)
        SHPTOT(1,3,I) = -O25*(O1-X+Y)*(O1+X)*(O1-Y)
        SHPTOT(1,4,I) = O5*(O1+X)*(O1-Y*Y)
        SHPTOT(1,5,I) = -O25*(O1-X-Y)*(O1+X)*(O1+Y)
        SHPTOT(1,6,I) = O5*(O1-X*X)*(O1+Y)
        SHPTOT(1,7,I) = -O25*(O1+X-Y)*(O1-X)*(O1+Y)
        SHPTOT(1,8,I) = O5*(O1-X)*(O1-Y*Y)
 
        SHPTOT(2,1,I) = O25*(O1-Y)*(X+X+Y)
        SHPTOT(2,2,I) = -X*(O1-Y)
        SHPTOT(2,3,I) = O25*(O1-Y)*(X+X-Y)
        SHPTOT(2,4,I) = O5*(O1-Y*Y)
        SHPTOT(2,5,I) = O25*(O1+Y)*(X+X+Y)
        SHPTOT(2,6,I) = -X*(O1+Y)
        SHPTOT(2,7,I) = O25*(O1+Y)*(X+X-Y)
        SHPTOT(2,8,I) = -O5*(O1-Y*Y)
 
        SHPTOT(3,1,I) = O25*(O1-X)*(X+Y+Y)
        SHPTOT(3,2,I) = -O5*(O1-X*X)
        SHPTOT(3,3,I) = O25*(O1+X)*(-X+Y+Y)
        SHPTOT(3,4,I) = -Y*(O1+X)
        SHPTOT(3,5,I) = O25*(O1+X)*(X+Y+Y)
        SHPTOT(3,6,I) = O5*(O1-X*X)
        SHPTOT(3,7,I) = O25*(O1-X)*(Y+Y-X)
        SHPTOT(3,8,I) = -Y*(O1-X)
      ENDDO
 
      IPINTE = MINTE
 
C      RETURN
      END