Télécharger dtprec.eso

Retour à la liste

Numérotation des lignes :

  1. C DTPREC SOURCE STRU 06/12/14 21:15:10 5611
  2. c Sous-Programme du module MISTRAL1
  3. C --------------------------------------------------------------------------
  4. SUBROUTINE DTPREC (DTMI,DTMA,TMAX,
  5. & VEPSTH,VEPSEL,VEPSCR,VEPSE,EPSEQP,XXP,FI,PSIP,
  6. & VEPTHA,VEPELA,VEPCRA,VEPEA,EPSEPA,XXPA,FIA,
  7. & PSIPA, DTA,NP, NDPI,NDVP,NXX,NPSI, II, PINCR,
  8. & DT)
  9. C --------------------------------------------------------------------------
  10. C Determination du pas de temps de calcul DT en fonction :
  11. C - du minimum et du maximum imposes : DTMI et DTMA,
  12. C - de la duree maximale d'evolution consideree TMAX,
  13. C - des valeurs a l'instant t :
  14. C - des vitesses de dilatation thermique VEPSTH(IJ),
  15. C - des vitesses de deformations elastiques VEPSEL(IJ),
  16. C - des vitesses de croissance VEPSCR(IJ),
  17. C - des vitesses de deformations plastiques equivalentes VEPSE(IDP),
  18. C - des derivees des deformations plastiques equivalentes EPSEQP(IDP),
  19. C - des derivees des contraintes internes XXP(IJ,IXX),
  20. C - du flux de neutrons rapides FI,
  21. C - de la derivee PSIP de la variable de durcissement du a l'irradiation
  22. C PSI, si elle existe (NPSI>0),
  23. C - eventuellement, si NP est superieur ou egal a 1 :
  24. C - de leur valeurs a l'instant precedent : VEPTHA(IJ), VEPELA(IJ),
  25. C VEPCRA(IJ), VEPEA(IDP), EPSEPA(IDP), XXPA(IJ,IXX), FIA, PSIPA,
  26. C - de la duree DTA du pas de temps precedent,
  27. C - des increments maximaux autorises (dans PINCR) :
  28. C - des deformations de chaque nature,
  29. C - des contraintes internes,
  30. C - de la fluence de neutrons rapides,
  31. C - de PSI,
  32. C - des increments relatifs maximaux autorises (dans PINCR) :
  33. C - des vitesses de deformation de chaque nature,
  34. C - des derivees de contraintes internes,
  35. C - du flux de neutrons rapides,
  36. C - de la derivee de PSI.
  37. C --------------------------------------------------------------------------
  38. IMPLICIT INTEGER (I-N)
  39. IMPLICIT REAL*8 (A-H, O-Z)
  40. c std :
  41. PARAMETER ( NDVPMA = 4 , NXXMAX = 3 )
  42. PARAMETER ( IIMAX = 20+2*(1+NDVPMA)+6*NXXMAX )
  43. c std.
  44. DIMENSION VEPSTH(1:*),VEPSEL(1:*),VEPSCR(1:*),
  45. & VEPSE(0:*),EPSEQP(0:*),XXP(1:6,1:*),
  46. & VEPTHA(1:*),VEPELA(1:*),VEPCRA(1:*),
  47. & VEPEA(0:*),EPSEPA(0:*),XXPA(1:6,1:*)
  48. DIMENSION PINCR(1:*)
  49. c std :
  50. DIMENSION DYMA(1:IIMAX),DYPRMA(1:IIMAX),YP(1:IIMAX),YPA(1:IIMAX)
  51. c std.
  52. DO IJ = 1,6
  53. YP(IJ) = VEPSTH(IJ)
  54. YPA(IJ) = VEPTHA(IJ)
  55. DYMA(IJ) = PINCR(1)
  56. DYPRMA(IJ) = PINCR(6)
  57. END DO
  58. I = 6
  59. DO IJ = 1,6
  60. I = I+1
  61. YP(I) = VEPSEL(IJ)
  62. YPA(I) = VEPELA(IJ)
  63. DYMA(I) = PINCR(2)
  64. DYPRMA(I) = PINCR(7)
  65. END DO
  66. DO IJ = 1,6
  67. I = I+1
  68. YP(I) = VEPSCR(IJ)
  69. YPA(I) = VEPCRA(IJ)
  70. DYMA(I) = PINCR(3)
  71. DYPRMA(I) = PINCR(8)
  72. END DO
  73. DO IDP = 1-NDPI,NDVP
  74. YP(I+1) = VEPSE(IDP)
  75. YPA(I+1) = VEPEA(IDP)
  76. YP(I+2) = EPSEQP(IDP)
  77. YPA(I+2) = EPSEPA(IDP)
  78. IF (IDP.EQ.0) THEN
  79. DYMA(I+1) = PINCR(4)
  80. DYPRMA(I+1) = PINCR(9)
  81. DYMA(I+2) = PINCR(4)
  82. DYPRMA(I+2) = PINCR(9)
  83. ELSE
  84. DYMA(I+1) = PINCR(5)
  85. DYPRMA(I+1) = PINCR(10)
  86. DYMA(I+2) = PINCR(5)
  87. DYPRMA(I+2) = PINCR(10)
  88. END IF
  89. I = I+2
  90. END DO
  91. DO IXX = 1,NXX
  92. DO IJ = 1,6
  93. I = I+1
  94. YP(I) = XXP(IJ,IXX)
  95. YPA(I) = XXPA(IJ,IXX)
  96. DYMA(I) = PINCR(11)
  97. DYPRMA(I) = PINCR(12)
  98. END DO
  99. END DO
  100. I = I+1
  101. YP(I) = FI
  102. YPA(I) = FIA
  103. DYMA(I) = PINCR(13)
  104. DYPRMA(I) = PINCR(14)
  105. IF (NPSI.GT.0) THEN
  106. I = I+1
  107. YP(I) = PSIP
  108. YPA(I) = PSIPA
  109. DYMA(I) = PINCR(15)
  110. DYPRMA(I) = PINCR(16)
  111. END IF
  112. CALL PACALC (DTMI,DTMA,TMAX, I, DYMA,DYPRMA,
  113. & YP, DTA,YPA,NP, DT)
  114. RETURN
  115. END
  116.  
  117.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales