Télécharger la plaquette Cast3M


fr en

Télécharger g_cas.procedur

Retour à la liste

Numérotation des lignes : 

  1. * G_CAS     PROCEDUR  JB251061  22/08/09    21:15:02     11426          
  2. * =============================================================================
  3. *       PROCEDURE D'ANALYSE DE LA TABLE D'ENTREE FOURNIE A G_THETA
  4. *       ----------------------------------------------------------
  5. *
  6. * DESCRIPTION : DETERMINE SI LE CALCUL DEMANDE EST PREVU PAR LA VERSION
  7. *               ACTUELLE DE G_THETA, ET PREVIENT L'UTILISATEUR SI LE CAS
  8. *               ENVISAGE N'EST PAS TESTE OU VALIDE PAR LA BASE DE CAS TESTS
  9. *               ACTUELLE.
  10. *               ON EN PROFITE EGALEMENT POUR CREER CERTAINS OBJETS QUI SERONT
  11. *               UTILISES PAR G_THETA.
  12. * =============================================================================
  13. DEBP G_CAS SUPTAB*'TABLE' BOOL*'TABLE';
  14.  
  15. * I - DETERMINATION DU CAS DEMANDE ET VERIFICATION DES DONNEES OBLIGATOIRES
  16. * -------------------------------------------------------------------------
  17.  
  19. NMESS = 2;
  20. NDEC = NMESS + 20;
  21.  
  22. * I.1 - LECTURE DES DONNEES FOURNIES A SUPTAB
  23. * *******************************************
  24.  
  25. * I.1.A - OBJECTIF
  26. SI (NON (EXIS SUPTAB 'OBJECTIF'));
  27.     MESS 'ERREUR : IL FAUT SPECIFIER L INTEGRALE';
  28.     MESS '      A CALCULER PAR UN MOT';
  29.     ERRE 21 ; QUIT G_CAS;
  30. SINON;
  31.     SI (NEG (TYPE SUPTAB.'OBJECTIF') 'MOT');
  32.         MESS 'ERREUR : OBJECTIF INCORRECT. ON ATTEND UN ''MOT''.';
  33.         ERRE 21 ; QUIT G_CAS;
  34.     FINSI;
  35.     GOBJ = MOT SUPTAB.'OBJECTIF';
  36. FINSI;
  37. * MESSAGE
  38. MESS 'OBJECTIF :'/NMESS (MOT GOBJ)/NDEC;
  39.  
  40. * I.1.B - DIMENSION ET MODE DE CALCUL
  41. GDIME = VALE 'DIME';
  42. GMODE = VALE 'MODE';
  43. * MESSAGE
  44. MESSDIME = CHAI 'DIMENSION :'/NMESS GDIME/NDEC;
  45. MESS MESSDIME;
  46. MESSMODE = CHAI 'MODE :'/NMESS GMODE/NDEC;
  47. MESS MESSMODE;
  48.  
  49. * I.1.C - TYPE DE SOLUTION DONNEE
  50. SI (NON ((EXIS SUPTAB 'SOLUTION_RESO') OU (EXIS SUPTAB 'SOLUTION_PASAPAS')));
  51.     MESS 'ERREUR : IL FAUT UNE SOLUTION PROVENANT DE PASAPAS';
  52.     MESS '       OU DE RESO POUR DETERMINER L''INTEGRALE';
  53.     ERRE 21 ; QUIT G_CAS;
  54. SINON;
  55.     SI (EXIS SUPTAB 'SOLUTION_RESO');
  56.         SI (NEG (TYPE SUPTAB.'SOLUTION_RESO') 'CHPOINT');
  57.             MESS 'ERREUR : SOLUTION_RESO INCORRECTE.'
  58.             MESS '       ON ATTEND UN ''CHPOINT''.';
  59.             ERRE 21 ; QUIT G_CAS;
  60.         FINSI;
  61.         GSOLU = 'LINEAIRE';
  62.     SINON;
  63.         GSOLU = MOT 'PASAPAS';
  64.     FINSI;
  65. FINSI;
  66.  
  67. * I.1.D - MODELE MECANIQUE, MATERIAU ET HYPOTHESE DE CALCUL
  68. SI (EGA GSOLU 'LINEAIRE');
  69.     SI (NON (EXIS SUPTAB 'MODELE'));
  70.         MESS 'ERREUR : UNE SOLUTION ISSUE DE RESO NECESSITE UN MODELE';
  71.         ERRE 21 ; QUIT G_CAS;
  72.     FINSI;
  73.     SI (NON (EXIS SUPTAB 'CARACTERISTIQUES'));
  74.         MESS 'ERREUR : IL FAUT DONNER LE CHAMP CARACTERISTIQUE';
  75.         ERRE 21 ; QUIT G_CAS;
  76.     FINSI;
  77.     MOD_TOT = SUPTAB.'MODELE';
  78.     MOD_MEC = EXTR MOD_TOT 'FORM' 'MECANIQUE';
  79.     MAT_MEC = REDU (SUPTAB.'CARACTERISTIQUES') MOD_MEC;
  80.     GHYPO = 'HPP';
  81. SINON;
  82.     SI (EXIS SUPTAB.'SOLUTION_PASAPAS' 'WTABLE');
  83.         MOD_TOT = SUPTAB.'SOLUTION_PASAPAS'.'MODELE';
  84.         WTAB = SUPTAB.'SOLUTION_PASAPAS'.'WTABLE';
  85.         MOD_MEC = WTAB.'MOD_MEC';
  86.         MAT_MEC = WTAB.'MAT_MEC';
  87.     SINON;
  88.         MESS 'Absence de WTABLE !  l execution continue ...';
  89.         MOD_TOT = SUPTAB.'SOLUTION_PASAPAS'.'MODELE';
  90.         WTAB = SUPTAB.'SOLUTION_PASAPAS';
  91.         MOD_MEC = EXTR MOD_TOT 'FORM' 'MECANIQUE';
  92.         MAT_MEC = REDU (WTAB.'CARACTERISTIQUES') MOD_MEC;
  93.     FINSI;
  94.     SUPTAB.'MODELE' = MOD_MEC;
  95.     SI WTAB.'GRANDS_DEPLACEMENTS';
  96.         GHYPO = 'GRANDS_DEPLACEMENTS';
  97.     SINON;
  98.         GHYPO = 'HPP';
  99.     FINSI;
  100.     SI WTAB.'DYNAMIQUE';
  101.         GSOLU = CHAI GSOLU ' ' 'DYNAMIQUE';
  102.     SINON;
  103.         GSOLU = CHAI GSOLU ' ' 'STATIQUE';
  104.     FINSI;
  105. FINSI;
  106. GMTYPE = TABL;
  107. * COMPORTEMENT ELASTIQUE
  108. SI (EXIS MOD_MEC 'MATE' 'ISOTROPE');
  109.     GMTYPE.'ELASTIQUE' = MOT 'ELASTIQUE ISOTROPE';
  110. SINON;
  111.     GMTYPE.'ELASTIQUE' = MOT 'ELASTIQUE ANISOTROPE';
  112. FINSI;
  113. * COMPORTEMENT PLASTIQUE
  114. MPLAS = TABL;
  115. MPLAS.(1) MPLAS.(2) MPLAS.(3) = 'ISOTROPE' 'PARFAIT' 'CINEMATIQUE';
  116. SI (EXIS MOD_MEC 'MATE' 'PLASTIQUE');
  117.     GMTYPE.'PLASTIQUE' = MOT 'PLASTIQUE';
  118.     REPE I (DIME MPLAS);
  119.         SI (EXIS MOD_MEC 'MATE' MPLAS.&I);
  120.             GMTYPE.'PLASTIQUE' = CHAI GMTYPE.'PLASTIQUE' ' ' MPLAS.&I;
  121.         FINSI;
  122.     FIN I;
  123. FINSI;
  124. * COMPORTEMENT VISCOPLASTIQUE
  125. MVISC = TABL;
  126. MVISC.(1) MVISC.(2) MVISC.(3) MVISC.(4) MVISC.(5) MVISC.(6) =
  127.     'NORTON' 'POLYNOMIAL' 'BLACKBURN' 'RCCMR_316' 'RCCMR_304' 'LEMAITRE';
  128. SI (EXIS MOD_MEC 'MATE' 'FLUAGE');
  129.     GMTYPE.'FLUAGE' = MOT 'FLUAGE';
  130.     REPE I (DIME MVISC);
  131.         SI (EXIS MOD_MEC 'MATE' MVISC.&I);
  132.             GMTYPE.'FLUAGE' = CHAI GMTYPE.'FLUAGE' ' ' MVISC.&I;
  133.         FINSI;
  134.     FIN I;
  135. FINSI;
  136.  
  137. * PROPRIETES QUI DEPENDENT D'UN PARAMETRE
  138. CPARA = EXTR MAT_MEC 'COVA';
  139. PPARA = MOTS;
  140. REPE I (DIME CPARA);
  141.     PPARA = PPARA ET (EXTR CPARA &I);
  142. FIN I;
  143. * PROPRIETES QUI DEPENDENT DE LA POSITION
  144. MCOMP = EXTR MAT_MEC 'COMP';
  145. PPOSI = MOTS;
  146. REPE I (DIME MCOMP);
  147.     ICOMP = EXTR MCOMP &I;
  148.     SI (NON (EXIS PPARA ICOMP));
  149.         ICHAM = EXCO MAT_MEC ICOMP;
  150.  
  151. *       On teste le Type car 'COVA' a des exceptions (comme 'ECRO' qui est un EVOLUTION mais consideree constante)
  152. *       Amelioration a prevoir : boucle sur les SOUS-ZONES et s'assurer qu'il y a bien au moins 1 élément...
  153. *       On aimerait bien avoir un operateur qui repond par VRAI ou FAUX si un objet est constant !!!
  154.         ValTyp='TYPE' ('EXTR' ICHAM ICOMP 1 1 1);
  155.         SI ('NEG' ValTyp ('MOT' 'FLOTTANT')); 'ITER' I ; 'FINS';
  156.         SI (NEG (MINI ICHAM) (MAXI ICHAM));
  157.             PPOSI = PPOSI ET ICOMP;
  158.         FINSI;
  159.     FINSI;
  160. FIN I;
  161. * PROPRIETES A GRADIENT
  162. PGRAD = PPARA ET PPOSI;
  163. * DISCONTINUITES MATERIELLES
  164. SI (EXIS SUPTAB 'MODELES_COMPOSITES');
  165.     DISMAT = VRAI;
  166.     TABMOD = SUPTAB.'MODELES_COMPOSITES';
  167. SINON;
  168.     DISMAT = FAUX;
  169. FINSI;
  170. * MESSAGE TYPE DE SOLUTION
  171. MESS 'CALCUL :'/NMESS GSOLU/NDEC;
  172. * MESSAGE HYPOTHESE DE CALCUL
  173. MESS 'HYPOTHESE :'/NMESS GHYPO/NDEC;
  174. * MESSAGE MATERIAU
  175. MESSMAT = CHAI 'COMPORTEMENT :'/NMESS GMTYPE.'ELASTIQUE'/NDEC;
  176. SI (EXIS GMTYPE 'PLASTIQUE');
  177.     MESSMAT = CHAI MESSMAT ' ' GMTYPE.'PLASTIQUE';
  178. FINSI;
  179. SI (EXIS GMTYPE 'FLUAGE');
  180.     MESSMAT = CHAI MESSMAT ' ' GMTYPE.'FLUAGE';
  181. FINSI;
  182. MESS MESSMAT;
  183. * MESSAGE VARIATION DES PROPRIETES
  184. SI DISMAT;
  185.     MESSVAR = CHAI 'PROPRIETES :'/NMESS 'HOMOGENES PAR MORCEAUX'/NDEC;
  186. SINON;
  187.     SI ((DIME PGRAD) > 0);
  188.         MESSVAR = CHAI 'PROPRIETES :'/NMESS 'HETEROGENES A GRADIENT'/NDEC;
  189.     SINON;
  190.         MESSVAR = CHAI 'PROPRIETES :'/NMESS 'HOMOGENES'/NDEC;
  191.     FINSI;
  192. FINSI;
  193. MESS MESSVAR;
  194.  
  195. * I.1.E - MAILLAGE ET TYPE D'ELEMENTS
  196. MAILLAGE = EXTR MOD_MEC 'MAIL';
  197. SUPTAB.'FISSURE' = VIDE 'MAILLAGE';
  198. SI (EXIS SUPTAB 'LEVRE_SUPERIEURE');
  199.     SUPTAB.'FISSURE' = SUPTAB.'FISSURE' ET SUPTAB.'LEVRE_SUPERIEURE';
  200. FINSI;
  201. SI (EXIS SUPTAB 'LEVRE_INFERIEURE');
  202.     SUPTAB.'FISSURE' = SUPTAB.'FISSURE' ET SUPTAB.'LEVRE_INFERIEURE';
  203. FINSI;
  204. * ELEMENTS LINEAIRES OU NONLINEAIRES
  205. ELTYPE = MAILLAGE ELEM 'TYPE';
  206. ELLIN = MOTS 'TRI3' 'QUA4' 'CUB8' 'PRI6' 'PYR5' 'TET4';
  207. ELQUA = MOTS 'TRI6' 'QUA8' 'CU20' 'PR15' 'PY13' 'TE10';
  208. IENLE = LECT;
  209. REPE I (DIME ELTYPE);
  210.     SI (NON (EXIS (ELLIN ET ELQUA) (EXTR ELTYPE &I)));
  211.         IENLE = IENLE ET (LECT &I);
  212.     FINSI;
  213. FIN I;
  214. SI ((DIME IENLE) NEG 0);
  215.     MESS 'ATTENTION : IL Y A DES ELEMENTS ATYPIQUES DANS LE MAILLAGE...';
  216.     MESS '          LE CALCUL SE POURSUIT QUAND MEME.';
  217.     ELTYPE = ENLE ELTYPE IENLE;
  218. FINSI;
  219. SI (NON ((EXIS ELLIN ELTYPE 'ET') OU (EXIS ELQUA ELTYPE 'ET')));
  220.     MESS 'ATTENTION : IL Y A A LA FOIS DES ELEMENTS LINEAIRES ET DES';
  221.     MESS '          ELEMENTS QUADRATIQUES DANS LE MAILLAGE';
  222.     GELDEG = 1.5;
  223. SINON;
  224.     SI (EXIS ELLIN ELTYPE 'ET');
  225.         GELDEG = 1;
  226.     SINON;
  227.         GELDEG = 2;
  228.     FINSI;
  229. FINSI;
  230. * ELEMENTS XFEM OU STANDARD (MASSIF OU COQUE)
  231. SI (EXIS MOD_MEC 'ELEM' 'XQ4R' 'XC8R');
  232.     GELTYP = MOT 'XFEM';
  233. SINON;
  234.     EL2D = MOTS 'TRI3' 'TRI6' 'QUA4' 'QUA8';
  235.     EL3D = MOTS 'CUB8' 'CU20' 'PRI6' 'PR15' 'PYR5' 'PY13' 'TET4' 'TE10';
  236.     SI (NON ((EXIS EL2D ELTYPE 'ET') OU (EXIS EL3D ELTYPE 'ET')));
  237.         MESS 'ERREUR : LE MAILLAGE SUPPORT DU MODELE EST CONSTITUE';
  238.         MESS '       D''ELEMENTS 2D ET 3D.';
  239.         ERRE 21 ; QUIT G_CAS;
  240.     SINON;
  241.         SI ((EGA GDIME 3) ET (EXIS EL2D ELTYPE 'ET'));
  242.             GELTYP = 'STD COQUE';
  243.         SINON;
  244.             GELTYP = MOT 'STD MASSIF';
  245.         FINSI;
  246.     FINSI;
  247. FINSI;
  248. * MESSAGE
  249. MESSELEM = CHAI 'ELEMENTS :'/NMESS GELTYP/NDEC;
  250. MESSELEM = CHAI MESSELEM ' DEGRE' ' ' GELDEG;
  251. MESS MESSELEM;
  252.  
  253. * I.1.F - CHARGEMENT
  254. GCHAR = TABL;
  255. SI (EXIS MOD_TOT 'MATE' 'PRESSION');
  256.     SI (EGA GELTYP 'XFEM');
  257.         GCHAR.'PRESSION' = 'HORS LEVRES';
  258.     SINON;
  259.         MODCHA = EXTR MOD_TOT 'FORM' 'CHARGEMENT';
  260.         MODPRE = EXTR MODCHA 'COMP' 'PRESSION';
  261.         MAILPTOT = EXTR MODPRE 'MAIL';
  262.         MAILPF = INTE MAILPTOT (SUPTAB.'FISSURE');
  263.         SI ((NBEL MAILPF) > 0);
  264.             GCHAR.'PRESSION' = 'SUR LEVRES';
  265.         SINON;
  266.             GCHAR.'PRESSION' = 'HORS LEVRES';
  267.         FINSI;
  268.     FINSI;
  269. SINON;
  270.     GCHAR.'PRESSION' = 'AUCUN';
  271. FINSI;
  272. SI (EGA GSOLU 'LINEAIRE');
  273.     GCHAR.'MECANIQUE' = EXIS SUPTAB 'CHARGEMENTS_MECANIQUES';
  274.     SI (EXIS SUPTAB 'TEMPERATURES');
  275.         GCHAR.'THERMIQUE' = MOT 'DECOUPLE';
  276.     SINON;
  277.         GCHAR.'THERMIQUE' = 'AUCUN';
  278.     FINSI;
  279.     GCHAR.'DEFORMATIONS IMPOSEES' = EXIS SUPTAB 'DEFORMATIONS_IMPOSEES';
  280. SINON;
  281.     CHAR1 = SUPTAB.'SOLUTION_PASAPAS'.'CHARGEMENT';
  282.     GCHAR.'MECANIQUE' = (EXIS CHAR1 'DIMP') OU (EXIS CHAR1 'MECA');
  283.     SI (EXIS CHAR1 'T');
  284.         GCHAR.'THERMIQUE' = MOT 'DECOUPLE';
  285.     SINON;
  286.         SI ((EXIS CHAR1 'TIMP') OU (EXIS CHAR1 'Q') OU
  287.             (EXIS CHAR1 'TECO') OU (EXIS CHAR1 'TERA'));
  288.             GCHAR.'THERMIQUE' = MOT 'COUPLE';
  289.         SINON;
  290.             GCHAR.'THERMIQUE' = 'AUCUN';
  291.         FINSI;
  292.     FINSI;
  293.     GCHAR.'DEFORMATIONS IMPOSEES' = EXIS CHAR1 'DEFI';
  294. FINSI;
  295. NBCHAR = 0;
  296. MESSCHAR = MOT 'CHARGEMENT :';
  297. ICHAR = INDE GCHAR;
  298. REPE I (DIME ICHAR);
  299.     MCHAR = MOT ICHAR.&I;
  300.     SI (NEG NBCHAR 0);
  301.         MESSCHAR = ' ';
  302.     FINSI;
  303.     SI (EGA (TYPE GCHAR.(MOT ICHAR.&I)) 'LOGIQUE');
  304.         SI GCHAR.MCHAR;
  305.             MESSCHAR = CHAI MESSCHAR/NMESS MCHAR/NDEC;
  306.             MESS MESSCHAR;
  307.             NBCHAR = NBCHAR + 1;
  308.         FINSI;
  309.     FINSI;
  310.     SI (EGA (TYPE GCHAR.MCHAR) 'MOT');
  311.         SI (NEG GCHAR.MCHAR 'AUCUN');
  312.             MESSCHAR = CHAI MESSCHAR/NMESS MCHAR/NDEC;
  313.             MESSCHAR = CHAI MESSCHAR ' ' GCHAR.MCHAR;
  314.             MESS MESSCHAR;
  315.             NBCHAR = NBCHAR + 1;
  316.         FINSI;
  317.     FINSI;
  318. FIN I;
  319.  
  320. * I.1.G - CONTACT ENTRE LEVRES DE FISSURE
  321. BCONT = (EXIS SUPTAB 'MODELE_FISSURE');
  322. MESS 'CONTACT LEVRES :'/NMESS BCONT/NDEC;
  323.  
  324.  
  325. * I.2 - VERIFICATION QUE LE CAS EST TRAITABLE
  326. * *******************************************
  327.  
  328. * I.2.A - VERIFICATION QUE L'ON CONNAIT L'OBJECTIF
  329. SI ((NEG GOBJ 'J') ET (NEG GOBJ 'C*') ET (NEG GOBJ 'C*H')
  330.         ET (NEG GOBJ 'DJ/DA') ET (NEG GOBJ 'J_DYNA')
  331.             ET (NEG GOBJ 'DECOUPLAGE'));
  332.     MESS 'ERREUR : ON NE CONNAIT PAS L INTEGRALE SPECIFIEE';
  333.     MESS '       A CALCULER';
  334.     ERRE 21 ; QUIT G_CAS;
  335. FINSI;
  336.  
  337. * I.2.B - VERIFICATION QUE LE MATERIAU EST ISOTROPE
  338. SI (EGA GMTYPE.'ELASTIQUE' (MOT 'ELASTIQUE ANISOTROPE'));
  339.     MESS 'ERREUR : ON NE PEUT PAS TRAITER LE CAS DE MATERIAUX ANISOTROPES.';
  340.     ERRE 21 ; QUIT G_CAS;
  341. FINSI;
  342.  
  343. * I.2.C - VERIFICATION QUE L'ON A PAS A LA FOIS DES INTERFACES ET DES GRADIENTS
  344. *        DE PROPRIETES
  345. SI (DISMAT ET ((DIME PGRAD) > 0));
  346.     MESS 'ERREUR : ON NE PEUT PAS TRAITER LE CAS DE DISCONTINUITES';
  347.     MESS '       MATERIELLES DANS UN SOLIDE A GRADIENT DE PROPRIETES';
  348.     ERRE 21 ; QUIT G_CAS;
  349. FINSI;
  350.  
  351. * I.2.D - INTERFACES (2D SEULEMENT, ET ON DOIT AVOIR AU MOINS DEUX MODELES)
  352. SI DISMAT;
  353.     SI (EGA GDIME 3);
  354.         MESS 'ERREUR : ON NE PEUT PAS ENCORE TRAITER LES DISCONTINUITES DE';
  355.         MESS '       PROPRIETES EN 3D';
  356.         ERRE 21 ; QUIT G_CAS;
  357.     FINSI;
  358.     SI ((DIME SUPTAB.'MODELES_COMPOSITES') < 2);
  359.         MESS 'ERREUR : IL FAUT AU MOINS DEUX MODELES POUR';
  360.         MESS '       DETERMINER LA LIGNE COMMUNE D''INTERFACE';
  361.         ERRE 21 ; QUIT G_CAS;
  362.     FINSI;
  363. FINSI;
  364.  
  365. * I.2.E - OBJECTIF : J
  366. SI (EGA GOBJ 'J');
  367.     SI (EXIS GMTYPE 'FLUAGE');
  368.         MESS 'ERREUR : ON ATTEND UN COMPORTEMENT ELASTOPLASTIQUE POUR';
  369.         MESS '       CALCULER L''INTEGRALE J';
  370.         ERRE 21 ; QUIT G_CAS;
  371.     FINSI;
  372. FINSI;
  373.  
  374. * I.2.F - OBJECTIF : C* OU C*H
  375. SI ((EGA GOBJ 'C*') OU (EGA GOBJ 'C*H'));
  376.     SI (NON (EXIS GMTYPE 'FLUAGE'));
  377.         MESS 'ERREUR : ON ATTEND UN COMPORTEMENT VISCOPLASTIQUE POUR';
  378.         MESS '       CALCULER L''INTEGRALE' ' ' GOBJ;
  379.         ERRE 21 ; QUIT G_CAS;
  380.     FINSI;
  381.     SI (NEG GCHAR.'THERMIQUE' 'AUCUN');
  382.         MESS 'ERREUR : ON NE PEUT PAS ENCORE CALCULER L''INTEGRALE' ' ' GOBJ;
  383.         MESS '       DANS LE CAS D''UN CHARGEMENT THERMIQUE';
  384.         ERRE 21 ; QUIT G_CAS;
  385.     FINSI;
  386.     SI (NEG GHYPO 'HPP');
  387.         MESS 'ERREUR : ON NE PEUT PAS ENCORE CALCULER L''INTEGRALE' ' ' GOBJ;
  388.         MESS '       EN GRANDS DEPLACEMENTS';
  389.         ERRE 21 ; QUIT G_CAS;
  390.     FINSI;
  391.     SI (EGA GOBJ 'C*H');
  392.         REPE I (DIME MVISC);
  393.             SI ((NEG MVISC.&I 'NORTON') ET (EXIS MOD_MEC 'MATE' MVISC.&I));
  394.                 MESS 'ERREUR : IL FAUT UN MODELE DE FLUAGE NORTON';
  395.                 MESS '       SEUL POUR CALCULER L INTEGRALE' ' ' GOBJ;
  396.                                 ERRE 21 ; QUIT G_CAS;
  397.             FINSI;
  398.         FIN I;
  399.     FINSI;
  400. FINSI;
  401.  
  402. * I.2.G - OBJECTIF : DJ/DA
  403. SI (EGA GOBJ 'DJ/DA');
  404.     SI (EXIS GMTYPE 'FLUAGE');
  405.         MESS 'ERREUR : ON ATTEND UN COMPORTEMENT ELASTOPLASTIQUE POUR';
  406.         MESS '       CALCULER L''INTEGRALE DJ/DA';
  407.         ERRE 21 ; QUIT G_CAS;
  408.     FINSI;
  409.     SI (DISMAT OU ((DIME PGRAD) > 0));
  410.         MESS 'ERREUR : ON NE PEUT CALCULER L''INTEGRALE DJ/DA QUE';
  411.         MESS '       DANS LE CAS DE PROPRIETES HOMOGENES';
  412.         ERRE 21 ; QUIT G_CAS;
  413.     FINSI;
  414.     SI (NEG GELTYP 'STD MASSIF');
  415.         MESS 'ERREUR : ON NE PEUT CALCULER L''INTEGRALE DJ/DA QU''AVEC';
  416.         MESS '       DES ELEMENTS STANDARDS MASSIFS';
  417.         ERRE 21 ; QUIT G_CAS;
  418.     FINSI;
  419.     SI (NEG GHYPO 'HPP');
  420.         MESS 'ERREUR : ON NE PEUT CALCULER L''INTEGRALE DJ/DA QUE';
  421.         MESS '       SOUS L''HYPOTHESE DES PETITES PERTURBATIONS';
  422.         ERRE 21 ; QUIT G_CAS;
  423.     FINSI;
  424.     SI (NON (EXIS SUPTAB 'BLOCAGES_MECANIQUES'));
  425.         MESS 'ERREUR : IL FAUT DONNER LES BLOCAGES MECANIQUES';
  426.         MESS '       POUR CALCULER L''INTEGRALE DJ/DA'
  427.         ERRE 21 ; QUIT G_CAS;
  428.     FINSI;
  429. FINSI;
  430.  
  431. * I.2.H - OBJECTIF : J_DYNA
  432. SI (EGA GOBJ 'J_DYNA');
  433.     SI ((EXIS GMTYPE 'PLASTIQUE') OU (EXIS GMTYPE 'FLUAGE'));
  434.         MESS 'ERREUR : ON ATTEND UN COMPORTEMENT ELASTIQUE POUR CALCULER';
  435.         MESS '       L''INTEGRALE J_DYNA';
  436.         ERRE 21 ; QUIT G_CAS;
  437.     FINSI;
  438.     SI (NEG GSOLU (MOT 'PASAPAS DYNAMIQUE'));
  439.         MESS 'ERREUR : ON ATTEND UNE SOLUTION DE PASAPAS DYNAMIQUE POUR';
  440.         MESS '       CALCULER L''INTEGRALE J_DYNA';
  441.         ERRE 21 ; QUIT G_CAS;
  442.     FINSI;
  443. FINSI;
  444.  
  445. * I.2.I - OBJECTIF : DECOUPLAGE
  446. SI (EGA GOBJ (MOT 'DECOUPLAGE'));
  447.     SI ((EXIS GMTYPE 'PLASTIQUE') OU (EXIS GMTYPE 'FLUAGE'));
  448.         MESS 'ERREUR : ON ATTEND UN COMPORTEMENT ELASTIQUE POUR UTILISER';
  449.         MESS '       L''OPTION DECOUPLAGE';
  450.         ERRE 21 ; QUIT G_CAS;
  451.     FINSI;
  452.     SI ((DIME PGRAD) > 0);
  453.         MESS 'ERREUR : ON NE PEUT PAS UTILISER L''OPTION DECOUPLAGE POUR UN';
  454.         MESS '       SOLIDE A GRADIENT DE PROPRIETES';
  455.         ERRE 21 ; QUIT G_CAS;
  456.     FINSI;
  457.     SI (EGA GELTYP 'STD COQUE');
  458.         MESS 'ERREUR : ON NE PEUT PAS UTILISER L''OPTION DECOUPLAGE DANS LE';
  459.         MESS '       CAS DE COQUES';
  460.         ERRE 21 ; QUIT G_CAS;
  461.     FINSI;
  462. *   SI IL Y A DES INTERFACES IL FAUT VERIFIER QU'ELLES SONT PARALLELES A LA
  463. *   FISSURE, MAIS LA DIRECTION DE CELLE-CI EST OBTENUE APRES AVOIR CALCULE
  464. *   LE CHAMP THETA, DONC CETTE VERIFICATION EST FAITE DANS G_THETA
  465. FINSI;
  466.  
  467. * I.2.J - CONTACT ENTRE LES LEVRES : UNIQUEMENT AVEC RESO ET XFEM
  468. SI BCONT;
  469.     SI (NEG GSOLU 'LINEAIRE');
  470.         MESS 'ERREUR : CONTACT ENTRE LES LEVRES NON PREVU AVEC UNE SOLUTION';
  471.         MESS '       DE PASAPAS';
  472.         ERRE 21 ; QUIT G_CAS;
  473.     FINSI;
  474.     SI (NEG GELTYP (MOT 'XFEM'));
  475.         MESS 'ERREUR : CONTACT ENTRE LES LEVRES NON PREVU AVEC DES ELEMENTS';
  476.         MESS '       STANDARDS';
  477.         ERRE 21 ; QUIT G_CAS;
  478.     FINSI;
  479. FINSI;
  480.  
  481. * I.2.K - ON VERIFIE QU'IL N'Y A PAS DE GRADIENT DE COEFFICIENT DE POISSON
  482. SI (EXIS PGRAD 'NU');
  483.     MESS 'ERREUR : ON NE SAIT PAS ENCORE TRAITER LA PRESENCE D''UN GRADIENT';
  484.     MESS '       DE COEFFICIENT DE POISSON';
  485.     ERRE 21 ; QUIT G_CAS;
  486. FINSI;
  487.  
  488.  
  489. * I.3 - VERIFICATION DES DONNEES NECESSAIRES
  490. * ******************************************
  491.  
  492. * I.3.A - FRONT DE FISSURE
  493. SI (NON (EXIS SUPTAB 'FRONT_FISSURE'));
  494.     MESS 'ERREUR : ON VEUT LE FRONT DE LA FISSURE';
  495.     ERRE 21 ; QUIT G_CAS;
  496. FINSI;
  497. M_FRONT = SUPTAB.'FRONT_FISSURE';
  498. SI ((NEG (TYPE M_FRONT) 'MAILLAGE') ET (NEG (TYPE M_FRONT) 'POINT'));
  499.     MESS 'ERREUR : LE FRONT DE FISSURE DOIT ETRE DE TYPE MAILLAGE OU POINT';
  500.     ERRE 21 ; QUIT G_CAS;
  501. FINSI;
  502. SI (EGA (TYPE M_FRONT) 'POINT');
  503.     M_FRONT = MANU 'POI1' M_FRONT;
  504. SINON;
  505.     MTYPEL = M_FRONT ELEM 'TYPE';
  506.     MTYPEL = EXTR MTYPEL 1;
  507.     SI (NEG MTYPEL 'POI1');
  508.         M_FRONT = ORDO M_FRONT;
  509.         SUPTAB.'FRONT_FISSURE' = M_FRONT;
  510.     FINSI;
  511. FINSI;
  512. M_FRONT = M_FRONT COUL 'OLIV';
  513.  
  514. * I.3.B - FISSURE_2 ET SON FRONT POUR DJ/DA
  515. SI (EGA GOBJ 'DJ/DA');
  516.     SI ((EXIS SUPTAB 'FISSURE_2') OU (EXIS SUPTAB 'FRONT_FISSURE_2'));
  517.         SI (NON (EXIS SUPTAB 'FISSURE_2'));
  518.             MESS 'ERREUR : ON VEUT AUSSI LA FISSURE 2 POUR CALCULER';
  519.             MESS '       LES TERMES CROISES DE LA MATRICE';
  520.             ERRE 21 ; QUIT G_CAS;
  521.         FINSI;
  522.         SI (NON (EXIS SUPTAB 'FRONT_FISSURE_2'));
  523.             MESS 'ERREUR : ON VEUT AUSSI LE FROND DE LA FISSURE 2 POUR';
  524.             MESS '       CALCULER LES TERMES CROISES DE LA MATRICE';
  525.             ERRE 21 ; QUIT G_CAS;
  526.         FINSI;
  527.     SINON;
  528.         SI (EGA SUPTAB.'COUCHE' 0);
  529.             MESS 'ERREUR : LE NOMBRE DE COUCHES DOIT ETRE SUPERIEUR A';
  530.             MESS '       0 POUR LE CALCUL DU TERME PRINCIPAL DJi/DAi';
  531.             ERRE 21 ; QUIT G_CAS;
  532.         FINSI;
  533.     FINSI;
  534. FINSI;
  535.  
  536. * I.3.C - PRESSION OBLIGATOIRE SI CALCUL LINEAIRE ET MODELE DE PRESSION
  537. SI ((NEG GCHAR.'PRESSION' 'AUCUN') ET (EGA GSOLU 'LINEAIRE'));
  538.     SI (NON (EXIS SUPTAB 'PRESSION'));
  539.         MESS 'ERREUR : IL MANQUE LA DONNEE DU CHAMP DE PRESSION';
  540.         ERRE 21 ; QUIT G_CAS;
  541.     FINSI;
  542. FINSI;
  543.  
  544. * I.3.D - DEFINITION DE LA FISSURE NECESSAIRE
  545. SI (EGA GELTYP (MOT 'XFEM'));
  546.     SI (NON ((EXIS SUPTAB 'PSI') ET (EXIS SUPTAB 'PHI')));
  547.         MESS 'ERREUR : ON VEUT PSI et PHI LEVELSET DE LA FISSURE';
  548.         ERRE 21 ; QUIT G_CAS;
  549.     FINSI;
  550. SINON;
  551.     SI (EGA GT_OBJ 'DECOUPLAGE');
  552.         SI (NON ((EXIS SUPTAB 'LEVRE_SUPERIEURE') ET
  553.                     (EXIS SUPTAB 'LEVRE_INFERIEURE')));
  554.             MESS 'ERREUR : L''OBJECTIF DECOUPLAGE NECESSITE LES DEUX';
  555.             MESS '       LEVRES DE LA FISSURE';
  556.             ERRE 21 ; QUIT G_CAS;
  557.         FINSI;
  558.     SINON;
  559.         SI (NON ((EXIS SUPTAB 'LEVRE_SUPERIEURE') OU
  560.                     (EXIS SUPTAB 'LEVRE_INFERIEURE')));
  561.             MESS 'ERREUR : IL FAUT DONNER LA FISSURE';
  562.             MESS '(LEVRE_SUPERIEURE OU LEVRE_INFERIEURE OU LES 2)';
  563.             ERRE 21 ; QUIT G_CAS;
  564.         FINSI;
  565.     FINSI;
  566. FINSI;
  567.  
  568. * I.3.E - ON VERIFIE QU'ON A OU BIEN LE NOMBRE DE COUCHES OU BIEN CHAMP_THETA
  569. SI (NON ((EXIS SUPTAB 'COUCHE') OU (EXIS SUPTAB 'CHAMP_THETA')));
  570.     MESS 'ERREUR : ON VEUT LE NOMBRE DE COUCHES D ELEMENTS';
  571.     MESS '       AUTOUR DE LA FISSURE QUI SE DEPLACE';
  572.     MESS '       OU LE CHAMP_THETA';
  573.     MESS '       POUR SIMULER LA PROPAGATION DE LA FISSURE';
  574.     ERRE 21 ; QUIT G_CAS;
  575. FINSI;
  576.  
  577. * I.3.F - ON NE CALCULE PAS CORRECTEMENT LE CAS THERMIQUE AVEC DES COQUES
  578. *        DONC POUR L'INSTANT ON DEBRANCHE L'OPTION
  579. SI ((EGA GELTYP 'STD COQUE') ET (NEG GCHAR.'THERMIQUE' 'AUCUN'));
  580.     MESS 'ERREUR : UNE CORRECTION EST NECESSAIRE POUR TRAITER UN CHARGEMENT';
  581.     MESS '       THERMIQUE AVEC LES ELEMENTS COQUE';
  582.     ERRE 21 ; QUIT G_CAS;
  583. FINSI;
  584.  
  585.  
  586. * =============================================================================
  587.  
  588. * II - STOCKAGE DES INFORMATIONS POUR TRANSFERT A G_THETA
  589. * -------------------------------------------------------
  590.  
  591. * II.1 - OBJETS ET INFOS UTILES DANS OBJUTI
  592. * *****************************************
  593.  
  594. OBJUTI = TABL;
  595. OBJUTI.'DIMENSION' = GDIME;
  596. OBJUTI.'MODE' = GMODE;
  597. OBJUTI.'MOD_TOT' = MOD_TOT;
  598. OBJUTI.'MOD_MEC' = MOD_MEC;
  599. OBJUTI.'MAT_MEC' = MAT_MEC;
  600. OBJUTI.'NMESS' = NMESS;
  601. OBJUTI.'MAILLAGE' = MAILLAGE;
  602. OBJUTI.'FRONT' = M_FRONT;
  603. SI (NEG GSOLU 'LINEAIRE');
  604.     OBJUTI.'WTAB' = WTAB;
  605. FINSI;
  606.  
  607. * II.2 - BOOLEENS DANS BOOL
  608. * *************************
  609.  
  610. * OBJECTIF
  611. BOOL.'J' = EGA SUPTAB.'OBJECTIF' 'J';
  612. BOOL.'C*' = EGA SUPTAB.'OBJECTIF' 'C*';
  613. BOOL.'C*H' = EGA SUPTAB.'OBJECTIF' 'C*H';
  614. BOOL.'DJ/DA' = EGA SUPTAB.'OBJECTIF' 'DJ/DA';
  615. BOOL.'J_DYNA' = EGA SUPTAB.'OBJECTIF' 'J_DYNA';
  616. BOOL.'DECOUPLAGE' = EGA SUPTAB.'OBJECTIF' (MOT 'DECOUPLAGE');
  617. * PASAPAS
  618. BOOL.'PASAPAS' = NEG GSOLU 'LINEAIRE';
  619. * GRANDS DEPLACEMENTS
  620. BOOL.'GRANDS_DEP' = EGA GHYPO 'GRANDS_DEPLACEMENTS';
  621. * MODELE DE PRESSION
  622. BOOL.'MODE_PRES' = NEG GCHAR.'PRESSION' 'AUCUN';
  623. * PRESSION SUR FISSURE
  624. BOOL.'PRES_FISS' = EGA GCHAR.'PRESSION' 'SUR LEVRES';
  625. * CHARGEMENTS THERMIQUES
  626. BOOL.'THER_DECO' = EGA GCHAR.'THERMIQUE' (MOT 'DECOUPLE');
  627. BOOL.'THER' = NEG GCHAR.'THERMIQUE' 'AUCUN';
  628. * DEFORMATIONS IMPOSEES
  629. BOOL.'DEF_IMP' = GCHAR.'DEFORMATIONS IMPOSEES';
  630. * ORDRE DES ELEMENTS
  631. BOOL.'EL_LIN' = EGA GELDEG 1;
  632. BOOL.'EL_QUA' = EGA GELDEG 2;
  633. * ELEMENTS XFEM
  634. BOOL.'XFEM' = EXIS MOD_MEC 'ELEM' 'XQ4R' 'XC8R';
  635. * ELEMENTS COQUE
  636. BOOL.'COQ' = EGA GELTYP 'STD COQUE';
  637. * ROTATION DE CORPS RIGIDE
  638. BOOL.'XFEM' = EXIS MOD_MEC 'ELEM' 'XQ4R' 'XC8R';
  639. * ELEMENTS COQUE
  640. BOOL.'XFEM' = EXIS MOD_MEC 'ELEM' 'XQ4R' 'XC8R';
  641. * ELEMENTS COQUE
  642. BOOL.'COQ' = EGA GELTYP 'STD COQUE';
  643. * ROTATION DE CORPS RIGIDE
  644. BOOL.'ROT_RIG' = EXIS SUPTAB 'ROTATION_RIGIDIFIANTE';
  645. * PERSO1
  646. SI (EXIS SUPTAB 'PERSO1');
  647.     BOOL.'PERSO1' = SUPTAB.'PERSO1';
  648. SINON;
  649.     BOOL.'PERSO1' = FAUX;
  650. FINSI;
  651. * FROTTEMENT ENTRE LEVRES DE FISSURE
  652. BOOL.'FROT' = EXIS SUPTAB 'MODELE_FISSURE';
  653.  
  654.  
  655. * SAUT DE LIGNE AVANT DE RETOURNER DANS G_THETA
  656. SAUT 'LIGNE';
  657.  
  658. FINP OBJUTI;
  659.  
  660.  
  661.  
  662.  
  663.  
  664.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales