Sources Esope | Cast3M

barste
C BARSTE    SOURCE    CHAT      05/01/12    21:35:29     5004
      SUBROUTINE BARSTE(XMAT,XCAR,DEPST,SIG0,VAR0,SIGF,VARF,DEFP)
*
      IMPLICIT INTEGER(I-N)
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION XMAT(16),VAR0(14),VARF(14)
      DIMENSION EPSON(5),SIGMA(5),DEPST(*)
      CHARACTER*8 CMATE
C----------------------------------------------------------------------
C
C     COMPORTEMENT DE FIBRE DE FERRAILLE
C
C----------------------------------------------------------------------
C     Pierre Pegon (ISPRA) Juillet 1994 +- clone de FIBSTE
C----------------------------------------------------------------------
C
C      XMAT( 1) YOUNG
C      XMAT( 2) NU
C      XMAT( 3) RHO
C      XMAT( 4) ALPHA
C      XMAT( 5) MAX. ELAST. STRESS
C      XMAT( 6) ULTIMATE STRESS
C      XMAT( 7) HARDENING STRAIN
C      XMAT( 8) ULTIMATE STRAIN
C      XMAT( 9) Ro FACTOR
C      XMAT(10) b  FACTOR
C      XMAT(11) a1 FACTOR
C      XMAT(12) a2 FACTOR
C      XMAT(13) FACTOR L/D
C      XMAT(14) a6 FACTOR
C      XMAT(15) c FACTOR
C      XMAT(16) a FACTOR
C
C      SIG0 AND SIGF STRESS
C      DEPST,DEFP
C
C                      VAR0( 1) VARF( 1) FLAG
C                      VAR0( 2) VARF( 2) EPSO
C                      VAR0( 3) VARF( 3) R FACTOR
C                      VAR0( 4) VARF( 4) TANGENT MODULUS
C                      VAR0( 5) VARF( 5) LAST REV. STRAIN
C                      VAR0( 6) VARF( 6) INTERSEPTION POINT
C                      VAR0( 8) VARF( 7) MAX. REV. POST. STRAIN
C                      VAR0( 9) VARF( 8) MIN. REV. POST. STRAIN
C                      VAR0(10) VARF( 9) LAST REV. STRESS
C                      VAR0(11) VARF(10) INTERSEPTION POINT
C                      VAR0(13) VARF(11) MAX. REV. POST. STRESS
C                      VAR0(14) VARF(12) MIN. REV. POST. STRESS
C
C----------------------------------------------------------------------
*
       DEPS = DEPST(1)
       EYOUN = XMAT( 1)
       FSY__ = XMAT( 5)
       FSU__ = XMAT( 6)
       EPSH_ = XMAT( 7)
       EPSU_ = XMAT( 8)
       ROFAC = XMAT( 9)
       BFACT = XMAT(10)
       A1FAC = XMAT(11)
       A2FAC = XMAT(12)
       FACLD = XMAT(13)
       A6FAC = XMAT(14)
       CFACT = XMAT(15)
       AFACT = XMAT(16)
C
       IFLAG = NINT(VAR0(1))
       STRAI = VAR0(2) + DEPS
       RFACT = VAR0(3)
       TANGE = VAR0(4)
C
       DO IFACT = 1, 2
          EPSON(IFACT) = VAR0(4+IFACT)
          SIGMA(IFACT) = VAR0(8+IFACT)
       END DO
C
       EPSON(3) = VAR0(2)
       SIGMA(3) = SIG0 / XCAR
C
       DO IFACT = 4, 5
          EPSON(IFACT) = VAR0(3+IFACT)
          SIGMA(IFACT) = VAR0(7+IFACT)
       END DO
C
       CALL STEEL1
     .       ( EYOUN, FSY__, FSU__, EPSH_, EPSU_, ROFAC, BFACT,
     .         A1FAC, A2FAC, FACLD, A6FAC, CFACT, AFACT, IFLAG,
     .         STRAI, RFACT, EPSON, SIGMA, TANGE, STRES )
C
       VARF(1) = DBLE(IFLAG)
       VARF(2) = STRAI
       VARF(3) = RFACT
       VARF(4) = TANGE
C
       DO IFACT = 1, 2
          VARF(4+IFACT) = EPSON(IFACT)
          VARF(8+IFACT) = SIGMA(IFACT)
       END DO
C
       DO IFACT = 4, 5
          VARF(3+IFACT) = EPSON(IFACT)
          VARF(7+IFACT) = SIGMA(IFACT)
       END DO
C
       SIGF    = STRES * XCAR
       DEFP    = DEPS - ((SIGF - SIG0) / (EYOUN * XCAR))
C
       RETURN
       END