Télécharger unilater.procedur

Retour à la liste

Numérotation des lignes :

  1. * UNILATER PROCEDUR PV 20/03/13 21:15:11 10548
  2. * MODIF JUILLET 1987 POUR PERMETTRE DES JEUX DANS LES LES 2 DIRECTIONS
  3. *
  4. * CETTE PROCEDURE EST APPELER PAR RESOU
  5. * LES ARGUMENTS SONT : MATAB TABLE CONTENANT LES INFORMATIONS UTILES
  6. * C'EST A DIRE RRR BBB STAT SUP RITOU ET LISEA
  7. * FFF FORCE A METTRE AU SECOND MEMBRE
  8. *
  9. * RRR MATRICE DE RIGIDITE SANS LES APPUIS
  10. * BBB MATRICE DE RIGIDITE DES APPUIS
  11. * STAT LOGIQUE INDIQUANT SI C'EST LE PREMIER PASSAGE
  12. * SUP SUPER ELEMENT EQUIVALENT
  13. * RITOU DERNIERE RAIDEUR UTILISEE DANS LA RESOLUTION
  14. * LISEA DESCRIPTEUR DES APPUIS COURAMMENT ACTIFS
  15. *
  16. 'DEBP' UNILATER MATAB*'TABLE' FFF*'CHPOINT' MCLE/'MOT' FL/'CHPOINT';
  17.  
  18. * Si il y a lieu,nbnegs est le nombre de multiplicateurs de lagrange contenus da
  19. nbnegs = 0;
  20. nbnegt = 0;
  21. mostab ='MOT' 'NOSTAB';
  22.  
  23. LOG_FL='EGA' ('TYPE' FL) 'CHPOINT' ;
  24. LOG_ITER = 'EGA' ('VALE' 'RESO') 'ITER';
  25.  
  26. 'SI' ('EGA' 'INIB' MCLE);
  27. 'ARGU' TEMP*'RIGIDITE';
  28. MATAB.7 = TEMP;
  29. 'ARGU' TEMP*'LISTENTI';
  30. MATAB.6 = TEMP;
  31. MATAB.'OK' = VRAI ;
  32. 'FINSI';
  33.  
  34. * RRR = MATAB.1 ;
  35. BBB = MATAB.2 ;
  36.  
  37. 'SI' LOG_FL ;
  38. FADZ ='EXCO' FL 'FADH' 'NOID' 'LX' ;
  39. FL ='EXCO' FL 'LX' 'NOID' 'LX' ;
  40. chp2 = BBB * FADZ ;
  41. chp_z = BBB * FL ;
  42. FFF = FFF + chp_z + chp2 ;
  43. 'DETR' chp_z ;
  44. 'DETR' chp2 ;
  45. 'FINSI';
  46.  
  47. STAT = MATAB.3 ;
  48.  
  49. 'SI' STAT ;
  50. 'SI' MATAB.'VRAISUP';
  51. SUP = MATAB.4 ;
  52. 'SINON';
  53. RISUP= MATAB.4 ;
  54. 'FINSI';
  55. 'SINON' ;
  56.  
  57. ************************************************************************
  58. * CALCUL DU SUPER ELEMENT (SI BESOIN)
  59. ************************************************************************
  60. MMM ='EXTR' MATAB.1 'MAILLAGE';
  61. MMB ='EXTR' BBB 'MAILLAGE';
  62. ** MMU = MMM 'ELEM' 'APPU' 'LARG' MMB;
  63. NTOT='NBNO' MMM ;
  64. NAPP='NBEL' MMB;
  65. ** MESS ' unilater napp ntot' ' ' NAPP ' ' NTOT ;
  66. ** MESS ' comparaison' ' ' (NAPP ** 2.) ' ' (2 * 6 * NTOT ** 1.333333333) ;
  67. * Le super element est suppose etre en n^2 alors que la matrice est en n ^4/3
  68. 'SI' (((NAPP ** 2.) > ((2 * 6 *NTOT) ** 1.333333)) 'OU' MATAB.'NSYM' 'OU' LOG_ITER);
  69. * MESS ' unilater pas de super element' napp ntot;
  70. RISUP = MATAB.1 ;
  71. MATAB.4 = MATAB.1 ;
  72. MATAB.'VRAISUP'= FAUX ;
  73.  
  74. 'SINON';
  75. * mess ' on calcule le super element';
  76. * je remets l'option NOMU car il y a un problème de normalisation avec les mults
  77. * A voir si elle ne pose pas des problèmes de surcontraintes.
  78. SUP ='SUPER' 'RIGI' MATAB.1 BBB ;
  79. MATAB.4 = SUP ;
  80. MATAB.'VRAISUP'= VRAI ;
  81. 'FINSI';
  82. 'FINSI' ;
  83.  
  84. ISUP = MATAB.'VRAISUP' ;
  85. MATAB.3= VRAI;
  86.  
  87. ************************************************************************
  88. * AU CAS OU IL N'Y AURAIT PAS DE DEPIMP
  89. ************************************************************************
  90. FA = FFF + ('DEPI' BBB 0.);
  91. DEPTOT = FA 'EXCO' 'FLX' 'FLX' ;
  92. 'SI' ISUP ;
  93. RISUP= ('EXTRAI' SUP 'RIGI') ;
  94. ** list resu risup;
  95. ** risup = cano risup;
  96. ** list resu risup;
  97. MASUP= 'EXTRAI' RISUP 'MAIL' ;
  98. DEPTOT = DEPTOT - (DEPTOT REDU MASUP);
  99. F = 'SUPER' 'CHAR' SUP FA ;
  100. f_lx = f 'EXCO' 'FLX' 'NOID';
  101. f_lx_m = f_lx 'EXTR' 'MAIL';
  102. 'SI' ('NEG' ('TYPE' F_LX_m) 'ENTIER');
  103. nbnegs = f_lx_m nbno;
  104. 'FINSI';
  105. 'SINON';
  106. RISUP = MATAB.1 * 1;
  107. F=FA 'ENLE' 'FLX';
  108. 'FINSI';
  109. 'SI' ('NON' MATAB.'VRAISUP');
  110. nbnegs = 0;
  111. 'FINSI';
  112. FDEPTO=F + DEPTOT ;
  113.  
  114. ************************************************************************
  115. * INITIALISATION
  116. ************************************************************************
  117. 'SI' ('NON' STAT);
  118. MATAB.'OK' = VRAI;
  119. 'FINSI';
  120. 'SI' (STAT 'ET' MATAB.'OK') ;
  121. RITOU = MATAB.5 ;
  122. LISEA = MATAB.6 ;
  123. *** BLOINI = BBB ;
  124. FDEPTOT=FDEPTO;
  125. 'SINON' ;
  126. 'SI' ('EXISTE' MATAB 7) ;
  127. BLOINI = MATAB.7;
  128. RITOU = RISUP 'ET' MATAB.7 ;
  129. LISEA = MATAB.6 'ET' ('LECT') ;
  130. FDEPTOT=FDEPTO;
  131. 'SINON';
  132. BLOINI = BBB ;
  133. * RITOU = RISUP * 1.;
  134. RITOU = RISUP 'ET' BLOINI ;
  135. * INITIALISER LISEA A UNE VALEUR IMPOSSIBLE
  136. LISEA ='LECT' -1 ;
  137. FDEPTOT= F ;
  138. 'FINSI';
  139. ** 'MESS' 'on est bien la ';
  140. ** RITOU = RISUP 'ET' BLOINI ;
  141. ** RITOU = RISUP * 1. ;
  142. 'FINSI' ;
  143. *
  144. MATAB.'OK' = VRAI;
  145. matab.5 = 1 ;
  146. matab.6 = 1 ;
  147.  
  148. LITOT ='LECT' ;
  149. BLOTOT = BBB ;
  150.  
  151. nbe = 0;
  152. MAFREIN = 'VIDE' 'MAILLAGE' / 'POI1';
  153. ************************************************************************
  154. * RECHERCHE DES BLOQUAGES ACTIFS
  155. ************************************************************************
  156. OPTION ='MOT' 'RAPIDE';
  157. 'SI' ('EXIS' FL) ;
  158. OPTIO2='MOT' 'INIT';
  159. 'SINON';
  160. OPTIO2='MOT' 'CONT';
  161. 'FINSI';
  162.  
  163. I = 0 ;
  164. NCONV = VRAI ;
  165.  
  166. 'REPETER' BOUCL1 ;
  167. I = I + 1 ;
  168. 'SI' LOG_ITER;
  169. DE = 'RESO' 'NOID' 'NOUNIL' RITOU FDEPTOT;
  170. 'SINON';
  171. MAFREIN*'MAILLAGE' NBE*'ENTIER' DE = 'RESO' 'NOID' 'ENSE' 'NOUNIL' MOSTAB RITOU FDEPTOT ;
  172. nbnegt = 'DIAG' ritou;
  173. 'FINSI';
  174. 'SI' LOG_FL;
  175. BLOTO LISEN LOG1 = BLOTOT 'EXCITER' DEPTOT DE MAFREIN OPTION FL ;
  176. 'SINON';
  177. BLOTO LISEN LOG1 = BLOTOT 'EXCITER' DEPTOT DE MAFREIN OPTION ;
  178. 'FINSI';
  179. 'SI' ('NON' ('VERI' DE));
  180. DE = 'VIDE' 'CHPOINT'/'DIFFUS';
  181. 'MESS' 'mise a zero des deplacements';
  182. 'QUIT' boucl1;
  183. 'FINSI';
  184. * list lisen;
  185. 'SI' ((I 'EGA' 5) 'ET' ('EGA' OPTION 'RAPIDE'));
  186. OPTION ='MOT' 'MOYEN';
  187. 'FINSI';
  188.  
  189. 'SI' (('NEG' 'INIB' MCLE) 'OU' (I 'NEG' 1));
  190. 'SI' ((LISEN 'EGA' LISEA) 'OU' LOG1) ;
  191. 'SI' (I 'NEG' 1) ;
  192. 'SI' ((NBE 'EGA' 0) 'OU' ('EGA' OPTION 'QAPIDE'));
  193. NCONV= FAUX ;
  194. 'QUIT' BOUCL1;
  195. 'SINON';
  196. M1 = 'EXTR' (RISUP ET BLOTO) 'MAIL';
  197. M2 = 'EXTR' RITOU 'MAIL';
  198. M3 = M1 'DIFF' M2;
  199. 'SI' (('NBEL' M3) 'EGA' 0) ;
  200. NCONV= FAUX ;
  201. 'QUIT' BOUCL1 ;
  202. 'FINSI';
  203. 'FINSI';
  204. 'FINSI';
  205. 'FINSI';
  206.  
  207. 'SI' ((LISEN 'DANS' LITOT) 'OU' (('MULT' &BOUCL1 100) 'ET' ('NEG' OPTION 'LENT'))) ;
  208. 'SI' ('EGA' OPTION 'LENT');
  209. 'SI' ('EGA' OPTIO2 'CONT');
  210. OPTIO2= 'MOT' 'INIT';
  211. OPTION= 'MOT' 'RAPIDE';
  212. BLOTO=BBB;
  213.  
  214. LITOT= 'LECT' ;
  215. LISEN=LISEN * -1;
  216. 'MESS' ' *** UNILATER strategie alternative a la' ' ' I ' eme iteration';
  217. mostab = 'MOT' 'STAB';
  218. I=0;
  219. 'SINON';
  220. 'QUIT' BOUCL1;
  221. 'FINSI';
  222. 'SINON';
  223. OPTION = 'MOT' 'LENT';
  224. LITOT = 'LECT';
  225. 'MESS' ' *** UNILATER strategie lente a la' ' ' I ' eme iteration';
  226. 'FINSI';
  227. 'FINSI';
  228. 'FINSI';
  229. LITAN=LITOT;
  230. LITOT=LITOT 'ET' LISEN;
  231. 'DETR' LITAN;
  232. 'DETR' DE ;
  233. * 'SI' ('EXISTE' MATAB 5);
  234. * 'SI' ('NEG' RITOU (MATAB.5)); 'DETR' RITOU; 'FINSI';
  235. * 'SINON';
  236. 'DETR' RITOU;
  237. * 'FINSI';
  238. * 'SI' (I 'NEG' 1);GEO='EXTRAI' BLOT 'MAIL';'DETR' GEO 'TOUT';
  239. * 'DETR' BLOT 'ELEM' ;'FINSI';
  240.  
  241. RITOU = RISUP 'ET' BLOTO ;
  242. BLOT = BLOTO ;
  243. LISEA = LISEN ;
  244. FDEPTOT= FDEPTO;
  245. 'FIN' BOUCL1;
  246.  
  247. * CFBUG = 'CHAINE' ' *** UNILATER convergence a l''iteration ';
  248. * 'MESS' CFBUG ' ' I;
  249. 'SI' (NBE 'NEG' 0) ;
  250. MATAB.'OK' = FAUX;
  251. 'FINSI';
  252.  
  253. MATAB.5 = RITOU ;
  254. MATAB.6 = LISEA ;
  255. MATAB.7 = BLOTO ;
  256. MATAB.13 = nbnegt - nbnegs;
  257.  
  258. 'SI' NCONV ;
  259. NCONV =FAUX;
  260. MATAB.'OK'=FAUX;
  261. 'FINSI';
  262.  
  263. 'SI' NCONV ;
  264. 'MESS' ' *** UNILATER il n y a pas de solution au systeme ';
  265. RITOU = RISUP 'ET' BBB ;
  266. LISEA = 'LECT' 0;
  267. MATAB.5 = RITOU ;
  268. MATAB.6 = LISEA ;
  269. MATAB.7 = BLOTO;
  270. 'SOUCI' 2345;
  271.  
  272. 'SINON';
  273. * CFBUG = 'CHAINE' ' *** UNILATER convergence a l''iteration ';
  274. 'SI' ('NON' MATAB.'OK');
  275. CFBUG = 'CHAINE' ' *** UNILATER non convergence a l''iteration ';
  276. 'MESS' CFBUG I ' ' nbe;
  277. MATAB.13 = 1234 ;
  278. 'SOUCI' 1234;
  279. 'FINSI';
  280. MATAB.'NITER' = I;
  281.  
  282. ************************************************************************
  283. * CALCUL SUR TOUTE LA STRUCTURE
  284. ************************************************************************
  285. 'SI' ISUP;
  286. DE1 ='SUPER' 'DEPL' SUP DE FFF;
  287. DE2 = DE1 'ET' (DE 'ENLE' 'LX') 'NOER';
  288. 'DETR' DE1;
  289. 'DETR' DE ;
  290. 'DETR' FA ;
  291. 'SINON';
  292. DE2 = DE ;
  293. 'FINSI' ;
  294.  
  295. 'SI' LOG_FL;
  296. DE2 = DE2 - FADZ ;
  297. FL = FL 'REDU' (BBB 'EXTR' 'MAIL' 'MULT');
  298. DE3 = DE2 - FL ;
  299. 'DETR' DE2 ;
  300. DE2 = DE3 ;
  301. 'FINSI';
  302. 'FINSI' ;
  303. nbcand = dime lisen;
  304. nbact = somm lisen;
  305. * mess 'unilater convergence a:' ' ' i ' candidats:' ' ' nbcand ' actifs:' ' ' nbact;
  306.  
  307.  
  308.  
  309. 'DETR' F ;
  310. 'DETR' DEPTOT ;
  311. 'DETR' FDEPTOT ;
  312.  
  313. 'SI' ( 'EXISTE' MATAB 50) ;
  314. DE3 = 'MREM' DE2 matab.50 matab.10 matab.11;
  315. 'RESPRO' DE3;
  316. 'SINON' ;
  317. * mess ' dans unilater de2 ';list de2;
  318. 'RESPRO' DE2 ;
  319. 'FINSI' ;
  320.  
  321. 'SI' ('EGA' 'INIB' MCLE);
  322. 'SI' LOG_FL ;
  323. 'RESP' 'bid' 'bid' 'bid' 'bid';
  324. 'SINON';
  325. 'RESP' 'bid' 'bid' 'bid' ;
  326. 'FINSI';
  327. 'FINSI';
  328. 'FINP' ;
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales