Télécharger spplanc.procedur

Retour à la liste

Numérotation des lignes :

  1. * SPPLANC PROCEDUR OF166741 23/02/07 11:58:41 11590
  2. **********************************************************************
  3. * *
  4. * UNE PROCEDURE LE CALCUL DES SPECTRES DE PLANCHER *
  5. * *
  6. **********************************************************************
  7. *
  8. 'DEBPROC' SPPLANC ZTAB*'TABLE' ;
  9. **********************************************************************
  10. **********************************************************************
  11. * *
  12. * PROCEDURE S P P L A N C *
  13. * --------------------------- *
  14. * *
  15. * AUTEUR F. BEN JEMAA (DMT/SEMT/EMSI) *
  16. * *
  17. * CALCUL DES SPECTRES DE PLANCHER PAR UNE APPROCHE ANALYTIQUE *
  18. * THESE DE DOCTORAT DE 3 EME CYCLE 01/10/1990 - 30/03/1994 *
  19. * *
  20. **********************************************************************
  21. * *
  22. * SPPLANC TAB1 *
  23. * *
  24. * TAB1 : OBJET DE TYPE TABLE *
  25. * *
  26. **********************************************************************
  27. * *
  28. * TAB1 : objet de type table contenant *
  29. * *
  30. * *
  31. * Indice Type Commentaires *
  32. * *
  33. * STRUC TABLE Caractéristiques modales *
  34. * de la structure support *
  35. * *
  36. * Indice Type *
  37. * *
  38. * NMODE ENTIER Nombre de modes *
  39. * FREQU TABLE Les frequences modales *
  40. * AMORT TABLE Les amortissements modaux*
  41. * *
  42. * PLANCH TABLE Caractéristiques du *
  43. * Plancher étudié (P) *
  44. * *
  45. * Indice Type *
  46. * *
  47. * LISFREQ LISTREEL Axe fréquentiel du *
  48. * spectre de plancher *
  49. * PAR DEFAUT : *
  50. * discrétisation par la *
  51. * procédure "DISCRFR" *
  52. * *
  53. * COEFFPL TABLE Les coefficients de *
  54. * participation modale *
  55. * en P : ( Qn * PHIn ) / Mn*
  56. * *
  57. * AMORTPL FLOTTANT Amortissement du spectre *
  58. * de plancher à calculer *
  59. * *
  60. * TYPSPPL MOT Type du spectre de *
  61. * plancher *
  62. * 'DEPL' : déplacement *
  63. * 'VITE' : pseudo-vitesse *
  64. * 'ACCE' : pseudo-accél. *
  65. * *
  66. * EXCIT TABLE Données de l'excitation *
  67. * ( processus séparable ) *
  68. * *
  69. * Indice Type *
  70. * *
  71. * ENVE MOT Type de l'enveloppe *
  72. * 'PLATLIN' : *
  73. * montée-plat-descente *
  74. * ( par défaut : plateau ) *
  75. * *
  76. * DUREE FLOTTANT Durée du signal *
  77. * *
  78. * TDEB FLOTTANT Temps où commence *
  79. * le plateau ( montée ) *
  80. * *
  81. * TFIN FLOTTANT Temps où se termine *
  82. * le plateau ( début desc.)*
  83. * *
  84. * DSP EVOLUTION D.S.P. de la fonction *
  85. * aléatoire stationnaire *
  86. **********************************************************************
  87. **********************************************************************
  88. *
  89. *=====================================================================
  90. * LES DONNEES DU PROBLEME
  91. *=====================================================================
  92. *
  93. ZPI = PI ; Z2PI = 2.0 * ZPI ;
  94. *
  95. STRUC = 'MOT' 'STRUC' ;
  96. NMODE = 'MOT' 'NMODE' ;
  97. FREQU = 'MOT' 'FREQU' ;
  98. AMORT = 'MOT' 'AMORT' ;
  99. PLANCH = 'MOT' 'PLANCH' ;
  100. LISFREQ = 'MOT' 'LISFREQ' ;
  101. COEFFPL = 'MOT' 'COEFFPL' ;
  102. AMORTPL = 'MOT' 'AMORTPL' ;
  103. TYPSPPL = 'MOT' 'TYPSPPL' ;
  104. EXCIT = 'MOT' 'EXCIT' ;
  105. DUREE = 'MOT' 'DUREE' ;
  106. ENVE = 'MOT' 'ENVE' ;
  107. TDEB = 'MOT' 'TDEB' ;
  108. TFIN = 'MOT' 'TFIN' ;
  109. DSP = 'MOT' 'DSP' ;
  110. *
  111. ZNMOD = ZTAB. STRUC . NMODE ;
  112. TABF = ZTAB. STRUC . FREQU ;
  113. TEPS = ZTAB. STRUC . AMORT ;
  114. *
  115. TX = ZTAB. PLANCH . COEFFPL ;
  116. EPSPL = ZTAB. PLANCH . AMORTPL ;
  117. ZTYPSP = ZTAB. PLANCH . TYPSPPL ;
  118. *
  119. ZPTLINE = 'MOT' 'PLATLIN' ;
  120. ZPTPLAT = 'MOT' 'PLATEAU' ;
  121. ZT = ZTAB. EXCIT . DUREE ;
  122. ZENVE = ZTAB. EXCIT . ENVE ;
  123. 'SI' ( 'EGA' ZENVE ZPTLINE ) ;
  124. ZTDEB = ZTAB. EXCIT . TDEB ;
  125. ZTFIN = ZTAB. EXCIT . TFIN ;
  126. 'SINON' ;
  127. 'MESS' 'L ENVELOPPE EST CONSIDERE PAR DEFAUT PLATEAU' ;
  128. ZENVE = ZPTPLAT ;
  129. 'FINSI' ;
  130. DSPE = ZTAB. EXCIT . DSP ;
  131. *
  132. *=====================================================================
  133. * CARACTERISATION DU MOUVEMENT DU PLANCHER
  134. * PAR UN PROCESSUS SEPARABLE
  135. *=====================================================================
  136. *
  137. 'MESS' ' ' ;
  138. 'MESS' '==============================================================';
  139. 'MESS' 'CARACTERISATION DU MOUVEMENT DU PLANCHER' ;
  140. 'MESS' '==============================================================';
  141. 'MESS' ' ' ;
  142. 'MESS' 'STRUCTURE SUPPORT : ' ;
  143. 'MESS' '-----------------' ;
  144. *
  145. * DEFINITION DE L'AXE DES TEMPS :
  146. *
  147. IMOD = 0 ;
  148. ZZ1 = 0.0 ;
  149. 'REPETER' BOUCM ZNMOD ;
  150. IMOD = IMOD '+' 1 ;
  151. ZZ0 = ( TABF.IMOD ) '*' ( TEPS.IMOD ) ;
  152. 'SI' ( ZZ0 '>' ZZ1 ) ;
  153. ZI0 = IMOD ;
  154. ZZ1 = ZZ0 ;
  155. 'FINSI' ;
  156. 'FIN' BOUCM ;
  157. *
  158. LTEV = DISCRTM TABF.ZI0 TEPS.ZI0 ZT ;
  159. NTV = 'DIME' LTEV ;
  160. LTEV0 = 'ENLEVER' LTEV 1 ;
  161. NTV1 = NTV '-' 1 ;
  162. *
  163. * CREATION DE L'ENVELOPPE D'EXCITATION
  164. * DANS LE CAS OU L'ENVELOPPE EST LINEAAIRE-PLAT-LINEAIRE
  165. *
  166. TABENV = 'TABLE' ;
  167. TABENV.1 = LTEV ;
  168. 'SI' ( 'EGA' ZENVE ZPTLINE ) ;
  169. ZDT1 = ZTDEB '/' 10.0 ;
  170. LT1 = 'PROG' 0.0 'PAS' ZDT1 ZTDEB ;
  171. LENV1 = LT1 '*' ( 1.0 / ZTDEB ) ;
  172. ZDT2 = ( ZTFIN '-' ZTDEB ) '/' 10.0 ;
  173. LT2 = 'PROG' ( ZTDEB + ZDT2 ) 'PAS' ZDT2 ZTFIN ;
  174. LENV2 = 'PROG' ( 'DIME' LT2 ) '*' 1.0 ;
  175. ZDT3 = ( ZT '-' ZTFIN ) '/' 10.0 ;
  176. LT3 = 'PROG' ( ZTFIN + ZDT3 ) 'PAS' ZDT3 ZT ;
  177. LENV3 = ( 'PROG' ( 'DIME' LT3 ) '*' ZT ) '-' LT3 ;
  178. LENV3 = LENV3 '*' ( 1.0 '/' ( ZT '-' ZTFIN ) ) ;
  179. LT0 = LT1 'ET' LT2 'ET' LT3 ;
  180. LENV0 = LENV1 'ET' LENV2 'ET' LENV3 ;
  181. LENV = 'IPOL' LTEV LT0 LENV0 ;
  182. TITRE 'ENVELOPPE : TDEBUT =' ZTDEB 'TFIN =' ZTFIN ;
  183. ENV = 'EVOL' 'MANU' 'TEMPS' LTEV 'ENVELOP' LENV ;
  184. DESSIN ENV 'CARR' 'MIMA' ;
  185. TABENV.2 = LENV ;
  186. 'FINSI' ;
  187. *
  188. * CALCUL DES COEFFICIENTS D'AJUSTEMENT
  189. * DE LA FONCTION DE TRANSFERT DE LA STRUCTURE SUPPORT
  190. *
  191. * APPEL DE LA PROCEDURE AJUSTE
  192. *
  193. IMOD = 0 ;
  194. LCT0 = 'TABLE' ;
  195. LEPST0 = 'TABLE' ;
  196. 'REPETER' BOUCM ZNMOD ;
  197. IMOD = IMOD '+' 1 ;
  198. *
  199. EPSI = TEPS.IMOD ;
  200. OMGI = TABF.IMOD * Z2PI ;
  201. COEFAJ = AJUSTE TABF.IMOD EPSI TABENV ;
  202. LCT0.IMOD = COEFAJ.1 ;
  203. LEPST0.IMOD = COEFAJ.2 ;
  204. *
  205. TITRE 'C(T0) : F0 =' TABF.IMOD 'EPS0 =' EPSI ;
  206. CT0 = 'EVOL' 'MANU' 'TEMPS' LTEV0 'C(T0)' LCT0.IMOD ;
  207. DESSIN CT0 'CARR' 'MIMA' ;
  208. *
  209. TITRE 'C**2(T0) : F0 =' TABF.IMOD 'EPS0 =' EPSI ;
  210. LCT02 = ( LCT0.IMOD ) * ( LCT0.IMOD ) ;
  211. CT02 = 'EVOL' 'MANU' 'TEMPS' LTEV0 'C**2(T0)' LCT02 ;
  212. DESSIN CT02 'CARR' 'MIMA' ;
  213. *
  214. TITRE 'EPS(T0) : F0 =' TABF.IMOD 'EPS0 =' EPSI ;
  215. EPST0 = 'EVOL' 'MANU' 'TEMPS' LTEV0 'EPS(T0)' LEPST0.IMOD ;
  216. DESSIN EPST0 'CARR' 'MIMA' ;
  217. 'MESS' ' ' ;
  218. 'MESS' 'MODE :' IMOD 'FREQ. :' TABF.IMOD 'AMORT. :' TEPS.IMOD ;
  219. *
  220. FIN BOUCM ;
  221. *
  222. *
  223. ***** CALCUL DES FONCTIONS DE TRANSFERT MODALES APPROCHEES *****
  224. *
  225. *
  226. * DISCRETISATION DE L'AXE DES FREQUENCE
  227. *
  228. FMIN = 0.0 ;
  229. FMAX = 100.0 ;
  230. LFREQ = DISCRFR TABF TEPS FMIN FMAX ;
  231. NFREQ = 'DIME' LFREQ ;
  232. LFREQ2 = LFREQ * LFREQ ;
  233. *
  234. * INTERPOLATION DE LA DSP STATIONNAIRE
  235. * SUR LE NOUVEAU AXE DES FREQUENCES
  236. *
  237. XDSPE = 'EXTRAIRE' DSPE 'ABSC' ;
  238. YDSPE = 'EXTRAIRE' DSPE 'ORDO' ;
  239. YDSPEC = 'IPOL' LFREQ XDSPE YDSPE ;
  240. DSPEC = 'EVOL' 'MANU' 'FREQUENCE' LFREQ 'D.S.P.' YDSPEC ;
  241. *
  242. LZEROF = 'PROG' NFREQ * 0. ;
  243. EVINIT = 'EVOL' 'MANU' LFREQ LZEROF ;
  244. LUNF = 'PROG' NFREQ * 1. ;
  245. ECUN0 = 'EVOL' 'COMP' 'FREQUENCE' LFREQ LZEROF LZEROF ;
  246. ECUN1 = 'EVOL' 'COMP' 'FREQUENCE' LFREQ LUNF LZEROF ;
  247. *
  248. ITEM = 0 ;
  249. TEM1 = 0.0 ;
  250. LVARAPP = 'PROG' ;
  251. DSPAPP = EVINIT ;
  252. DSPAPP1 = EVINIT ;
  253. RVARMAXA = 0.0 ;
  254. REPETER BOUC2 NTV1 ;
  255. ITEM = ITEM + 1 ;
  256. *
  257. TEM2 = 'EXTRAIRE' LTEV0 ITEM ;
  258. DTEM = ( TEM2 - TEM1 ) / ( 2.0 * ZT ) ;
  259. *
  260. IMOD = 0 ;
  261. HA = ECUN0 ;
  262. REPETER BOUC3 ZNMOD ;
  263. IMOD = IMOD + 1 ;
  264. *
  265. LEPSITEM = LEPST0.IMOD ;
  266. EPSITEM = 'EXTRAIRE' LEPSITEM ITEM ;
  267. LCITEM = LCT0.IMOD ;
  268. CITEM = 'EXTRAIRE' LCITEM ITEM ;
  269. *
  270. FREQI = TABF.IMOD ;
  271. FREQI2 = FREQI * FREQI ;
  272. LRE = ( LUNF * FREQI2 ) - LFREQ2 ;
  273. *
  274. RIM = 2.0 * EPSITEM * FREQI ;
  275. LIM = LFREQ * RIM ;
  276. EVCOMP = 'EVOL' 'COMP' 'REIM' 'FREQUENCE' LFREQ
  277. 'REEL' LRE 'IMAGIN' LIM ;
  278. HID = ( ECUN1 / EVCOMP ) * CITEM ;
  279. HIA = HID * FREQI2 * ( -1.0 ) ;
  280. HA = HA + ( HIA * ( TX.IMOD ) ) ;
  281. *
  282. FIN BOUC3 ;
  283. *
  284. ********* MODULE DE LA FONCTION DE TRANSFERT A L'INSTANT T0 **********
  285. *
  286. HA = 'RIMP' HA ;
  287. MODHA = 'EXTRAIRE' HA 'COUR' 1 ;
  288. *
  289. ******** D.S.P. DE LA REPONSE DE LA STRUCTURE A L'INSTANT T0 *********
  290. *
  291. DSPAPP2 = MODHA * MODHA * DSPEC ;
  292. *
  293. ******* VARTIANCE DE LA REPONSE DE LA STRUCTURE A L'INSTANT T0 *******
  294. *
  295. LSOM0 = 'INTG' DSPAPP2 ;
  296. RVAR0 = 'EXTRAIRE' LSOM0 1 ;
  297. LVARAPP = LVARAPP 'ET' LSOM0 ;
  298. *
  299. * LA D.S.P. MOYENNE DE LA REPONSE DE LA STRUCTURE
  300. *
  301. DSPAPP = DSPAPP '+' ( ( DSPAPP1 '+' DSPAPP2 ) '*' DTEM ) ;
  302. *
  303. * MAXIMUM DE LA VARIANCE
  304. * D.S.P. A L'INSTANT OU LA VARIANCE EST MAXIMUM
  305. *
  306. LOGIC1 = ( RVAR0 > RVARMAXA ) ;
  307. LOGIC2 = (( 'ABS' (( RVAR0 - RVARMAXA ) / RVAR0 )) < 1.0E-2 ) ;
  308. SI ( OU LOGIC1 LOGIC2 ) ;
  309. TMAX = TEM2 ;
  310. RVARMAXA = RVAR0 ;
  311. DSPMAX = DSPAPP2 ;
  312. FINSI ;
  313. *
  314. TEM1 = TEM2 ;
  315. DSPAPP1 = DSPAPP2 ;
  316. *
  317. MENAGE ;
  318. FIN BOUC2 ;
  319. *
  320. TITRE 'VARIANCE : NMODE =' ZNMOD ;
  321. LVARAPP = 'INSERER' LVARAPP 1 0. ;
  322. VARAPP = 'EVOL' 'MANU' 'TEMPS' LTEV 'VARIANCE' LVARAPP ;
  323. DESSIN VARAPP 'CARR' 'MIMA' ;
  324. *
  325. *
  326. TITRE 'D.S.P. : NMODE =' ZNMOD ;
  327. LABSC = 'EXTRAIRE' DSPAPP 'ABSC' ; LABSC = 'ENLEVER' LABSC 1 ;
  328. LORDO = 'EXTRAIRE' DSPAPP 'ORDO' ; LORDO = 'ENLEVER' LORDO 1 ;
  329. DSPAPP0 = 'EVOL' 'MANU' 'FREQUENCE' LABSC 'D.S.P.' LORDO ;
  330. DESSIN DSPAPP0 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  331. *
  332. VARMOY = 'EXTRAIRE' ( 'INTG' VARAPP ) 1 ;
  333. VARMOY = VARMOY '/' ZT ;
  334. LENVPL = ( LVARAPP '/' VARMOY ) '**' 0.50 ;
  335. ENVPL = 'EVOL' 'MANU' 'TEMPS' LTEV 'ENVE PL' LENVPL ;
  336. TABENVPL = 'TABLE' ;
  337. TABENVPL.1 = LTEV ;
  338. TABENVPL.2 = LENVPL ;
  339. *
  340. DSPPL = DSPAPP ;
  341. *
  342. *=====================================================================
  343. * CALCUL DU SPECTRE DE PLANCHER
  344. * AMORTISSEMENT : ZTAB. PLANCH . AMORTPL
  345. *=====================================================================
  346. *
  347. 'MESS' ' ' ;
  348. 'MESS' '==============================================================';
  349. 'MESS' 'CALCUL DU SPECTRE DE PLANCHER ( TYPE : ' ZTYPSP ' )' ;
  350. 'MESS' '==============================================================';
  351. 'MESS' ' ' ;
  352. 'MESS' 'AMORTISSEMENT DU SPECTRE : ' EPSPL ;
  353. 'MESS' '------------------------' ;
  354. *
  355. * AXE DES FREQUENCES DU SPECTRE
  356. *
  357. 'SI' ( 'EXIST' ( ZTAB. PLANCH ) LISFREQ ) ;
  358. 'MESS' 'L AXE FREQUENTIEL DU SPECTRE EST DONNE PAR L UTILISATEUR' ;
  359. LFOSC = ZTAB. PLANCH . LISFREQ ;
  360. 'SINON' ;
  361. 'MESS' ' ' ;
  362. 'MESS' 'DISCRETISATION FREQUENTIELLE PAR LA PROCEDURE "DISCRFR" :
  363. [0.5HZ 30.0HZ]' ;
  364. 'MESS' '-------------------------------------------------------' ;
  365. FMINPL = 0.50 ;
  366. FMAXPL = 30.0 ;
  367. LFOSC = DISCRFR TABF TEPS FMINPL FMAXPL ;
  368. 'FINSI' ;
  369. *
  370. NOSC = 'DIME' LFOSC ;
  371. *
  372. IOSC = 0 ;
  373. TABFPL = TABF ;
  374. TEPSPL = TEPS ;
  375. ZNMOD1 = ZNMOD + 1 ;
  376. TEPSPL.ZNMOD1 = EPSPL ;
  377. LNBREAPP = 'PROG' ;
  378. LDELTAPP = 'PROG' ;
  379. LSIGMAPP = 'PROG' ;
  380. LFPICAPP = 'PROG' ;
  381. 'REPETER' BOUC6 NOSC ;
  382. IOSC = IOSC + 1 ;
  383. *
  384. FREQI = 'EXTRAIRE' LFOSC IOSC ;
  385. TABFPL.ZNMOD1 = FREQI ;
  386. OMGI = Z2PI * FREQI ;
  387. *
  388. 'MESS' ' ' ;
  389. 'MESS' '*** OSCILLATEUR AU PLANCHER *** :' FREQI EPSPL ;
  390. *
  391. * CALCUL DES COEFFICIENTS D'AJUSTEMENT
  392. * DE LA FONCTION DE TRANSFERT DE L'OSCILLATEUR AU PLANCHER
  393. *
  394. * APPEL DE LA PROCEDURE AJUSTE
  395. *
  396. COEFAJ = AJUSTE FREQI EPSPL TABENVPL ;
  397. LCI = COEFAJ.1 ;
  398. LEPSI = COEFAJ.2 ;
  399. *
  400. * DISCRETISATION DU DOMAINE DES FREQUENCES POUR L'INTEGRATION
  401. *
  402. LFREQ = DISCRFR TABFPL TEPSPL FMIN FMAX ;
  403. NFREQ = 'DIME' LFREQ ;
  404. LFREQ2 = LFREQ '*' LFREQ ;
  405. *
  406. * INTERPOLATION DE DSPPL SUR LE NOUVEAU AXE FREQUENTIEL
  407. *
  408. XDSPPL = 'EXTRAIRE' DSPPL 'ABSC' ;
  409. YDSPPL = 'EXTRAIRE' DSPPL 'ORDO' ;
  410. YDSPPL1 = 'IPOL' LFREQ XDSPPL YDSPPL ;
  411. DSPPL1 = 'EVOL' 'MANU' 'FREQUENCE' LFREQ 'DSPPL' YDSPPL1 ;
  412. *
  413. FREQI2 = FREQI '*' FREQI ;
  414. LZEROF = 'PROG' NFREQ '*' 0.0 ;
  415. EVINIT = 'EVOL' 'MANU' LFREQ LZEROF ;
  416. LUNF = 'PROG' NFREQ '*' 1.0 ;
  417. LFREQI2 = LUNF '*' FREQI2 ;
  418. LRE = LFREQI2 '-' LFREQ2 ;
  419. ECUN1 = 'EVOL' 'COMP' 'FREQUENCE' LFREQ LUNF LZEROF ;
  420. *
  421. ITEM = 0 ;
  422. TEM1 = 0.0 ;
  423. LVAROSC = 'PROG' ;
  424. DSPAPP1 = EVINIT ;
  425. RVARMAXA = 0.0 ;
  426. 'REPETER' BOUC7 NTV1 ;
  427. ITEM = ITEM '+' 1 ;
  428. *
  429. TEM2 = 'EXTRAIRE' LTEV0 ITEM ;
  430. DTEM = ( TEM2 '-' TEM1 ) '/' ( 2.0 '*' ZT ) ;
  431. CI = 'EXTRAIRE' LCI ITEM ;
  432. EPSI = 'EXTRAIRE' LEPSI ITEM ;
  433. *
  434. RIM = 2.0 '*' EPSI '*' FREQI ;
  435. LIM = LFREQ '*' RIM ;
  436. EVCOMP = 'EVOL' 'COMP' 'REIM' 'FREQUENCE' LFREQ
  437. 'REEL' LRE 'IMAGIN' LIM ;
  438. *
  439. HDEPL = ( ECUN1 / EVCOMP ) * ( CI / ( Z2PI * Z2PI ) ) ;
  440. *
  441. * MODULE DE LA FONCTION DE TRANSFERT A L'INSTANT T0
  442. *
  443. HDEPL = 'RIMP' HDEPL ;
  444. MODHDEPL = 'EXTRAIRE' HDEPL 'COUR' 1 ;
  445. *
  446. ******** D.S.P. DE LA REPONSE DE LA STRUCTURE A L'INSTANT T0 *********
  447. *
  448. DSPAPP2 = MODHDEPL * MODHDEPL * DSPPL1 ;
  449. *
  450. ******* VARTIANCE DE LA REPONSE DE LA STRUCTURE A L'INSTANT T0 *******
  451. *
  452. LSOM0 = 'INTG' DSPAPP2 ;
  453. RVAR0 = 'EXTRAIRE' LSOM0 1 ;
  454. LVAROSC = LVAROSC 'ET' LSOM0 ;
  455. *
  456. * LA D.S.P. MOYENNE DE LA REPONSE DE LA STRUCTURE
  457. *
  458. DSPOSC = ( DSPAPP1 + DSPAPP2 ) * DTEM ;
  459. *
  460. * MAXIMUM DE LA VARIANCE
  461. * D.S.P. A L'INSTANT OU LA VARIANCE EST MAXIMUM
  462. *
  463. LOGIC1 = ( RVAR0 > RVARMAXA ) ;
  464. LOGIC2 = (( 'ABS' (( RVAR0 - RVARMAXA ) / RVAR0 )) < 1.0E-2 ) ;
  465. SI ( OU LOGIC1 LOGIC2 ) ;
  466. TMAX = TEM2 ;
  467. RVARMAXA = RVAR0 ;
  468. DSPMAX = DSPAPP2 ;
  469. FINSI ;
  470. *
  471. TEM1 = TEM2 ;
  472. DSPAPP1 = DSPAPP2 ;
  473. *
  474. MENAGE ;
  475. FIN BOUC7 ;
  476. *
  477. ******************** APPEL DE LA PROCEDURE LIVO **********************
  478. ****** CALCUL DE N0, DELTA, TEMPS MODIFIE TMOD ET FACTEUR DE PIC *****
  479. *
  480. LVAROSC = 'INSERER' LVAROSC 1 0. ;
  481. VAROSC = 'EVOL' 'MANU' 'TEMPS' LTEV 'VAR OSCI' LVAROSC ;
  482. *
  483. * APPEL DE LA PROCEDURE LIVO
  484. *
  485. TPIC = LIVO VAROSC DSPOSC ;
  486. *
  487. LNBREAPP = LNBREAPP 'ET' ( 'PROG' TPIC.1 ) ;
  488. *
  489. LDELTAPP = LDELTAPP 'ET' ( 'PROG' TPIC.2 ) ;
  490. *
  491. LSIGMAPP = LSIGMAPP 'ET' ( 'PROG' TPIC.3 ) ;
  492. *
  493. LFPICAPP = LFPICAPP 'ET' ( 'PROG' TPIC.4 ) ;
  494. *
  495. FIN BOUC6 ;
  496. *
  497. TITRE 'SPECTRE N0 : NMODE =' ZNMOD 'AMORT. PL. =' EPSPL ;
  498. ENBREAPP = 'EVOL' 'MANU' 'FREQUENCE' LFOSC 'N0' LNBREAPP ;
  499. DESSIN ENBREAPP 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  500. *
  501. TITRE 'SPECTRE DELTA : NMODE =' ZNMOD 'AMORT. PL. =' EPSPL ;
  502. EDELTAPP = 'EVOL' 'MANU' 'FREQUENCE' LFOSC 'DELTA' LDELTAPP ;
  503. DESSIN EDELTAPP 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  504. *
  505. TITRE 'SPECTRE SIGMA : NMODE =' ZNMOD 'AMORT. PL. =' EPSPL ;
  506. ESIGMAPP = 'EVOL' 'MANU' 'FREQUENCE' LFOSC 'SIGMA' LSIGMAPP ;
  507. DESSIN ESIGMAPP 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  508. *
  509. TITRE 'SPECTRE FACTPIC : NMODE =' ZNMOD 'AMORT. PL. =' EPSPL ;
  510. EFPICAPP = 'EVOL' 'MANU' 'FREQUENCE' LFOSC 'FACTPIC' LFPICAPP ;
  511. DESSIN EFPICAPP 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  512. *
  513. LSPPLDEP = LFPICAPP * LSIGMAPP ;
  514. ESPPLDEP = 'EVOL' 'MANU' 'FREQUENCE' LFOSC 'SPEC PL' LSPPLDEP ;
  515. *
  516. * TRANSFORMATION DU SRO DE PLANCHER CALCULE EN TYPE VOULU
  517. *
  518. TITRE 'SPECTRE PLANCHER : TYPE_SP =' ZTYPSP 'NMODE =' ZNMOD
  519. 'AMORT. PL. =' EPSPL ;
  520. ZDEPL = 'MOT' 'DEPL' ;
  521. 'SI' ( 'EGA' ZTYPSP ZDEPL ) ;
  522. ESPPLAPP = ESPPLDEP ;
  523. 'SINON' ;
  524. ESPPLAPP = 'CHSP' ESPPLDEP 'ENTR' ZDEPL 'SORT' ZTYPSP ;
  525. 'FINSI' ;
  526. DESSIN ESPPLAPP 'LOGX' 'LOGY' 'CARR' 'MIMA' ;
  527. *
  528. VARP = 'MOT' 'VARP' ;
  529. DSPP = 'MOT' 'DSPP' ;
  530. NBR0 = 'MOT' 'NBR0' ;
  531. DELT = 'MOT' 'DELT' ;
  532. SIGM = 'MOT' 'SIGM' ;
  533. FPIC = 'MOT' 'FPIC' ;
  534. SPPL = 'MOT' 'SPPL' ;
  535. ZTABAPP = 'TABLE' ;
  536. ZTABAPP. VARP = VARAPP ;
  537. ZTABAPP. DSPP = DSPAPP ;
  538. ZTABAPP. NBR0 = ENBREAPP ;
  539. ZTABAPP. DELT = EDELTAPP ;
  540. ZTABAPP. SIGM = ESIGMAPP ;
  541. ZTABAPP. FPIC = EFPICAPP ;
  542. ZTABAPP. SPPL = ESPPLAPP ;
  543. 'FINPROC' ZTABAPP ;
  544.  
  545.  
  546.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales