Télécharger pasapas.procedur

Retour à la liste

* PASAPAS   PROCEDUR  MB234859  24/03/18    21:15:13     11873          
 
'DEBP' PASAPAS  PRECED*'TABLE';
'SAUT' 1 'LIGNE';
'MESS'
'------------------ DEBUT DE LA PROCEDURE PASAPAS --------------------';
************************************************************************
*                                                                      *
*   PRECED      objet de type TABLE                                    *
*               C'est une table donnant , les arguments d'entrees, les *
*               options, puis les  resultats des pas precedents        *
*                                                                      *
* Etat initial au debut du pas de temps decrit par le MCHELM WTAB.ETAT1*
* champs de materiaux :                                                *
*     WTAB.'MAT_REF' materiau etat a la temperature de REFERENCE       *
*     WTAB.'MAT0'    materiau etat debut de calcul                     *
*     WTAB.'MAT1'    materiau fin du pas de temps                      *
*                                                                      *
************************************************************************
 
****************   I PARTIE   ******************************************
* Verifications des infos transmises et valeurs par defaut
PAS_DEFA PRECED ;
* Creation des tables de sortie et initialisations
PAS_INIT PRECED ;
 
WTAB  = PRECED.'WTABLE'      ;
conti = PRECED.'CONTINUATION';
estim = PRECED.'ESTIMATION'  ;
*-----------------------------------------------------------------------
*              Appel aux procedures utilisateurs
*-----------------------------------------------------------------------
'SI' WTAB.'PROCEDURE_PERSO1';
  PRECED.'PERSO1_APPEL' = 1 ;
  PERSO1 PRECED ;
  'SI' ('EXIS' PRECED 'ARRET') ;
    WTAB.'ARRET' = PRECED.'ARRET' ;
  'FINSI' ;
'FINSI';
*
'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  REEV_MEC PRECED 0 ;
'FINSI' ;
*
'SI' WTAB.'PROCEDURE_REEV_THE' ;
  REEV_THE PRECED 0 ;
'FINSI' ;
*-----------------------------------------------------------------------
*              Initialisation ETAT et MATERIAUX
*-----------------------------------------------------------------------
WTAB.'ETAT0'   = PAS_ETAT PRECED WTAB.'TEMPS0'            ;
WTAB.'ETAT1'   = WTAB.'ETAT0'                             ;
WTAB.'MAT0'    = PAS_MATE PRECED WTAB.'ETAT0'             ;
WTAB.'MAT1'    = WTAB.'MAT0'                              ;
*
*---------   initialisation deformation thermique de reference
'SI' WTAB.'FOR_MECA' ;
  'SI' WTAB.'ITHER' ;
    'SI' ('EGA' WTAB.'ETREF' 'INCONNU');
      WTAB.'ETAT_REF'= PAS_ETAT PRECED WTAB.'TEMPS0' 'REFERENCE';
      WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF'          ;
      WTAB.'ETREF'   ='EPTH' WTAB.'MO_TOT' WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
    'FINS' ;
*
    'SI' ('EGA' ('TYPE' WTAB.'TET1') 'CHPOINT');
      TET1 ='CHAN' 'CHAM' WTAB.'TET1' WTAB.'MO_TOT' 'STRESSES' 'TEMPERATURES' ;
    'FINS';
    ETT0  = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
    WTAB.'ETHER1' = ETT0 - WTAB.'ETREF' ;
*
    'SI' WTAB.'POR1';
      WTAB.'MSRTHER1'= PAS_EPTH PRECED WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
    'FINS' ;
  'FINS' ;
'FINS' ;
 
**************************   II PARTIE  *************************
******************************************************************
******************* boucle sur les pas de temps  *****************
******************************************************************
* ------------quelques initialisations de l'algorithme
PASFINAL = 0 ;
IPAS     = 0 ;
IAUTO    = 1 ;
IREREDU  = VRAI;
TEMP0    = WTAB.'TEMPS0';
ISAUV    = VRAI;
DTV      = ('EXTR' WTAB.'TEMPS_CALCULES' 1) - TEMP0 ;
'SI' ( DTV '<' 1.e-15 );
  'SI' WTAB.'FREQUENTIEL' ;
    DTV = 1.e-14 ;
  'SINON' ;
    DTV =('EXTR' WTAB.'TEMPS_CALCULES' 2) - TEMP0 ;
  'FINSI';
'FINSI';
DT_AVANT = DTV ;
*-----------------------------------------------------------------------
*              Debut de la boucle sur les pas de temps
*-----------------------------------------------------------------------
'REPETER' BEXTERN  ;
*
* ----- Determiner le nouvel instant a calculer TI
*
  NPAS = 'DIME' WTAB.'TEMPS_CALCULES';
  ICHG = WTAB.'ICHG'; ICHG=ICHG + 1; WTAB.'ICHG'= ICHG;
  'SI' ( ICHG '>' NPAS) ; 'QUITTER' BEXTERN; 'FINSI';
  TI = 'EXTRAIRE'  WTAB.'TEMPS_CALCULES' ICHG ;
  TIV=TI;
  'SI' WTAB.'FREQUENTIEL' ;
    'SI' (TI '<' TEMP0 ) ;  'ITERER'  BEXTERN ; 'FINSI' ;
  'SINON' ;
    ITERTPS = (TI '<' TEMP0 ) 'OU' (TI 'EGA' PRECED.'TEMPS'. 0) ;
    'SI' ('NON' WTAB.'REEQUILIBRAGE') ;
      ITERTPS = ITERTPS 'OU' ('EGA' TI TEMP0) ;
    'FINSI';
    'SI' ITERTPS ;
      'ITERER' BEXTERN ;
    'FINSI';
  'FINSI';
*
* ----- Ajustement du pas en fonction du nb d iteration du pas precedent
*
  PASFINAL=PASFINAL+1;
  'SI' WTAB.'PAS_AJUSTE';
    DTV=DT_AVANT;
    'SI' WTAB.'CONV';
      'SI' (WTAB.'NOMBRE_ITERATIONS' > 20);
        DTV=DTV'/' (2. ** 0.5);
      'FINSI';
      'SI' (WTAB.'NOMBRE_ITERATIONS' <  7);
        'SI' IREREDU;
          DTV=DTV '*' (2. ** 0.5);
        'FINSI';
      'FINSI';
      DT_AVANT= DTV;
      IREREDU=VRAI;
    'SINON';
      DTV=0.0000000001D0* DT_AVANT;
      DT_AVANT= DT_AVANT /2.;
      IREREDU=FAUX;
    'FINSI';
    TTI = DTV* 1.0000000001 + TEMP0;
    'SI' ( TTI '&lt;EG' TIV );
      TI=TTI;
      PASFINAL=0;
    'FINSI';
  'FINSI';
*
  estim.'TEMPS'=TI;
  'SI' (PASFINAL '>EG' 1.5) ; DT_AVANT= TI-TEMP0; 'FINSI';
  WTAB.'T_FINAL' = TI;
  WTAB.'DT_INIT' = TI-TEMP0;
  'SI'((WTAB.'CONSOLIDATION' 'OU' WTAB.'DYNAMIQUE')
       'ET' (WTAB.'DT_INIT' 'EGA' 0.));
    'ITERER' BEXTERN;
  'FINSI';
  WTAB.'DT'= WTAB.'DT_INIT';
*
* ----- Compteur IPAS des pas de temps calcules
  IPAS = IPAS + 1;
  WTAB.'PAS'=IPAS;
 
* ----- Mise a jour du modele si chargement de type MODE :
  'SI' WTAB.'CHAR_MODE' ;
    MOD1P     =  WTAB.'MODELE' ;
    MODEVOL1  = 'TIRE' PRECED.'MODELE' 'MODE' TI ;
    WTAB.'MODELE' = MODEVOL1 ;
 
    'SI' WTAB.'CHAR_MATE' ;
      MATEVOL1  = 'TIRE' PRECED.'CARACTERISTIQUES' 'MATE' TI ;
      WTAB.'CARACTERISTIQUES' = MATEVOL1 ;
    'FINSI' ;
 
    PAS_MODL PRECED ;
 
*   MaJ table rayonnement :
    'SI' WTAB.'RAYO' ;
      WTAB.'RAYONNEMENT' = 'PRRA' WTAB.'MOD_RAY' ;
    'FINSI' ;
 
*   On sauvegarde les modeles successifs pour analyse resultats :
    ESTIM.'MODELES' = WTAB.'MODELE' ;
 
*   Initialisation TINI si thermique :
    'SI' WTAB.'THE1' ;
      MODX      = WTAB.'MOD_COND' ;
      MODXP     = MOD1P 'EXTR' 'MATE' 'CONDUCTION' ;
      GEO1      = MODX  'EXTR' 'MAIL' ;
      GEO1P     = MODXP 'EXTR' 'MAIL' ;
      DGEO1     = GEO1  'DIFF' GEO1P ;
 
*     Adapation du modele : transport de la solution
      'SI' ((WTAB.'ADAP_MODE') 'ET' ('NON' (TI '<' (WTAB.'TPS1_ADAP')))) ;
        mess '*****  Transport solution adaptation' ;
        IADAP1    = (WTAB.'INDI_ADAP') + 1 ;
        'SI' (IADAP1 '&lt;EG' ('DIME' (WTAB.'LTPS_ADAP'))) ;
          WTAB.'TPS1_ADAP' = WTAB.'LTPS_ADAP' 'EXTR' IADAP1 ;
          WTAB.'INDI_ADAP' = IADAP1 ;
        'SINON' ;
          WTAB.'TPS1_ADAP' = 'MAXI' WTAB.'TEMPS_CALCULES' + 1. ;
        'FINSI' ;
 
*       Projection du champ de temperature sur la partie adaptee :
        DGEO1P    = DGEO1 'INTE' GEO1P ;
        DGEO2P    = (DGEO1 'INTE' GEO1) 'INCLU' DGEO1P 'VOLU' 'BARY'  ;
        CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
        CHAMT1P   = 'CHAN' 'CHAM' DGEO1P CHT1P ;
        CHT2P     = 'PROI' CHAMT1P  DGEO2P ;
        CHT1P     = ('REDU' CHT1P (GEO1P 'DIFF' DGEO1P)) 'ET' CHT2P ;
        CONTI.'TEMPERATURES' = CHT1P ;
 
*       Calcul de la capacite courante sur la partie adaptee :
        DMODX     = 'REDU' MODX DGEO2P ;
        DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
        DMATX     = 'VARI' 'NUAG' DMODX DMATX CHT2P ;
        CAPAX     = 'CAPA' DMODX DMATX ;
        CAPA1P    = ('REDU' (WTAB.'CAPA_COURANTE') (GEO1P 'DIFF' DGEO1P)) 'ET' CAPAX ;
        WTAB.'CAPA_COURANTE' = CAPA1P ;
 
        DGEO1     = (DGEO1 'INTE' GEO1) 'DIFF' DGEO2P ;
      'FINSI' ;
 
*     Calcul temperature dans partie apportee du modele :
      'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
*       Quantite de chaleur sur geometrie GEO1P :
        CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
        CAPA1P    = WTAB.'CAPA_COURANTE' lump ;
        CHQ1P     = CAPA1P * CHT1P ;
*       Quantite de chaleur dans apport :
        DMODX     = 'REDU' MODX DGEO1 ;
        DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
        CHTINIX   = DMATX 'EXCO' 'TINI' 'T' ;
        CHTINIX   = 'CHAN' 'CHPO' CHTINIX DMODX 'MOYE' ;
        DMATX     = 'VARI' 'NUAG' DMODX DMATX CHTINIX ;
        CAPAX     = ('CAPA' DMODX DMATX) lump ;
        CHQX      = CAPAX * CHTINIX ;
*       Calcul T sur GEO1 :
        CAPA1     = CAPA1P et CAPAX ;
        CHTX1     = 'MANU' 'CHPO' GEO1 1 'T' 1. 'NATURE' 'DIFFUS' ;
        CHQX1     = CAPA1 * CHTX1;
        CHT1      = (CHQ1P + CHQX) * ('INVE' CHQX1) ('MOTS' 'Q') ('MOTS' 'Q') ('MOTS' 'T') ;
*        CHT1      = reso CAPA1 (CHQ1P + CHQX) ; comm plus lent avec RESO ;
        CONTI.'TEMPERATURES' = CHT1 ;
      'FINSI' ;
 
*      Sauvegarde TEMPERATURES au debut du pas apres APPORT :
       IND1     = ('DIME' PRECED.'TEMPERATURES_APPORT') - 1 ;
       CHTAPP1  = CONTI.'TEMPERATURES' 'EXCO' 'T' 'TAPP' ;
       PRECED.'TEMPERATURES_APPORT' . IND1 = CHTAPP1 ;
       ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
 
*   Finsi formulation thermiquue
    'FINSI' ;
 
*   Initialisation PROPORTIONS_PHASES si metallurgie :
    'SI' WTAB.'FOR_METALLU' ;
      MODX      = WTAB.'MODELE' 'EXTR' 'FORM' 'METALLURGIE' ;
      MODXP     = MOD1P         'EXTR' 'FORM' 'METALLURGIE' ;
      GEO1      = MODX  'EXTR' 'MAIL' ;
      GEO1P     = MODXP 'EXTR' 'MAIL' ;
      DGEO1     = GEO1 'DIFF' GEO1P ;
      'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
        CHMET0    = CONTI.'PROPORTIONS_PHASES' ;
        DMODX     = 'REDU' MODX DGEO1 ;
        CHMET1    = 'ZERO' DMODX 'VARINTER' ;
        LISCO     = 'EXTR' DMODX 'VARI' ;
        CMP1      = 'EXCO' CHMET1 ('EXTR' LISCO 1) ('EXTR' LISCO 1) ;
        CHMET1    = CHMET1 + (CMP1 + 1.D0);
        CHMET1    = CHMET0 'ET' CHMET1 ;
        CONTI.'PROPORTIONS_PHASES' = CHMET1 'REDU' MODX ;
*trac CHMET1 MODX ;
      'FINSI' ;
    'FINS' ;
 
*   Initialisation MECA si besoin :
    'SI' WTAB.'FOR_MECA' ;
      MODM1    = 'VIDE' 'MMODEL' ;
      MODM1P   = 'VIDE' 'MMODEL' ;
      'SI'  WTAB.'MEC1' ;
        MODM1    = MODM1 'ET' WTAB.'MOD_MEC' ;
        MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'MECANIQUE') ;
      'FINSI' ;
      'SI'  WTAB.'POR1' ;
        MODM1    = MODM1 'ET' WTAB.'MOD_POR' ;
        MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'POREUX') ;
      'FINSI' ;
      'SI' ('NON' ('VIDE' MODM1)) ;
        GEOM1    = 'EXTR' MODM1  'MAIL' ;
        GEOM1P   = 'EXTR' MODM1P 'MAIL' ;
        DGEOM1   = GEOM1 'DIFF' GEOM1P ;
        'SI' ('NON' (('VIDE' DGEOM1) 'OU' ('VIDE' (DGEOM1 'INTE' GEOM1)))) ;
          DMODM1   = 'REDU' MODM1 DGEOM1 ;
 
*         Mise a jour ETREF :
          WTAB.'ETAT_REF'= PAS_ETAT PRECED WTAB.'TEMPS0' 'REFERENCE'  ;
          WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF' ;
          TREF1    = 'EXCO' WTAB.'MAT_REF' 'TREF' 'T' ;
          WTAB.'TEMPERATURE_REFERENCE' = 'CHAN' 'TYPE' TREF1 'TEMPERATURES' ;
          DETREF1  = 'EPTH' DMODM1 WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
          WTAB.'ETREF' = WTAB.'ETREF' 'ET' DETREF1 ;
 
*         Mise a jour ETHER1 :
          ETAT1    = PAS_ETAT PRECED TI ;
          MAT1     = PAS_MATE PRECED ETAT1 ;
          TET1     = ('TIRE' PRECED.'CHARGEMENT' 'TAPP' TI) 'EXCO' 'TAPP' 'T' ;
          DETHER1  = ('EPTH' DMODM1 MAT1 TET1) - DETREF1 ;
          WTAB.'ETHER1' = WTAB.'ETHER1' 'ET' DETHER1 ;
 
*         Mise a jour deplacements et deformations :
          DEPDGEO1 = ('EXCO' ETAT1 ('EXTR' DMODM1 'DEPL')) 'CHAN' 'CHPO' DMODM1 ;
          DEPSL1   = ('EPSI' DMODM1 DEPDGEO1) - DETHER1 ;
 
*         Mise a jour table estimation :
          estim.DEPLACEMENTS               = conti.DEPLACEMENTS 'ET' DEPDGEO1 ;
          estim.CONTRAINTES                = conti.CONTRAINTES  'ET' ('ZERO' DMODM1 'CONTRAIN') ;
          estim.VARIABLES_INTERNES         = conti.VARIABLES_INTERNES  'ET' ('ZERO' DMODM1 'VARINTER') ;
          estim.DEFORMATIONS_INELASTIQUES  = conti.DEFORMATIONS_INELASTIQUES  'ET' ('ZERO' DMODM1 'DEFINELA') ;
          estim.DEFORMATIONS               = conti.DEFORMATIONS 'ET' ('ZERO' DMODM1 'DEFORMAT') ;
 
          'SI' ('EXISTE' PRECED 'DEFORMATIONS_APPORT');
            estim.DEFORMATIONS_APPORT      = conti.DEFORMATIONS_APPORT 'ET' DEPSL1 ;
          'FINSI' ;
        'FINSI' ;
 
      'SINON' ;
            estim.DEFORMATIONS_APPORT      = conti.DEFORMATIONS_APPORT ;
      'FINSI' ;
    'FINSI' ;
 
* Fin traitement CHAR_MODE
  'FINSI' ;
*
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  I_BOTH = 0 ;
  'REPETER' BO_BOTH WTAB.'BOU_METH' ;
    I_BOTH = I_BOTH + 1 ;
*
*   Re-initialisation de WTAB.'CHARGEMENT' en tete de boucle mec-ther
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
      WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT_I' ;
    'FINSI';
*
*   ####################################################################
*   ########### RESOLUTION D'UN PAS SI THERMIQUE/DIFFUSION #############
*   ####################################################################
    'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF') ;
*
*     Se placer dans la configuration adequate
      'SI' WTAB.'FOR_MECA' ;
        'SI' (I_BOTH > 1) ;
          'SI' WTAB.'GRANDS_DEPLACEMENTS' ;
            WTAB.'RECARI'   = VRAI ;
            WTAB.'REA_GEOM' = VRAI ;
            'FORM' WTAB.'FOR' ;
          'FINSI';
        'SINON' ;
          'FORM' WTAB.'GE0_DEB' ;
        'FINSI' ;
      'FINSI' ;
*
      'SI' (TI 'NEG' TEMP0);
        'SI' ('NON' ('EXISTE' PRECED 'PAS_MAX'));
          WTAB.'TEM_CALC' = 'PROG' TI;
        'SINON';
          'SI' ((TEMP0 + PRECED.'PAS_MAX') '>EG' TI);
            WTAB.'TEM_CALC' = 'PROG' TI;
          'SINON';
            WTAB.'TEM_CALC' = 'PROG' TEMP0
                                   'PAS'  PRECED.'PAS_MAX' TI;
            WTAB.'TEM_CALC' = 'ENLE'  WTAB.'TEM_CALC' 1;
          'FINSI';
        'FINSI';
 
*       Mise a jour blocages passes dans chargement
*       -> ISO AVANT MAIS A FAIRE A CHAQUE FOIS SI DEPEND DE LA MECA ??
        'SI' ('EGA' I_BOTH 1) ;
*         Cas BLOCAGES_THERMIQUES (BLOT) :
          'SI' WTAB.'CHAR_BLOT' ;
            BLOT1 = 'TIRE' PRECED.'BLOCAGES_THERMIQUES' 'BLOT' TI ;
            WTAB.'BLOCAGES_THERMIQUES' = BLOT1 ;
          'FINSI' ;
*
*         Cas BLOCAGES_DIFFUSIONS (BLOD) :
          'SI' WTAB.'CHAR_BLOD' ;
            BLOD1 = 'TIRE' PRECED.'BLOCAGES_DIFFUSIONS' 'BLOD' TI ;
            WTAB.'BLOCAGES_DIFFUSIONS' = BLOD1 ;
          'FINSI' ;
        'FINSI' ;
*
* ----- Appel a la procedure thermique (lineaire ou nonlineaire) ----
*
        'SI' ('NON' WTAB.'COUPLAGE'); 'MENAGE'; 'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'NONLINEAIRE');
          CHTER = TRANSNON PRECED;
        'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'LINEAIRE');
          CHTER = TRANSLIN PRECED;
        'FINSI';
        'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
          WTAB.'NOUV_PAS' = ('EXTR' WTAB.'TEM_CALC' 1) - TEMP0;
          CHTER = DUPONT2 PRECED;
        'FINSI';
*
*       Verification d'une erreur en sortie
        'SI' CHTER.'ERREUR';
          'ERREUR' ' ';
        'FINSI';
*
*       Se placer sur la configuration de reference (appel proc ut.)
        'FORM' WTAB.'FOR0' ;
*
*        Reevaluation des donnees du calcul dependant de la temperature
        'SI' WTAB.'PROCEDURE_REEV_THE' ;
          REEV_THE PRECED  1 ;
        'FINSI' ;
      'FINS';
*
    'FINSI' ;
*   ####################################################################
*   ###### RESOLUTION D'UN PAS SI MECANIQUE/MECANIQUE DES FLUIDES ######
*   ####################################################################
    'SI' (WTAB.'FOR_MECA' 'OU' WTAB .'NVSTNL') ;
      'SAUT' 1 'LIGN';
      'MESSAGE' ' Numero du pas : ' IPAS '  Indice d evolution : ' ICHG ' -> temps :' TI;
 
*--------------------- calcul de la temperature ---------------------
* CB215821 : On met la thermique dans le Chargement pour 'TIRER' le chargement
*            au bon instant dans UNPAS pour la MECANIQUE
*            Il faudra faire de meme avec la MECANIQUE si la THERMIQUE en depend
*     'SI' WTAB.'FOR_THER';
*       THTA1='TABLE'; THTA2='TABLE';
*       THTA1.0=TEMP0; THTA1.1=TI;
*       THTA2.0= conti.'TEMPERATURES' 'ENLE' 'LX' ;
*       THTA2.1= estim.'TEMPERATURES' 'ENLE' 'LX' ;
*       CHTH='CHAR' 'T' THTA1 THTA2;
*       CHASANST= WTAB.'CHARGEMENT' 'ENLE' 'T';
*       WTAB.'CHARGEMENT'= CHASANST 'ET' CHTH;
*     'FINSI';
*
*     Se placer sur la configuration de debut de pas
      'FORM' WTAB.'GE0_DEB' ;
*
      'MENA' ;
      IERRMEC = UNPAS PRECED;
*
*     Se placer sur la configuration de reference (appel proc ut.)
      'FORM' WTAB.'FOR0' ;
*
*     Test si on a converge
      'SI' IERRMEC ;
        'ERREUR' 997 ;
      'FINSI';
*
*     Reevaluation des donnees du calcul dependant de la mecanique
      'SI' WTAB.'PROCEDURE_REEV_MEC' ;
        REEV_MEC PRECED 1;
      'FINSI' ;
*
    'FINSI';
*   ####################################################################
*   ############ TEST DE LA CONVERGENCE MECANIQUE THERMIQUE ############
*   ####################################################################
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
*      je cherche la convergence thermo-mecanique : je dois au moins
*      calculer deux fois mon probleme
      WTAB.'CONV_THMEC' = FAUX ;
      'SI' (I_BOTH > 1) ;
*       Test sur toutes les composantes (notamment, si DIFFUSION)
        CHT1     = WTAB.'THER_COURANT' ;
        DUABS2   = 'ABS' (WTAB.'THER_COURANTP' - CHT1) ;
        CRICOH1  = 0. ;
        NBINCO1  = 'DIME' WTAB.'PRIM_TOT' ;
        'REPE' BINCO1 NBINCO1 ;
          LINCOI1  = 'MOTS' ('EXTR' WTAB.'PRIM_TOT' &BINCO1) ;
          MDUABSI1 = 'MAXI' DUABS2 'AVEC' LINCOI1 ;
          NORMI1   = 'MAXI' 'ABS' CHT1 'AVEC' LINCOI1 ;
          'SI' (NORMI1 '&lt;EG' (1.E-14 * MDUABSI1)) ;
            NORMI1 = 1. ;
          'FINS' ;
          CRICOHI1 = MDUABSI1 / NORMI1 ;
          'SI' (CRICOHI1 '>' CRICOH1) ;
            CRICOH1  = CRICOHI1 ;
         'FINS' ;
        'FIN' BINCO1 ;
 
        WTAB.'CONV_THMEC' = CRICOH1 '<' (WTAB . 'CRITERE_COHERENCE') ;
*       Fin de boucle Si ne converge Pas
        'SI'('NON' WTAB.'CONV_THMEC') ;
          'SI' (I_BOTH >EG WTAB.'BOU_METH');
            'MESS' 'PAS DE COHERENCE TROUVEE MECANIQUE THERMIQUE' ;
            'ERREUR' 999;
          'FINSI' ;
        'FINSI' ;
      'FINSI' ;
*     THER_COURANTPrecedent dans WTAB pour test CONVERGENCE_MEC_THE
      WTAB.'THER_COURANTP' = WTAB.'THER_COURANT' ;
    'SINON' ;
*     ici je ne cherche pas la convergence thermomecanique
      WTAB.'CONV_THMEC' = VRAI ;
    'FINSI' ;
*
    'SI' WTAB.'CONV_THMEC' ;
      'QUITTER' BO_BOTH ;
    'FINSI' ;
*
  'FIN' BO_BOTH ;
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
* +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
*
* ----------------------------------------------------------------------
*       Mise a jour de quantites de WTAB a partir de celles a TI
* ----------------------------------------------------------------------
*
* Formulation THERMIQUE
  'SI' WTAB.'FOR_THER';
    'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
      WTAB.'TET0'              = estim.'TEMPERATURES' ;
      WTAB.'VIEUXPAS'          = WTAB.'NOUV_PAS' ;
      WTAB.'RELAXATION_DUPONT' = CHTER.'RELAXATION_DUPONT';
    'FINSI';
  'FINSI' ;
*
* Formulation MECANIQUE
  'SI' WTAB.'FOR_MECA' ;
*
    'SI' WTAB.'ITHER' ;
      WTAB.'TET1'   = WTAB.'TET2';
      WTAB.'ETHER1' = WTAB.'ETHER2';
      'SI' WTAB.'POR1';
        WTAB.'MSRTHER1'= WTAB.'MSRTHER2';
      'FINSI';
    'FINSI' ;
*
    'SI' WTAB.'CHAR_DEFI' ; 
      WTAB.'DEFOR1' = WTAB.'DEFOR2';
    'FINSI';
*
    'SI' WTAB.'DYNAMIQUE' ;
      'SI' ('NON' WTAB.'LIAISON_PERSISTANTE') ;
        WTAB.'FREA1' = WTAB.'FOPL' ;
      'FINSI';
      WTAB.'REAPREC' = estim.'REACTIONS';
    'FINSI';
*
*   Actualiser la configuration de debut de pas
    'SI' ( WTAB.'GRANDS_DEPLACEMENTS' 'OU'
          (WTAB.'FEFP_FORMULATION' 'ET' WTAB.'UPDATE_LAGRANGIAN')) ;
      WTAB.'GE0_DEB' = WTAB.'FOR' ;
    'FINSI';
*
  'FINSI';
*
* Mise a jour du temps initial du prochain pas de temps
  DT2 = (TI - TEMP0) / 10000.;
  'SI' (WTAB.'AUTOMATIQUE' 'OU' ('NON' WTAB.'CONV'));
    TEMP0 = ( TI - TEMP0) *  WTAB.'AUTOCOEF' + TEMP0;
    'MESS' ' Temps effectivement calcule et non converge : ' TEMP0;
  'SINON';
    TEMP0 = TI;
  'FINSI';
  WTAB.'TEMPS0' = TEMP0;
 
* Procedure utilisateur
  'SI' WTAB.'FOR_MECA' ;
    'SI' WTAB.'PROCEDURE_PERSO1' ;
      PRECED.'PERSO1_APPEL' = 2 ;
      PERSO1 PRECED;
      'SI' ('EXIS' PRECED 'ARRET') ;
        WTAB.'ARRET' = PRECED.'ARRET' ;
      'FINSI' ;
      TEMP0 = WTAB.'TEMPS0' ;
    'FINSI';
*
*   Redefinir WTAB.'CHARGEMENT_I'
    'SI' WTAB.'CONVERGENCE_MEC_THE' ;
      WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT' ;
    'FINSI';
  'FINSI';
*
* pour ne pas sauvegarder la matrice de raideur si on doit la recalculer
  'SI' ('EXIS' WTAB 'RRRR') ;
    'SI' WTAB.'RECARI' ;
      'OUBL' WTAB 'RRRR' ;
    'FINSI';
  'FINSI';
*
* ----------------------------------------------------------------------
*        Remplir CONTINUATION et table de resultats + sauvegarde
* ----------------------------------------------------------------------
  ISAUV = PAS_RESU TEMP0 iauto PRECED ;
*
* Option AUTOMATIQUE
  'SI' WTAB.'AUTOMATIQUE'; 
    IAUTO=IAUTO+1;
    'SI' ((WTAB.'AUTOCOEF' 'EGA'  0.9999999D0) 'OU' (TEMP0 '>EG' TI)) ;
      TEMP0=TI;
      'MESS' ' Objectif atteint '; 'MESS' ' ';
      WTAB.'AUTODEUX' = FAUX ;
      WTAB.'AUTORED1' = 0 ;
      WTAB.'AUTOREDU' = 1. ;
      IAUTO=1;
    'SINON';
      'MESS' ' Objectif non atteint: On recommence'; 'MESS' '  ';
      'SI' ( IAUTO >EG WTAB.'AUTOPAS');
        'ERREUR' 1000;
*       'MESS' 'Pilotage non converge  apres ' IAUTO ' pas.';
      'FINSI';
      WTAB.'AUTODEUX'=VRAI;
      ICHG=ICHG - 1; WTAB.'ICHG' = ICHG ;
    'FINSI';
  'FINSI';
*
* Option PAS_AJUSTE
  'SI' WTAB.'PAS_AJUSTE';
    'SI' ((TI < TIV) 'OU' ('NON' WTAB.'CONV')); 
      ICHG=ICHG-1; WTAB.'ICHG' = ICHG ;
    'FINSI';
  'FINSI';
*
  'SI' WTAB.'ARRET';
    'QUITTER' BEXTERN;
  'FINSI';
*
'FIN' BEXTERN;
*-----------------------------------------------------------------------
*              Fin de la boucle sur les pas de temps
*-----------------------------------------------------------------------
'SI' ('NEG' WTAB.'AMORTISSEMENT' 'INCONNU');
  WTAB.'AMORTISSEMENT' = TOTO ;
'FINSI';
*
'SI' ('NEG' ('TYPE'  WTAB.'GE0_DEB') 'MOT') ;
  'OUBL' WTAB 'GE0_DEB' ;
'FINSI' ;
*
* pour forcer le calcul de la rigidite si on  rappele  pasapas
'SI' ('EXIS' WTAB 'RRRR') ;
  'OUBL' WTAB 'RRRR';
'FINSI';
*
* on tue WTAB.'MAT1' s'il existe car il peut etre tres gourmand en place
WTAB.'MAT1' = 'MOT' 'INCONNU';
*
'MESS' ' ';
'MESS'
'------------------- FIN DE LA PROCEDURE PASAPAS ---------------------';
'SAUT' 1 'LIGNE';
************************************************************************
'FINPROC' PRECED ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales