Télécharger varihc.procedur

Retour à la liste

Numérotation des lignes :

  1. * VARIHC PROCEDUR BR232186 16/12/05 22:04:41 9238
  2. ****************************************************
  3. * Procedure de tracking par resolution d'un probleme
  4. * de conduction thermique stationnaire
  5. * Application au modele E-FEM
  6. * Version :
  7. * Variable online global tracking
  8. * Creation :
  9. * Francesco RICCARDI 22/08/2016
  10. * Benjamin RICHARD
  11. * Contact :
  12. * Francesco.Riccardi[at]cea.fr
  13. * Benjamin.Richard[at]cea.fr
  14. * Institution :
  15. * CEA\DEN\DANS\DM2S\SEMT\EMSI
  16. ****************************************************
  17. * Voir notice TRACKING pour plus d'informations
  18. ****************************************************
  19. *
  20. *******----DEBUT Procedure VARIHC----*******
  21. *
  22. DEBP VARIHC TAB2*'TABLE';
  23.  
  24.  
  25. * Indice d'evolution
  26. NPAS = dime tab2. deplacements;
  27. NPAS = NPAS - 1;
  28. *LIST NPAS;
  29.  
  30. * Modeles
  31. MODEL1 = TAB2. 'MODELE';
  32. MODELS = EXTR MODEL1 'ZONE';
  33.  
  34. * Modele et materiau EFEM
  35. MODEL11 = MODELS. 1;
  36. SURFACE1 = MODELS. 2;
  37. MATr1 = TAB2. 'WTABLE'. 'CARACTERISTIQUES';
  38. MATr11 = REDU MATr1 SURFACE1;
  39. E11 = EXCO MATr11 YOUN;
  40. NU11 = EXCO MATr11 NU;
  41. P11 = EXCO MATr11 FT;
  42. P12 = EXCO MATR11 XNX;
  43. P13 = EXCO MATR11 XNY;
  44. P14 = EXCO MATr11 IND1;
  45. P15 = EXCO MATR11 XIE;
  46. P16 = EXCO MATR11 YIE;
  47.  
  48. * Coordonnees de la geometrie
  49. X0 = COOR 1 SURFACE1;
  50. Y0 = COOR 2 SURFACE1;
  51. X0S = CHAN 'CHAM' X0 MODEL11 'STRESSES';
  52. X0S = CHAN 'TYPE' X0S 'CONTRAINTES PRINCIPALES';
  53. X0S = CHAN 'COMP' 'SI11' X0S;
  54. Y0S = CHAN 'CHAM' Y0 MODEL11 'STRESSES';
  55. Y0S = CHAN 'TYPE' Y0S 'CONTRAINTES PRINCIPALES';
  56. Y0S = CHAN 'COMP' 'SI11' Y0S;
  57.  
  58. * Nombre de root elements
  59. NROOTS = TAB2. 'NROOTS';
  60. *LIST NROOTS;
  61.  
  62. * Nombre maximum de fissures
  63. MAXR = TAB2. 'NRMAX';
  64.  
  65. * Variables internes : NFLA
  66. FLAG = EXCO (TAB2. 'VARIABLES_INTERNES'. NPAS) 'NFLA';
  67. *TRAC FLAG MODEL11;
  68. VFLAG = MAXI FLAG;
  69. ELACT1 = FLAG ELEM 'EGALE' 1.;
  70.  
  71. * Maximum des contraintes principales
  72. SIG1 = TAB2. 'CONTINUATION'. 'CONTRAINTES';
  73. PRIN1 = PRIN SIG1 MODEL11;
  74. SIGMA11 = EXCO 'SI11' PRIN1;
  75. COS1X = NOMC 'SI11' (EXCO PRIN1 'COX1');
  76. COS1Y = NOMC 'SI11' (EXCO PRIN1 'COY1');
  77. SIGMAX = MAXI SIGMA11;
  78.  
  79. *
  80. *----- Debut algorithme de tracking ---------------------------
  81. *
  82. SI ((SIGMAX > 0.) ET (NPAS < (TAB2. 'NPAS_TRACKING')));
  83.  
  84.  
  85. * Elements qui violent le critere de resistance
  86. ***dans la phase elastique lineaire VFLAG=0***
  87. SI (VFLAG EGA 0.);
  88. ELSP11 = SIGMA11 ELEM 'MAXI';
  89. SINON;
  90. MESH0 = TAB2. 'MESH'. (NPAS - 1);
  91. SURFRED = SURFACE1 DIFF MESH0;
  92. SIGRED = REDU SIGMA11 SURFRED;
  93. ***pour assurer que les points test n'appartiennent pas a MESH0***
  94. ***cela peut se passer si on a des bloccages***
  95. ELSP11 = SIGRED ELEM 'EGSUPE' (MAXI P11);
  96. FINSI;
  97. NTEST = NBEL ELSP11;
  98. SI (NTEST > 0);
  99. SP11 = REDU SIGMA11 ELSP11;
  100. FINSI;
  101.  
  102. TABISO0 = TABLE;
  103. TABROOT = TABLE;
  104. TABEROOT = TABLE;
  105. SI (VFLAG EGA 0);
  106. TABEROOT. 1 = SIGMA11 ELEM 'MAXI';
  107. TABROOT. 1 = BARY (TABEROOT. 1);
  108. SI (NROOTS EGA 1);
  109. TABROOT. 1 = TAB2. 'PROOTS'. 1;
  110. TABEROOT. 1 = TAB2. 'EROOTS'. 1;
  111. FINSI;
  112. SINON;
  113. i = 0;
  114. ***NROOTS est surement >0***
  115. REPETER BOUCLE1 NROOTS;
  116. indice = i * 4;
  117. LXIN0 = TAB2. 'TABISO'. (indice + 1);
  118. LYIN0 = TAB2. 'TABISO'. (indice + 2);
  119. LXOUT0 = TAB2. 'TABISO'. (indice + 3);
  120. LYOUT0 = TAB2. 'TABISO'. (indice + 4);
  121. MESH0 = TAB2. 'MESH_ISO'. (i + 1);
  122. * Nombre de points qui composent la fissure
  123. DIMM0 = DIME LXIN0;
  124. ***si tous les elements sont actives on touche rien***
  125. FLAGISO = REDU FLAG MESH0;
  126. MESHACT = FLAGISO ELEM 'SUPERIEUR' 0.;
  127. NACT = NBEL MESHACT;
  128. SI ((NACT > 0) ET (NACT < DIMM0));
  129. SI ((NACT + 1) EGA DIMM0);
  130. LISTEN0 = DIMM0;
  131. SINON;
  132. LISTEN0 = ENTI (PROG (NACT + 1) PAS 1 DIMM0);
  133. FINSI;
  134. * Partie activee de la fissure
  135. LXIN0 = ENLE LXIN0 LISTEN0;
  136. LYIN0 = ENLE LYIN0 LISTEN0;
  137. LXOUT0 = ENLE LXOUT0 LISTEN0;
  138. LYOUT0 = ENLE LYOUT0 LISTEN0;
  139. FINSI;
  140. LXG0 = (LXIN0 + LXOUT0) / 2.;
  141. LYG0 = (LYIN0 + LYOUT0) / 2.;
  142. TABROOT. (i + 1) = TAB2. 'PROOTS'. (i + 1);
  143. TABEROOT. (i + 1) = TAB2. 'EROOTS'. (i + 1);
  144. ***le point root est le point output du dernier element active***
  145. ***si NACT=0 il coincide avec celui du pas precedent***
  146. SI (NACT > 0);
  147. TABROOT. (i + 1) = (EXTR LXOUT0 NACT) (EXTR LYOUT0 NACT);
  148. TABEROOT. (i + 1) = MESH0 ELEM 'CONTENANT'
  149. ((EXTR LXG0 NACT) (EXTR LYG0 NACT));
  150. FINSI;
  151. TABISO0. (indice + 1) = LXIN0;
  152. TABISO0. (indice + 2) = LYIN0;
  153. TABISO0. (indice + 3) = LXOUT0;
  154. TABISO0. (indice + 4) = LYOUT0;
  155. i = i + 1;
  156. FIN BOUCLE1;
  157. FINSI;
  158.  
  159. SI (NTEST > 0);
  160. * Points root potentiels ordonnes par contrainte decroissante
  161. TABTEST = TABLE;
  162. i = 0;
  163. REPETER BOUCLE2 NTEST;
  164. i = i + 1;
  165. STEST = EXTR SP11 'SI11' 1 i 1;
  166. SI (i EGA 1);
  167. LSP11 = PROG STEST;
  168. LPTEST = PROG i;
  169. SINON;
  170. LSP11 = LSP11 ET (PROG STEST);
  171. LPTEST = LPTEST ET (PROG i);
  172. FINSI;
  173. FIN BOUCLE2;
  174. TABTEST. 1 = LPTEST;
  175. TABTEST. 2 = LSP11;
  176. TABTEST = ORDO TABTEST 2 'DECR';
  177. FINSI;
  178.  
  179. *
  180. *\\\\ Resolution du probleme de conduction ////*
  181. *
  182. * Cosinus des tangentes
  183. COS2X = EXCO PRIN1 'COX2';
  184. COS2Y = EXCO PRIN1 'COY2';
  185. COS2Z = EXCO PRIN1 'COZ2';
  186.  
  187. * Champ vectoriel des tangentes
  188. *SIGMA22 = MANU 'CHML' MODEL11 'SI22' 1. 'TYPE'
  189. *'CONTRAINTES PRINCIPALES' 'STRESSES';
  190. *PRIN12 = (SIGMA22 ET COS2X ET COS2Y ET COS2Z);
  191. *VECTAN = VECT PRIN12 MODEL11 0.001 'SI22';
  192.  
  193. * Modele thermique
  194. MOTH = MODE SURFACE1 THERMIQUE ANISOTROPE;
  195. * Perturbation conductivite numerique
  196. TTPETIT = 1.e-6;
  197. * Tenseur conductivite anisotrope
  198. TTX = NOMC 'UX' COS2X;
  199. TTY = NOMC 'UX' COS2Y;
  200. KXX = (TTX ** 2) + ((TTX ** 0) * TTPETIT);
  201. KYY = (TTY ** 2) + ((TTY ** 0) * TTPETIT);
  202. KXY = TTX * TTY;
  203. PX = 1.0 0.;
  204. MATH = MATE MOTH 'DIRECTION' PX K11 KXX K21 KXY K22 KYY;
  205. * Matrice de rigidite
  206. KTH = COND MOTH MATH;
  207. * Conditions aux limites
  208. PCL1 = CHAN 'POI1' (TAB2. 'LBC');
  209. CLT1 = BLOQ PCL1 'T';
  210. CLTH = CLT1;
  211. * Temperature imposee
  212. VBC = TAB2. 'BCSTH';
  213. DE1 = DEPI CLT1 VBC;
  214. DETH = DE1;
  215. * Assemblage
  216. KTHTOT = KTH ET CLTH;
  217. * Resolution
  218. RESTH = RESO KTHTOT DETH;
  219. T0 = CHAN 'CHAM' RESTH MOTH 'NOEUD';
  220. T0 = EXCO T0 'T';
  221. TAB2. 'RESTH'. NPAS = RESTH;
  222.  
  223. *
  224. *\\\\ Extraction des isovaleurs ////*
  225. *
  226. SI (NROOTS EGA MAXR);
  227. NTEST = 0;
  228. FINSI;
  229. TISOPAS = TABLE;
  230. TABMESH1 = TABLE;
  231. MESH1 = VIDE 'MAILLAGE';
  232. ***on choisit un point du domaine en faisant l'hypothese***
  233. ***que aucune fissure passe par ceci***
  234. P0 = MANU 'POI1' ((X0 * Y0) POIN 'MINI');
  235. i = 0;
  236. REPETER BOUCLE3 (NROOTS + NTEST);
  237. i = i + 1;
  238. * Fissure activees aux pas precedents
  239. SI (i &lt;EG NROOTS);
  240. PPA = TABROOT. i;
  241. MPPA = MANU 'POI1' PPA;
  242. T0P = PROI T0 MPPA;
  243. TG = EXTR T0P 'T' PPA;
  244. ISOVG = ISOV T0 TG;
  245. * TRAC (ISOVG ET (CONT SURFACE1));
  246. ***cette phase est critique***
  247. ***si on perd l'unicite de la solution ORDO ne marche pas***
  248. ***arreter la procedure de tracking***
  249. ISOVG = ORDO ISOVG;
  250. T0G = MANU 'CHML' MOTH 'T' TG 'NOEUD';
  251. T01 = T0 - T0G;
  252. T02 = T01 MASQ 'SUPERIEUR' 0.;
  253. MAILA = T02 ELEM 'EGALE' 1.;
  254. MAILB = T02 ELEM 'EGALE' 0.;
  255. MESHISO = SURFACE1 DIFF (MAILA ET MAILB);
  256. * Extraction du maillage
  257. MM1 = (CHAN 'POI1' MESHISO) ET P0;
  258. MMT = (CHAN 'POI1' MESH1) ET P0;
  259. CHECK = MMT INTE MM1;
  260. SI ((NBEL CHECK) > 1);
  261. ISOVG = TAB2. 'ISOTEST'. i;
  262. FINSI;
  263. MESH1 = MESH1 ET MESHISO;
  264. TISOPAS. i = ISOVG;
  265. TABMESH1. i = MESHISO;
  266. TAB2. 'ISOTEST'. i = ISOVG;
  267. * Nouvelles fissures
  268. ***on fait l'hypothese d'avoir une seule nouvelle fissure***
  269. ***par pas de temps***
  270. SINON;
  271. iTEST = ENTI (EXTR (TABTEST. 1) (i - NROOTS));
  272. ETEST = ELSP11 ELEM iTEST;
  273. PPP = BARY ETEST;
  274. MPPP = MANU 'POI1' PPP;
  275. T0P = PROI T0 MPPP;
  276. TG = EXTR T0P 'T' PPP;
  277. ISOVG = ISOV T0 TG;
  278. * Extraction du maillage
  279. T0G = MANU 'CHML' MOTH 'T' TG 'NOEUD';
  280. T01 = T0 - T0G;
  281. T02 = T01 MASQ 'SUPERIEUR' 0.;
  282. MAILA = T02 ELEM 'EGALE' 1.;
  283. MAILB = T02 ELEM 'EGALE' 0.;
  284. MESHISO = SURFACE1 DIFF (MAILA ET MAILB);
  285. MM1 = (CHAN 'POI1' MESHISO) ET P0;
  286. MMT = (CHAN 'POI1' MESH1) ET P0;
  287. CHECK = MMT INTE MM1;
  288. * On verifie s'il y a des intersection entre maillages
  289. ***dans ce cas la on ecarte l'isovaleur***
  290. SI ((NBEL CHECK) EGA 1);
  291. ISOVG = ORDO ISOVG;
  292. * TRAC (ISOVG ET (CONT SURFACE1));
  293. T0RED = REDU T0 ETEST;
  294. ISOROOT = ISOV T0RED TG;
  295. PROOT = ISOROOT POIN 1;
  296. CHECK1 = SURFACE1 ELEM 'CONTENANT' PROOT 'TOUS';
  297. ***on fait l'hypothese que le root element appartient au contour***
  298. SI ((NBEL CHECK1) > 1);
  299. PROOT = ISOROOT POIN 2;
  300. FINSI;
  301. TABROOT. (NROOTS + 1) = PROOT;
  302. TABEROOT. (NROOTS + 1) = ETEST;
  303. TISOPAS. (NROOTS + 1) = ISOVG;
  304. TAB2. 'ISOTEST'. (NROOTS + 1) = ISOVG;
  305. TABMESH1. (NROOTS + 1) = MESHISO;
  306. TAB2. 'NROOTS' = (TAB2. 'NROOTS') + 1;
  307. QUIT BOUCLE3;
  308. FINSI;
  309. FINSI;
  310. FIN BOUCLE3;
  311. TAB2. 'PROOTS' = TABROOT;
  312. TAB2. 'EROOTS' = TABEROOT;
  313.  
  314. ***cette partie sert a creer un systeme d'abscisses curvilignes***
  315. ***avec sense positif selon celui de propagation des fissures***
  316. ***l'origine est en pointe de fissure***
  317. TABISO1 = TABLE;
  318. NN = DIME TABROOT;
  319. *LIST NN;
  320. i = 0;
  321. REPETER BOUCLE4 NN;
  322. i = i + 1;
  323. indice = (i - 1) * 4;
  324. PROOT = TABROOT. i;
  325. EROOT = TABEROOT. i;
  326. ISOVG = TISOPAS. i;
  327. MESHISO = TABMESH1. i;
  328. NUMEL = (NBNO ISOVG) - 1;
  329. NACT = 0;
  330. SI ((VFLAG > 0.) ET (i &lt;EG NROOTS));
  331. FLAGISO = REDU FLAG (TAB2. 'MESH_ISO'. i);
  332. MESHACT = FLAGISO ELEM 'SUPERIEUR' 0.;
  333. NACT = NBEL MESHACT;
  334. FINSI;
  335. XISOVG = COOR 1 ISOVG;
  336. YISOVG = COOR 2 ISOVG;
  337. EVOLX = EVOL 'CHPO' XISOVG ISOVG;
  338. EVOLY = EVOL 'CHPO' YISOVG ISOVG;
  339. LISX = EXTR EVOLX 'SCAL';
  340. LISY = EXTR EVOLY 'SCAL';
  341. LISABSC = EXTR EVOLX 'ABSC';
  342. NUMP = NBNO ISOVG;
  343. LISP = PROG 1 PAS 1 NUMP;
  344. j = 0;
  345. REPETER B_INT NUMP;
  346. j = j + 1;
  347. Pj = ISOVG POIN j;
  348. SI (Pj EGA PROOT 1.E-10);
  349. jroot = j;
  350. * LIST jroot;
  351. * LIST NUMP;
  352. QUIT B_INT;
  353. FINSI;
  354. FIN B_INT;
  355. SROOT = EXTR LISABSC jroot;
  356. LISABSC1 = LISABSC - ((LISP / LISP) * SROOT);
  357. MM = MAXI LISABSC1;
  358. TABABS = TABLE;
  359. TABABS. 1 = LISABSC1;
  360. TABABS. 2 = LISP;
  361. TABABS. 3 = LISX;
  362. TABABS. 4 = LISY;
  363. SI (NACT EGA 0);
  364. ***si MM=0 il faut changer le signe***
  365. SI ((MM EGA 0.));
  366. TABABS. 1 = -1. * LISABSC1;
  367. TABABS = ORDO TABABS 1 'CROI';
  368. FINSI;
  369. ***le dernier point est un point de sortie***
  370. LXIN = ENLE (TABABS. 3) (DIME LISX);
  371. LYIN = ENLE (TABABS. 4) (DIME LISY);
  372. ***le premier point est un point d'entree***
  373. LXOUT = ENLE (TABABS. 3) 1;
  374. LYOUT = ENLE (TABABS. 4) 1;
  375. TABISO1. (indice + 1) = LXIN;
  376. TABISO1. (indice + 2) = LYIN;
  377. TABISO1. (indice + 3) = LXOUT;
  378. TABISO1. (indice + 4) = LYOUT;
  379. SINON;
  380. TABISO1. (indice + 1) = TABISO0. (indice + 1);
  381. TABISO1. (indice + 2) = TABISO0. (indice + 2);
  382. TABISO1. (indice + 3) = TABISO0. (indice + 3);
  383. TABISO1. (indice + 4) = TABISO0. (indice + 4);
  384. SI (NACT < NUMEL);
  385. ***on cherche le point correspondant a la pointe de fissure***
  386. PTEST = ISOVG POIN (jroot + 1);
  387. TEST = NBEL (EROOT ELEM 'CONTENANT' PTEST 'NOVERIF');
  388. SI (TEST > 0);
  389. TABABS. 1 = -1. * LISABSC1;
  390. jroot = (NUMP - jroot) + 1;
  391. FINSI;
  392. TABABS = ORDO TABABS 1 'CROI';
  393. SI (jroot EGA 2);
  394. LISTEN = 1;
  395. SINON;
  396. LISTEN = ENTI (PROG 1 PAS 1 (jroot - 1));
  397. FINSI;
  398. LISX1 = ENLE (TABABS. 3) LISTEN;
  399. LISY1 = ENLE (TABABS. 4) LISTEN;
  400. * Partie potentielle de la fissure
  401. LXIN1 = ENLE LISX1 (DIME LISX1);
  402. LYIN1 = ENLE LISY1 (DIME LISY1);
  403. LXOUT1 = ENLE LISX1 1;
  404. LYOUT1 = ENLE LISY1 1;
  405. * On integre avec la partie activee
  406. TABISO1. (indice + 1) =
  407. TABISO0. (indice + 1) ET LXIN1;
  408. TABISO1. (indice + 2) =
  409. TABISO0. (indice + 2) ET LYIN1;
  410. TABISO1. (indice + 3) =
  411. TABISO0. (indice + 3) ET LXOUT1;
  412. TABISO1. (indice + 4) =
  413. TABISO0. (indice + 4) ET LYOUT1;
  414. FINSI;
  415. FINSI;
  416. FIN BOUCLE4;
  417. TAB2. 'TABISO' = TABISO1;
  418.  
  419. *
  420. *\\\\ Creation des chamelem ////*
  421. *
  422. ***CHM vaut sur les isovaleurs et 0 ailleurs***
  423. CHM = SIGMA11 * 0.;
  424. * Abscisses des points d'entree des fissures
  425. CHIX = CHM;
  426. * Ordonnees des points d'entree des fissures
  427. CHIY = CHM;
  428. * Composante x des normales
  429. CHNX = CHM;
  430. * Composante y des normales
  431. CHNY = CHM;
  432. TAB2. 'MESH'. NPAS = VIDE 'MAILLAGE';
  433. i = 0;
  434. REPETER BOUCLE5 NN;
  435. i = i + 1;
  436. indice = (i - 1) * 4;
  437. MESHISO = TABMESH1. i;
  438. NACT = 0;
  439. SI ((VFLAG > 0.) ET (i &lt;EG NROOTS));
  440. FLAGISO = REDU FLAG (TAB2. 'MESH_ISO'. i);
  441. MESHACT = FLAGISO ELEM 'SUPERIEUR' 0.;
  442. NACT = NBEL MESHACT;
  443. FINSI;
  444. LXIN = TABISO1. (indice + 1);
  445. LYIN = TABISO1. (indice + 2);
  446. LXOUT = TABISO1. (indice + 3);
  447. LYOUT = TABISO1. (indice + 4);
  448. LXG = (LXIN + LXOUT) / 2.;
  449. LYG = (LYIN + LYOUT) / 2.;
  450. SI (NACT EGA 0);
  451. MTEST = MESHISO;
  452. SINON;
  453. MDIFF = MESHISO DIFF MESHACT;
  454. MTEST = MDIFF ET MESHACT;
  455. FINSI;
  456. j = 0;
  457. REPETER B_INT (DIME LXIN);
  458. j = j + 1;
  459. * Coordonnees des points entree et sortie
  460. XIj = EXTR LXIN j;
  461. YIj = EXTR LYIN j;
  462. XOj = EXTR LXOUT j;
  463. YOj = EXTR LYOUT j;
  464. * Coordonnees des points moyens
  465. XGj = EXTR LXG j;
  466. YGj = EXTR LYG j;
  467. PGj = XGj YGj;
  468. * Calcul de la tangente et de la normale a la fissure
  469. LL = (((XIj - XOj) ** 2) + ((YIj - YOj) ** 2)) ** 0.5;
  470. SI (YIj > YOj);
  471. TY = (YIj - YOj) / LL;
  472. TX = (XIj - XOj) / LL;
  473. SINON;
  474. TY = (YOj - YIj) / LL;
  475. TX = (XOj - XIj) / LL;
  476. FINSI;
  477. SI (YIj EGA YOj);
  478. TY = 0.;
  479. TX = -1.;
  480. FINSI;
  481. NX = TY;
  482. NY = -1. * TX;
  483. * Element contenant le point moyen
  484. ELj = MTEST ELEM 'CONTENANT' PGj;
  485. VALXj = MAXI (REDU X0S ELj);
  486. VALYj = MAXI (REDU Y0S ELj);
  487. * Champ nul sauf dans ELi
  488. CHPX = X0S MASQ 'EGALE' VALXj;
  489. CHPY = Y0S MASQ 'EGALE' VALYj;
  490. CHP = CHPX * CHPY;
  491.  
  492. * Champs par elements pour le model EFEM
  493. CHM = CHM + CHP;
  494. CHIX = CHIX + (CHP * XIj);
  495. CHIY = CHIY + (CHP * YIj);
  496. CHNX = CHNX + (CHP * NX);
  497. CHNY = CHNY + (CHP * NY);
  498.  
  499. * Extraction de la mesh de la fissure potentielle
  500. SI(j EGA 1);
  501. LISO = DROI 1 (XIj YIj) (XOj YOj);
  502. MESHi = ELj;
  503. SINON;
  504. LISO = LISO ET (DROI 1 (XIj YIj) (XOj YOj));
  505. MESHi = MESHi ET ELj;
  506. FINSI;
  507. FIN B_INT;
  508. TAB2. 'ISOTOT'. i = LISO;
  509. TAB2. 'MESH_ISO'. i = MESHi;
  510. TAB2. 'MESH'. NPAS = (TAB2. 'MESH'. NPAS) ET MESHi;
  511.  
  512. FIN BOUCLE5;
  513. *TRAC CHM MODEL11;
  514.  
  515. *
  516. *\\\\ Mise a jour des parametres materiaux ////*
  517. *
  518. MATr2 = MATE MODEL11 YOUN E11 NU NU11 FT P11 XNX CHNX
  519. XNY CHNY IND1 CHM XIE CHIX YIE CHIY;
  520. MATr1 = MATr2;
  521. TAB2. 'WTABLE'. 'CARACTERISTIQUES' = MATR1;
  522.  
  523.  
  524. FINSI;
  525.  
  526.  
  527. FINP MATR1 ;
  528.  
  529.  
  530.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales