Télécharger la plaquette Cast3M


fr en

Télécharger hrayo.procedur

Retour à la liste

Numérotation des lignes : 

  1. * HRAYO     PROCEDUR  AM        14/04/17    21:15:03     8000           
  2. ************************************************************************
  3.  'DEBPROC' HRAYO mcv*'MMODEL'
  4.            mor1*'MMODEL' mar1*'MCHAML' tt1*'CHPOINT'
  5.            mor2/'MMODEL' mar2/'MCHAML' tt2*'CHPOINT'
  6.            rel12/'MAILLAGE' stefan/'FLOTTANT' ;
  7.  
  8. ************************************************************************
  9. * Calcul d'un coefficient d'échange linéarisé pour le traitement
  10. * du rayonnement infini et face à face :
  11. *
  12. * Données:
  13. *   mcv     : modele de convection (sur maillage standard ou raccord)
  14. *   mor1    : modele de rayonnement defini sur le maillage l1
  15. *   mat1    : champ d'émissivités associé au modèle mor1
  16. *   tt1     : champoint défini sur l1
  17. *   indice 2: idem maillage l2
  18. *             mais mor2 et mar2 inutilisés en cas de rayonnement infini
  19. *             car on va chercher E_IN dans mat1
  20. *   rel12   : géométrie définissant les relations entre le support
  21. *             de l1 et le support de l2
  22. *            (nécessaire pour le rayonnement face à face)
  23. * Resultat
  24. *   h       : coefficient d'échange linéarisé défini sur le modèle mcv
  25. *
  26. ************************************************************************
  27. * constante de Stefan-Boltzmann
  28. 'SI' ('NON' ('EXIS' stefan)) ;
  29.  stefan = 5.673e-8 ;
  30. 'FINSI' ;
  31.  
  32. * extraction des emissivites et transformation en champoint
  33. * (de type SCAL pour les operations arithmétiques)
  34.  
  35. 'SI' ( 'EXIS' rel12 ) ;
  36. * cas du rayonnement face a face ( rel12 existe)
  37.  
  38. * extraction des emissivites et transformation en champoint
  39. * (de type SCAL pour les operations arithmétiques)
  40. ee1 = 'EXCO' mar1 'EMIS' 'SCAL';
  41. e1  = 'CHAN' 'CHPO' mor1 ee1 ;
  42.  
  43. ee2 = 'EXCO' mar2 'EMIS' 'SCAL';
  44. ex2 = 'CHAN' 'CHPO' mor2 ee2 ;
  45.  
  46. t1 = 'NOMC' tt1 'SCAL' ;
  47. tx2= 'NOMC' tt2 'SCAL' ;
  48.  
  49. * projection des champs sur le maillage l1
  50.  
  51. rel21 = 'INVE' rel12 ;
  52.  
  53.  t2 = 'KPRO' tx2 rel21 ;
  54.  e2 = 'KPRO' ex2 rel21 ;
  55.  
  56. 'SINON' ;
  57. * cas du rayonnement infini      ( rel12 n'existe pas)
  58.  
  59. ee1 = 'EXCO' mar1 'EMIS' 'SCAL';
  60. e1  = 'CHAN' 'CHPO' mor1 ee1 ;
  61.  
  62.  
  63. 'SI' ('EXIS' MAR1 'E_IN' ) ;
  64.   ee2 = 'EXCO' mar1 'E_IN' 'SCAL';
  65.   ex2 = 'CHAN' 'CHPO' mor1 ee2 ;
  66. 'SINON' ;
  67.   ex2 = 'MANU' 'CHPO' ('EXTR' mor1 'MAIL')
  68.           1 'SCAL' 1. 'NATURE' 'DIFFUS' ;
  69. 'FINSI' ;
  70.  
  71. t1 = 'NOMC' tt1 'SCAL' ;
  72. tx2= 'NOMC' tt2 'SCAL' ;
  73.  
  74. t2 = tx2 ;
  75. e2 = ex2 ;
  76. 'FINSI' ;
  77.  
  78. * calcul sur le maillage l1
  79. r1 = 1. '-' e1 ;
  80. r2 = 1. '-' e2 ;
  81. dd = r1 '*' r2 ;
  82. d = 1. '-' dd ;
  83. ee=(e1 '*' e2) '/' d ;
  84. sie = stefan '*'ee ;
  85. 2t1 = t1 '*' t1; 2t2 = t2 '*' t2;
  86. hh1 = (2t1 '+' 2t2) '*' (t1 '+' t2) ;
  87. hh  = sie '*' hh1 ;
  88. h1 = 'NOMC' hh 'H' 'NATU' DIFFUS  ;
  89.  
  90. * projection sur le mailllage l2
  91. 'SI' ( 'EXIS' rel12 ) ;
  92. * cas du rayonnement face a face
  93. h2 = 'KPRO' h1 rel12 ;
  94. h12 = h1 'ET' h2 ;
  95. 'SINON' ;
  96. * cas du rayonnement infini
  97. h12 = h1 ;
  98. 'FINSI' ;
  99.  
  100. * definition du champ h sur le modele de convection
  101. *he  = 'CHAN' 'CHAM' h12 mcv 'NOEU' ;
  102. he  = 'CHAN' 'CHAM' h12 mcv 'RIGIDITE' ;
  103. h   = 'CHAN' 'TYPE' he  'CARACTERISTIQUE' ;
  104. 'FINPROC' h ;
  105.  
  106.  
  107.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales