Télécharger fausmp.eso

Retour à la liste

Numérotation des lignes :

fausmp
  1. C FAUSMP SOURCE CHAT 05/01/12 23:56:53 5004
  2. SUBROUTINE FAUSMP(NESP,
  3. & GAMG,ROG,PG,UNG,UTG,
  4. & GAMD,ROD,PD,UND,UTD,
  5. & YG,YD,FLU1,
  6. & CELLT)
  7. C************************************************************************
  8. C
  9. C PROJET : CASTEM 2000
  10. C
  11. C NOM : FAUSMP
  12. C
  13. C DESCRIPTION : Formulation Volumes Finis pour les Equations
  14. C d'Euler Multi-Especes relatives à un melange
  15. C de gaz ideals.
  16. C
  17. C Calcul du flux aux interfaces avec la methode
  18. C AUSM-PLUS de M.-S. Liou
  19. C
  20. C (voir:
  21. C 1) BECCANTINI, PAILLERE,
  22. C "Upwind Flux Splitting Schemes..."
  23. C RAPPORT DMT 97//268
  24. C 2) M.-S. LIOU "A sequel to AUSM: AUSM+"
  25. C JCP, 129:364:382, 1996
  26. C )
  27. C
  28. C LANGUAGE : FORTRAN 77
  29. C
  30. C AUTEUR : A. BECCANTINI DRN/DMT/SEMT/LTMF
  31. C
  32. C************************************************************************
  33. C
  34. C APPELES
  35. C
  36. C FAUSMP ------ FUAUSM
  37. C
  38. C
  39. C************************************************************************
  40. C
  41. C**** Entrées:
  42. C
  43. C NESP = nombre d'especes considérées dans les Equations
  44. C d'Euler
  45. C
  46. C GAMG, GAMD = les "gamma" du gaz (gauche et droite)
  47. C
  48. C ROG, ROD = les densités
  49. C
  50. C PG, PD = les pressions
  51. C
  52. C UNG, UND = vitesses normales
  53. C
  54. C UTG, UTD = vitesses tangentielles
  55. C
  56. C YG, YD = tables des fractiones massiques
  57. C
  58. C**** Sorties:
  59. C
  60. C FLU1 = table du flux a l'interface dans le repaire
  61. C (n,t), i.e.
  62. C (rho*un, rho*un*un + p, rho*un*ut, rho*un*ht,
  63. C rho*un*y1, ...)
  64. C
  65. C CELLT = condition de stabilité, i.e.
  66. C
  67. C dT/diamax < cellt
  68. C
  69. C************************************************************************
  70. C
  71. C HISTORIQUE (Anomalies et modifications éventuelles)
  72. C
  73. C HISTORIQUE : Créé le 30.10.2000
  74. C
  75. C************************************************************************
  76. C
  77. C N.B.: Toutes les variables sont DECLAREES
  78. C
  79. C
  80. IMPLICIT INTEGER(I-N)
  81. INTEGER NESP, I1
  82. REAL*8 GAMG,ROG,PG
  83. & ,GAMD,ROD,PD
  84. & ,GM1G,AG2,AG,UNG,UTG,MG,HTG
  85. & ,GM1D,AD2,AD,UND,UTD,MD,HTD
  86. & ,YG(*),YD(*),FLU1(*),CELLT
  87. & ,ALPHA,BETA, MPLUS, MMINUS, PPLUS, PMINUS
  88. & ,AMED, MMED, AMMED, MMEDP, MMEDM, PMED
  89. PARAMETER(ALPHA = 0.1875D0,BETA=0.125D0)
  90. C
  91. C
  92. C**** YG, YD, FLU1, déjà definis avant
  93. C
  94. C Dans le cas Euler monoespece, on doit
  95. C avoir :
  96. C YG(1) = YD(1) = 0.0D0
  97. C
  98. C
  99. C**** Etat "gauche"
  100. C
  101. C AG = vitesse du son
  102. C MG = nombre de Mach normal
  103. C HTG = enthalpie totale
  104. C
  105. GM1G = GAMG - 1.0D0
  106. AG2 = GAMG * PG/ ROG
  107. AG = SQRT(AG2)
  108. HTG = AG2 /GM1G + 0.5D0 * (UNG*UNG + UTG*UTG)
  109. C
  110. C**** Etat "droite"
  111. C
  112. C AD = vitesse du son
  113. C MD = nombre de Mach normal
  114. C HTD = enthalpie totale
  115. C
  116. GM1D = GAMD - 1.0D0
  117. AD2 = GAMD * PD/ ROD
  118. AD = SQRT(AD2)
  119. HTD = AD2 / GM1D + 0.5D0 * (UND*UND + UTD*UTD)
  120. C
  121. AMED = 0.5D0 * (AG + AD)
  122. C AMED = SQRT(AG * AD)
  123. MG = UNG / AMED
  124. MD = UND / AMED
  125. CALL FUAUSM(ALPHA,BETA,MG,MD,MPLUS,MMINUS,PPLUS,PMINUS)
  126. MMED = MPLUS + MMINUS
  127. AMMED = ABS(MMED)
  128. MMEDP = 0.5D0 * (MMED + AMMED)
  129. MMEDM = 0.5D0 * (MMED - AMMED)
  130. PMED = PG * PPLUS + PD * PMINUS
  131. C
  132. CELLT = 1.0D0/((AMMED + 1) * AMED)
  133. C
  134. C**** Le flux
  135. C
  136. FLU1(1) = AMED * ( MMEDP * ROG + MMEDM * ROD)
  137. FLU1(2) = AMED * ( MMEDP * ROG * UNG + MMEDM * ROD * UND) + PMED
  138. FLU1(3) = AMED * ( MMEDP * ROG * UTG + MMEDM * ROD * UTD )
  139. FLU1(4) = AMED * ( MMEDP * ROG * HTG + MMEDM * ROD * HTD )
  140. DO I1 = 1, NESP, 1
  141. FLU1(4+I1) = AMED * ( MMEDP * ROG * YG(I1)
  142. & + MMEDM * ROD * YD(I1))
  143. ENDDO
  144. C
  145. RETURN
  146. END
  147.  
  148.  
  149.  
  150.  
  151.  
  152.  
  153.  
  154.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales