Sources Esope | Cast3M

noeref
C NOEREF    SOURCE    CHAT      05/01/13    01:58:11     5004
      SUBROUTINE NOEREF(XYZ,ITYP,INO)
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C
C     RECHERCHE SI LE POINT XYZ EST UN NOEUD DANS LES COORDONNEES
C       DE REFERENCE
C     INO=0  CE N EST PAS UN NOEUD
C     INO=1  C'EST UN NOEUD
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8 (A-H,O-Z)
C
      DIMENSION XYZ(3)
C
      EPS=1.D-14
C
      NDIM=2
C        ON CHERCHE SI ON A AFFAIRE    A UN NOEUD DU MAILLAGE
       ITEST=0
       INO=0
      IF(ITYP.EQ.4.OR.ITYP.EQ.6.OR.ITYP.EQ.7)THEN
C              L ELEMENT DE REFERENCE EST UN TRIANGLE
             DO 30 I=1,NDIM
             IF(ABS(XYZ(I)).LT.EPS)ITEST=ITEST+1
             IF(ABS(1.D0-XYZ(I)).LT.EPS)ITEST=ITEST+1
   30        CONTINUE
      ELSEIF(ITYP.EQ.8.OR.ITYP.EQ.11)THEN
C              L ELEMENT DE REFERENCE EST UN CARRE
             DO 35 I=1,NDIM
             IF(ABS(1.D0+XYZ(I)).LT.EPS)ITEST=ITEST+1
             IF(ABS(1.D0-XYZ(I)).LT.EPS)ITEST=ITEST+1
   35        CONTINUE
      ELSEIF(ITYP.EQ.16)THEN
C              L ELEMENT DE REFERENCE EST UN PRISME
             NDIM=3
             IF((ABS(XYZ(3)-1.D0).LT.EPS).OR.
     *                 (ABS(XYZ(3)+1.D0).LT.EPS))ITEST=ITEST+1
             DO 40 I=1,2
             IF(ABS(XYZ(I)).LT.EPS)ITEST=ITEST+1
             IF(ABS(1.D0-XYZ(I)).LT.EPS)ITEST=ITEST+1
   40        CONTINUE
      ELSEIF(ITYP.EQ.14)THEN
C              L ELEMENT DE REFERENCE EST UN CUBE
             NDIM=3
             DO 45 I=1,NDIM
             IF(ABS(1.D0+XYZ(I)).LT.EPS)ITEST=ITEST+1
             IF(ABS(1.D0-XYZ(I)).LT.EPS)ITEST=ITEST+1
   45        CONTINUE
      ELSEIF(ITYP.EQ.23)THEN
C              L ELEMENT DE REFERENCE EST UN TETRAEDRE
             NDIM=3
             DO 50 I=1,NDIM
             IF(ABS(XYZ(I)).LT.EPS)ITEST=ITEST+1
             IF(ABS(1.D0-XYZ(I)).LT.EPS)ITEST=ITEST+1
   50        CONTINUE
      ENDIF
      IF(ITEST.EQ.NDIM)INO=1
C
      RETURN
      END