Télécharger devolu.eso

Retour à la liste

Numérotation des lignes :

devolu
  1. C DEVOLU SOURCE CHAT 05/01/12 22:46:57 5004
  2.  
  3. C=======================================================================
  4. C= D E V O L U =
  5. C= ----------- =
  6. C= Fonction : =
  7. C= ---------- =
  8. C= Calcul du volume affecte a un point de Gauss connaissant initia- =
  9. C= lement le jacobien en ce point. =
  10. C= Les derivees des fonctions de forme par rapport aux coordonnees =
  11. C= REELLES x,y,z sont aussi egalement calculees en ce point. =
  12. C= =
  13. C= Parametres : (E)=Entree (S)=Sortie =
  14. C= ------------ =
  15. C= XEL (E) Coordonnees GLOBALES des noeuds de l element =
  16. C= SHP (E/S) Valeurs des fonctions de forme et de leurs =
  17. C= derivees au point considere (point de Gauss) =
  18. C= MFR (E) Formulation associee a l'element fini =
  19. C= NBNO (E) Nombre de NOEUDS de l element fini =
  20. C= IFOU (E) Mode de calcul utilise (cf. IFOUR dans CCOPTIO) =
  21. C= NIFOU (E) Numero du mode de Fourier (si IFOU=1) =
  22. C= IDIM (E) Dimension du probleme traite (1 a 3) =
  23. C= DIM3 (E) Epaisseur dans l'hypothese des contraintes planes =
  24. C= RR (E) Rayon au point considere (axisymetrique,spherique)=
  25. C= DJac (E/S) Jacobien/Volume calcule en ce point de Gauss =
  26. C= =
  27. C= Remarque : =
  28. C= ---------- =
  29. C= Lors de l'entree dans le sous-programme, SHP(2 a 4,*) contient =
  30. C= les DERIVEES des fonctions de forme par rapport aux coordonnees =
  31. C= de REFERENCE Qsi,Eta,Dzeta. =
  32. C= En sortie du sous-programme, SHP(2 a 4,*) contient les DERIVEES =
  33. C= des fonctions de FORME par rapport aux coordonnees REELLES x,y,z. =
  34. C=======================================================================
  35.  
  36. SUBROUTINE DEVOLU (XEL,SHP,MFR,NBNO,IFOU,NIFOU,IDIM,DIM3,RR,DJAC)
  37.  
  38. IMPLICIT INTEGER(I-N)
  39. IMPLICIT REAL*8 (A-H,O-Z)
  40.  
  41. -INC CCREEL
  42.  
  43. DIMENSION XEL(3,*),SHP(6,*)
  44.  
  45. PARAMETER (XUn=1.)
  46. C= Quelques constantes (2.Pi et 4.Pi)
  47. PARAMETER (X2Pi=6.283185307179586476925286766559D0)
  48. PARAMETER (X4Pi=12.566370614359172953850573533118D0)
  49.  
  50. CALL JACOBI(XEL,SHP,IDIM,NBNO,DJAC)
  51.  
  52. RR=XUn
  53. C ===
  54. C 1 - Cas 2D CONTraintes PLANes
  55. C ===
  56. IF (IFOU.EQ.-2) THEN
  57. IF (MFR.EQ.1.OR.MFR.EQ.31) DJAC=DJAC*DIM3
  58. C ===
  59. C 2 - Cas 2D AXISymetrie et FOURier
  60. C ===
  61. ELSE IF (IFOU.EQ.0.OR.IFOU.EQ.1) THEN
  62. IF (MFR.NE.35) CALL DISTRR(XEL,SHP,NBNO,RR)
  63. IF (IFOU.EQ.0.OR.(IFOU.EQ.1.AND.NIFOU.EQ.0)) THEN
  64. DJAC=X2Pi*DJAC*RR
  65. ELSE
  66. DJAC=XPi*DJAC*RR
  67. ENDIF
  68. C ===
  69. C 3 - Cas 1D AXISymetriques
  70. C ===
  71. ELSE IF (IFOU.EQ.12.OR.IFOU.EQ.13.OR.IFOU.EQ.14) THEN
  72. CALL DISTRR(XEL,SHP,NBNO,RR)
  73. DJAC=X2Pi*DJAC*RR
  74. C ===
  75. C 4 - Cas 1D SPHErique
  76. C ===
  77. ELSE IF (IFOU.EQ.15) THEN
  78. CALL DISTRR(XEL,SHP,NBNO,RR)
  79. DJAC=X4Pi*DJAC*RR*RR
  80. ENDIF
  81.  
  82. RETURN
  83. END
  84.  
  85.  
  86.  
  87.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales