Télécharger waam.procedur

Retour à la liste

Numérotation des lignes :

  1. * WAAM PROCEDUR PASCAL 20/11/04 21:22:16 10765
  2. DEBP WAAM TAB1*'TABLE' ;
  3.  
  4. *-------------------------- Initialisations ---------------------------*
  5.  
  6. * Lecture des options :
  7. argu MOT1*'MOT' ;
  8.  
  9. * icas1 = 1 / 2 pour MAIL / VISU
  10. * Si 0 in fine : erreur.
  11. icas1 = 0 ;
  12.  
  13. *----------------------------------------------------------------------*
  14. * Option MAIL
  15. *----------------------------------------------------------------------*
  16.  
  17. si (ega mot1 'MAIL') ;
  18. icas1 = 1 ;
  19.  
  20. *----------------- Lecture des arguments de l'option ------------------*
  21.  
  22. imot1 = faux ; imot2 = faux ; imot3 = faux ; imot4 = faux ;
  23. repe b1 4 ;
  24. argu moti1/'MOT' ;
  25. si (non (exis moti1)) ; quit b1 ; fins ;
  26.  
  27. * Arguments option MAIL :
  28. si (ega moti1 'PAS') ;
  29. imot1 = vrai ;
  30. argu lpas1/'LISTREEL' ;
  31. si (exis lpas1) ;
  32. npas1 = dime lpas1 ;
  33. si (npas1 ega 0) ;
  34. erre '***** ERREUR : le LISTREEL fourni est de dimension nulle.' ;
  35. quit waam ;
  36. fins ;
  37. pas1 = extr lpas1 1 ;
  38. sino ;
  39. argu pas1*'FLOTTANT' ;
  40. lpas1 = prog pas1 ;
  41. npas1 = 1 ;
  42. fins ;
  43. fins ;
  44. si (ega moti1 'LARG') ;
  45. imot2 = vrai ;
  46. argu larg1*'FLOTTANT' ;
  47. fins ;
  48. si (ega moti1 'DENS') ;
  49. imot3 = vrai ;
  50. argu dens1*'FLOTTANT' ;
  51. fins ;
  52.  
  53. * Arguments option TEMP :
  54. si (ega moti1 'TEMP') ;
  55. imot4 = vrai ;
  56. argu dtca1/'FLOTTANT' ;
  57. si (non (exis dtca1)) ;
  58. dtca1 = -1. ;
  59. fins ;
  60. * argu dtca2/'FLOTTANT' ;
  61. * si (non (exis dtca2)) ;
  62. * dtca2 = -1. ;
  63. * fins ;
  64. fins ;
  65. fin b1 ;
  66. si (non imot1) ;
  67. erre '***** ERREUR : il manque la donnee du PAS de discretisation du depot' ;
  68. quit waam ;
  69. fins ;
  70. si (non imot2) ;
  71. si (exis tab1 'LARGEUR_DE_PASSE') ;
  72. larg1 = tab1.largeur_de_passe ;
  73. sino ;
  74. erre '***** ERREUR : il manque la donnee de la LARGeur du depot' ;
  75. quit waam ;
  76. fins ;
  77. fins ;
  78. si (non imot3) ;
  79. argu N1/'ENTIER' ;
  80. si (exis N1) ;
  81. N1 = maxi (lect N1 1) ;
  82. sino ;
  83. N1 = 1 ;
  84. fins ;
  85. dens1 = pas1 / (flot N1) ;
  86. fins ;
  87.  
  88. *------------------- MAILLAGE des passes de soudage -------------------*
  89.  
  90. si (non (exis tab1 passes)) ;
  91. erre '***** ERREUR : la table de SOUDAGE en entree n"a pas d"indice PASSES' ;
  92. quit waam ;
  93. fins ;
  94.  
  95. * Definition d'une tolerance geometrique :
  96. tol1 = 1.e-4 * dens1 ;
  97.  
  98. * Maillage d'une section de cordon :
  99. lsi1 = (0 0 0) droi (0 larg1 0) dini dens1 dfin dens1 ;
  100.  
  101. * Initialisattion sorties (MAIL) :
  102. tab2 = table ;
  103. ttps1 = table ;
  104. tmai1 = table ;
  105. indi1 = 0 ;
  106.  
  107. * On parcourt la trajectoire :
  108. mtraj1 = tab1.trajectoire ;
  109. mail2 = vide maillage ;
  110. idebui1 = vrai ;
  111. ibouci1 = faux ;
  112.  
  113. * Boucle sur elements de la trajectoire :
  114. nb1 = nbel mtraj1 ;
  115. repe b1 nb1 ;
  116.  
  117. * Lecture ieme element de la trajectoire :
  118. eli1 = mtraj1 elem &b1 ;
  119. Pi1 = eli1 poin 1 ;
  120. Pi2 = eli1 poin 2 ;
  121. vai1 = Pi2 moin Pi1 ;
  122. vni1 = vai1 / (norm vai1) ;
  123. mcouli1 = (eli1 elem coul) extr 1 ;
  124. imaili1 = ega mcouli1 'ROUG' ;
  125. idepli1 = ega mcouli1 'VERT' ;
  126. *
  127. * Segment VERT : deplacement
  128. si idepli1 ;
  129. idebui1 = vrai ;
  130. ibouci1 = faux ;
  131. iter b1 ;
  132. fins ;
  133. *
  134. * Segment ROUGE : maillage
  135. si imaili1 ;
  136.  
  137. * Si debut nouvelle passe :
  138. si idebui1 ;
  139.  
  140. * Identification de la passe :
  141. npassi1 = 0 ;
  142. repe bp1 (dime tab1.passes) ;
  143. mailpss1 = (tab1.passes.&bp1).maillage ;
  144. pps1 pps2 = (mailpss1 poin 1) (mailpss1 poin 2) ;
  145. si ((Pi1 ega pps1) et (Pi2 ega pps2)) ;
  146. tpassi1 = tab1.passes.&bp1 ;
  147. npassi1 = &bp1 ;
  148. mess '***** WAMM : maillage de la passe :' npassi1 ;
  149. quit bp1 ;
  150. fins ;
  151. fin bp1 ;
  152. si (npassi1 ega 0) ;
  153. erre '***** WAAM : passe non identifiee' ;
  154. quit waam ;
  155. fins ;
  156.  
  157. * Hauteur de cordon :
  158. debi1 = tpassi1 . debit ;
  159. vite1 = tpassi1 . vitesse ;
  160. haut1 = debi1 / vite1 / larg1 ;
  161. mess (chai '***** WAMM : hauteur de la passe :' npassi1 ' =' haut1) ;
  162.  
  163. * Maillage :
  164. * si1 : maillage section courante :
  165. * vnsi1 : normale a la section
  166. si1 = lsi1 tran (0 0 haut1) dini dens1 dfin dens1 ;
  167. vnsi1 = 1 0 0 ;
  168.  
  169. * Positionnement extremite initiale (Pi1 au centre de l'arete superieure) :
  170. Pmsup1 = 0 (0.5*larg1) haut1 ;
  171. si1 = si1 plus (Pi1 moin Pmsup1) ;
  172.  
  173. * Initialisation section extremite finale :
  174. si2 = si1 plus vai1 ;
  175. vnsi2 = vnsi1 ;
  176. angl2 = 0. ;
  177. *
  178. * Orientation sections de maillage :
  179. * Par defaut, selon vni1 :
  180. vnsmai1 = vni1 ;
  181. vnsmai2 = vnsmai1 ;
  182.  
  183. * Detection suite segments rouges et boucle :
  184. si (&b1 neg nb1) ;
  185. elip1 = mtraj1 elem (&b1 + 1) ;
  186. mcoulip1 = (elip1 elem coul) extr 1 ;
  187. isuiti1 = ega mcoulip1 'ROUG' ;
  188. si isuiti1 ;
  189. idebui1 = faux ;
  190. vai2 = (elip1 poin 2) moin (elip1 poin 1) ;
  191. vni2 = vai2 / (norm vai2) ;
  192. vasmai2 = vni1 plus vni2 ;
  193. vnsmai2 = vasmai2 / (norm vasmai2) ;
  194. elfini1 = elip1 ;
  195. pfini1 = elip1 poin 2 ;
  196. nb2 = nb1 - (&b1 + 1) ;
  197. i2 = &b1 + 2 ;
  198. * Rq : si nb2 = 0, le bloc n'est pas execute
  199. repe b2 nb2 ;
  200. eli2 = mtraj1 elem i2 ;
  201. mcoul2 = (eli2 elem coul) extr 1 ;
  202. si (neg mcoul2 'ROUG') ; quit b2 ; fins ;
  203. pfini1 = eli2 poin 2 ;
  204. elfini1 = eli2 ;
  205. vafini1 = pfini1 moin (eli2 poin 1) ;
  206. vnfini1 = vafini1 / (norm vafini1) ;
  207. i2 = i2 + 1 ;
  208. fin b2 ;
  209. ibouci1 = (norm (pfini1 moin pi1)) < tol1 ;
  210. si ibouci1 ;
  211. mess '***** WAAM : boucle fermee detectee' ;
  212. * On definit la normale a la section de maillage (SMA) :
  213. vasmai1 = vni1 plus vnfini1 ;
  214. vnsmai1 = vasmai1 / (norm vasmai1) ;
  215. fins ;
  216. fins ;
  217. fins ;
  218.  
  219. * Orientation de si1 selon vnsmai1 :
  220. *list vnsmai1 ; list vnsi1 ;
  221. *trac (0 -0 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
  222. vnnz1 = pvec vnsmai1 vnsi1 ;
  223. lvnnz1 = norm vnnz1 ;
  224. * Si sinus non nul a tol1 pres, on oriente la section :
  225. si (lvnnz1 neg 0. (tol1 / dens1)) ;
  226. si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
  227. angl1 = asin lvnnz1 ;
  228. si ((psca vnsmai1 vnsi1) > 0.) ;
  229. angl1 = -1. * angl1 ;
  230. fins ;
  231. si1 = si1 tour angl1 pi1 (pi1 plus vnnz1) ;
  232. vnsi1 = vnsmai1 ;
  233. si2 = si1 plus vai1 ;
  234. vnsi2 = vnsi1 ;
  235. angl2 = 0. ;
  236. fins ;
  237. *trac (0 -0 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
  238.  
  239. * Si boucle, on garde la section de maillage du debut :
  240. si ibouci1 ;
  241. sfini1 = si1 ;
  242. vnfini1 = vnsmai1 ;
  243. fins ;
  244.  
  245. sino ;
  246.  
  247. * On a deja si1 correctement orientee.
  248. * On doit orienter si2.
  249. * Par defaut, orientation de si1 :
  250. vnsmai2 = vni1 ;
  251.  
  252. * Si fin d'une boucle, orientation si2 connue :
  253. si (ibouci1 et (pi2 ega pfini1)) ;
  254. vnsmai2 = vnfini1 ;
  255. sino ;
  256. si (&b1 neg nb1) ;
  257. elip1 = mtraj1 elem (&b1 + 1) ;
  258. mcoulip1 = (elip1 elem coul) extr 1 ;
  259. isuiti1 = ega mcoulip1 'ROUG' ;
  260. si isuiti1 ;
  261. vai2 = (elip1 poin 2) moin (elip1 poin 1) ;
  262. vni2 = vai2 / (norm vai2) ;
  263. vasmai2 = vni1 plus vni2 ;
  264. vnsmai2 = vasmai2 / (norm vasmai2) ;
  265. fins ;
  266. fins ;
  267. fins ;
  268.  
  269. * Fin "Si idebui1 / sinon" :
  270. fins ;
  271. *
  272. * Orientation de si2 selon vnsmai2 :
  273. *list vnsmai2 ; list vnsi2 ;
  274. *trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) titr 'orientation si2' ;
  275. vnnz1 = pvec vnsmai2 vnsi2 ;
  276. lvnnz1 = norm vnnz1 ;
  277. * Si sinus non nul a tol1 pres, on oriente la section :
  278. si (lvnnz1 neg 0. (tol1 / dens1)) ;
  279. si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
  280. angl2 = asin lvnnz1 ;
  281. si ((psca vnsmai2 vnsi2) > 0.) ;
  282. angl2 = -1. * angl2 ;
  283. fins ;
  284. si2 = si2 tour angl2 pi2 (pi2 plus vnnz1) ;
  285. vnsi2 = vnsi2 tour angl2 (0 0 0) vnnz1 ;
  286. fins ;
  287. *trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
  288. *si (ibouci1 et (pi2 ega pfini1)) ;
  289. *trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
  290. *fins ;
  291.  
  292. *---- Maillage du segment :
  293.  
  294. llpas1 = somm (lpas1 enle npas1) ;
  295. leli1 = mesu eli1 ;
  296. si (leli1 &lt;EG llpas1) ;
  297. erre '***** ERREUR : somme pas de discretisation > long. ' &b1 'e passe' ;
  298. quit waam ;
  299. fins ;
  300.  
  301. * Boucle sur les pas de discretisation :
  302.  
  303. * pasi1 : pas de discretisation courant
  304. * nei1 : nb maillages pour ce pas de discretisation du segment
  305. * pami1 : pas de maillage courant
  306. * nei2 : nbel crees par pas de maillage
  307.  
  308. tpsi2 = tpassi1.instants extr 1 ;
  309. repe bp1 npas1 ;
  310. pasi1 = extr lpas1 &bp1 ;
  311. si (&bp1 neg npas1) ;
  312. nei1 = 1 ;
  313. pami1 = pasi1 ;
  314. sino ;
  315. llmi1 = leli1 - llpas1 ;
  316. nei1 = llmi1 / pasi1 + 0.5 ;
  317. nei1 = maxi (lect (enti nei1) 1) ;
  318. *mess 'nei1=' nei1 ;
  319. pami1 = llmi1 / (flot nei1) ;
  320. fins ;
  321.  
  322. vtrani1 = pami1 * vni1 ;
  323. ltrani1 = norm vtrani1 ;
  324. nei2 = enti (ltrani1 / dens1 + 0.5) ;
  325. nei2 = maxi (lect (enti nei2) 1) ;
  326. *mess 'nei2=' nei2 ;
  327. itouri1 = (abs angl2) > 0. ;
  328. *list itouri1 ;
  329. *list angl2 ;
  330. angli2 = angl2 / (flot nei1) ;
  331. vnsi22 = vnsi1 ;
  332. si22 = si1 ;
  333. dti2 = ltrani1 / vite1 ;
  334. repe b2 nei1 ;
  335. pi22 = pi1 plus vtrani1 ;
  336. si itouri1 ;
  337. vnsi22 = vnsi22 tour angli2 (0 0 0) vnnz1 ;
  338. pi33 = pi22 plus vnnz1 ;
  339. pi44 = pi22 plus (pvec vnsi22 vnnz1) ;
  340. si22 = si22 proj cyli vtrani1 plan pi22 pi33 pi44 ;
  341. sino ;
  342. si22 = si1 plus vtrani1 ;
  343. fins ;
  344. maili2 = si1 volu si22 nei2 ;
  345. si1 = si22 ;
  346. pi1 = pi22 ;
  347. maili2 = maili2 coul (indi1+1) ;
  348. mail2 = mail2 et maili2 ;
  349. tmai1 . indi1 = mail2 ;
  350. ttps1 . indi1 = tpsi2 ;
  351. tpsi2 = tpsi2 + dti2 ;
  352. indi1 = indi1 + 1 ;
  353. fin b2 ;
  354.  
  355. fin bp1 ;
  356.  
  357. *trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
  358.  
  359. vnsi1 = vnsi2 ;
  360. vnsmai1 = vnsmai2 ;
  361.  
  362. * Fin si imail1 (segment rouge) ;
  363. sino ;
  364. erre '***** ERREUR : pb definition trajectoire, couleur segment inconnue' ;
  365. quit waam ;
  366. fins ;
  367.  
  368. * Fin boucle segments trajectoire
  369. fin b1 ;
  370. * elim mail2 tol1 ;
  371.  
  372. * Enregistrement des sorties :
  373. tab2.maillage = mail2 ;
  374. tab2.evolution_maillage = table ;
  375. tab2.evolution_maillage.temps = ttps1 ;
  376. tab2.evolution_maillage.maillage = tmai1 ;
  377.  
  378. *-------------------------- Sous-option TEMP --------------------------*
  379.  
  380. si imot4 ;
  381.  
  382. * Valeurs par defaut dtca1 :
  383. si (dtca1 < 0.) ;
  384. dtca1 = (ttps1.1 - ttps1.0) / pi ;
  385. fins ;
  386. * si (dtca2 < 0.) ;
  387. * dtca2 = dtca1 ;
  388. * fins ;
  389.  
  390. * Redecoupage de la liste des temps de l'evolution de la puissance thermique :
  391. evqt1 = tab1.evolution_puissance ;
  392. ltqt1 = extr evqt1 absc ;
  393. lqqt1 = extr evqt1 ordo ;
  394. tol2 = 1.e-6 * (maxi lqqt1) ;
  395.  
  396. nb1 = dime ltqt1 ;
  397. t0 = extr ltqt1 1 ;
  398. q0 = extr lqqt1 1 ;
  399. ltca1 = prog t0 ;
  400. repe b1 (nb1 - 1) ;
  401. ip1 = &b1 + 1 ;
  402. t1 = extr ltqt1 ip1 ;
  403. q1 = extr lqqt1 ip1 ;
  404. dt1 = t1 - t0 ;
  405. si (&b1 ega 1) ; dt0 = dt1 ; fins ;
  406. si (dt1 &lt;EG dtca1) ;
  407. ltca1 = ltca1 et (prog t1) ;
  408. t0 = t1 ;
  409. q0 = q1 ;
  410. dt0 = dt1 ;
  411. iter b1 ;
  412. fins ;
  413. si ((q0 > tol2) ou (q1 > tol2)) ;
  414. ltca1 = ltca1 et ((prog t0 pas dtca1 t1) enle 1) ;
  415. sino ;
  416. * mess 'dt0 = ' dt0 ;
  417. * mess 'dtca1 = ' dtca1 ;
  418. * mess 'dtf1 = ' dtf1 ;
  419. ltca1 = ltca1 et ((prog t0 pas dt0 geom 2. t1) enle 1) ;
  420. fins ;
  421. t0 = t1 ;
  422. q0 = q1 ;
  423. ntca1 = dime ltca1 ;
  424. dt0 = (ltca1 extr ntca1) - (ltca1 extr (ntca1-1)) ;
  425. fin b1 ;
  426.  
  427. * Verification si liste temps calcules bien ordonnee :
  428. ltca2 = ordo ltca1 ;
  429. si (((ltca2 - ltca1) maxi abs) > (1.e-3*dtca1)) ;
  430. erre '***** ERREUR WAAM dans construction liste TEMPS_CALCULES' ;
  431. quit waam ;
  432. fins ;
  433.  
  434. tab2.temps_calcules = ltca1 ;
  435.  
  436. * Fin sous-option TEMP :
  437. fins ;
  438.  
  439. resp tab2 ;
  440. quit waam ;
  441. * Fin option MAILLAGE :
  442. fins ;
  443.  
  444. *----------------------------------------------------------------------*
  445. * Option VISU *
  446. *----------------------------------------------------------------------*
  447.  
  448. si (ega mot1 'VISU') ;
  449. icas1 = 2 ;
  450. *
  451. * Lecture MOT CACH / FACE :
  452. argu mot1/'MOT' ;
  453. si (exis mot1) ;
  454. cle1 = text mot1 ;
  455. sino ;
  456. cle1 = text ' ' ;
  457. fins ;
  458.  
  459. * Lecture maillage complementaire a afficher :
  460. argu mail2/maillage ;
  461. si (non (exis mail2)) ;
  462. mail2 = vide maillage ;
  463. fins ;
  464.  
  465. mail1 = tab1.maillage ;
  466. tmai1 = tab1.evolution_maillage.maillage ;
  467. dep0 = manu chpo (mail1 et mail2) 3 ux 0 uy 0 uz 0 ;
  468. def0 = vide deforme ;
  469. i1 = 0 ;
  470. repe b2 (dime tmai1) ;
  471. maili1 = tmai1.i1 ;
  472. maili1 = maili1 et mail2 ;
  473. defi1 = defo maili1 dep0 0. ;
  474. def0 = def0 et defi1 ;
  475. i1 = i1 + 1 ;
  476. fin b2 ;
  477. trac cle1 anim def0 ;
  478.  
  479. quit waam ;
  480. * Fin option VISU :
  481. fins ;
  482.  
  483. *----------------------------------------------------------------------*
  484. * FIN *
  485. *----------------------------------------------------------------------*
  486. *
  487. * MOT1 n'est pas un des mots-cles des options de la procedure :
  488. si (icas1 ega 0) ;
  489. erre '***** ERREUR WAAM : MOT-cle option WAAM non reconnu.' ;
  490. quit waam ;
  491. fins ;
  492.  
  493. FINP ;
  494.  
  495.  
  496.  
  497.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales