Télécharger la plaquette Cast3M


fr en

Télécharger gatt.eso

Retour à la liste

Numérotation des lignes : 

gatt

  1. C GATT      SOURCE    PV        21/11/02    21:15:10     11158          
  2.        SUBROUTINE GATT(TAU,SEQUV,SIGM,SS,EPSV,VAR,XMAT,NSTRS,PHI1,
  3.      &                 PHITAU,TTAU,EPS0,VARPT)
  4. C-----------------------------------------------------------------------
  5. C                MODELE GATT_MONERIE (EF MASSIFS SEULEMENT)
  6. C           CALCUL DES VITESSES DES GRANDEURS SUIVANTES:
  7. C  - DEFORMATIONS VISCOPLASTIQUES
  8. C  - DEFORMATIONS DE DENSIFICATION ET DE GONFLEMENT
  9. C  - POROSITE ET DEFORMATION VISCOPLASTIQUE CUMULEE
  10. C-----------------------------------------------------------------------
  11. C
  12. C  ENTREES
  13. C  -------
  14. C TAU          = SOUS PAS
  15. C SEQUV        = CONTRAINTE DE VON MISES            AU DEB. DU SOUS PAS
  16. C SIGM         = (TRACE DU TENS. DES CONTRAINTES)/3 AU DEB. DU SOUS PAS
  17. C SS(NSTRS)    = CONTRAINTES DEVIATORIQUES          AU DEB. DU SOUS PAS
  18. C EPSV(NSTRS)  = DEFORMATIONS VISCOPLASTIQUES       AU DEB. DU SOUS PAS
  19. C VAR(NVARI=6) = VARIABLES INTERNES                 AU DEB. DU SOUS PAS
  20. C XMAT         = CARACTERISTIQUES THERMOMECANIQUES DU MATERIAU
  21. C PHI1         = DENSITE DE FISSION AU DEB. DU SOUS PAS
  22. C PHITAU       = DENSITE DE FISSION INSTANCIEE (A LA FIN DU SOUS PAS)
  23. C TTAU         = TEMPERATURE        INSTANCIEE (A LA FIN DU SOUS PAS)
  24. C
  25. C  SORTIES
  26. C  -------
  27. C EPS0(NSTRS)    = VITESSES DES DEFORMATIONS VISCOPLASTIQUES  +
  28. C                  VITESSES DES DEFORMATIONS DE DENSIFICATION +
  29. C                  VITESSES DES DEFORMATIONS DE GONFLEMENT
  30. C VARPT(NVARI=6) = VITESSES DES VARIABLES INTERNES
  31. C VAR(4)         = FONCTION TETA EN CAS DE COUPLAGE STATIQUE
  32. C-----------------------------------------------------------------------
  33.        IMPLICIT INTEGER(I-N)
  34.        IMPLICIT REAL*8(A-H,O-Z)
  35. C
  36.  
  37. -INC PPARAM
  38. -INC CCOPTIO
  39. -INC CCREEL
  40. C
  41.        PARAMETER (XZER=0.D0,UNTIER=0.333333333333333D0)
  42. C
  43.        DIMENSION XMAT(*),VARPT(*),EPS0(*),SS(*),EPSV(*),VAR(*)
  44.        DIMENSION EPSPRI(6),EPSPT1(6),EPSPT2(6),EPSSEC(6)
  45.        DIMENSION EPS0V(6),EPSVD(6)
  46. C
  47. C ---------- DEF. VISCOPLASTIQUE HYDROSTATIQUE
  48. C
  49.        EPSVM=UNTIER*(EPSV(1)+EPSV(2)+EPSV(3))
  50. C
  51. C ---------- DEF. VISCOPLASTIQUES DEVIATORIQUES
  52. C
  53.        DO 5 I=1,NSTRS
  54.          A=XZER
  55.          IF(I.LE.3) A=1.0D0
  56.          EPSVD(I)=EPSV(I)-A*EPSVM
  57.  5     CONTINUE
  58. C
  59. C ----------- DEFORMATION VISCOPLASTIQUE EQUIVALENTE
  60. C
  61.        EEQUV=PROCON(EPSVD,EPSVD,NSTRS)
  62.        EEQUV=SQRT(2.D0*UNTIER*EEQUV)
  63. C
  64. C ---------- POROSITE, BURNUP & FCT. DE COUPLAGE AU DEB. DU SOUS PAS
  65. C
  66.        PORO=VAR(2)
  67.        BU=VAR(3)
  68.        TETA0=VAR(4)
  69. C
  70. C ---------- PROPRIETES VISCOPLASTIQUES DU MATERIAU
  71. C
  72. C   Les 4 premieres valeurs de Xmat_OBLIGATOIRES sont YOUN,NU,RHO,ALPH
  73. C   puis R,DG,...(caract. mecaniques non lineaires obligatoires)
  74. C   La premiere valeur de Xmat_FACULTATIF est VISQ et la deuxieme en CP
  75. C   est DIM3
  76. C   puis TYPE,COMP,...(caract. mecaniques non lineaires facultatives)
  77. C
  78.         RHO  = XMAT(3)
  79.         RR   = XMAT(5)
  80.         DG   = XMAT(6)
  81.         XK1  = XMAT(7)
  82.         XM1  = XMAT(8)
  83.         Q1   = XMAT(9)
  84.         XN1  = XMAT(10)
  85.         XK2  = XMAT(11)
  86.         XM2  = XMAT(12)
  87.         Q2   = XMAT(13)
  88.         XN2  = XMAT(14)
  89.         OMEG = XMAT(15)
  90.         QQ   = XMAT(16)
  91.         HH   = XMAT(17)
  92.         BETA = XMAT(18)
  93.         XK   = XMAT(19)
  94.         XA   = XMAT(20)
  95.         Q3   = XMAT(21)
  96.         XN3  = XMAT(22)
  97.         ADEN = XMAT(23)
  98.         XKGON= XMAT(24)
  99.         RHO0 = 1.D0-XMAT(25)
  100.         BUMI = XMAT(26)
  101.         EFIS = XMAT(27)
  102.         DG0  = XMAT(28)
  103.         CR1  = XMAT(29)
  104.         CR2  = XMAT(30)
  105.         CR3  = XMAT(31)
  106.         CR   = XMAT(32)
  107.         XKP  = XMAT(33)
  108.         AP   = XMAT(34)
  109.         BP   = XMAT(35)
  110.         QP   = XMAT(36)
  111. C
  112. C ---------- TYPE = 0. COMBUSTIBLE UO2, SINON COMBUSTIBLE AFA3GLAA
  113. C
  114.         NTYPE=38
  115.         IF (IFOUR.EQ.-2) NTYPE=39
  116.         TYPE= XMAT(NTYPE)
  117. C
  118. C ---------- DYN = 0. COUPLAGE STATIQUE, SINON COUPLAGE DYNAMIQUE
  119. C
  120.         DYN = XMAT(NTYPE+2)
  121. C
  122.         IF (DYN.NE.XZER) THEN
  123.            DYN1= XMAT(NTYPE+3)
  124.            TO=DYN1
  125.            IF (TYPE.NE.XZER) THEN
  126.               DYN2= XMAT(NTYPE+4)
  127.               DYN3= XMAT(NTYPE+5)
  128.               TO1 = (DYN2 - TTAU) / DYN3
  129.               TO  = ( DYN1*(1.D0+TANH(TO1)) ) + 1.D0
  130.            ENDIF
  131.         ENDIF
  132. C
  133. C ---------- COMP = 0. COMBUSTIBLE COMPRESSIBLE, SINON INCOMPRESSIBLE
  134. C
  135.         COMP= XMAT(NTYPE+1)
  136. C
  137. C ---------- CARACTERISTIQUES VISCOPLASTIQUES DU MATERIAU
  138. C
  139.         AKP=XKP*EXP(-1.D0*QP/RR/TTAU)
  140.         WC1=1.D0+TANH((CR-CR2)/CR3)
  141.         WC1=1.D0+0.5D0*CR1*WC1
  142.         AK1=XK1*WC1*(DG**XM1)*EXP(-1.D0*Q1/RR/TTAU)
  143.         WC2=2.D0*(DG0**XM2)*(1.D0-(COS(DG/DG0)))
  144.         AK2=XK2*WC2*EXP(-1.D0*Q2/RR/TTAU)
  145.         AK3=XA*EXP(-1.D0*Q3/RR/TTAU)
  146. C
  147. C--------------------------------------------------------------------
  148. C  Fluage therm. primaire: definition de la vitesse de déform. EPSPRI
  149. C--------------------------------------------------------------------
  150.         IF (EEQUV.LT.1D-10) EEQUV=1D-10
  151.         AP1=AP-1.D0
  152.         PRIM = AKP*(SEQUV**AP1)/(EEQUV**BP)
  153.         DO 8 I=1,NSTRS
  154.            EPSPRI(I)=1.5D0*PRIM*SS(I)
  155.   8     CONTINUE
  156. C
  157. C----------------------------------------------------------------------
  158. C  Fluage therm. secondaire: definition de Ai et Bi fct. de la porosite
  159. C----------------------------------------------------------------------
  160.         EXPA1 = -1.D0/XN1
  161.         EXPAB1= 2.D0*XN1/(XN1+1.D0)
  162.         A1    = (XN1*( (PORO**EXPA1) - 1.D0 ))**(-1.D0*EXPAB1)
  163.         B1    = (1.D0+((2.D0/3.D0)*PORO))/((1.D0-PORO)**EXPAB1)
  164. C
  165.         EXPA2 = -1.D0/XN2
  166.         EXPAB2= 2.D0*XN2/(XN2+1.D0)
  167.         A2    = (XN2*( (PORO**EXPA2) - 1.D0 ))**(-1.D0*EXPAB2)
  168.         B2    = (1.D0+((2.D0/3.D0)*PORO))/((1.D0-PORO)**EXPAB2)
  169. C
  170.         IF (COMP.NE.XZER) THEN
  171.            B1 = B1 + A1/4.D0
  172.            B2 = B2 + A2/4.D0
  173.            A1 = XZER
  174.            A2 = XZER
  175.         ENDIF
  176. C-----------------------------------------------------------------------
  177. C  Fluage therm. secondaire: def. des potentiels thermodyn. PSI1 et PSI2
  178. C-----------------------------------------------------------------------
  179.         EXP1=XN1 + 1.D0
  180.         EX1 = 0.5D0*EXP1
  181.         ZZ1 =A1*(1.5D0*SIGM)**2+B1*SEQUV**2
  182.         PSI1=(AK1/EXP1)*(ZZ1**EX1)
  183. C
  184.         EXP2=XN2 + 1.D0
  185.         EX2 = 0.5D0*EXP2
  186.         ZZ2 =A2*(1.5D0*SIGM)**2+B2*SEQUV**2
  187.         zz2=min(zz2,xgrand**(1/ex2))
  188.         PSI2=(AK2/EXP2)*(ZZ2**EX2)
  189. C--------------------------------------------------------------------
  190. C  Fluage therm. secondaire: vit. de def. / mecanismes EPSPT1, EPSPT2
  191. C--------------------------------------------------------------------
  192.         EXPM1 = (XN1 - 1.D0)/2.D0
  193.         DO 10 I=1,NSTRS
  194.           IF(I.LE.3) THEN
  195.             SIG1 = 1.5D0*A1*SIGM + 3.D0*B1*SS(I)
  196.           ELSE
  197.             SIG1 = 3.D0*B1*SS(I)
  198.           ENDIF
  199.           EPSPT1(I) =0.5D0*AK1*(ZZ1**EXPM1)*SIG1
  200.  10    CONTINUE
  201. C
  202.         EXPM2 = (XN2 - 1.D0)/2.D0
  203.           EPSPT2I =0.5D0*AK2*(ZZ2**EXPM2)
  204.         DO 20 I=1,NSTRS
  205.           IF(I.LE.3) THEN
  206.             SIG2 = 1.5D0*A2*SIGM + 3.D0*B2*SS(I)
  207.           ELSE
  208.             SIG2 = 3.D0*B2*SS(I)
  209.           ENDIF
  210.           EPSPT2(I)=EPSPT2I*SIG2
  211.  20     CONTINUE
  212. C---------------------------------------------------------------------
  213. C Def. de la fonction de couplage statique entre les 2 mecanismes TETA
  214. C---------------------------------------------------------------------
  215.         GSEQ1 = B1/(B1+A1/4.D0)
  216.         GSEQ2 = 9.D0*A1/(4.D0*B1+A1)
  217.         GSEQ  = (GSEQ1*SEQUV**2.D0)+(GSEQ2*SIGM**2.D0)
  218.         GSEQUV=SQRT(GSEQ)
  219.         IF (GSEQUV.LT.1D-10) THEN
  220.           TETA  = XZER
  221.         ELSE
  222.           THERB = OMEG*(GSEQUV**(-QQ))
  223.           TT    = (TTAU-THERB)/HH
  224.           TETA  = 0.5D0*BETA*(1.D0+TANH(TT))
  225.         ENDIF
  226. C--------------------------------------------------------------------
  227. C Vit. de la fct. de couplage dynamique entre les 2 mecanismes TETAPT
  228. C--------------------------------------------------------------------
  229. C ---------- DYN = 0. couplage statique, sinon couplage dynamique
  230. C
  231.         IF (DYN.NE.XZER) THEN
  232.            IF (TETA.LT.1D-10) THEN
  233.               TETAPT = XZER
  234.            ELSE
  235.               TETAPT = ((TETA-TETA0)**2.D0) / (TO * TETA)
  236.               TETAPT =SIGN(TETAPT,TETA-TETA0)
  237.            ENDIF
  238.            TETA   = TETA0
  239.         ELSE
  240.            TETAPT = XZER
  241.         ENDIF
  242. C-----------------------------------------------------------------------
  243. C Fluage thermique secondaire: vitesse de deformation viscoplast. EPSSEC
  244. C-----------------------------------------------------------------------
  245.         IF (GSEQUV.LT.1D-10.OR.DYN.NE.XZER) THEN
  246.           DERTET2 = XZER
  247.         ELSE
  248.           DERTET1 =
  249.      &      0.5D0*BETA*QQ*OMEG*(GSEQUV**(-2.D0-QQ))/HH
  250.           DERTET2 = DERTET1*(1.D0 - (TANH(TT))**2)
  251.         ENDIF
  252.         DO 30 I=1,NSTRS
  253.           A=XZER
  254.           IF(I.LE.3) A=1.0D0
  255.           VIT = (1.D0 - TETA)*EPSPT1(I) + TETA*EPSPT2(I)
  256.           EPSSEC(I) = VIT +
  257.      &    DERTET2*(PSI2-PSI1)*(A*GSEQ2*UNTIER*SIGM + 1.5D0*GSEQ1*SS(I))
  258.  30     CONTINUE
  259. C------------------------------------------------------------------------
  260. C Viscoplast. due a l irradiation EPS0IR (en vit.)
  261. C Prise en compte de l acceleration de la viscoplast. thermique (en vit.)
  262. C EPS0 = (1+k*fit)(EPSPRI+EPSSEC) + EPS0IR
  263. C------------------------------------------------------------------------
  264.         IF (SEQUV.LT.1D-10) THEN
  265.           SIR=XZER
  266.         ELSE
  267.           SIR=SEQUV**(XN3-1.D0)
  268.         ENDIF
  269.         DO 40 I=1,NSTRS
  270.           EPS0IR = AK3*PHITAU*SIR*(1.5D0*SS(I))
  271.           EPS0V(I)=(1.D0 + XK*PHITAU)*(EPSPRI(I)+EPSSEC(I)) + EPS0IR
  272.           EPS0(I)=EPS0V(I)
  273.  40     CONTINUE
  274. C-------------------------------------------------------------------------
  275. C Vit. de def. de gonflement EPS0G et vit. de def. de densification EPS0D.
  276. C-------------------------------------------------------------------------
  277.         AMU238=238.D0
  278.         AMUO2=238.D0 + 16.D0 + 16.D0
  279.         AKBU=(AMUO2/AMU238)*EFIS/(RHO*RHO0)
  280.         BUTAU=BU+(0.5D0*AKBU*TAU*(PHI1+PHITAU))
  281.         IF(BU.GE.BUMI.OR.BUTAU.GE.BUMI) THEN
  282.           BUMAX0=60.D0*BUMI
  283.           CRIT=1.D-10
  284.           DO 50 I=1,100
  285.             BUMAX = BUMI*EXP(1.D0-(ADEN/(XKGON*BUMAX0)))
  286.             BUMAX = (0.2D0*BUMAX) + (0.8D0*BUMAX0)
  287.             TEST=ABS((BUMAX-BUMAX0)/BUMAX0)
  288.             IF (TEST.LT.CRIT) GOTO 60
  289.             BUMAX0=BUMAX
  290.  50       CONTINUE
  291.  60       CONTINUE
  292.           AA = (-1.D0*RHO0*(ADEN-(XKGON*BUMAX))) /
  293.      &           ((1.D0+ADEN)*(LOG(BUMAX/BUMI)))
  294.         ENDIF
  295.         IF(BU.LT.BUMI) EPS0D1=0.D0
  296.         IF(BU.GE.BUMI)
  297.      &    EPS0D1=-1.D0*(1.D0+(XKGON*BU))*AA*LOG(BU/BUMI)/
  298.      &      (RHO0+(AA*LOG(BU/BUMI)))
  299.         IF(BUTAU.LT.BUMI) EPS0DT=0.D0
  300.         IF(BUTAU.GE.BUMI)
  301.      &    EPS0DT=-1.D0*(1.D0+(XKGON*BUTAU))*AA*LOG(BUTAU/BUMI)/
  302.      &        (RHO0+(AA*LOG(BUTAU/BUMI)))
  303.         EPS0D=(EPS0DT-EPS0D1)/3.D0/TAU
  304.         EPS0G=XKGON*0.5D0*AKBU*(PHI1+PHITAU)/3.D0
  305.         DO 70 I=1,3
  306.           EPS0(I)=EPS0V(I)+EPS0D+EPS0G
  307.  70     CONTINUE
  308. C------------------------------------------------------------------
  309. C Vit. des var. int.: déformation viscoplast. cumulée + la porosité
  310. C                     + le taux de combustion + fct. de couplage
  311. C                     + def de densification  + def de gonflement
  312. C------------------------------------------------------------------
  313.         EPSC = PROCON(EPS0,EPS0,NSTRS)
  314.         VARPT(1) = SQRT(2.D0*EPSC/3.D0)
  315.         IF (COMP.NE.XZER) THEN
  316.            VARPT(2) = XZER
  317.         ELSE
  318.            VARPT(2) = (1.D0-PORO)*(EPS0V(1) + EPS0V(2) + EPS0V(3))
  319.            VARPT(2) = VARPT(2) + (3.D0*EPS0D)
  320.         ENDIF
  321.         VARPT(3) = 0.5D0*AKBU*(PHI1+PHITAU)
  322.         VARPT(4) = TETAPT
  323.         IF (DYN.EQ.XZER) VAR(4)=TETA
  324.         VARPT(5) = EPS0D
  325.         VARPT(6) = EPS0G
  326. C
  327.         RETURN
  328.         END
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales