Télécharger condens.procedur

Retour à la liste

Numérotation des lignes :

  1. * CONDENS PROCEDUR MAGN 09/09/02 21:15:02 6480
  2. DEBPROC CONDENS RXT*TABLE $paroic*MMODEL TP*MOT TF*MOT MRVP*MOT
  3. KHcu*'FLOTTANT';
  4.  
  5. *-------------------------------------------------*
  6. * calcul du flux condensé Jv par Chilton-Colburn *
  7. * et la corrélation de convection naturelle *
  8. * Sh = kL/Dv = 0.13 (Gr Sc)**1/3 *
  9. * Jv = k ro (Yv - Yvsat) en kg/m²s *
  10. *-------------------------------------------------*
  11. *
  12. * indice P pour l'interface fluide (à la distance YP) en P
  13. * indice I pour l'interface paroi/condensante en I
  14. *
  15. * Rv = TBT.'Rgvap' constante des gaz parfait pour la vapeur
  16. *
  17. * YVI = ROVI/ROI fraction massique de vapeur à l'interface en I
  18. * ROVI Densité de vapeur à l'interface (Kg/m**3) en I
  19. *
  20. *
  21. * ROP densité mélange en P
  22. * PvP = ROVP * Rv * (TFP+273.15) pession partielle de vapeur en P
  23. * ROVP densité vapeur en P
  24. *
  25. * TFP : Température bulk du mélange gazeux en P
  26. * Pt : Pression totale dans l'enceinte (0D) en P
  27. *
  28. *
  29. * En sortie
  30. * KKC coefficient d'échange de masse sur l'équation de
  31. * densité de vapeur : KKC*(ROVAP - ROVI) (m/s)
  32. *
  33. * ROVI Densité de vapeur à l'interface (Kg/m**3) en I
  34. *
  35. * HT Coefficient d'échange thermique pour le gaz
  36. * du à la convection (W/m**2/°c)
  37. *
  38. * Fcond densite de flux condense
  39. *
  40. * FHP Fcond*Lv + HT*(Tgaz -Tparoi)
  41. *
  42. *------------------------------------------------------------
  43. * Modif 11/05: Choix du modèle de corrélation MODCOND (cf. notice ENCEINTE)
  44. *
  45. *-------------------------------------------------------------
  46. * La première chose à faire !!!!!
  47. TBT=rxt.'TBT' ;
  48. * La première chose à faire !!!!!
  49.  
  50. Si (non TBT.'VAPEUR') ;
  51. QUITTER CONDENS ;
  52. Finsi ;
  53.  
  54. tic=rxt.'TIC';
  55. Si (exist tic 'FACTEU');
  56. fac=tic.'FACTEU';
  57. Sinon;
  58. fac=1.;
  59. Finsi;
  60.  
  61. *Géométrie
  62. GEO=rxt.'GEO';
  63. paroic = doma $paroic maillage ;
  64. Diagpc = 'DOMA' $paroic 'XXDIAGSI' ;
  65. *
  66. Mui=redu (tic.'Mu') paroic ;
  67.  
  68. ndlc=dime tic.'PT' ;
  69. Pt=extr tic.'PT' ndlc ;
  70. Rhomn=extr tic.'Rhom' ndlc ;
  71. Lv=TBT.'Lv' ;
  72. Cpm= extr tic.'Cpm' ndlc ;
  73. ************************************************************************
  74. * Réduction des grandeurs aux parois
  75.  
  76. TBP=redu tic.TP paroic ;
  77. TFP=redu tic.TF paroic;
  78. ROVPP = redu tic.MRVP paroic ;
  79. ROVPP = 'KOPS' ROVPP '|<' 1.e-10 ;
  80.  
  81. RH2P = 0. ;
  82. Si TBT.'TH2' ;
  83. RH2P = redu tic.'RH2' paroic ;
  84. RH2P = 'KOPS' RH2P '|<' 1.e-10 ;
  85. Finsi ;
  86.  
  87. RHEP = 0. ;
  88. Si TBT.'THE' ;
  89. RHEP = redu tic.'RHE' paroic ;
  90. RHEP = 'KOPS' RHEP '|<' 1.e-10 ;
  91. Finsi ;
  92.  
  93. RO2P = 0. ;
  94. Si TBT.'TO2' ;
  95. RO2P = redu tic.'RO2' paroic ;
  96. RO2P = 'KOPS' RO2P '|<' 1.e-10 ;
  97. Finsi ;
  98.  
  99. RN2P = 0. ;
  100. Si TBT.'TN2' ;
  101. RN2P = redu tic.'RN2' paroic ;
  102. RN2P = 'KOPS' RN2P '|<' 1.e-10 ;
  103. Finsi ;
  104.  
  105. RCO2P= 0. ;
  106. Si TBT.'TCO2' ;
  107. RCO2P= redu tic.'RCO2' paroic ;
  108. RCO2P = 'KOPS' RCO2P '|<' 1.e-10 ;
  109. Finsi ;
  110.  
  111. RCOP = 0. ;
  112. Si TBT.'TCO' ;
  113. RCOP = redu tic.'RCO' paroic ;
  114. RCOP = 'KOPS' RCOP '|<' 1.e-10 ;
  115. Finsi ;
  116.  
  117. * Densité du mélange en limite fluide (en P)
  118. * (ROP issu de la loi d'état si BM1)
  119. ROP=redu tic.'RHO' paroic ;
  120. ROP='KOPS' ROP '|<' 1.e-10 ;
  121.  
  122. * Densité du mélange hors l'air en paroi : ROPa
  123. ROPa= ROVPP + RH2P + RHEP + RO2P + RN2P + RCO2P + RCOP ;
  124.  
  125. * On en déduit la densité de l'air en limite fluide (en P)
  126. RAIRP=ROP - ROPa ;
  127. RAIRP='KOPS' RAIRP '|<' 1.e-10 ;
  128.  
  129. IROP= INVE ROP ;
  130.  
  131. * D'où les fractions massiques (en P)
  132. YVP = ROVPP * IROP ;
  133. YH2P = RH2P * IROP ;
  134. YHEP = RHEP * IROP ;
  135. YO2P = RO2P * IROP ;
  136. YN2P = RN2P * IROP ;
  137. YCO2P = RCO2P * IROP ;
  138. YCOP = RCOP * IROP ;
  139. YAIRP = RAIRP * IROP ;
  140.  
  141. * pression de saturation à l'interface (en I)
  142. PSATI= PSATT (TBP + 273.15) ;
  143. *mess ' Mini Maxi Psat ' (mini Psat) (maxi Psat) ;
  144.  
  145. * pression de vapeur pres de la paroi (en P)
  146. RVT = TBT.'Rgvap' * (Tfp + 273.15);
  147. PvP = ROVPP * RVT ;
  148. *mess ' Mini Maxi PvP ' (mini PvP) (maxi PvP) ;
  149.  
  150. * masse volumique à l'interface (en I)
  151. RVTI = TBT.'Rgvap' * (TBP + 273.15);
  152. ROVI = PSATI * (inve RVTI) ;
  153.  
  154. YINCP = (YVP * 0.0) + 1.0 - YVP ;
  155.  
  156. YO2NP = YO2P + (YAIRP * 0.21) ;
  157. YN2NP = YN2P + (YAIRP * 0.79) ;
  158.  
  159. Rginc = (TBT.'Rgo2'*YO2P) + (TBT.'Rgn2'*YN2P) + (TBT.'Rghe'*YHEP)
  160. + (TBT.'Rgh2'*YH2P) + (TBT.'Rgco'*YCOP) + (TBT.'Rgco2'*YCO2P)
  161. + (TBT.'Rgair'*YAIRP) ;
  162.  
  163. * Pression partielle des incondensables
  164. PINC = Pt - PSATI ;
  165. *mess ' Mini Maxi Pinc ' (mini Pinc) (maxi Pinc) ;
  166.  
  167. RAVI = PINC * YINCP *
  168. ((((abs Rginc) + 1.) * ((abs (TBP + 273.15)) + 1.e-5)) ** (-1.));
  169. *((((abs Rginc) + 1.) * (TBP + 273.15)) ** (-1.)) ;
  170.  
  171. ROI = ROVI + RAVI ;
  172.  
  173. * Fraction massique vapeur à l'interface a saturation
  174. YVI = ROVI * (inve ROI) ;
  175.  
  176. * coefficient de diffusion de la vapeur dans le mélange (m2/s)
  177. DV = VAPDIF Pt (TFP+273.15) YVP YH2P YHEP YO2NP YN2NP YCO2P YCOP ;
  178. *mess 'Mini DV maxi DV ' (mini DV) (MAxi DV) ;
  179.  
  180. * coefficient d'échange de masse k (m/s)
  181.  
  182. BB = 0.13 * ((9.81 * Rhomn *(inve MUi))**0.33333 );
  183. *mess ' mini maxi BB ' (mini bb) (maxi BB) ;
  184. DRO = ((ABS (ROP - ROI))*IROP) ** 0.33333 ;
  185. 'SI' ('EGA' TBT.'MODCOND' 'CHIL1');
  186. may1 = 'MASQUE' (1.-YVI) 'SUPERIEUR' 0.0001;
  187. denom = (may1 * (1.-YVI)) + ((1.-may1) * 0.0001);
  188. DRO = DRO * ('INVE' DENOM);
  189. 'FINSI' ;
  190. KK = (DV ** 0.66667)* DRO * BB ;
  191.  
  192. * Calcul du coefficient Echange convectif
  193. * Ht = DRO*BB*Lambda*(rho*(inve Mui))**0.333
  194. * or Pr = 1 donc Lambda = Mui*Cp
  195. LAMBM = Mui* Cpm ;
  196. HT = DRO * BB * LAMBM * ((Rhomn *(inve Mui))**0.33333) ;
  197.  
  198. * fonction indicatrice de la condensation
  199. DPV = PvP - PSATI ;
  200. *mess 'Mini maxi DPV ' (mini dpv) (maxi dpv) ;
  201. IND = DPV MASQUE 'EGSUP' 0. ;
  202. IND = KCHT $paroic SCAL SOMMET IND ;
  203.  
  204. HT = (HT*IND) - ((IND-1.)*KHcu) ;
  205.  
  206. INDH=HT MASQ 'EGSUP' KHcu ;
  207. HT = (HT*INDH) - ((INDH-1.)*KHcu) ;
  208.  
  209. A1 = 5000. ;
  210. AL1 = 0.8; ALA1 = AL1*A1;
  211. B1 = ALA1 *((2.*(1.-AL1))**(-1.));
  212. IK1 = MASQUE HT 'INFERIEUR' ALA1;
  213. HT = (IK1*HT) + ((1.-IK1)*A1*(HT+B1)*(INVE (A1+HT+B1)));
  214.  
  215. KKC = KK * IND ;
  216. KKC1 = 'KCHT' $paroic 'SCAL' 'SOMMET' KKC ;
  217. KKC1 = KKC1 * fac ;
  218. KKC=NOEL $paroic KKC1 ;
  219.  
  220. * coefficient d'échange pour yvap (kg/m2/s)
  221.  
  222. KRO = (KK * ROP) * IND ;
  223. KRO=kcht $paroic 'SCAL' 'SOMMET' kro ;
  224.  
  225. * calcul de la masse de vapeur condensée QC (kg/s)
  226. DYV = YVP - YVI ;
  227. FCOND = DYV * KRO ;
  228. QC = Diagpc * FCOND ;
  229. QC = ABS (SOMT QC) ;
  230. Econd = TBT.'Cvvap' * (SOMT (Diagpc * FCOND * (Tfp + 273.15))) ;
  231. Hcond = TBT.'Cpvap' * (SOMT (Diagpc * FCOND * (Tfp + 273.15))) ;
  232. Econd = ABS (Econd) ;
  233. Hcond = ABS (Hcond) ;
  234. * Sorties
  235.  
  236. **** Affichage de grandeurs moyennes
  237. volp = 'SOMT' (Diagpc) ;
  238. *'MESS' '==> Tgaz moyen paroi = '((somt (Diagpc * Tfp))/volp) ;
  239. *'MESS' '==> Tpar moyen paroi = '((somt (Diagpc * Tbp))/volp) ;
  240. *'MESS' '==> Yvpa moyen paroi = '((somt (Diagpc * YVP))/volp) ;
  241. *'MESS' '==> KKC (mini) (maxi) = ' (MINI KKC) (MAXI KKC) ;
  242.  
  243. ROVI = 'KCHT' $paroic 'SCAL' 'SOMMET' rovi;
  244. Fcond = 'KCHT' $paroic 'SCAL' 'SOMMET' FCOND ;
  245.  
  246. *------------------------------------------------------
  247. * FHP = densite de flux transmise au mur (W/m2)
  248. * On prend la somme de la convection et de la condensation
  249. * FHP = FCOND * Lv + HT* (Tgaz-Tparoi)
  250. *
  251.  
  252.  
  253. Fconv = ( Tfp - Tbp ) * HT ;
  254. Fconv = 'KCHT' $paroic 'SCAL' 'SOMMET' Fconv ;
  255. Fconv = 'NOEL' $paroic Fconv ;
  256. FHP = ((noel $paroic (FCOND * Lv)) + Fconv ) ;
  257.  
  258. HT = HT * fac;
  259. HT =noel $paroic ht ;
  260.  
  261.  
  262. * Fin calcul du flux condensé Jv par Chilton-Colburn *
  263. *******************************************************
  264. FINPROC QC Fcond Econd Hcond KKC ROVI FHP HT ;
  265.  
  266.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales