Télécharger clinc.procedur

Retour à la liste

Numérotation des lignes :

  1. * CLINC PROCEDUR SERRE 21/06/28 21:15:01 11045
  2. 'DEBP' CLINC rxt*'TABLE' rtf*'TABLE' TKAS*'LOGIQUE' NIC*'MOT' Nj*'MOT' ;
  3. *
  4. * Imposition des conditions aux limites de Dirichlet sur les champs scalaires
  5. * aux Entrées / Sorties du domaine fluide
  6. *
  7. * E/ RXT : TABLE : Données de execrxt
  8. * E/ RTF : TABLE : Description d'une équation scalaire
  9. * E/ TKAS : LOGIQUE : Vrai si le // est actif
  10. * E/ NIC : MOT : Nom de l'inconnue scalaire
  11. * E/ NJ : MOT : Nom de l'indice de Breches . i ou Sorties . i
  12. * contenant la valeur à imposer
  13. *
  14. * /S rtf . 'CLIM' : CHPO : Vecteur des conditions aux limites
  15. *
  16. TBT = rxt . 'TBT' ;
  17. TIC = rxt . 'TIC' ;
  18. GEO = rxt . 'GEO' ;
  19. cpv matxx = 'KOPS' 'MATRIK' ;
  20. mess ' CLINC NIC=' NIC ' ' Nj ;
  21.  
  22. 'SI' ((TBT.'TPAROIF') et ('EGA' NIC 'TF')) ;
  23. TBPW = 'REDU' (tic.'TP') GEO.'paroif' ;
  24. tic.'TBPW' = 'KCHT' GEO.'$paroif' 'SCAL' 'SOMMET' TBPW ;
  25. TBFW = 'REDU' (tic.NIC) GEO.'paroif' ;
  26. tic.'TBFW' = 'KCHT' GEO.'$paroif' 'SCAL' 'SOMMET' TBFW ;
  27. 'FINSI' ;
  28. *
  29. * Prise en compte des Entrées et des Sorties à Timp
  30. 'SI' (TBT . 'TTsortie') ;
  31. NBR = 'DIME' rxt . 'Sorties' ;
  32. ibr = 'INDE' rxt . 'Sorties' ;
  33. 'REPE' BBRS NBR ;
  34. Briches = rxt . 'Sorties' . (ibr.&BBRS) ;
  35. brecheis = Briches . 'srechei' ;
  36. * On ne fait rien pour un clapet de décharge
  37. * ou en extraction (ventilation forcée)
  38. 'SI' ('NON' Briches . 'TTOUT') ;
  39. cpv = cpv 'ET'
  40. ('MANU' 'CHPO' brecheis 1 NIC (Briches . Nj) 'NATURE' 'DISCRET') ;
  41. 'FINS' ;
  42. 'FIN' BBRS ;
  43. 'FINS' ;
  44. 'SI' TBT . 'TTbreche' ;
  45. cpv = cpv 'ET' tic . 'Breches' . NIC ;
  46. 'FINS' ;
  47. *
  48. * Prise en compte du //
  49. 'SI' (TBT . 'TTbreche' 'OU' TBT . 'TTsortie') ;
  50. 'SI' (TKAS 'ET' ('EXIS' rtf 'CLIM')) ;
  51. rtf . 'CLIM' = rtf . 'CLIM' '+' cpv ;
  52. 'SINO' ;
  53. rtf . 'CLIM' = cpv ;
  54. 'FINS' ;
  55. 'FINS' ;
  56. *
  57. * Prise en compte des recomineurs
  58. 'SI' (TBT . 'TRECOMB') ;
  59. cpvrec = rxt . 'TIC' . 'RECOMB' . NIC ;
  60. 'SI' (TBT.'TTbreche' ou TBT.'TTsortie') ;
  61. rtf . 'CLIM' = rtf . 'CLIM' '+' cpvrec ;
  62. 'SINO' ;
  63. rtf . 'CLIM' = cpvrec ;
  64. 'FINS' ;
  65. 'FINS' ;
  66. *
  67. 'FINP' ;
  68.  
  69.  
  70.  
  71.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales