Télécharger la plaquette Cast3M


fr en

Télécharger mdrecomb.procedur

Retour à la liste

Numérotation des lignes : 

  1. * MDRECOMB  PROCEDUR  FD144363  24/03/27    21:15:04     11877          
  2. 'DEBPROC' MDRECOMB RXT*'TABLE   ' ;
  3. *
  4. *
  5. * Couplage du modèle 0D du PAR avec le modèle fluide CFD
  6. *--------------------------------------------------------------------------
  7. * E/    : rxt    : Table contenant tous les data pour les fluides
  8. *  /S   : Qo_i   : Différence de débit entre la sortie et l'entrée des PARs
  9. *                  pour l'espèce i (en kg/s)
  10. *  /S   : drhpar : Différence de débit enthalpique entre la sortie et
  11. *                  l'entrée des PARs (en W)
  12. *
  13. *  /S : Sauvegarde pour post-traitement local dans tic . 'RECOMB' . &BCLREC
  14. *  /S : Sauvegarde pour C.L. de l'inconnue 'XXX' dans tic . 'RECOMB' . 'XXX'
  15. *--------------------------------------------------------------------------
  16. *
  17. *
  18. 'MESS' '$$$$ RECOMBINEUR $$$$' ;
  19. tbt = RXT . 'TBT' ;
  20. tic = RXT . 'TIC' ;
  21. geo = RXT . 'GEO' ;
  22. *
  23. idim = 'VALE' 'DIME' ;
  24. 'SI' ('EGA' idim 2) ;
  25.      LMOT1 = 'MOTS' '1UN' '2UN' ;
  26. 'SINO' ;
  27.      LMOT1 = 'MOTS' '1UN' '2UN' '3UN' ;
  28. 'FINS' ;
  29. Dt  = tic . 'DT' ;
  30. Tps = tic . 'Tps' ;
  31. Pe = 'EXTR' tic . 'PT' ('DIME' tic . 'PT') ;
  32. *
  33. * Initialisation pour les bilans de masse et d'energie 0D
  34. *
  35. * Décomposition Air en entree PAR en N2 et O2
  36. QIN_O2a  = 0. ;
  37. QIN_N2a  = 0. ;
  38. QIN_AIR  = 0. ;
  39. *
  40. * Entree du modele PAR 
  41. QIN_H2   = 0. ;
  42. QIN_H2O  = 0. ;
  43. QIN_O2   = 0. ;
  44. QIN_N2   = 0. ;
  45. QIN_HE   = 0. ;
  46. QIN_CO2  = 0. ;
  47. QIN_CO   = 0. ;
  48. *
  49. * Sortie du modele PAR
  50. QOUT_H2  = 0. ;
  51. QOUT_H2O = 0. ;
  52. QOUT_O2  = 0. ;
  53. QOUT_N2  = 0. ;
  54. QOUT_HE  = 0. ;
  55. QOUT_CO2 = 0. ;
  56. QOUT_CO  = 0. ;
  57. *
  58. * Recomposition Air en sortie PAR à partir N2 et O2
  59. QOUT_O2a = 0. ;
  60. QOUT_N2a = 0. ;
  61. QOUT_AIR = 0. ;
  62. *
  63. drhpar   = 0. ;
  64. *
  65. * Initialisation des conditions aux limites scalaire CFD à la sortie des PARs
  66. cltf mat1 = 'KOPS' 'MATRIK' ;
  67. clrvp  = 'COPI' cltf ;
  68. clrh2  = 'COPI' cltf ;
  69. clro2  = 'COPI' cltf ;
  70. clrn2  = 'COPI' cltf ;
  71. clrhe  = 'COPI' cltf ;
  72. clrco  = 'COPI' cltf ;
  73. clrco2 = 'COPI' cltf ;
  74. clrair = 'COPI' cltf ;
  75. *
  76. * Initialisation des CL vectorielles CFD à l'entrée et à la sortie des PARs
  77. clupar = 'COPI' cltf ;
  78. *
  79. *
  80. *- Boucle principale sur les PARs
  81. *
  82. *
  83. NBREC = 'DIME' rxt . 'RECOMB' ;
  84. 'REPE' BCLREC NBREC ;
  85.    RECI = rxt . 'RECOMB' . &BCLREC ;
  86.    RTRI = tic . 'RECOMB' . &BCLREC ;
  87.    TYPR     = RECI . 'TYPR' ;
  88.    NSECTION = RECI . 'NSECTION' ;
  89. *
  90. ** Modèle, surface, facteur géométrique et normale à l'entrée et à la sortie du PAR
  91.    NAME = 'CHAI' '$REC'  'ent' &BCLREC ; $ENTREE = GEO . NAME ;
  92.    NAME = 'CHAI' 'SREC'  'ent' &BCLREC ; SENTREE = GEO . NAME ;
  93.    NAME = 'CHAI' 'fgREC' 'ent' &BCLREC ; FG_ENT  = GEO . NAME ;
  94.    NAME = 'CHAI' 'DREC'  'ent' &BCLREC ; dire    = GEO . NAME ;
  95.    NAME = 'CHAI' 'REC'  'entI' &BCLREC ; ENTREI  = GEO . NAME ;
  96. *
  97.    NAME = 'CHAI' '$REC'  'sor' &BCLREC ; $SORTIE = GEO . NAME ;
  98.    NAME = 'CHAI' 'SREC'  'sor' &BCLREC ; SSORTIE = GEO . NAME ;
  99.    NAME = 'CHAI' 'fgREC' 'sor' &BCLREC ; FG_SOR  = GEO . NAME ;
  100.    NAME = 'CHAI' 'DREC'  'sor' &BCLREC ; dirs    = GEO . NAME ;
  101.    NAME = 'CHAI' 'REC'  'sorI' &BCLREC ; SORTII  = GEO . NAME ;
  102. *
  103. ** Surfaces des mailles duales
  104.    Sduae = 'DOMA' $ENTREE 'XXDIAGSI' ;
  105.    Sduas = 'DOMA' $SORTIE 'XXDIAGSI' ;
  106. *
  107. ** Fractions massiques moyennes à l'entrée du modèle PAR
  108. ** (décomposition de l'air en N2 et O2 avec redéfinition de Rair pour que Yo2+Yn2=Yair)
  109.    Rgo2  = tbt . 'Rgo2' ;
  110.    Rgn2  = tbt . 'Rgn2' ;
  111.    Rgair = (0.21 '/' Rgo2) '+' (0.79 '/' Rgn2) '**' -1. ;
  112.    YO2ea = 0.21 '*' Rgair '/' Rgo2 '*' tic . 'YAIR' ;
  113.    YN2ea = 0.79 '*' Rgair '/' Rgn2 '*' tic . 'YAIR' ;
  114. *
  115.    YO2ea = 'KCHT' $ENTREE 'SCAL' 'SOMMET' YO2ea ;
  116.    YO2ea = ('SOMT' (YO2ea '*' Sduae)) '/' SENTREE ;
  117.    YN2ea = 'KCHT' $ENTREE 'SCAL' 'SOMMET' YN2ea ;
  118.    YN2ea = ('SOMT' (YN2ea '*' Sduae)) '/' SENTREE ;
  119.    YAIRe = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YAIR' ;
  120.    YAIRe = ('SOMT' (YAIRe '*' Sduae)) '/' SENTREE ;
  121. *
  122. * O2, N2 et H2O sont obligatoires (voir execrxt), donc tests inutils
  123. * mais le heater pourrait fonctionner un jour sans O2, N2 et H2O -> on les laisse
  124.    'SI' TBT . 'TO2' ;
  125.       YO2e  = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YO2' ;
  126.       YO2e  = ('SOMT' (YO2e  '*' Sduae)) '/' SENTREE ;
  127.    'SINO' ;
  128.       YO2e  = 0.D0 ;
  129.    'FINSI' ;
  130.    YO2e = YO2e '+' YO2ea ;
  131. *
  132.    'SI' TBT . 'TN2' ;
  133.       YN2e  = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YN2' ;
  134.       YN2e  = ('SOMT' (YN2e  '*' Sduae)) '/' SENTREE ;
  135.    'SINO' ;
  136.       YN2e  = 0.D0 ;
  137.    'FINSI' ;
  138.    YN2e = YN2e '+' YN2ea ;
  139. *
  140.    'SI' TBT . 'TH2' ;
  141.       YH2e  = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YH2' ;
  142.       YH2e  = ('SOMT' (YH2e  '*' Sduae)) '/' SENTREE ;
  143.    'SINO' ;
  144.       YH2e  = 0. ;
  145.    'FINSI' ;
  146.    'SI' TBT . 'VAPEUR' ;
  147.       YH2Oe = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YVAP' ;
  148.       YH2Oe = ('SOMT' (YH2Oe '*' Sduae)) '/' SENTREE ;
  149.    'SINO' ;
  150.       YH2Oe = 0. ;
  151.    'FINSI' ;
  152.    'SI' TBT . 'THE' ;
  153.       YHEe  = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YHE' ;
  154.       YHEe  = ('SOMT' (YHEe  '*' Sduae)) '/' SENTREE ;
  155.    'SINO' ;
  156.       YHEe  = 0. ;
  157.    'FINSI' ;
  158.    'SI' TBT . 'TCO' ;
  159.       YCOe  = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YCO' ;
  160.       YCOe  = ('SOMT' (YCOe  '*' Sduae)) '/' SENTREE ;
  161.    'SINO' ;
  162.       YCOe  = 0. ;
  163.    'FINSI' ;
  164.    'SI' TBT . 'TCO2' ;
  165.       YCO2e = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'YCO2' ;
  166.       YCO2e = ('SOMT' (YCO2e '*' Sduae)) '/' SENTREE ;
  167.    'SINO' ;
  168.       YCO2e = 0. ;
  169.    'FINSI' ;
  170. *
  171. ** Tgaz, Tplaque à l'entrée du PAR
  172.    Te = 'KCHT' $ENTREE 'SCAL' 'SOMMET' tic . 'TF' ;   
  173.    TIN = ('SOMT' (Te '*' Sduae)) '/' SENTREE ;
  174.    TINK = TIN '+' 273.15 ;
  175.    TP = 'EXTR' rtri . 'Tpla' ('DIME' rtri . 'Tpla') ;
  176.    TPK = TP '+' 273.15 ;
  177. *
  178. *----------------------------
  179. * Recombineur de type SIEMENS
  180. *----------------------------
  181. *
  182.    'SI' ('EGA' typr 'SIEMENS') ;
  183.      AA1    = RECI . 'A' ;
  184.      BB1    = RECI . 'B' ;
  185.      XH2ONI = RECI . 'XH2ON' ;
  186.      XH2OFI = RECI . 'XH2OFF' ;
  187.      BETAI  = RECI . 'BETA' ;
  188.      YH2s YO2s YN2s YH2Os YHEs YCO2s YCOs TsK TPK DEB EFF XH2ONF
  189.      = 'FLAM' 'RECOMBIN'
  190.      YH2e YO2e YN2e YH2Oe YHEe YCO2e YCOe
  191.      TINK TPK Pe Dt 0 typr AA1 BB1 XH2ONI XH2OFI BETAI ;
  192.      RECI . 'XH2ON' = XH2ONF ;
  193. *
  194. *---------------------------
  195. * Recombineur de type HEATER
  196. *---------------------------
  197. *
  198.    'SINO' ;
  199.      PUI0 = 'IPOL' Tps RECI . 'PUISSANCE' ;
  200.      PUI1 = 'IPOL' (Tps '-' Dt) RECI . 'PUISSANCE' ;
  201.      A1 = PUI0 '-' PUI1 '/' DT ;
  202.      FUITE = RECI . 'QHOUSING' ;
  203.      HRAPP = RECI . 'HRAPP' ;
  204.      CRAPP = RECI . 'CRAPP' ;
  205.      YH2s YO2s YN2s YH2Os YHEs YCO2s YCOs TsK TPK DEB
  206.      = 'FLAM' 'RECOMBIN'
  207.      YH2e YO2e YN2e YH2Oe YHEe YCO2e YCOe
  208.      TINK TPK Pe Dt 0 typr A1 fuite hrapp crapp ;
  209.      EFF = 0.D0 ;
  210.    'FINSI' ;
  211. *
  212.    TS = TSK '-' 273.15 ;
  213.    TP = TPK '-' 273.15 ;
  214.    NDEB = DEB '*' NSECTION ;
  215. *
  216. ** Recomposition de l'air à la sortie du PAR à partir de N2 et O2
  217. * (dépend si O2 est en excès ou en défaut sauf heater où on reconstitue l'air de l'entrée)
  218.    'SI' (TBT . 'TO2' 'ET' TBT . 'TN2') ;
  219.      alfa  = (0.21 '*' Rgn2) '/' (0.79 '*' Rgo2) ;
  220.      'SI' (YO2s '<' (alfa '*' YN2s)) ;
  221.         YO2sa = YO2s ;
  222.         YN2sa = YO2s '/' alfa ; 
  223.      'SINO' ;
  224.         YO2sa = alfa '*' YN2s ;
  225.         YN2sa = YN2s ; 
  226.      'FINS' ;
  227.    'SINO' ;
  228.         YO2sa = YO2ea ;
  229.         YN2sa = YN2ea ;
  230.    'FINS' ;
  231.    YAIRs = YN2sa '+' YO2sa ;
  232. *
  233. * Vitesses débitantes à l'entrée et à la sortie du PAR (en m/s)
  234. * avec prise en compte du facteur géométrique et du nombre de sections
  235.    RG_IN  = (TBT . 'Rgvap' '*' YH2Oe)
  236.         '+' (TBT . 'Rgh2'  '*' YH2e) 
  237.         '+' (TBT . 'Rgair' '*' YAIRe) 
  238.         '+' (TBT . 'Rgo2'  '*' (YO2e-YO2ea)) 
  239.         '+' (TBT . 'Rgn2'  '*' (YN2e-YN2ea)) 
  240.         '+' (TBT . 'Rghe'  '*' YHEe) 
  241.         '+' (TBT . 'Rgco'  '*' YCOe) 
  242.         '+' (TBT . 'Rgco2' '*' YCO2e) ;
  243.    RG_IN  = ('SOMT' (RG_IN '*' Sduae)) '/' SENTREE ;
  244.    RO_IN  = Pe '/' (RG_IN '*' TINK) ;
  245.    UN_IN  = ndeb '*' FG_ENT '/' (SENTREE '*' RO_IN) ;
  246. *
  247.    RG_OUT = (TBT . 'Rgvap' '*' YH2Os) 
  248.         '+' (TBT . 'Rgh2'  '*' YH2s) 
  249.         '+' (TBT . 'Rgair' '*' YAIRs) 
  250.         '+' (TBT . 'Rgo2'  '*' (YO2s-YO2sa)) 
  251.         '+' (TBT . 'Rgn2'  '*' (YN2s-YN2sa)) 
  252.         '+' (TBT . 'Rghe'  '*' YHEs) 
  253.         '+' (TBT . 'Rgco'  '*' YCOs) 
  254.         '+' (TBT . 'Rgco2' '*' YCO2s) ; 
  255.    RG_OUT = ('SOMT' (RG_OUT '*' Sduas)) '/' SSORTIE ;
  256.    RO_OUT = Pe '/' (RG_OUT '*' TSK) ;
  257.    UN_OUT = ndeb '*' FG_SOR '/' (SSORTIE '*' RO_OUT) ;
  258. *
  259. ** Enthalpie massique à l'entrée et à la sortie du PAR (en J/kg)
  260.    Cph2_e Cphe_e Cpo2_e Cpn2_e Cpco2_e Cpco_e Cpair_e
  261.    = CALCP TIN ;
  262.    Cph2_s Cphe_s Cpo2_s Cpn2_s Cpco2_s Cpco_s Cpair_s
  263.    = CALCP TS ;
  264.    Cpvap = TBT . 'Cpvap' ;
  265.    CP_IN  = Cpvap '*' YH2Oe  
  266.      '+' (Cph2_e  '*' YH2e)  
  267.      '+' (Cpair_e '*' YAIRe)  
  268.      '+' (Cpo2_e  '*' (YO2e-YO2ea))  
  269.      '+' (Cpn2_e  '*' (YN2e-YN2ea))  
  270.      '+' (Cphe_e  '*' YHEe)  
  271.      '+' (Cpco2_e '*' YCO2e) 
  272.      '+' (Cpco_e  '*' YCOe)  ;
  273.    H_IN  = CP_IN '*' TINK ;
  274. *
  275.    CP_OUT = Cpvap '*' YH2Os
  276.      '+' (Cph2_s  '*' YH2s)  
  277.      '+' (Cpair_s '*' YAIRs)  
  278.      '+' (Cpo2_s  '*' (YO2s-YO2sa))  
  279.      '+' (Cpn2_s  '*' (YN2s-YN2sa))  
  280.      '+' (Cphe_s  '*' YHEs)  
  281.      '+' (Cpco2_s '*' YCO2s) 
  282.      '+' (Cpco_s  '*' YCOs)  ;
  283.    H_OUT = CP_OUT '*' TSK ;
  284. *
  285. ** Contribution du PAR aux bilans massiques 0D (Q en kg/s)
  286.    QIN_H2   = ndeb '*' YH2e  '+' QIN_H2   ;
  287.    QIN_H2O  = ndeb '*' YH2Oe '+' QIN_H2O  ;
  288.    QIN_AIR  = ndeb '*' YAIRe '+' QIN_AIR  ;
  289.    QIN_O2   = ndeb '*' (YO2e-YO2ea) '+' QIN_O2   ;
  290.    QIN_N2   = ndeb '*' (YN2e-YN2ea) '+' QIN_N2   ;
  291.    QIN_HE   = ndeb '*' YHEe  '+' QIN_HE   ;
  292.    QIN_CO2  = ndeb '*' YCO2e '+' QIN_CO2  ;
  293.    QIN_CO   = ndeb '*' YCOe  '+' QIN_CO   ;
  294. *
  295.    QIN_O2a  = ndeb '*' YO2ea '+' QIN_O2a  ;
  296.    QIN_N2a  = ndeb '*' YN2ea '+' QIN_N2a  ;
  297. *
  298.    QOUT_H2  = ndeb '*' YH2S  '+' QOUT_H2  ;
  299.    QOUT_H2O = ndeb '*' YH2OS '+' QOUT_H2O ;
  300.    QOUT_AIR = ndeb '*' YAIRs '+' QOUT_AIR  ;
  301.    QOUT_O2  = ndeb '*' (YO2s-YO2sa) '+' QOUT_O2  ;
  302.    QOUT_N2  = ndeb '*' (YN2s-YN2sa) '+' QOUT_N2  ;
  303.    QOUT_HE  = ndeb '*' YHES  '+' QOUT_HE  ;
  304.    QOUT_CO2 = ndeb '*' YCO2S '+' QOUT_CO2 ;
  305.    QOUT_CO  = ndeb '*' YCOS  '+' QOUT_CO  ;
  306. *
  307.    QOUT_O2a = ndeb '*' YO2sa '+' QOUT_O2a  ;
  308.    QOUT_N2a = ndeb '*' YN2sa '+' QOUT_N2a  ;
  309. *
  310. ** Contribution des PARs au bilan d'energie 0D (drhpar en W)
  311.    drhpar = H_OUT '-' H_IN '*' ndeb '+' drhpar ;
  312. *
  313. ** Conditions aux limites en vitesse (en m/s)
  314.    toto1 = 'KCHT' $ENTREE 'VECT' 'SOMMET' 'COMP' LMOT1 (dire * UN_IN) ;
  315.    tutu1 = 'KCHT' $SORTIE 'VECT' 'SOMMET' 'COMP' LMOT1 (dirs * UN_OUT) ;
  316.    'SI' tbt . 'FPAROI' ;
  317.      NAME = 'CHAI' 'REC'  'ent' &BCLREC ; ENTREE  = GEO . NAME ;
  318.      NAME = 'CHAI' 'REC'  'sor' &BCLREC ; SORTIE  = GEO . NAME ;
  319.      toto1 = 'REDU' toto1 ENTREE ;
  320.      tutu1 = 'REDU' tutu1 SORTIE ;
  321.    'SINO' ;
  322.      toto1 = 'REDU' toto1 ENTREI ;
  323.      tutu1 = 'REDU' tutu1 SORTII ;
  324.    'FINS' ;
  325.    toto1 = 'KCHT' $ENTREE 'VECT' 'SOMMET' 'COMP' LMOT1 toto1 ;
  326.    tutu1 = 'KCHT' $SORTIE 'VECT' 'SOMMET' 'COMP' LMOT1 tutu1 ;
  327.    clupar = clupar 'ET' toto1 'ET' tutu1 ;
  328. *
  329. ** Conditions aux limites en température (en C)
  330.    cltf   = cltf 'ET'
  331.    ('MANU' 'CHPO' SORTII 1 'TF' TS 'NATURE' 'DISCRET') ;
  332. *
  333. ** Conditions aux limites en densités partielles (en kg/m3)
  334.    clrvp  = clrvp  'ET'
  335.    ('MANU' 'CHPO' SORTII 1 'RVP'  (RO_OUT '*' YH2Os) 'NATURE' 'DISCRET') ;
  336.    clrh2  = clrh2  'ET'
  337.    ('MANU' 'CHPO' SORTII 1 'RH2'  (RO_OUT '*' YH2s)  'NATURE' 'DISCRET') ;
  338.    clro2  = clro2  'ET'   
  339.    ('MANU' 'CHPO' SORTII 1 'RO2'  (RO_OUT '*' (YO2s-YO2sa)) 'NATURE' 'DISCRET') ;
  340.    clrn2  = clrn2  'ET'  
  341.    ('MANU' 'CHPO' SORTII 1 'RN2'  (RO_OUT '*' (YN2s-YN2sa)) 'NATURE' 'DISCRET') ;
  342.    clrhe  = clrhe  'ET'  
  343.    ('MANU' 'CHPO' SORTII 1 'RHE'  (RO_OUT '*' YHEs)  'NATURE' 'DISCRET') ;
  344.    clrco  = clrco  'ET'  
  345.    ('MANU' 'CHPO' SORTII 1 'RCO'  (RO_OUT '*' YCOs)  'NATURE' 'DISCRET') ;
  346.    clrco2 = clrco2 'ET'
  347.    ('MANU' 'CHPO' SORTII 1 'RCO2' (RO_OUT '*' YCO2s) 'NATURE' 'DISCRET') ;
  348.    clrair = clrair 'ET'
  349.    ('MANU' 'CHPO' SORTII 1 'RAIR' (RO_OUT '*' YAIRs) 'NATURE' 'DISCRET') ;
  350. *
  351. * Sauvegarde dans TIC des data pour post-traitement local
  352. * (T en C, DEB en kg/s, Efficiency et Y sans unité, U en m/s)
  353.    rtri . 'Tpla'  = rtri . 'Tpla'  'ET' ('PROG' TP)  ;
  354.    rtri . 'Tin'   = rtri . 'Tin'   'ET' ('PROG' TIN) ;
  355.    rtri . 'Tout'  = rtri . 'Tout'  'ET' ('PROG' TS)  ;
  356. *
  357.    rtri . 'DEB'   = rtri . 'DEB'   'ET' ('PROG' ndeb)  ;
  358.    rtri . 'EFF'   = rtri . 'EFF'   'ET' ('PROG' EFF)   ;
  359. *
  360.    rtri . 'YH2E'  = rtri . 'YH2E'  'ET' ('PROG' YH2e)  ;
  361.    rtri . 'YH2OE' = rtri . 'YH2OE' 'ET' ('PROG' YH2Oe) ;
  362.    rtri . 'YO2E'  = rtri . 'YO2E'  'ET' ('PROG' YO2e)  ;
  363.    rtri . 'YN2E'  = rtri . 'YN2E'  'ET' ('PROG' YN2e)  ;
  364.    rtri . 'YHEE'  = rtri . 'YHEE'  'ET' ('PROG' YHEe)  ;
  365.    rtri . 'YCO2E' = rtri . 'YCO2E' 'ET' ('PROG' YCO2e) ;   
  366.    rtri . 'YCOE'  = rtri . 'YCOE'  'ET' ('PROG' YCOe)  ;
  367. *   
  368.    rtri . 'YH2S'  = rtri . 'YH2S'  'ET' ('PROG' YH2s)  ;
  369.    rtri . 'YH2OS' = rtri . 'YH2OS' 'ET' ('PROG' YH2Os) ;
  370.    rtri . 'YO2S'  = rtri . 'YO2S'  'ET' ('PROG' YO2s)  ;
  371.    rtri . 'YN2S'  = rtri . 'YN2S'  'ET' ('PROG' YN2s)  ;
  372.    rtri . 'YHES'  = rtri . 'YHES'  'ET' ('PROG' YHEs)  ;
  373.    rtri . 'YCO2S' = rtri . 'YCO2S' 'ET' ('PROG' YCO2s) ;
  374.    rtri . 'YCOS'  = rtri . 'YCOS'  'ET' ('PROG' YCOs)  ;
  375. *
  376.    rtri . 'Uin'   = rtri . 'Uin'   'ET' ('PROG' UN_IN)  ;
  377.    rtri . 'Uout'  = rtri . 'Uout'  'ET' ('PROG' UN_OUT) ;
  378. *
  379.    rtri . 'Hin'   = rtri . 'Hin'   'ET' ('PROG' H_IN)  ;
  380.    rtri . 'Hout'  = rtri . 'Hout'  'ET' ('PROG' H_OUT) ;
  381. 'FIN' BCLREC ;
  382. *
  383. ** Sauvegarde des conditions aux limites
  384. tic . 'RECOMB' . 'UN'   = clupar ;
  385. tic . 'RECOMB' . 'TF'   = cltf   ;
  386. tic . 'RECOMB' . 'RVP'  = clrvp  ;
  387. tic . 'RECOMB' . 'RH2'  = clrh2  ;
  388. tic . 'RECOMB' . 'RO2'  = clro2  ;
  389. tic . 'RECOMB' . 'RN2'  = clrn2  ;
  390. tic . 'RECOMB' . 'RHE'  = clrhe  ;
  391. tic . 'RECOMB' . 'RCO'  = clrco  ;
  392. tic . 'RECOMB' . 'RCO2' = clrco2 ;
  393. tic . 'RECOMB' . 'RAIR' = clrair ;
  394. *
  395. ** Contribution des PARs aux bilans de masse 0D (Qo_beta en kg/s)
  396. ** (la masse totale étant inchangée, l'air fait tampon dans execrxt)
  397. QO_H2  = QOUT_H2  '-' QIN_H2  ;
  398. QO_O2  = QOUT_O2  '-' QIN_O2  ;
  399. QO_H2O = QOUT_H2O '-' QIN_H2O ;
  400. QO_N2  = QOUT_N2  '-' QIN_N2  ;
  401. *
  402. * Affichage pour vérification
  403. QO_AIR = QOUT_AIR '-' QIN_AIR ;
  404. QO_OUT = QOUT_H2  '+' QOUT_O2 '+' QOUT_H2O '+' QOUT_N2 '+' QOUT_HE '+'
  405.          QOUT_CO2 '+' QOUT_CO '+' QOUT_AIR ; 
  406. QO_IN  = QIN_H2   '+' QIN_O2  '+' QIN_H2O  '+' QIN_N2  '+' QIN_HE  '+'
  407.          QIN_CO2  '+' QIN_CO  '+' QIN_AIR ;
  408. 'MESS' 'DQ / Qin / Qout (kg/s)' ;
  409. 'MESS' '-------------------------------------------------------------' ;
  410. 'MESS' 'Balance :' ' ' (QO_OUT '-' QO_IN) ' ' QO_OUT ' ' QO_IN ;
  411. 'MESS' '-------------------------------------------------------------' ;
  412. 'MESS' 'H2      :' ' ' QO_H2  ' ' QIN_H2  ' ' QOUT_H2  ;
  413. 'MESS' 'H2O     :' ' ' QO_H2O ' ' QIN_H2O ' ' QOUT_H2O ;
  414. 'MESS' 'O2      :' ' ' QO_O2  ' ' QIN_O2  ' ' QOUT_O2  ;
  415. 'MESS' 'N2      :' ' ' QO_N2  ' ' QIN_N2  ' ' QOUT_N2  ;
  416. 'MESS' 'AIR     :' ' ' QO_AIR ' ' QIN_AIR ' ' QOUT_AIR ;
  417. 'MESS' ' ' ;
  418. 'SI' TBT . 'THE' ;
  419. 'MESS' 'HE      :' ' ' (QIN_HE  '-' QOUT_HE)  ' ' QIN_HE  ' ' QOUT_HE  ;
  420. 'FINS' ;
  421. 'SI' TBT . 'TCO2' ;
  422. 'MESS' 'CO2     :' ' ' (QIN_CO2 '-' QOUT_CO2) ' ' QIN_CO2 ' ' QOUT_CO2 ;
  423. 'FINS' ;
  424. 'SI' TBT . 'TCO' ;
  425. 'MESS' 'CO      :' ' ' (QIN_CO  '-' QOUT_CO)  ' ' QIN_CO  ' ' QOUT_CO  ;
  426. 'FINS' ;
  427. 'MESS' '-------------------------------------------------------------' ;
  428. *
  429. 'RESP' QO_H2 QO_O2 QO_H2O QO_N2 drhpar ;
  430. 'FINP' ;
  431.  
  432.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales