Télécharger la plaquette Cast3M


fr en

Télécharger bmat28.eso

Retour à la liste

Numérotation des lignes : 

bmat28

  1. C BMAT28    SOURCE    FANDEUR   10/08/31    21:15:16     6735
  2.  
  3. C=======================================================================
  4. C=                          B M A T 2 8                                =
  5. C=                          -----------                                =
  6. C=  Fonction :                                                         =
  7. C=  ----------                                                         =
  8. C=   Calcul de la matrice B reliant les deformations en un point d'un  =
  9. C=   element fini aux ddls de deplacement aux noeuds de cet element    =
  10. C=   Le jacobien est egalement evalue au point de Gauss pour verifier  =
  11. C=   ulterieurement si l'element fini n'est pas trop distordu.         =
  12. C=                                                                     =
  13. C=  Parametres :  (E)=Entree  (S)=Sortie                               =
  14. C=  ------------                                                       =
  15. C=   iGau     (E)   Numero du point de Gauss considere                 =
  16. C=   NBPGAU   (E)   Nombre de points de Gauss de l'element fini        =
  17. C=   POIGAU,QSIGAU   (E)   |  Poids et coordonnees de reference des    =
  18. C=   ETAGAU,DZEGAU   (E)   |  differents points de Gauss de l'element  =
  19. C=   ITEL     (E)   Type de l'element fini (cf. NOMTP dans bdata.eso)  =
  20. C=   MFR      (E)   Formulation associee a l'element fini              =
  21. C=   NBNO     (E)   Nombre de noeuds de l'element fini                 =
  22. C=   LRE      (E)   Nombre de DDL de l'element fini                    =
  23. C=   IFOU     (E)   Mode de calcul utilise (cf. IFOUR dans CCOPTIO)    =
  24. C=   NST      (E)   Nombre de composantes de deformations              =
  25. C=   NN       (E)   Numero du mode de Fourier (si IFOU=1)              =
  26. C=   DIM3     (E)   Epaisseur dans l'hypothese des contraintes planes  =
  27. C=   XEL      (E)   Coordonnees des noeuds de l'element fini etudie    =
  28. C=   SHPTOT   (E)   Fonctions de forme et leurs derivees               =
  29. C=   SHP      (S)   Fonctions de forme et leurs derivees actuelles     =
  30. C=   BGENE    (S)   Matrice de gradients (B) calcule au point de Gauss =
  31. C=   DJAC     (S)   Jacobien au point de Gauss etudie                  =
  32. C=   XDPGE,YDPGE   (E)   Coordonnees du noeud support (mode PLAN GENE) =
  33. C=                                                                     =
  34. C=  Remarque :                                                         =
  35. C=  ----------                                                         =
  36. C=   Lors de l'entree dans le sous-programme, SHPTOT(2 a 4,*) contient =
  37. C=   les DERIVEES des fonctions de forme par rapport aux coordonnees   =
  38. C=   de REFERENCE Qsi,Eta,Dzeta.                                       =
  39. C=   En sortie du sous-programme, SHP(2 a 4,*) contient les DERIVEES   =
  40. C=   des fonctions de FORME par rapport aux coordonnees REELLES x,y,z. =
  41. C=======================================================================
  42.  
  43.       SUBROUTINE BMAT28 (iGau,NBPGAU,POIGAU,QSIGAU,ETAGAU,DZEGAU,
  44.      &                   ITEL,MFR,NBNO,LRE,IFOU,NST,NN,DIM3,XEL,
  45.      &                   SHPTOT,SHP,BGENE,DJAC,XDPGE,YDPGE)
  46.  
  47.       IMPLICIT INTEGER(I-N)
  48.       IMPLICIT REAL*8 (A-H,O-Z)
  49.  
  50. -INC CCREEL
  51.  
  52.       DIMENSION XEL(3,*),BGENE(NST,*),SHP(6,*),SHPTOT(6,NBNO,*),
  53.      &          POIGAU(*),QSIGAU(*),ETAGAU(*),DZEGAU(*)
  54.  
  55.       DIMENSION BB1(3,9),GEOM(20),XX(3),YY(3)
  56.  
  57.       DATA XX / .5D0,.0D0,.5D0 /
  58.       DATA YY / .0D0,.5D0,.5D0 /
  59.  
  60.       IF (ITEL.NE.28.AND.ITEL.NE.45) RETURN
  61.  
  62.       RR=XZero
  63.       CALL ZERO(BGENE,NST,LRE)
  64.  
  65. C ===
  66. C  Element COQUE DKT
  67. C ===
  68.       DO i=1,NBNO
  69.         SHP(1,i)=SHPTOT(1,i,iGau)
  70.         SHP(2,i)=SHPTOT(2,i,iGau)
  71.         SHP(3,i)=SHPTOT(3,i,iGau)
  72.       ENDDO
  73.       CALL DEVOLU(XEL,SHP,MFR,NBNO,IFOU,NN,2,DIM3,RR,DJAC)
  74.       k = 1
  75.       DO i = 1, NBNO
  76.         BGENE(1,k) = SHP(2,i)
  77.         BGENE(2,k) = XZero
  78.         BGENE(3,k) = SHP(3,i)
  79.         BGENE(1,k+1) = XZero
  80.         BGENE(2,k+1) = SHP(3,i)
  81.         BGENE(3,k+1) = SHP(2,i)
  82.         K=K+6
  83.       ENDDO
  84.       CALL GEOCST(XEL,GEOM)
  85.       CALL BFDKT(XX(iGau),YY(iGau),GEOM,BB1)
  86.       DJAC=GEOM(17)
  87.       K=2
  88.       KK=0
  89.       DO i=1,3
  90.         DO IX=1,3
  91.           DO IY=1,3
  92.             BGENE(3+IX,K+IY)=BB1(IX,IY+KK)
  93.           ENDDO
  94.         ENDDO
  95.         K=K+6
  96.         KK=KK+3
  97.       ENDDO
  98.  
  99.       RETURN
  100.       END
  101.  
  102.  
  103.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales