Télécharger ecrxx.eso

Retour à la liste

Numérotation des lignes :

ecrxx
  1. C ECRXX SOURCE STRU 08/12/22 21:15:14 6246
  2. c Sous-Programme du module MISTRAL0
  3. C --------------------------------------------------------------------------
  4. SUBROUTINE ECRXX (VEPSP,VEPSE,XX, TT,EPSEQ,FI,FIT,PSI,
  5. & IXX,NXX, NDPI,NDVP, NPECRX,PECRX,PDVDI,
  6. & XXP,XXP0)
  7. C --------------------------------------------------------------------------
  8. C Calcul, pour les contraintes internes de nature IXX :
  9. C - des termes XXP(IJ,IXX) et XXP0(IJ,IXX) de l'expression suivante
  10. C des derivees par rapport au temps des contraintes internes :
  11. C dXX(IJ,IXX)/dt = XXP(IJ,IXX) + XXP0(IJ,IXX)*VEPSE(0)
  12. C en fonction :
  13. C - des vitesses de deformation VEPSP(IJ,IDP)
  14. C (si KPLAST=1, VEPSP(IJ,0) correspond a VEPSE(0)=1),
  15. C - des vitesses de deformation equivalente VEPSE(IDP),
  16. C - des contraintes internes XX(IJ,IXXP),
  17. C - de la temperature TT,
  18. C - des deformations equivalentes EPSEQ(IDP),
  19. C - du flux de neutrons rapides FI,
  20. C - de la fluence FIT et de la variable PSI de durcissement du a
  21. C l'irradiation,
  22. C - des parametres transmis dans PECRX et PDVDI.
  23. C NPECRX (incremente ici) etant en entree le nombre de ceux de PECRX
  24. C correspondant aux contraintes internes de natures IXXP < IXX.
  25. C IDP compris entre 1-NDPI et NDVP.
  26. C IXXP compris entre 1 et NXX.
  27. C --------------------------------------------------------------------------
  28. IMPLICIT INTEGER (I-N)
  29. IMPLICIT REAL*8 (A-H, O-Z)
  30. PARAMETER ( NPTTM = 5 , NPPSIM = 6 )
  31. PARAMETER ( NPEDIM = 13+6*NPTTM+NPPSIM )
  32. c (NPEDIM = 49)
  33. PARAMETER ( NVM=2 , NPATDM = 14 , NPFIM = 9 )
  34. PARAMETER ( NPERVM = 11+NVM*(NPEDIM+2*NPATDM+NPFIM+11) )
  35. c (NPERVM = 205)
  36. DIMENSION VEPSP(1:6,0:*),VEPSE(0:*),EPSEQ(0:*),XX(1:6,1:*)
  37. DIMENSION PECRX(1:*),PDVDI(1:*)
  38. DIMENSION ECXX(1:6),HM(1:6),XM(1:6),YM(1:6),SXM(1:6)
  39. DIMENSION PECDI(1:NPEDIM),PERV(1:NPERVM)
  40. DIMENSION XXP(1:6,1:*),XXP0(1:6,1:*)
  41. DO IJ = 1,6
  42. XXP(IJ,IXX) = 0.
  43. XXP0(IJ,IXX) = 0.
  44. END DO
  45. NPDVDI = NDPI+NDVP+IXX
  46. KVDI = NINT(PDVDI(NPDVDI))
  47. IF (KVDI.EQ.0) THEN
  48. PSIIXX = FIT
  49. ELSE
  50. PSIIXX = PSI
  51. END IF
  52. C -----------------------
  53. C Ecrouissage cinematique
  54. C
  55. DO IJ = 1,6
  56. ECXX(IJ) = PECRX(NPECRX+IJ)
  57. SXM(IJ) = 0.
  58. END DO
  59. NPECRX = NPECRX+6
  60. DO IDP = 1-NDPI,NDVP
  61. NPECRX = NPECRX+1
  62. NPECDI = NINT(PECRX(NPECRX))
  63. KCC = NINT(PECRX(NPECRX+1))
  64. IF (KCC.EQ.0) THEN
  65. NPECRX = NPECRX+1
  66. ELSE
  67. IF (KCC.EQ.-1) THEN
  68. NPECRX = NPECRX+2
  69. CC = PECRX(NPECRX)
  70. ELSE
  71. DO IP = 1,NPECDI
  72. PECDI(IP) = PECRX(NPECRX+IP)
  73. END DO
  74. NPECRX = NPECRX+NPECDI
  75. CALL FECRDI (TT,EPSEQ(IDP),PSIIXX, 0, PECDI,
  76. & CC,DSRDTT,DSRDEP,DSRPSI)
  77. END IF
  78. DO IJ = 1,6
  79. XM(IJ) = CC*VEPSP(IJ,IDP)
  80. END DO
  81. IF (IDP.EQ.0) THEN
  82. CALL PROMAH (ECXX,XM, YM)
  83. DO IJ = 1,6
  84. XXP0(IJ,IXX) = YM(IJ)
  85. END DO
  86. ELSE
  87. DO IJ = 1,6
  88. SXM(IJ) = SXM(IJ)+XM(IJ)
  89. END DO
  90. END IF
  91. END IF
  92. END DO
  93. CALL PROMAH (ECXX,SXM, YM)
  94. DO IJ = 1,6
  95. XXP(IJ,IXX) = YM(IJ)
  96. END DO
  97. C ----------------------
  98. C Restauration dynamique
  99. C
  100. DO IJ = 1,6
  101. HM(IJ) = PECRX(NPECRX+IJ)
  102. SXM(IJ) = 0.
  103. END DO
  104. NPECRX = NPECRX+6
  105. DO IDP = 1-NDPI,NDVP
  106. DO IJ = 1,6
  107. XM(IJ) = 0.
  108. END DO
  109. DO IXXP = 1,NXX
  110. NPECRX = NPECRX+1
  111. NPECDI = NINT(PECRX(NPECRX))
  112. KDD = NINT(PECRX(NPECRX+1))
  113. IF (KDD.EQ.0) THEN
  114. NPECRX = NPECRX+1
  115. ELSE
  116. IF (KDD.EQ.-1) THEN
  117. NPECRX = NPECRX+2
  118. DD = PECRX(NPECRX)
  119. ELSE
  120. DO IP = 1,NPECDI
  121. PECDI(IP) = PECRX(NPECRX+IP)
  122. END DO
  123. NPECRX = NPECRX+NPECDI
  124. CALL FECRDI (TT,EPSEQ(IDP),PSIIXX, 0, PECDI,
  125. & DD,DSRDTT,DSRDEP,DSRPSI)
  126. END IF
  127. DO IJ = 1,6
  128. XM(IJ) = XM(IJ)+DD*XX(IJ,IXXP)
  129. END DO
  130. END IF
  131. END DO
  132. IF (IDP.EQ.0) THEN
  133. CALL PROMAH (HM,XM, YM)
  134. DO IJ = 1,6
  135. XXP0(IJ,IXX) = XXP0(IJ,IXX)-YM(IJ)
  136. END DO
  137. ELSE
  138. DO IJ = 1,6
  139. SXM(IJ) = SXM(IJ)+XM(IJ)*VEPSE(IDP)
  140. END DO
  141. END IF
  142. END DO
  143. CALL PROMAH (HM,SXM, YM)
  144. DO IJ = 1,6
  145. XXP(IJ,IXX) = XXP(IJ,IXX)-YM(IJ)
  146. END DO
  147. C --------------------------------
  148. C Restauration statique eventuelle
  149. C
  150. NPECRX = NPECRX+1
  151. KRS = NINT(PECRX(NPECRX))
  152. IF (KRS.EQ.0) RETURN
  153. NPECRX = NPECRX+1
  154. KRS = NINT(PECRX(NPECRX))
  155. DO IJ = 1,6
  156. IF (IJ.EQ.3) THEN
  157. HM(IJ) = PECRX(NPECRX+1)
  158. & +PECRX(NPECRX+2)*EXP((PECRX(NPECRX+3)+PECRX(NPECRX+4)*TT)*TT)
  159. NPECRX = NPECRX+4
  160. ELSE
  161. NPECRX = NPECRX+1
  162. HM(IJ) = PECRX(NPECRX)
  163. END IF
  164. XM(IJ) = XX(IJ,IXX)
  165. END DO
  166. XEQ = SQRT( HM(1)*(XM(2)-XM(3))**2
  167. & + HM(2)*(XM(3)-XM(1))**2 + HM(3)*(XM(1)-XM(2))**2
  168. & + 2.*( HM(4)*XM(4)**2 + HM(5)*XM(5)**2 + HM(6)*XM(6)**2 ) )
  169. NPECRX = NPECRX+1
  170. NPERV = NINT(PECRX(NPECRX))
  171. IF (XEQ.EQ.0.D0) THEN
  172. NPECRX = NPECRX+NPERV
  173. ELSE
  174. DO IP = 1,NPERV
  175. PERV(IP) = PECRX(NPECRX+IP)
  176. END DO
  177. NPECRX = NPECRX+NPERV
  178. CALL ECOREV (XEQ,0.D0,0.D0,TT,FI,PSIIXX, PERV, XXPRS)
  179. DO IJ = 1,6
  180. XM(IJ) = XXPRS*XM(IJ)/XEQ
  181. END DO
  182. CALL PROMAH (HM,XM, YM)
  183. IF (KRS.EQ.2) THEN
  184. DO IJ = 1,6
  185. XM(IJ) = YM(IJ)
  186. END DO
  187. CALL PROMAH (ECXX,XM, YM)
  188. END IF
  189. DO IJ = 1,6
  190. XXP(IJ,IXX) = XXP(IJ,IXX)-YM(IJ)
  191. END DO
  192. END IF
  193. C ---------------------------------
  194. RETURN
  195. END
  196.  
  197.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales