Télécharger la plaquette Cast3M


fr en

Télécharger calcdisp.procedur

Retour à la liste

Numérotation des lignes : 

  1. * CALCDISP  PROCEDUR  GBM       04/12/22    21:15:01     4973           
  2. *---------------------------------------------------------------------
  3. *---------PROCEDURE DE CALCUL DE LA DISPERSIVITE----------------------
  4. *---------------------------------------------------------------------
  5. 'DEBP'  CALCDISP QELEM*'CHPOINT' DISPL*'CHPOINT' DISPT*'CHPOINT'     ;
  6. *  |-----------------------------------------------------------------|
  7. *  | Généralités : CALCDISP calcule le tenseur de dispersion         |
  8. *  |               du problème de transport convection-diffusion.    |
  9. *  |-----------------------------------------------------------------|
  10. *  |                                                                 |
  11. *  |-----------------------------------------------------------------|
  12. *  |                         ENTREES                                 |
  13. *  |-----------------------------------------------------------------|
  14. *  |                                                                 |
  15. *  | ALPHAL   : coefficient longitudinal de dispersivité             |
  16. *  |                                                                 |
  17. *  | ALPHAT   : coefficient transverse de dispersivité               |
  18. *  |                                                                 |
  19. *  | QELEM    : vitesse au centre de chaque élément                  |
  20. *  |-----------------------------------------------------------------|
  21. *  |                         SORTIES                                 |
  22. *  |-----------------------------------------------------------------|
  23. *  |                                                                 |
  24. *  |                                                                 |
  25. *  | dif_disp : C'est le tenseur de dispersion                       |
  26. *  |                                                                 |
  27. *  |                                                                 |
  28. **********************************************************************
  29.  
  30.  
  31.  
  32. * Seulement si présence de convection et présence de
  33. * dispersivité et disp_l et disp_t
  34.  
  35. 'SI' (DISPERSI )                                                       ;
  36. * vpetit = 1.D-20 sur le meme nombre de zone que DISPL
  37.    vpetit =  'MANUEL' 'CHPO' ('EXTRAIRE' DISPL MAILLAGE) 'SCAL' 1.D-30 ;
  38.    vpetit = 'NOMC' 'SCAL' vpetit 'NATU' DISCRET                        ;
  39.    DISPL = 'NOMC' 'SCAL' DISPL                                         ;
  40.    DISPT = 'NOMC' 'SCAL' DISPT                                         ;
  41.  
  42.  
  43. *   on calcul la dispersivité
  44. *   dimension 2
  45.    'SI' ('EGA' ('VALEUR' 'DIME') 2)                                    ;
  46.       V1 = 'EXCO' Qelem 'VX' 'SCAL'                                    ;
  47.       V2 = EXCO Qelem 'VY' 'SCAL'                                      ;
  48.       VC = (V1 * V1) '+' (V2 * V2)                                     ;
  49.       VC = (VC**0.5)                                                   ;
  50.       VC = VC + vpetit                                                 ;
  51.       VCM1 = VC '**' -1                                                ;
  52.       D11P = ((DISPL - DISPT) * V1*V1*VCM1) + (DISPT * VC)             ;
  53.       D22P = ((DISPL - DISPT) * V2*V2*VCM1) + (DISPT * VC)             ; 
  54.       D21P = (DISPL - DISPT) * V1*V2*VCM1                              ;   
  55.  
  56.       D11P = 'NOMC' K11 D11P                                           ;
  57.       D21P = 'NOMC' K21 D21P                                           ; 
  58.       D22P = 'NOMC' K22 D22P                                           ;
  59.       dif_disp = D11P '+' D22P '+' D21P                                ;
  60.  
  61.    'FINSI'                                                             ;
  62. *  dimension 3
  63.    'SI' ('EGA' ('VALEUR' 'DIME') 3)                                    ;
  64.       V1 = 'EXCO' Qelem 'VX' 'SCAL'                                    ;
  65.       V2 = EXCO Qelem 'VY' 'SCAL'                                      ;
  66.       V3 = EXCO Qelem 'VZ' 'SCAL'                                      ;
  67.       VC = (V1 * V1) '+' (V2 * V2) '+' (V3 *  V3)                      ;
  68.       VC = VC**0.5                                                     ;
  69.       VC = VC + vpetit                                                 ;
  70.       VCM1 =  VC '**' -1                                               ;
  71.       D11P = ((DISPL - DISPT) * V1*V1*VCM1) + (DISPT * VC)             ;
  72.       D22P = ((DISPL - DISPT) * V2*V2*VCM1) + (DISPT * VC)             ;
  73.       D33P = ((DISPL - DISPT) * V3*V3*VCM1) + (DISPT * VC)             ;     
  74.       D21P = (DISPL - DISPT) * V1*V2*VCM1                              ;
  75.       D31P = (DISPL - DISPT) * V1*V3*VCM1                              ;
  76.       D32P = (DISPL - DISPT) * V2*V3*VCM1                              ;
  77.  
  78.       D11P = 'NOMC' K11 D11P                                           ;
  79.       D21P = 'NOMC' K21 D21P                                           ; 
  80.       D22P = 'NOMC' K22 D22P                                           ;
  81.       D31P = 'NOMC' K31 D31P                                           ;
  82.       D32P = 'NOMC' K32 D32P                                           ; 
  83.       D33P = 'NOMC' K33 D33P                                           ;
  84.  
  85.       dif_disp = D11P '+' D22P '+' D33P '+' D21P '+' D31P '+' D32P     ;        
  86.    'FINSI'                                                             ;
  87. 'FINSI'                                                                ;
  88.  
  89. 'FINPROC' dif_disp                                                     ;
  90.  
  91.  
  92.  
  93.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales