Télécharger chama2.eso

Retour à la liste

Numérotation des lignes :

  1. C CHAMA2 SOURCE FANDEUR 19/10/08 21:15:10 10329
  2.  
  3. C=======================================================================
  4. C= C H A M A 2 =
  5. C= ----------- =
  6. C= =
  7. C= Fonction : =
  8. C= ---------- =
  9. C= Calcul du MCHAML (champ par element aux noeuds) des flux nodaux =
  10. C= equivalents a des sources volumiques. Cas BIDIMENSIONNEL MASSIF =
  11. C= =
  12. C= Parametres : (E)=Entree (S)=Sortie =
  13. C= ------------ =
  14. C= IPSONO (E) Pointeur sur le segment MELVAL des SOURCES =
  15. C= IPGEOM (E) Pointeur sur un objet MAILLAGE elementaire =
  16. C= IPINTE (E) Pointeur sur un segment MINTE contenant les =
  17. C= caracteristiques d'integration =
  18. C= IPCHEQ (S) Pointeur sur un segment MELVAL contenant les =
  19. C= flux de chaleur nodaux equivalents =
  20. C= =
  21. C= Variables locales : =
  22. C= ------------------- =
  23. C= XEL(3,NBPTEL) Coordonnees GLOBALES des noeuds d'un element =
  24. C= Surf Surface elementaire au point de Gauss =
  25. C= AEL Vecteur de travail =
  26. C= =
  27. C= Denis ROBERT, le 16 fevrier 1988. =
  28. C=======================================================================
  29.  
  30. SUBROUTINE CHAMA2 (IPSONO,IPGEOM,IPINTE, IPCHEQ)
  31.  
  32. IMPLICIT INTEGER(I-N)
  33. IMPLICIT REAL*8 (A-H,O-Z)
  34.  
  35.  
  36. -INC PPARAM
  37. -INC CCOPTIO
  38. -INC CCREEL
  39.  
  40. -INC SMCHAML
  41. -INC SMELEME
  42. -INC SMINTE
  43. -INC SMCOORD
  44.  
  45. SEGMENT MMAT1
  46. REAL*8 XEL(3,NBPTEL), AEL(NBPTEL)
  47. ENDSEGMENT
  48.  
  49. C= Quelques constantes (2.Pi)
  50. PARAMETER (X2Pi=6.283185307179586476925286766559D0)
  51.  
  52. C 1 - INITIALISATION
  53. C ====================
  54. C 1.1 - Recuperation d'informations sur le maillage elementaire
  55. C =====
  56. MELEME=IPGEOM
  57. SEGACT,MELEME
  58. NBPTEL=NUM(/1)
  59. NbElt=NUM(/2)
  60. C =====
  61. C 1.2 - Recuperation d'informations sur l'element fini du maillage
  62. C =====
  63. MINTE=IPINTE
  64. C* SEGACT,MINTE
  65. NBPGAU=POIGAU(/1)
  66. C* NBNO=SHPTOT(/2)
  67. C* On doit avoir -> NBNO = NBPTEL
  68. C =====
  69. C 1.3 - Activation du MCHAML contenant les valeurs des sources
  70. C =====
  71. MELVA1=IPSONO
  72. SEGACT,MELVA1
  73. NBPTE1=MELVA1.VELCHE(/1)
  74. NEL1=MELVA1.VELCHE(/2)
  75. * IPSONO s'appuie normalement sur IPINTE
  76. * On doit avoir : NBPGAU = NBPTE1 si NBPTE1 != 1 (champ constant par element)
  77. * NEL1 = NELT si NEL1 != 1 (champ uniforme)
  78. C =====
  79. C 1.4 - Initialisation du segment de travail MMAT1
  80. C =====
  81. SEGINI,MMAT1
  82. C =====
  83. C 1.5 - Initialisation du segment resultat MELVAL contenant les valeurs
  84. C des flux nodaux pour chaque element du maillage (IPGEOM)
  85. C =====
  86. N1PTEL=NBPTEL
  87. N1EL=NbElt
  88. N2PTEL=0
  89. N2EL=0
  90. SEGINI,MELVAL
  91. IPCHEQ=MELVAL
  92.  
  93. C 2 - BOUCLE SUR LES ELEMENTS DU MAILLAGE ELEMENTAIRE IMAMOD
  94. C ============================================================
  95. DO iElt=1,NbElt
  96.  
  97. IEMIN1 = MIN(NEL1,iElt)
  98. C =====
  99. C 2.1 - Mise a zero de la source nodale equivalente AEL
  100. C =====
  101. DO iNoe = 1, NBPTEL
  102. AEL(iNoe) = XZero
  103. ENDDO
  104. C =====
  105. C 2.2 - Recuperation des coordonnees GLOBALES des noeuds de l'element
  106. C =====
  107. CALL DOXE(XCOOR,IDIM,NBPTEL,NUM,iElt,XEL)
  108. C =====
  109. C 2.3 - Boucle sur les points de Gauss de l'element iElt
  110. C =====
  111. DO iGau=1,NBPGAU
  112. C =======
  113. C 2.3.1 - Calcul du volume associe au point de Gauss iGau
  114. C Pour les elements MASSIFs, traitement du cas axisymetrique
  115. C =======
  116. S1=XZERO
  117. S2=XZERO
  118. S3=XZERO
  119. S4=XZERO
  120. DO iNoe = 1, NBPTEL
  121. S1=S1+SHPTOT(2,iNoe,iGau)*XEL(1,iNoe)
  122. S2=S2+SHPTOT(3,iNoe,iGau)*XEL(1,iNoe)
  123. S3=S3+SHPTOT(3,iNoe,iGau)*XEL(2,iNoe)
  124. S4=S4+SHPTOT(2,iNoe,iGau)*XEL(2,iNoe)
  125. ENDDO
  126. VOLU=S1*S3-S2*S4
  127. IF (IFOMOD.EQ.0) THEN
  128. CALL DISTRR(XEL,SHPTOT(1,1,iGau),NBPTEL,RR)
  129. VOLU=X2Pi*RR*VOLU
  130. ENDIF
  131. VOLU=ABS(VOLU)*POIGAU(iGau)
  132. C =======
  133. C 2.3.2 - Calcul de la contribution du point de Gauss a AEL
  134. C pour cet element (MCHAML aux noeuds)
  135. C =======
  136. IGMIN1 = MIN(iGau,NBPTE1)
  137. R_z = VOLU * MELVA1.VELCHE(IGMIN1,IEMIN1)
  138. DO iNoe = 1, NBPTEL
  139. AEL(iNoe) = AEL(iNoe) + SHPTOT(1,iNoe,iGau) * R_z
  140. ENDDO
  141. ENDDO
  142. C =====
  143. C 2.4 - Calcul des flux equivalents sur cet element (MCHAML aux noeuds)
  144. C =====
  145. DO iNoe = 1,NBPTEL
  146. VELCHE(iNoe,iElt) = AEL(iNoe)
  147. ENDDO
  148. ENDDO
  149.  
  150. C 3 - MENAGE : DESACTIVATION/DESTRUCTION DE SEGMENTS
  151. C ====================================================
  152. SEGSUP,MMAT1
  153.  
  154. C* RETURN
  155. END
  156.  
  157.  
  158.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales