Télécharger flamh.eso

Retour à la liste

Numérotation des lignes :

  1. C FLAMH SOURCE SERRE 16/07/19 21:15:01 9018
  2. SUBROUTINE FLAMH(YH2e,YO2e,YN2e,YH2Oe,YHEe,YCO2e,YCOe,
  3. & PRESe,TEMPe,
  4. & TEMPSOR,TEMPPLA,Q,
  5. & YH2SOR,YO2SOR,YN2SOR,YH2OSOR,YHESOR,YCO2SOR,YCOSOR,
  6. & DDT,iKA,iMOD,iCST,IHI)
  7. C------------------------------------------------------------------------
  8. C Modélisation d'un recombineur thermique par une approche 0D.
  9. *------------------------------------------------------------------------
  10. C
  11. C---------------------------
  12. C Parametres Entree/Sortie :
  13. C---------------------------
  14. C
  15. C E/ YH2e : flottant : Fraction massique moyenne de H2 (PAR inlet)
  16. C E/ YO2e : flottant : Fraction massique moyenne de O2 (PAR inlet)
  17. C E/ YN2e : flottant : Fraction massique moyenne de N2 (PAR inlet)
  18. C E/ YH2Oe : flottant : Fraction massique moyenne de H2O (PAR inlet)
  19. C E/ YHEe : flottant : Fraction massique moyenne de HE (PAR inlet)
  20. C E/ YCO2e : flottant : Fraction massique moyenne de CO2 (PAR inlet)
  21. C E/ YCOe : flottant : Fraction massique moyenne de CO (PAR inlet)
  22. C E/ PRESe : flottant : Pression moyenne autour du PAR (Pa)
  23. C E/ TEMPe : flottant : Température moyenne du gaz (PAR inlet, K)
  24. C /S TEMPSOR : flottant : Température moyenne du gaz (PAR outlet, K)
  25. C E/S TEMPPLA : flottant : Température moyenne des plaques du PAR (K)
  26. C /S Q : flottant : Débit dans le PAR (kg/s)
  27. C /S YH2SOR : flottant : Fraction massique moyenne de H2 (PAR outlet)
  28. C /S YO2SOR : flottant : Fraction massique moyenne de O2 (PAR outlet)
  29. C /S YN2SOR : flottant : Fraction massique moyenne de N2 (PAR outlet)
  30. C /S YH2OSOR : flottant : Fraction massique moyenne de H2O (PAR outlet)
  31. C /S YHESOR : flottant : Fraction massique moyenne de HE (PAR outlet)
  32. C /S YCO2SOR : flottant : Fraction massique moyenne de CO2 (PAR outlet)
  33. C /S YCOSOR : flottant : Fraction massique moyenne de CO (PAR outlet)
  34. C E/ DDT : flottant : Pas de temps (s)
  35. C E/ IKA : entier : Flag pour correction du coefficient d'échange
  36. C comme dans RALOC (voir fla009.eso)
  37. C E/ IMOD : entier : Modélisation du PAR (1=SIEMENS, 2=HEATER)
  38. C E/ ICST : entier : Pointeur de LISTREEL, paramètres du modèle
  39. C /S IHI : entier : Flag de convergence et gestion des erreurs
  40. C
  41. C------------------------------------------------------------------------
  42. C
  43. C Langage : ESOPE + FORTRAN 77
  44. C
  45. C----------------
  46. C Modifications :
  47. C----------------
  48. C
  49. C 2012 : F. Dabbene - mise en oeuvre du modele HEATER sur la base du
  50. C modèle SIEMENS
  51. C
  52. C------------------------------------------------------------------------
  53. IMPLICIT INTEGER(I-N)
  54. IMPLICIT REAL*8 (A-H,O-Z)
  55. -INC SMLREEL
  56. C
  57. C===============================================================
  58. C Ordre des espèces : 1 N2, 2 O2, 3 H2, 4 H2O, 5 HE, 6 CO2, 7 CO
  59. C===============================================================
  60. C
  61. real*8 xi(7),om(7)
  62. C
  63. C Description du segment de travail TRAV (initialisé ici, il est
  64. C transmis à tous les .eso du modèle (de fla001.eso à fla019.eso).
  65. C Les valeurs numériques sont celles du recombineur SIEMENS FR/1-150
  66. C Hauteur totale du recombineur = 1 m
  67. C Longueur du recombineur (Lgr) = 0.15 m
  68. C Profondeur du recombineur (W) = 0.15 m
  69. C Nombre de plaques (n) = 14
  70. C
  71. C IKALP : Flag pour correction RALOC du coefficient d'échange (=IKA)
  72. C IMODEL : Modélisation du PAR (1=SIEMENS, 2=AUTRE) (=IMOD)
  73. C E : Distance entre deux plaques (= 0.01 m)
  74. C (Lgr/(n+1), W=largeur et n=nombre de plaques)
  75. C L : Hauteur des plaques (= 0.15 m)
  76. C LCH : Hauteur de la cheminée (= 0.85 m)
  77. C DH : Diamètre hydraulique entre les plaques (= 0.01875 m)
  78. C (2EW/(E+W))
  79. C S : Surface des plaques (= 0.675 m2)
  80. C (2n*LW, n=nombre de plaques)
  81. C SP : Section de passage entrée/sortie fluide du PAR (= 0.0225 m2)
  82. C (Lgr*W)
  83. C CK : Demi somme des coefficients de perte de charge à l'entrée et à
  84. C la sortie du PAR (= 3/2)
  85. C MC : Masse des plaques (= 0.133 kg)
  86. C CPC : Chaleur spécifique des plaques (= 132.6 J/kg/K)
  87. C G : Gravité (=9.81 m/s2)
  88. C R : Constante des gaz (= 8.314 J/mol/K)
  89. C DELTAH : Energie libérée par la combustion d'un kg d'H2 (= 120 MJ/kg)
  90. C M(7) : Masse molaire des constituants du mélange (kg/mol)
  91. C ncst : Nombre de constantes du modèle (= longueur du listreel ICST)
  92. C CSTMOD : Constantes du modèle (= contenu de ICST)
  93. C CPI(7) : Chaleurs massiques des constituants (J/kg/K)
  94. C AL : Cste fonction de CP(i)
  95. C EPS_MH2 : Seuil en deça duquel on suppose que la consommation d'H2 max
  96. C est mise à 0. (kg/s)
  97. C EPS_DT : Ecart entre la température des plaques et la température du
  98. C gaz (Tc-T) en deça duquel on suppose qu'il n'y a pas
  99. C d'échange convectif (K)
  100. C EPS_CON : Critère de convergence
  101. C U : Vitesse minimale dans le PAR (= 0.01 m/s)
  102. C
  103. segment trav
  104. integer iKALP,iMODEL
  105. real*8 e,L,Lch,Dh,S,sp,Ck
  106. real*8 mc,Cpc
  107. real*8 g,R,deltah
  108. real*8 M(nbesp),cstmod(ncst)
  109. real*8 Cpi(nbesp),al
  110. real*8 eps_mh2,eps_dt,eps_con,u
  111. real*8 XH2MOY,XO2MOY,XN2MOY,XH2OMOY,PRESSION,TEMPENT
  112. real*8 XHEMOY,XCO2MOY,XCOMOY
  113. endsegment
  114. C
  115. IHI = 0
  116. MLREEL = ICST
  117. SEGACT MLREEL
  118. NCST = PROG(/1)
  119. NBESP = 7
  120. SEGINI TRAV
  121. C
  122. C------------------------------------ Remplissage du segment TRAV
  123. C
  124. C Gestion du HEATER
  125. DO 10 I1=1,NCST
  126. CSTMOD(I1) = PROG(I1)
  127. 10 CONTINUE
  128. SEGDES MLREEL
  129. C
  130. C Paramètres dépendant de la géométrie
  131. C (à changer si le PAR n'est pas un FR/1-150)
  132. IMODEL = IMOD
  133. e = 0.01D0
  134. L = 0.15D0
  135. Lch = 0.85D0
  136. Dh = 0.01875D0
  137. S = 0.675D0
  138. sp = 0.0225D0
  139. Ck = 3.D0
  140. C
  141. C Paramètres physico-chimiques
  142. C-> La capacité thermique des plaques du PAR est corrigée par CSTMOD(4).
  143. C-> Comme on ne se sert que de mc*cpc on fait porter la correction sur mc
  144. C-> (mc=5.D0 et Cpc=480.D0 soit cstmod(4)=136.0868234 ont permis de
  145. C-> valider le modele sur la base de la maquette du heater pour ERCOSAM)
  146. mc = 0.133D0 * cstmod(4)
  147. Cpc = 132.6D0
  148. g = 9.81D0
  149. R = 8.3144621D0
  150. deltah = 1.2D8
  151. M(1) = 2.D0 * 0.0140067D0
  152. M(2) = 2.D0 * 0.0159994D0
  153. M(3) = 2.D0 * 0.00100794D0
  154. M(4) = 2.D0 * 0.00100794D0 + 0.0159994D0
  155. M(5) = 0.004002602D0
  156. M(6) = 2.D0 * 0.0159994D0 + 0.0120107D0
  157. M(7) = 0.0120107D0 + 0.0159994D0
  158. C
  159. Cpi(1) = 1046.D0
  160. Cpi(2) = 942.D0
  161. Cpi(3) = 14490.D0
  162. Cpi(4) = 2014.D0
  163. Cpi(5) = 5192.D0
  164. Cpi(6) = 1117.D0
  165. Cpi(7) = 1042.D0
  166. C
  167. C Absence de réaction chimique
  168. al = 0.D0
  169. C
  170. C Transformation des fractions massiques en fractions molaires
  171. OM(1) = YN2e
  172. OM(2) = YO2e
  173. OM(3) = YH2e
  174. OM(4) = YH2Oe
  175. OM(5) = YHEe
  176. OM(6) = YCO2e
  177. OM(7) = YCOe
  178. CALL FLA013(xi,om,trav)
  179. C
  180. C Fractions molaires, pression et température à l'entrée du HEATER
  181. XN2MOY = xi(1)
  182. XO2MOY = xi(2)
  183. XH2MOY = xi(3)
  184. XH2OMOY = xi(4)
  185. XHEMOY = xi(5)
  186. XCO2MOY = xi(6)
  187. XCOMOY = xi(7)
  188. PRESSION = PRESe
  189. TEMPENT = TEMPe
  190. C
  191. iKALP = iKA
  192. C
  193. C Critère de convergence et vitesse minimale dans le PAR
  194. eps_mh2 = 1.D-10
  195. eps_dt = 1.D-3
  196. eps_con = 1.D-8
  197. u = 0.01D0
  198. C
  199. C-------------------------------- Fin Remplissage du segment TRAV
  200. C
  201. C
  202. C Limitation du pas de temps à 0.5s
  203. C (Découpage du pas de temps en sous pas de temps si trop grand)
  204. t = 0.D0
  205. HEASTOT = 0.D0
  206. HEAFTOT = 0.D0
  207. C I = 1
  208. TMAX = DDT
  209. Tc = TEMPPLA
  210. dt = 0.5D0
  211. IF (ddt .LT. dt) THEN
  212. dt = ddt
  213. ENDIF
  214. 20 CONTINUE
  215. IF (.NOT.(t.lt.tmax)) GOTO 30
  216. C
  217. C Calcul de la temperature des plaques au temps t+dt
  218. IF ((t+dt) .GE. tmax) THEN
  219. dt = tmax - t
  220. ENDIF
  221. call HEA011(TC1,HEAS,HEAF,T,DT,TC,TRAV)
  222. IF (TC1 .LT. 0.D0) THEN
  223. IHI = -100
  224. RETURN
  225. ENDIF
  226. C
  227. C Cumul de l'énergie transmise au fluide
  228. t = t + dt
  229. Tc = Tc1
  230. HEASTOT = HEASTOT + HEAS*dt
  231. HEAFTOT = HEAFTOT + HEAF*dt
  232. GOTO 20
  233. 30 CONTINUE
  234. C
  235. C Sortie lorsque le temps final est atteint
  236. HEASTOT = HEASTOT / ddt
  237. HEAFTOT = HEAFTOT / ddt
  238. C
  239. C Calcul du débit et des conditions de sortie
  240. C au temps t+dt pour la nouvelle temperature de plaques Tc
  241. C (si pb de débit négatif on sort en erreur)
  242. xmh2 = 0.D0
  243. deb = FLA015(T,TC,XMH2,TRAV)
  244. C
  245. C Température en sortie du PAR (bilan d'énergie du gaz)
  246. C (si pb de température négative on sort en erreur)
  247. IF ((TC-TEMPe).LT.EPS_DT) THEN
  248. Tgaz = TEMPe
  249. ELSE
  250. CPE = FLA003(OM,TRAV)
  251. Tgaz = TEMPe - heaftot/(cpe*deb)
  252. ENDIF
  253. C
  254. ROE = FLA001(PRESe,TEMPe,Xi,TRAV)
  255. ROS = FLA001(PRESe,Tgaz,Xi,TRAV)
  256. velocin = deb / (roe * sp)
  257. velocout = deb / (ros * sp)
  258. IF ((DEB .LT. 0.D0) .OR. (Tgaz .LT. 0.D0)) THEN
  259. IHI = -999
  260. RETURN
  261. ENDIF
  262. C
  263. YN2SOR = YN2e
  264. YO2SOR = YO2e
  265. YH2SOR = YH2e
  266. YH2OSOR = YH2Oe
  267. YHESOR = YHEe
  268. YCO2SOR = YCO2e
  269. YCOSOR = YCOe
  270. TEMPPLA = Tc
  271. Q = deb
  272. TEMPSOR = Tgaz
  273. C
  274. SEGSUP trav
  275. RETURN
  276. END
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales