Télécharger la plaquette Cast3M


fr en

Télécharger TABLO2D.procedur

Retour à la liste

Numérotation des lignes : 

  1. * TABLO2D   PROCEDUR  JC220346  16/05/10    21:15:00     8926           
  2. ************************************************************************
  3. * NOM         : TABLO2D
  4. * DESCRIPTION : Affiche sous forme graphique 2D (matrice de cases
  5. *               colorees) un tableau de valeurs numeriques.
  6. ************************************************************************
  7. * ENTREES : LO  [MOT]      = MOT-CLE VALANT LINE OU LOGA
  8. *           NL  [ENTIER]   = NOMBRE DE LIGNES
  9. *           NC  [ENTIER]   = NOMBRE DE COLONNES
  10. *           LV  [LISTREEL] = LISTE DES NL*NC VALEURS
  11. *           TIT [MOT]      = TITRE DU GRAPHIQUE
  12. * SORTIES : AUCUNE
  13. ************************************************************************
  14. * SYNTAXE :
  15. *
  16. *            TABLO2D | ('LINE') | NLIG NCOL LVAL (TIT) ;
  17. *                    |  'LOGA'  |
  18. *
  19. ************************************************************************
  20. DEBP TABLO2D LO/'MOT' NL*'ENTIER' NC*'ENTIER' LV*'LISTREEL' TIT/'MOT' ;
  21.  
  22. *  MODIFICATION DES OPTIONS
  23.    NDIM1 = VALE 'DIME' ;
  24.    ELTY1 = VALE 'ELEM' ;
  25.    SI (NDIM1 EGA 1) ;
  26.       ERRE 709 'AVEC' NDIM1 ;
  27.    FINS ;
  28.    OPTI 'ELEM' 'QUA4' ;
  29.  
  30. *  ===================
  31. *  PARAMETRES D'ENTREE
  32. *  ===================
  33.  
  34. *  GESTION DE L'ECHELLE
  35.    KLOGA = FAUX ;
  36.    MCOMP = 'X' ;
  37.    MOECH = MOTS 'LINE' 'LOGA' ;
  38.    SI (EXIS LO) ;
  39.       ILO = POSI LO 'DANS' MOECH ;
  40.       SI (ILO > 0) ;
  41.          SI (ILO EGA 2) ;
  42.             KLOGA = VRAI ;
  43.             MCOMP = '10^X' ;
  44.          FINS ;
  45.       SINON ;
  46.          SI (EXIS TIT) ;
  47.             ERRE 1052 'AVEC' 'LINELOGA' ;
  48.          SINON ;
  49.             TIT = LO ;
  50.          FINS ;
  51.       FINS ;
  52.    FINS ;
  53.  
  54. *  GESTION DE LA LISTE DES VALEURS
  55.    NV = DIME LV ;
  56.    SI (NV EGA 0) ;
  57.       ERRE 1027 'AVEC' 'LISTREEL' ;
  58.    FINS ;
  59.    SI (NL <EG 0) ;
  60.       ERRE 36 'AVEC' NL ;
  61.    FINS ;
  62.    SI (NC <EG 0) ;
  63.       ERRE 36 'AVEC' NC ;
  64.    FINS ;
  65.    SI (NV NEG (NL*NC)) ;
  66.       ERRE 199 ;
  67.    FINS ;
  68.  
  69. *  TITRE DU GRAPHIQUE
  70.    SI (NON (EXIS TIT)) ;
  71.       TIT = ' ' ;
  72.    FINS ;
  73.  
  74.  
  75. *  =====================
  76. *  CREATION DU GRAPHIQUE
  77. *  =====================
  78.  
  79.    NDIM1 = VALE 'DIME' ;
  80.    SI (NDIM1 EGA 2) ;
  81.       MAIL1 = (0. NL) DROI NC (NC NL) TRAN NL (0. (-1*NL)) ;
  82.    SINON ;
  83.       MAIL1 = (0. NL 0.) DROI NC (NC NL 0.) TRAN NL (0. (-1*NL) 0.) ;
  84.    FINS ;
  85.  
  86. *  AFFICHAGE DES DONNEES
  87.    $MAIL1 = MODE MAIL1 'THERMIQUE' 'ISOTROPE' ;
  88.    SI KLOGA ;
  89.       LV = (LOG (ABS LV)) / (LOG 10.) ;
  90.    FINS ;
  91.    CHML1 = MANU 'CHML' $MAIL1 'REPA' 'SCAL' LV 'GRAVITE' ;
  92.    SI (NDIM1 EGA 2) ;
  93.       TRAC $MAIL1 CHML1 'TITR' TIT ;
  94.    SINON ;
  95.       TRAC $MAIL1 CHML1 (0. 0. 1.E20) 'TITR' TIT ;
  96.    FINS ;
  97.  
  98. *  RETABLISSEMENT DES OPTIONS D'ORIGINE
  99.    SI (NEG ELTY1 '    ') ;
  100.       OPTI 'ELEM' ELTY1 ;
  101.    FINS ;
  102.    SI (NDIM1 EGA 3) ;
  103.       OPTI 'OEIL' (1.E6 -1.2E6 0.9E6) ;
  104. *     (OEIL PAR DEFAUT DANS PRTRAC.ESO)
  105.    FINS ;
  106.  
  107. FINP ;
  108.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales