Télécharger la plaquette Cast3M


fr en

Télécharger g_calcul.procedur

Retour à la liste

Numérotation des lignes : 

  1. * G_CALCUL  PROCEDUR  JB251061  22/09/05    21:15:01     11444          
  2. DEBP G_CALCUL SUPTAB*'TABLE' OBJUTI*'TABLE' BOOL*'TABLE';
  3. * =============================================================================
  4. *           PROCEDURE DE CALCUL DES INTEGRALES NECESSAIRES A G_THETA
  5. *           --------------------------------------------------------
  6. *
  7. * DESCRIPTION : EFFECTUE LE CALCUL DE L'INTEGRALE SPECIFIEE DANS L'INDICE
  8. *               'OBJECTIF' DE LA TABLE SUPTAB.
  9. *               ON BOUCLE SUR LES PAS DE CALCUL, SUR LES INTEGRALES A CALCULER
  10. *               ET ENFIN SUR LES NOEUDS DU FRONT DE FISSURE.
  11. * =============================================================================
  12.  
  13. * QUELQUES OBJETS UTILES
  14.  
  15. MOD_MEC_R = OBJUTI.'MOD_MEC_R';
  16. MAILMOD = EXTR MOD_MEC_R 'MAILLAGE';
  17. SI BOOL.'DECOUPLAGE';
  18.     CH_AUX = SUPTAB.'CH_AUX';
  19. FINSI;
  20. * CHAMPS NULS
  21. CMD000 = CHAN 'NOEUD' MOD_MEC_R (ZERO MOD_MEC_R 'DEPLACEM');
  22. CMD001 = CHAN 'STRESSES' MOD_MEC_R (ZERO MOD_MEC_R 'DEPLACEM');
  23. GRA000 = ZERO MOD_MEC_R 'GRADIENT';
  24. FOR000 = CHAN 'CHPO' MOD_MEC_R (ZERO MOD_MEC_R 'FORCES  ');
  25. DEP000 = CHAN 'CHPO' MOD_MEC_R (ZERO MOD_MEC_R 'DEPLACEM');
  26. SI (EGA GMODE 'PLANGENE');
  27.     FOR000 = MANU 'CHPO' (EXTR MOD_MEC_R 'MAIL') 2 'FX' 0.
  28.                 'FY' 0. 'TITR' 'FORCES  ' 'NATURE' 'DIFFUS';
  29.     FOR000 = FOR000 ET (MANU 'CHPO' (VALE 'MODE' 'PLANGENE')
  30.                 3 'FZ' 0. 'MX' 0. 'MY' 0.
  31.                 'TITR' 'FORCES  ' 'NATURE' 'DIFFUS');
  32.     DEP000 = MANU 'CHPO' (EXTR MOD_MEC_R 'MAIL') 2 'UX' 0.
  33.                 'UY' 0. 'TITR' 'DEPLACEM' 'NATURE' 'DIFFUS';
  34.     DEP000 = DEP000 ET (MANU 'CHPO' (VALE 'MODE' 'PLANGENE')
  35.                 3 'UZ' 0. 'RX' 0. 'RY' 0.
  36.                 'TITR' 'DEPLACEM' 'NATURE' 'DIFFUS');
  37. FINSI;
  38. * EN CAS D'UN MODELE DE PRESSION
  39. SI BOOL.'MODE_PRES';
  40.     MODCHA = EXTR OBJUTI.'MOD_TOT' 'FORM' 'CHARGEMENT';
  41.     MODPRE = EXTR MODCHA 'COMP' 'PRESSION';
  42.     SI (NON BOOL.'PASAPAS');
  43.         MATPRE = REDU (SUPTAB.'PRESSION') MODPRE;
  44.     FINSI;
  45.     MAILPTOT = EXTR MODPRE 'MAIL';
  46.     MAILPF = INTE MAILPTOT (SUPTAB.'FISSURE');
  47. FINSI;
  48.  
  49.  
  50. SI (BOOL.'COQ' ET BOOL.'EL_QUA');
  51.    MAT2 = MAT_INST;
  52. SINON;
  53.    MAT2 = TEXT '        ';
  54. FINSI;
  55. SI BOOL.'COQ';
  56.     MATCOMP = EXTR MAT_MEC 'COMP';
  57.     MOTCARA = MOTS 'EPAI' 'EXCE' 'DIM3';
  58.     CAR1 = EXCO MAT_MEC MOTCARA 'NOID';
  59. SINON;
  60.     CAR1 = TEXT '   ';
  61. FINSI;
  62.  
  63. NBG = OBJUTI.'NBG';
  64.  
  65. * FRONT DE FISSURE EN POI1
  66. FF = SUPTAB.'FRONT_FISSURE';
  67. SI (EGA (TYPE FF) 'POINT');
  68.     FF1 = MANU 'POI1' FF;
  69. FINSI;
  70. SI (EGA (TYPE FF) 'MAILLAGE');
  71.     FF1 = CHAN 'POI1' FF;
  72. FINSI;
  73.  
  74. * QUELQUES MOTS POUR SIMPLIFIER L'ECRITURE
  75.  
  76. NEXTR = GDIME;
  77. SI BOOL.'COQ';
  78.     NEXTR = 6;
  79. FINSI;
  80. MUI = EXTR (EXTR MOD_MEC_R 'DEPL') (LECT 1 PAS 1 NEXTR);
  81. MFI = EXTR (EXTR MOD_MEC_R 'FORC') (LECT 1 PAS 1 NEXTR);
  82. MGI = EXTR MOD_MEC_R 'GRAD';
  83. MU1 = EXTR MUI 1 ; MU2 = EXTR MUI 2 ; MU3  = MOT 'UZ';
  84. MF1 = EXTR MFI 1 ; MF2 = EXTR MFI 2 ; MF3  = MOT 'FZ';
  85. MFA1= MOT  'FAX' ; MFA2 = MOT 'FAY' ; MFA3 = MOT 'FAZ';
  86. GR1 GR2 GR3 = (EXTR MGI 1) (EXTR MGI 2) (EXTR MGI 3);
  87. GR4 GR5 GR6 = (EXTR MGI 4) (EXTR MGI 5) (EXTR MGI 6);
  88. GR7 GR8 GR9 = (EXTR MGI 7) (EXTR MGI 8) (EXTR MGI 9);
  89. SM1 = MOT  'SMXX' ; SM2  = MOT 'SMYY' ; SM3  = MOT 'SMZZ';
  90. SM4 = MOT  'SMXY' ; SM5  = MOT 'SMXZ' ; SM6  = MOT 'SMYZ';
  91. EP1 = MOT  'EPXX' ; EP2  = MOT 'EPYY' ; EP3  = MOT 'EPZZ';
  92. EP4 = MOT  'GAXY' ; EP5  = MOT 'GAXZ' ; EP6  = MOT 'GAYZ';
  93. SI (EGA GMODE 'AXIS');
  94.    MU3 = MOT 'UT';
  95.    SM1 = MOT 'SMRR' ; SM2 = MOT 'SMZZ' ; SM3 = MOT 'SMTT';
  96.    SM4 = MOT 'SMRZ';
  97.    EP1 = MOT 'EPRR' ; EP2 = MOT 'EPZZ' ; EP3 = MOT 'EPTT';
  98.    EP4 = MOT 'GARZ';
  99. FINSI;
  100. *BP: PETIT AJOUT DE NOM DE COMPOSANTE DE CHPOINT
  101. SI (BOOL.'J' OU BOOL.'J_DYNA') ; MOCOMP = 'J' ;    FINSI;
  102. SI (BOOL.'C*' OU BOOL.'C*H') ; MOCOMP = 'C*' ;   FINSI;
  103. SI BOOL.'DJ/DA' ; MOCOMP = 'DJDA' ; FINSI;
  104.  
  105. * VALEURS INITIALES
  106.  
  107. S10  = 0. ; S20  = 0. ; S30  = 0. ; S40  = 0. ; S41 = 0. ; S50  = 0.;
  108. S60  = 0. ; S70  = 0. ; S80  = 0. ; S90  = 0. ; S100 = 0.;
  109. S110 = 0. ; S120 = 0. ; S130 = 0. ; S140 = 0. ; S141 = 0.;
  110. S150 = 0. ; S160 = 0. ; S170 = 0. ; S180 = 0.;
  111. S190 = 0. ; S200 = 0. ; S210 = 0. ; S220 = 0.;
  112.  
  113.  
  114. * DETERMINATION DE LA TAILLE DE LA 1ERE COLONNE A AFFICHER
  115. SI ((EGA GDIME 3) ET (NON BOOL.'COQ'));
  116.     NDEC = DIME 'GLOBAL';
  117.     REPE INO (NBEL FF1);
  118.         PM = (FF1 ELEM &INO) POIN 1;
  119.         NNO = NOEU PM;
  120.         NDEC1 = DIME (CHAI NNO);
  121.         NDEC = MAXI NDEC NDEC1;
  122.     FIN INO;
  123. SINON;
  124.     PM = FF1 POIN 1;
  125.     NNO = NOEU PM;
  126.     NDEC = DIME (CHAI NNO);
  127. FINSI;
  128.  
  129.  
  130. * TITRES A AFFICHER SELON LE PROBLEME TRAITER
  131. * *******************************************
  132.  
  133. * TITRE GENERAL
  134. NMESS = OBJUTI.'NMESS';
  135. MOBJ = MOT SUPTAB.'OBJECTIF';
  136. CHINT = CHAI MOBJ;
  137. SI (BOOL.'J_DYNA');
  138.     MOBJ = CHAI 'J';
  139. SINON;
  140.     SI (BOOL.'DJ/DA');
  141.         SI (EXIS SUPTAB 'FISSURE_2');
  142.             MOBJ = CHAI 'CROISEE DJi/DAj';
  143.             CHINT = CHAI 'DJi/DAj';
  144.         FINSI;
  145.     FINSI;
  146. FINSI;
  147. SI BOOL.'THER';
  148.     CHATHE = CHAI ' THERMO-';
  149. SINON;
  150.     CHATHE = CHAI ' ';
  151. FINSI;
  152. SI BOOL.'DECOUPLAGE';
  153.     CHACAL = CHAI 'SEPARATION DES F.I.C. EN' CHATHE 'ELASTICITE';
  154.     CHINT = CHAI 'Ki';
  155. SINON;
  156.     SI BOOL.'PASAPAS';
  157.         SI (BOOL.'J' OU BOOL.'DJ/DA');
  158.             CHAMAT = CHAI 'ELASTO-PLASTICITE';
  159.         SINON;
  160.             SI BOOL.'J_DYNA';
  161.                 CHAMAT = CHAI 'ELASTO-DYNAMIQUE';
  162.             SINON;
  163.                 CHAMAT = CHAI 'VISCO-PLASTICITE';
  164.             FINSI;
  165.         FINSI;
  166.         CHACAL = CHAI 'INTEGRALE' ' ' MOBJ ' EN' CHATHE CHAMAT;
  167.         SI (BOOL.'C*H');
  168.             CHINT = CHAI 'C*(H)';
  169.         FINSI;
  170.     SINON;
  171.         CHACAL = CHAI 'INTEGRALE' ' ' MOBJ ' EN ELASTICITE';
  172.     FINSI;
  173. FINSI;
  174. * EN-TETE DES RESULTATS
  175. CTITR = CHAI;
  176. NCTITR = 0;
  177. SI BOOL.'PASAPAS';
  178.     CHPAS = CHAI 'No.Pas';
  179.     NPMAX = NBG + NBDEP;
  180.     NDPAS = NCTITR + (MAXI (DIME (CHAI NPMAX)) (DIME CHPAS)) + 1;
  181.     CTITR = CHAI CTITR CHPAS*NDPAS;
  182.     NCTITR = DIME CTITR;
  183. FINSI;
  184. SI BOOL.'DECOUPLAGE';
  185.     NDDEC = NCTITR + 5;
  186.     CTITR = CHAI CTITR 'Mode'*NDDEC;
  187.     NCTITR = DIME CTITR;
  188. FINSI;
  189. SI BOOL.'COQ';
  190.     NDCOQ = NCTITR + 7;
  191.     CTITR = CHAI CTITR 'Plan'*NDCOQ;
  192.     NCTITR = DIME CTITR;
  193. FINSI;
  194. SI ((EGA GDIME 3) ET (NON BOOL.'COQ'));
  195.     SI BOOL.'XFEM';
  196.         CHFRO = CHAI 'Int.';
  197.     SINON;
  198.         CHFRO = CHAI 'Noeud';
  199.     FINSI;
  200.     NDFRO = 6;
  201.     REPE INO (NBEL FF1);
  202.         PM = (FF1 ELEM &INO) POIN 1;
  203.         NNO = NOEU PM;
  204.         NDFRO = MAXI NDFRO (DIME (CHAI NNO));
  205.     FIN INO;
  206.     NDFRO = NDFRO + NCTITR + 1;
  207.     CTITR = CHAI CTITR CHFRO*NDFRO;
  208.     NCTITR = DIME CTITR;
  209. FINSI;
  210. NFLOT = 11 + 2;
  211. NDMEC = (DIME CTITR) + NFLOT;
  212. CTITR = CHAI CTITR 'Mecanique'*NDMEC;
  213. NDTHE = NDMEC + NFLOT;
  214. CTITR = CHAI CTITR 'Thermique'*NDTHE;
  215. NDVOL = NDTHE + NFLOT;
  216. CTITR = CHAI CTITR 'Volumique'*NDVOL;
  217. NDINT = NDVOL + NFLOT;
  218. CTITR = CHAI CTITR CHINT*NDINT;
  219. NDTIT = (NDINT / 2) + ((DIME CHACAL) / 2);
  220. SAUT 'LIGNE';
  221. MESS CHACAL*NDTIT;
  222. SLIGN = CHAI '_';
  223. REPE ICHAR ((DIME CHACAL) - 1);
  224.     SLIGN = CHAI SLIGN '_';
  225. FIN ICHAR;
  226. MESS SLIGN*NDTIT;
  227. SAUT 'LIGNE';
  228. NDCHA = (NDINT / 2) + (45 / 2);
  229. MESS 'Detail des contributions de chaque chargement'*NDCHA;
  230. MESS '_____________________________________________'*NDCHA;
  232. MESS CTITR;
  234.  
  235.  
  236. ***********************************************
  237. ***********************************************
  238. ********* BOUCLE SUR LE PAS DE CALCUL *********
  239. ***********************************************
  240. ***********************************************
  241.  
  242. SI ((EGA GDIME 3) OU BOOL.'PASAPAS' OU BOOL.'DECOUPLAGE');
  243.     TABRES = TABL SUPTAB.'RESULTATS';
  244. FINSI;
  245.  
  246. REPE BOUCEXT NBDEP;
  247.  
  248.     IABC = NBG + &BOUCEXT;
  249.  
  250. * DECLARATION DES TABLES STOCKANT LES RESULTATS POUR LE PAS DE TEMPS IABC
  251.     SI BOOL.'PASAPAS';
  252.         SI (EGA GDIME 3);
  253.             SI  BOOL.'DECOUPLAGE';
  254.                 REPE IRUPT GDIME;
  255.                     TABRES.(EXTR 'III' 1 &IRUPT).IABC = TABL;
  256.                 FIN IRUPT;
  257.             SINON;
  258.                 TABRES.IABC = TABL;
  259.             FINSI;
  260.         FINSI;
  261.         SUPTAB.'CHPO_RESULTATS'.IABC = VIDE 'CHPOINT'/'DISCRET';
  262.         SUPTAB.'CHAM_RESULTATS'.IABC = VIDE 'MCHAML';
  263.     FINSI;
  264.  
  265. ***************************************************
  266. ** DEPLACEMENTS,CONTRAINTES ... A L INSTANT INST **
  267. ***************************************************
  268.  
  269.     SI BOOL.'PASAPAS';
  270. * SOLUTION_PASAPAS
  271.         SI BOOL.'PERSO1';
  272. * CAS PERSO1
  273.             INST   =  ESTIM . 'TEMPS';
  274.             DEPINT = (ESTIM . 'DEPLACEMENTS') REDU ELTETA;
  275.             SIGF   = (ESTIM . 'CONTRAINTES' ) REDU MOD_MEC_R;
  276.             SI (BOOL.'GRANDS_DEP' ET (NON BOOL.'ROT_RIG'));
  277.                 SIGF = 'CAPI' SIGF DEPINT MOD_MEC_R;
  278.             FINSI;
  279.             SI BOOL.'ROT_RIG';
  280.                 SI (NON (EXIS (SUPTAB.'ROTATION_RIGIDIFIANTE') IABC));
  281.                     MESS 'ERREUR : Le deplacement du a une rotation';
  282.                     MESS '         rigidifiante au pas ' IABC ' n est pas'
  283.                     MESS '         donne';
  284.                     ERRE 21 ; QUIT G_THETA;
  285.                 FINSI;
  286.                 DEPINT = DEPINT -
  287.                 (REDU SUPTAB.'ROTATION_RIGIDIFIANTE'.IABC ELTETA);
  288.             FINSI;
  289.             SI (EXIS ESTIM 'VARIABLES_INTERNES');
  290.                 VARF = (ESTIM . 'VARIABLES_INTERNES') REDU MOD_MEC_R;
  291.             SINON;
  292.                 VARF = ZERO MOD_MEC_R 'VARINTER' ;;
  293.             FINSI;
  294.             SI BOOL.'C*';
  295.                 SI (EGA IABC 0);
  296.                     DELTAT = INST + 1.E+30;
  297.                     DEPINT = ESTIM . 'DEPLACEMENTS';
  298.                     VITDFI = ESTIM . 'DEFORMATIONS_INELASTIQUES';
  299.                     SIG1 = SIGF * 1.;
  300.                 FINSI;
  301.                 SI (IABC '>' 0);
  302.                     DELTAT= INST - (ESTIM . 'TEMPS');
  303.                     DEPINT= (ESTIM.'DEPLACEMENTS') - (ESTIM.'DEPLACEMENTS');
  304.                     VITDFI= (ESTIM.'DEFORMATIONS_INELASTIQUES')
  305.                                 - (ESTIM.'DEFORMATIONS_INELASTIQUES');
  306.                 FINSI;
  307.                 DEPINT = (REDU ELTETA DEPINT) / DELTAT;
  308.                 VITDFI = (REDU ELTETA VITDFI) / DELTAT;
  309.             FINSI;
  310.             SI BOOL.'J_DYNA';
  311.                 VITF = (ESTIM .'VITESSES')      REDU ELTETA;
  312.                 ACCF = (ESTIM .'ACCELERATIONS') REDU ELTETA;
  313.             FINSI;
  314.         SINON;
  315. * CAS OU ON APPELLE G_THETA APRES PASAPAS
  316.             INST = SUPTAB.'SOLUTION_PASAPAS'.'TEMPS'.IABC;
  317.             DEPINT = (SUPTAB.'SOLUTION_PASAPAS'.'DEPLACEMENTS'.IABC)
  318.             REDU ELTETA;
  319.             SIGF = (SUPTAB.'SOLUTION_PASAPAS'.'CONTRAINTES'.IABC)
  320.                     REDU MOD_MEC_R;
  321.             SI (BOOL.'GRANDS_DEP' ET (NON BOOL.'ROT_RIG'));
  322.                 SIGF = 'CAPI' SIGF DEPINT MOD_MEC_R;
  323.             FINSI;
  324.             SI BOOL.'ROT_RIG';
  325.                 SI (NON (EXIS (SUPTAB.'ROTATION_RIGIDIFIANTE') IABC));
  326.                     MESS 'ERREUR : Le deplacement du a une rotation';
  327.                     MESS '         rigidifiante au pas ' IABC ' n est pas'
  328.                     MESS '         donne';
  329.                     ERRE 21 ; QUIT G_THETA;
  330.                 FINSI;
  331.                 DEPINT = DEPINT -
  332.                 (REDU SUPTAB.'ROTATION_RIGIDIFIANTE'.IABC ELTETA);
  333.             FINSI;
  334.             SI (EXIS (SUPTAB.'SOLUTION_PASAPAS') 'VARIABLES_INTERNES');
  335.                 VARF = (SUPTAB.'SOLUTION_PASAPAS'.'VARIABLES_INTERNES'.IABC)
  336.                 REDU MOD_MEC_R;
  337.             SINON;
  338.                 VARF = ZERO MOD_MEC_R 'VARINTER' ;;
  339.             FINSI;
  340.             SI BOOL.'C*';
  341.                 SI (EGA IABC 0);
  342.                     DELTAT = INST + 1.E+30;
  343.                     DEPINT = SUPTAB.'SOLUTION_PASAPAS'.'DEPLACEMENTS'.IABC;
  344.                     VITDFI = SUPTAB.'SOLUTION_PASAPAS'.
  345.                     'DEFORMATIONS_INELASTIQUES'.IABC;
  346.                     SIG1 = SIGF * 1.;
  347.                 FINSI;
  348.                 SI (IABC > 0);
  349.                     DELTAT = INST - (SUPTAB.'SOLUTION_PASAPAS'.'TEMPS'.
  350.                                 (IABC - 1));
  351.                     DEPINT = (SUPTAB.'SOLUTION_PASAPAS'.'DEPLACEMENTS'.IABC) -
  352.                     (SUPTAB.'SOLUTION_PASAPAS'.'DEPLACEMENTS'.(IABC - 1));
  353.                     VITDFI = (SUPTAB.'SOLUTION_PASAPAS'.
  354.                                 'DEFORMATIONS_INELASTIQUES'.IABC) -
  355.                                 (SUPTAB.'SOLUTION_PASAPAS'.
  356.                                 'DEFORMATIONS_INELASTIQUES'.(IABC - 1));
  357.                 FINSI;
  358.                 DEPINT = (REDU ELTETA DEPINT) / DELTAT;
  359.                 VITDFI = (REDU ELTETA VITDFI) / DELTAT;
  360.             FINSI;
  361.             SI BOOL.'J_DYNA';
  362.                 VITF = (SUPTAB.'SOLUTION_PASAPAS'.'VITESSES'.IABC)
  363.                 REDU ELTETA;
  364.                 ACCF = (SUPTAB.'SOLUTION_PASAPAS'.'ACCELERATIONS'.IABC)
  365.                 REDU ELTETA;
  366.             FINSI;
  367.         FINSI;
  368.     SINON;
  369. * SOLUTION_RESO
  370.         DEPINT = REDU (SUPTAB.'SOLUTION_RESO') ELTETA;
  371.         SIGF = SIGM 'LINE' DEPINT MOD_MEC_R MAT_MEC;
  372.     FINSI;
  373.  
  374. * ON CHANGE LE DEPLACEMENT DEPINT EN MCHAML AU NOEUD
  375.     DEPINT = CHAN 'CHAM' DEPINT MOD_MEC_R 'NOEUD' 'DEPLACEMENTS';
  376.  
  377. ****************************************************
  378. * MODIFICATION DES CHAMPS THETA ET PI SI GRANDE ROT
  379. ****************************************************
  380.  
  381.     SI (BOOL.'PASAPAS' ET BOOL.'ROT_RIG');
  382.         FORM SUPTAB.'ROTATION_RIGIDIFIANTE'.IABC;
  383.         OTER SUPTAB 'TAB_THETA';
  384.         SI BOOL.'DJ/DA';
  385.             OTER SUPTAB 'TAB_PI';
  386.         FINSI;
  387.         CH_THETA SUPTAB OBJUTI BOOL;
  388.     FINSI;
  389.  
  390. **********************************************************************
  391. * CALCUL DES GRADIENTS ET DE LA DIVERGENCE DES CHAMPS THETA
  392. **********************************************************************
  393.  
  394.     SI ((EGA &BOUCEXT 1) OU (BOOL.'PASAPAS' ET BOOL.'ROT_RIG'));
  395.         TTHETA = SUPTAB.'TAB_THETA';
  396.         INDTH = INDE TTHETA;
  397.         NBOU = DIME TTHETA;
  398.         SUPTAB.'GRTHETA' = TABL;
  399.         SUPTAB.'DIVTHETA' = TABL;
  400.         REPE BCNOEU NBOU;
  401.             IND0 = INDTH.&BCNOEU;
  402.             CHTHETA = TTHETA.IND0 + DEP000;
  403.             GRTHETA = GRAD MOD_MEC_R CHTHETA CAR1;
  404.             DIVTHETA = (EXCO GR1 GRTHETA 'SCAL') +
  405.                         (EXCO GR5 GRTHETA 'SCAL') +
  406.                         (EXCO GR9 GRTHETA 'SCAL');
  407.             DIVTHETA = CHAN 'TYPE' DIVTHETA 'SCALAIRE';
  408.             SUPTAB.'GRTHETA'.IND0 = GRTHETA;
  409.             SUPTAB.'DIVTHETA'.IND0 = DIVTHETA;
  410.         FIN BCNOEU;
  411.     FINSI;
  412.  
  413.  
  414. ***************************************************
  415. ********** TEMPERATURES A L INSTANT INST **********
  416. ***************************************************
  417.  
  418.     SI BOOL.'THER';
  419.         SI BOOL.'PASAPAS';
  420.             SI BOOL.'THER_DECO';
  421.                 TEPINT = 'TIRE' CHAR1 INST 'T';
  422.             SINON;
  423. * bp, 2014-11-13 : ajout distinction cas BOOL.'THER' et BOOL.'THER_DECO'
  424.                 TEPINT = REDU ELTETA SUPTAB.'SOLUTION_PASAPAS'.'TEMPERATURES'.
  425.                             IABC;
  426.             FINSI;
  427.         SINON;
  428.             TEPINT = SUPTAB.'TEMPERATURES';
  429.         FINSI;
  430.     FINSI;
  431.  
  432.  
  433. ***************************************************
  434. ********** DEF IMPOSEE A L INSTANT INST **********
  435. ***************************************************
  436.  
  437.     SI BOOL.'DEF_IMP';
  438.         SI BOOL.'PASAPAS';
  439.             DEFI = 'TIRE' CHAR1 INST 'DEFI';
  440.         SINON;
  441.             DEFI = SUPTAB.'DEFORMATIONS_IMPOSEES';
  442.         FINSI;
  443.     FINSI;
  444.  
  445. ***************************************************
  446. ********** CONTACT FROTTANT **********
  447. ***************************************************
  448.  
  449.     SI BOOL.'FROT';
  450.         SI BOOL.'PASAPAS';
  451. * ...TODO
  452.         SINON;
  453. * A PRIORI DEPLACEMENT_FISSURE PAS TRES UTILE ...
  454.             SI (EXIS SUPTAB 'DEPLACEMENT_FISSURE');
  455.                 WDEP  = SUPTAB . 'DEPLACEMENT_FISSURE';
  456.             SINON;
  457.                 WDEP  = REDU (SUPTAB.'SOLUTION_RESO') MAICON;
  458.             FINSI;
  459.             TOTO = EXTR WDEP 'MAIL';
  460.             SI (EGA (NBEL TOTO) 0);
  461.                 MESS 'ERREUR : IL FAUT DEPLACEMENT_FISSURE SI MODELE_FISSURE';
  462.                 ERRE 21 ; QUIT G_THETA;
  463.             FINSI;
  464.             SI (EXIS SUPTAB 'PRESSION_FISSURE');
  465.                 SIGCON = SUPTAB . 'PRESSION_FISSURE';
  466.             SINON;
  467.                 SIGCON = REDU SIGF OBJCON;
  468.             FINSI;
  469. * PEUT ETRE FAIRE UN TEST SUR SIGCON ...
  470.         FINSI;
  471.     FINSI;
  472.  
  473. *****************************************************
  474. * CONTRAINTE RECALCULEE SI BOOL.'THER' = VRAI et NON BOOL.'PASAPAS' *
  475. *****************************************************
  476.  
  477.     SI (BOOL.'THER' ET (NON BOOL.'PASAPAS'));
  478.         SIGF = SIGF - (THET MOD_MEC_R MAT_MEC TEPINT);
  479.     FINSI;
  480.  
  481.  
  482. ***************************************************
  483. ************ MATERIAU A L INSTANT INST ************
  484. ***************************************************
  485.  
  486.     SI (BOOL.'GRADPROP' ET BOOL.'THER' ET BOOL.'PASAPAS');
  487.         MAT_INST = VARI 'NUAG' MOD_MEC_R MAT_MEC (EXCO 'T' TEPINT 'T');
  488.     SINON;
  489.         MAT_INST = MAT_MEC;
  490. * bp: ne devrait on pas ecrire ci dessous..? inutile?
  491. * MAT_INST = REDU MOD_MEC_R MAT_MEC
  492.     FINSI;
  493.     OBJUTI.'MAT_INST' = MAT_INST;
  494.  
  495.  
  496. ***************************************************
  497. ********* RIGIDITE TOTALE A L INSTANT INST ********
  498. ***************************************************
  499.  
  500. * bp: utilite?
  501.     AUX_MECA = FAUX;
  502.     SI BOOL.'DECOUPLAGE';
  503.         AUX_MECA = EGA SUPTAB.'METH_AUX' 'MECA';
  504.     FINSI;
  505.     SI (BOOL.'DJ/DA' OU AUX_MECA);
  506.         SI BOOL.'PASAPAS';
  507.             SI (BOOL.'GRADPROP' ET BOOL.'THER');
  508.                 M1 = VARI 'NUAG' MOD_MEC_R (EXCO 'T' TEPINT 'T')
  509.                 (SUPTAB.'SOLUTION_PASAPAS'.'CARACTERISTIQUES');
  510.             SINON;
  511.                 M1 = SUPTAB.'SOLUTION_PASAPAS'.'CARACTERISTIQUES';
  512.             FINSI;
  513.             RIGTOT = RIGI M1 (SUPTAB.'SOLUTION_PASAPAS'.'MODELE');
  514.         SINON;
  515.             RIGTOT = RIGI (SUPTAB.'CARACTERISTIQUES') (SUPTAB.'MODELE');
  516.         FINSI;
  517.     FINSI;
  518.  
  519. ************************************
  520. *** RIGTOT + BLOCAGES MECANIQUES ***
  521. ************************************
  522.  
  523.     SI  BOOL.'DJ/DA';
  524.       SI BOOL.'PASAPAS';
  525.          RIGTOT = RIGTOT ET
  526.                  (SUPTAB.'SOLUTION_PASAPAS'.'BLOCAGES_MECANIQUES');
  527. * rem bp: on suppose ceux ci identique a ceux de wtab...
  528.       SINON;
  529.          RIGTOT = RIGTOT ET SUPTAB.'BLOCAGES_MECANIQUES';
  530.       FINSI;
  531.     FINSI;
  532.     OBJUTI.'RIGTOT' = RIGTOT;
  533.  
  534. ********************************************************************
  535. ****** CHARGEMENT MECANIQUE (FORCES NODALES) A L INSTANT INST ******
  536. ********************************************************************
  537.  
  538.     PREINT = FOR000;
  539.     SI BOOL.'PASAPAS';
  540. *** SOLUTION_PASAPAS ******************************
  541.         SI (EXIS CHAR1 'MECA');
  542.             PREINT = PREINT + ((TIRE CHAR1 INST 'MECA') REDU ELTETA);
  543.         FINSI;
  544.         SI BOOL.'MODE_PRES';
  545. * Dans le cas ou il y a un modele de pression
  546.             MATPRE = TIRE CHAR1 'PRES' INST;
  547. * --> on isole la partie du MMODEL de pression qui est appliquee
  548. * sur la fissure
  549.             SI BOOL.'PRES_FISS';
  550.                 MODPF = REDU MODPRE MAILPF;
  551.                 MATPF = REDU MATPRE MODPF;
  552.             FINSI;
  553. * --> on calcule les forces nodales equivalentes aux pressions
  554. * appliquees hors de la fissure
  555.             MAILPEXT = DIFF MAILPTOT MAILPF;
  556.             SI ((NBEL MAILPEXT) > 0);
  557.                 MODPEXT = REDU MODPRE MAILPEXT;
  558.                 MATPEXT = REDU MATPRE MODPEXT;
  559.                 PREINT = PREINT + (BSIG MODPEXT MATPEXT);
  560.             FINSI;
  561.         FINSI;
  562.     SINON;
  563. *** SOLUTION_RESO **********************************
  564.         SI (EXIS SUPTAB 'CHARGEMENTS_MECANIQUES');
  565.             PREINT = PREINT + (SUPTAB.'CHARGEMENTS_MECANIQUES' REDU ELTETA);
  566.         FINSI;
  567.         SI BOOL.'MODE_PRES';
  568. * Dans le cas ou il y a un modele de pression
  569. * --> on isole la partie du MMODEL de pression qui est appliquee sur
  570. * la fissure
  571.             SI BOOL.'PRES_FISS';
  572.                 MODPF = REDU MODPRE MAILPF;
  573.                 MATPF = REDU MATPRE MODPF;
  574.             FINSI;
  575. * --> on calcule les forces nodales equivalentes aux pressions
  576. * appliquees hors de la fissure
  577.             MAILPEXT = DIFF MAILPTOT MAILPF;
  578.             SI ((NBEL MAILPEXT) > 0);
  579.                 MODPEXT = REDU MODPRE MAILPEXT;
  580.                 MATPEXT = REDU MATPRE MODPEXT;
  581.                 PREINT = PREINT + (BSIG MODPEXT MATPEXT);
  582.             FINSI;
  583.         FINSI;
  584.     FINSI;
  585.  
  586. **********************************************************************
  587. ******** POUR LES PRESSIONS APPLIQUEES SUR LA FISSURE
  588. *        on calcule le MCHAML vectoriel de [pression * normale]
  589. **********************************************************************
  590.  
  591.     SI BOOL.'PRES_FISS';
  592. * champ de normale unitaire au maillage de la fissure
  593.         MAT_INSTF = PRES MODPF 'PRES' 1.;
  594.         NF1   = BSIG MODPF MAT_INSTF;
  595.         LCOMP = EXTR NF1 'COMP';
  596.         NF2   =  CHAN 'CHAM' NF1 MODPF 'STRESSES';
  597.         XX    = PSCA NF2 NF2 LCOMP LCOMP;
  598.         NF    = NF2 / (XX**0.5);
  599. * champ de pression normale au maillage de la fissure
  600.         PF    = CHAN 'STRESSES' MODPF MATPF;
  601.         PF    = CHAN 'TYPE' PF 'FORCES';
  602.         NCOMP = DIME LCOMP;
  603.         LCP   = MOTS NCOMP*'PRES';
  604.         PNF   = PF * NF LCP LCOMP LCOMP;
  605.     FINSI;
  606.  
  607. ****************************************************
  608. ***** APPEL A G_AUX POUR LES CHAMPS AUXILIAIRES ****
  609. ****************************************************
  610.  
  611. * G_AUX
  612.     SI AUX_MECA;
  613.         CH_AUX = G_AUX SUPTAB OBJUTI BOOL;
  614.         SI (EGA (TYPE CH_AUX) (MOT 'ANNULE'));
  615.             MESS 'ERREUR : G_AUX A RENCONTRE UN PROBLEME';
  616.             QUIT G_CALCUL;
  617.         FINSI;
  618.         SUPTAB.'CH_AUX' = CH_AUX;
  620.     FINSI;
  621.  
  622. *debut du cas contact frottant BOOL.'FROT' (btrolle 19/02/2013)
  623.     SI (BOOL.'FROT');
  624.         OBJCON = OBJUTI.'OBJCON';
  625.         OBJCON2 = OBJUTI.'OBJCON2';
  626.     FINSI;
  627. *fin du cas contact frottant BOOL.'FROT' (btrolle 19/02/2013)
  628.  
  629.  
  630. ***********************************************
  631. ***********************************************
  632. **** BOUCLE SUR LES INTEGRALES A CALCULER *****
  633. ***********************************************
  634. ***********************************************
  635.  
  636. * NBMIXT = nbre d integrale a calculer (=1 si J, =2 si K1 K2, =3
  637. * si K1 K2 K3)
  638.     NBMIXT = 1;
  639.     SI BOOL.'DECOUPLAGE';
  640.         C_MATE = OBJUTI.'C_MATE';
  641.         MU_1 = OBJUTI.'MU_1';
  642.         NBMIXT = 2;
  643.         SI (EGA GDIME 3);
  644.             NBMIXT = 3;
  645.         FINSI;
  646.     FINSI;
  647.     REPE BOUCMIX NBMIXT;
  648.  
  649.  
  650. *|=====================================================================|
  651. *|=======  I. OBJETS NECESSAIRES  =====================================|
  652.  
  653.  
  654.         SI BOOL.'DECOUPLAGE';
  655.             MOCOMP = CHAI 'K' &BOUCMIX;
  656.         FINSI;
  657.  
  658. ****************************************************
  659. **************** EN CAS DE DECOUPLAGE **************
  660. ****************************************************
  661.  
  662.         SI BOOL.'DECOUPLAGE';
  663.             MOTMIX = CH_AUX.&BOUCMIX.'MOTMIX';
  664.             MOTMIA = CH_AUX.&BOUCMIX.'MOTMIA';
  665.             A_PREI = CH_AUX.&BOUCMIX.'A_PREI';
  666.             A_DEPI = CH_AUX.&BOUCMIX.'A_DEPI';
  667.             A_SIGF = CH_AUX.&BOUCMIX.'A_SIGF';
  668.             A_DEPGR = CH_AUX.&BOUCMIX.'A_DEPGR';
  669. *debut du cas contact frottant BOOL.'FROT' (btrolle 19/02/2013)
  670.             SI (BOOL.'FROT');
  671.                 B_DEPGR = CH_AUX.&BOUCMIX.'B_DEPGR';
  672.             FINSI;
  673. *fin du cas contact frottant BOOL.'FROT' (btrolle 19/02/2013)
  674.         FINSI;
  675.  
  676.  
  677. ****************************************************
  678. ******* EN CAS DE CALCUL EN VISCO_PLASTICITE *******
  679. ****************************************************
  680.  
  681. * INITIALISATION DE FACT1
  682.         FACT1 = 1.;
  683.         SI (BOOL.'C*' OU BOOL.'C*H');
  684.             SI (EGA ITYPEF 1);
  685.                 CHAF1 = (CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF1 ' MAT_INST 'SCAL'))
  686.                 CHAN 'TYPE' 'SCALAIRE';
  687.                 CHAF2 = (CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF2 ' MAT_INST 'SCAL'))
  688.                 CHAN 'TYPE' 'SCALAIRE';
  689.                 CHAF3 = (CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF3 ' MAT_INST 'SCAL'))
  690.                 CHAN 'TYPE' 'SCALAIRE';
  691.                 SI (EXIS MAT_INST 'AF0 ');
  692.                     CHAF4 =( CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF4 ' MAT_INST 'SCAL'))
  693.                     CHAN 'TYPE' 'SCALAIRE';
  694.                     CHAF5 =( CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF5 ' MAT_INST 'SCAL'))
  695.                     CHAN 'TYPE' 'SCALAIRE';
  696.                     CHAF6 = (CHAN 'STRESSES' MOD_MEC_R (EXCO 'AF6 ' MAT_INST 'SCAL'))
  697.                     CHAN 'TYPE' 'SCALAIRE';
  698.                 FINSI;
  699.             FINSI;
  700.             SI BOOL.'C*';
  701.                 SI (EGA ITYPEF 1);
  702. * DENSITE D'ENERGIE POUR LES FLUAGES DONT ON A UNE
  703. * EXPRESSION EXPLICITE DE L'INTEGRATION SUR LE TEMPS
  704.                     SI (EXIS MAT_INST 'AF0 ');
  705.                         COE1 = ((MINI (CHAF2 + 1.)) + (MAXI (CHAF2 + 1.)))/2.;
  706.                         COE2 = ((MINI (CHAF4 + 1.)) + (MAXI (CHAF4 + 1.)))/2.;
  707.                         COE3 = ((MINI (CHAF6 + 1.)) + (MAXI (CHAF6 + 1.)))/2.;
  708.                         VMI1 = (EXCO ('VMIS' MOD_MEC_R SIGF MAT_INST) 'SCAL')
  709.                         CHAN 'TYPE' 'SCALAIRE'        ;
  710.                         ENERM1 = (CHAF2*((CHAF2 + 1.)**(-1.)))*CHAF1*(VMI1**COE1);
  711.                         ENERM2 = (CHAF4*((CHAF4 + 1.)**(-1.)))*CHAF3*(VMI1**COE2);
  712.                         ENERM3 = (CHAF6*((CHAF6 + 1.)**(-1.)))*CHAF5*(VMI1**COE3);
  713.                         ENERM = ENERM1 + ENERM2 + ENERM3;
  714.                     SINON;
  715.                         COE1 = ((MINI (CHAF2 + 1.)) + (MAXI (CHAF2 + 1.)))/2.;
  716.                         COE2 = ((MINI CHAF3) + (MAXI CHAF3))/2.;
  717.                         VMI1 = (EXCO ('VMIS' MOD_MEC_R SIGF MAT_INST) 'SCAL')
  718.                         CHAN 'TYPE' 'SCALAIRE'    ;
  719.                         SI ((EGA INST 0. 1.E-10) ET ('<'(COE2 - 1) 0.));
  720.                             V1 = 0.;
  721.                         SINON;
  722.                             V1 = INST**(COE2 - 1);
  723.                         FINSI;
  724.                         ENERM = (CHAF2*((CHAF2 + 1.)**(-1.)))*
  725.                                     CHAF1*(VMI1**COE1)*CHAF3*V1;
  726.                     FINSI;
  727.                     SI (BOOL.'COQ' ET BOOL.'EL_LIN') ; ENERM = ENERM*MOD_MEC_R EPAICH ; FINSI;
  728.                 FINSI;
  729.                 SI (EGA ITYPEF 2);
  730. * ON N'A PAS UNE EXPRESSION EXPLICITE DE
  731. * L'INTEGRATION DU FLUAGE SUR LE TEMPS
  732.                     SIGMOY = 0.5*(SIG1 + SIGF);
  733.                     SI ((EGA IABC 0) ET (NON BOOL.'REPRI'));
  734.                         ENERM = 'ENER' MOD_MEC_R VITDFI SIGMOY;
  735.                     SINON;
  736.                         ENERM = ENERM + ('ENER' MOD_MEC_R (VITDFI - VDI1) SIGMOY);
  737.                     FINSI;
  738.                     SIG11 = SIG1 ; SIG1 = SIGF ; VDI1 = VITDFI;
  739.                 FINSI;
  740.             FINSI;
  741. * FACTEUR AFFECTE A J SI ON CALCULE C*(H)
  742.             SI BOOL.'C*H';
  743.                 CHAR2 = EXTR CHAR1 'MECA';
  744.                 COE1 = ((MINI CHAF1) + (MAXI CHAF1)) / 2.;
  745.                 COE2 = ((MINI CHAF2) + (MAXI CHAF2)) / 2.;
  746.                 COE3 = ((MINI CHAF3) + (MAXI CHAF3)) / 2.;
  747.                 N1 = COE2 / COE3;
  748.                 SI (EGA INST 0. 1.E-10) ; INST = 1.E-10 ; FINSI;
  749.                 P1 = PROG 0. 'PAS' (INST / 100.) INST;
  750.                 P2 = PROG;
  751.                 REPE BF1 (DIME P1);
  752.                     T1 = EXTR P1 &BF1;
  753.                     V1 = 0.;
  754.                     REPE BF2 (DIME CHAR2);
  755.                         E1 = EXTR CHAR2 'EVOL' &BF2;
  756.                         V1 = V1 + ('IPOL' T1 (EXTR E1 'ABSC') (EXTR E1 ORDO));
  757.                     FIN BF2;
  758.                     P2 = P2 ET (PROG V1);
  759.                 FIN BF1;
  760.                 E1 = EVOL 'MANU' 'TEMPS' P1 'FORCE' (P2 ** N1);
  761.                 FACT1 = EXTR (INTG E1) 1;
  762.                 SI (EGA FACT1 0. 1.E-10) ; FACT1 = 1.E+30 ; FINSI;
  763.                 FACT1 = ((V1 ** N1) / FACT1) ** COE3;
  764.             FINSI;
  765.         FINSI;
  766.  
  767.  
  768. ********************************************************
  769. * SI LA COURBE DE TRACTION DEPEND DE LA TEMPERATURE ON *
  770. * CALCULE LA VARIATION DE CONTRAINTES DE VON-MISES LORS*
  771. * D'UNE AUGMENTATION (DETATE) DE LA TEMPERATURE A INST *
  772. ********************************************************
  773. *bp 11/08/2011 : on calcule plutot la variation de la limite d elasticite
  774. *                ce qui est moins faux si presence de decharge...
  775. *            => on construit VM1 comm VM2 !
  776.         SI (((DIME MODPLA) '>' 0) ET BOOL.'THER');
  777.             DETATE = 1.;
  778.             TEP1 = TEPINT + (MANU 'CHPO' ELTETA 1 'T' DETATE);
  779.             EPS1 = (EXCO VARF 'EPSE') CHAN 'TYPE' 'SCALAIRE';
  780.             MSQ1 = 'MASQ' 'SUPERIEUR' EPS1 1.E-10;
  781.             EPS1 = MSQ1 * EPS1;
  782. * rem : on pourrait utiliser BORN dans le futur
  783. * VMI1 = (CHAN ('VMIS' MOD_MEC_R SIGF MAT_INST)
  784. *         'TYPE' 'SCALAIRE')*MSQ1;
  785. * DETAVM = VMI1 * 0.;
  786.             DETAVM = 0.;
  787.             REPETER BCMOD2 NBOBJ;
  788.                 MODI = TABMOD.&BCMOD2;
  789. * VM1 = REDU VMI1 MODI;
  790.                 EPS2 = redu EPS1 MODI;
  791.                 SI (EXIS MODPLA &BCMOD2);
  792.                     SI (EGA MODPLA.&BCMOD2 1);
  793.                         MA1 = VARI 'NUAG' MODI (MATE MODI
  794.                                 'ECRO' TABTRA.&BCMOD2) TEPINT;
  795.                         VM1 = VARI 'NUAG' MODI (EXCO 'ECRO' MA1 'SIGM')
  796.                         EPS2 'STRESSES' 'SCALAIRE';
  797.                         VM1 = (EXCO VM1 'SIGM' 'SCAL') CHAN 'TYPE' 'SCALAIRE';
  798.                         MA2 = 'VARI' 'NUAG' MODI (MATE MODI
  799.                                 'ECRO' TABTRA.&BCMOD2) TEP1;
  800. * VM2 = 'VARI' 'NUAG' MODI (EXCO 'ECRO' MA2 SIGM)
  801. *       (REDU EPS1 MODI) 'STRESSES' 'SCALAIRE';
  802. * VM2 = ((EXCO VM2 SIGM 'SCAL')CHAN 'TYPE' 'SCALAIRE')
  803. *         * (REDU MSQ1 MODI);
  804.                         VM2 = VARI 'NUAG' MODI (EXCO 'ECRO' MA2 'SIGM')
  805.                                 EPS2 'STRESSES' 'SCALAIRE';
  806.                         VM2 = (EXCO VM2 SIGM 'SCAL') CHAN 'TYPE' 'SCALAIRE';
  807.                     FINSI;
  808.                     SI ((EGA MODPLA.&BCMOD2 2) OU
  809.                         (EGA MODPLA.&BCMOD2 3));
  810.                         MA1 = VARI 'NUAG' MODI (REDU MAT_MEC MODI) TEPINT;
  811.                         VM1 = CHAN 'STRESSES' MODI (EXCO MA1 'SIGY' 'SCAL');
  812.                         MA2 = VARI 'NUAG' MODI (REDU MAT_MEC MODI) TEP1;
  813. * EPS2 = REDU EPS1 MODI;
  814.                         VM2 = CHAN 'STRESSES' MODI (EXCO MA2 'SIGY' 'SCAL');
  815.                         SI (EGA MODPLA.&BCMOD2 2);
  816.                             HSCAL1 = (EXCO MA1 'H' 'SCAL') CHAN 'TYPE' 'SCALAIRE';
  817.                             VM1 = VM1 + ((CHAN 'STRESSES' MODI HSCAL1)*EPS2);
  818.                             HSCAL2 = (EXCO MA2 'H' 'SCAL') CHAN 'TYPE' 'SCALAIRE';
  819.                             VM2 = VM2 + ((CHAN 'STRESSES' MODI HSCAL2)*EPS2);
  820.                         FINSI;
  821. * VM2 = VM2 * (REDU MSQ1 MODI);
  822.                     FINSI;
  823.                     SI (EGA (TYPE DETAVM) 'FLOTTANT');
  824.                         DETAVM = ((VM2 - VM1) / DETATE);
  825.                     SINON;
  826.                         DETAVM = DETAVM + ((VM2 - VM1) / DETATE);
  827.                     FINSI;
  828.                 FINSI;
  829.             FIN BCMOD2;
  830.         FINSI;
  831.  
  832.  
  833.  
  834. *******************************************************
  835. **** ENERGIE DE DEFORMATION ELASTIQUE ET PLASTIQUE ****
  836. *******************************************************
  837. ***
  838. *** DENSITE D'ENERGIE EN ELASTO OU THERMO-ELASTO-PLASTICITE ET
  839. *** DENSITE D'ENERGIE LIEE A LA VARIATION DE COURBE DE TRACTION
  840. ***
  841.         SI (NON BOOL.'C*');
  842.             WELAS = 0.5*('ENER' MOD_MEC_R SIGF ('ELAS' MOD_MEC_R SIGF MAT_INST));
  843. *         SI (BOOL.'PASAPAS' ET (NON BOOL.'DECOUPLAGE'));
  844.             SI (BOOL.'PASAPAS');
  845.                 SI (EGA IABC 0);
  846.                     VMI1 = CHAN ('VMIS' MOD_MEC_R SIGF MAT_INST) 'TYPE' 'SCALAIRE';
  847.                     SI (BOOL.'COQ' ET BOOL.'EL_LIN') ; VMI1 = VMI1*MOD_MEC_R EPAICH ; FINSI;
  848.                     WPLAS=0.5*VMI1*((EXCO VARF 'EPSE')CHAN 'TYPE' 'SCALAIRE');
  849.                     SI (((DIME MODPLA) '>' 0) ET BOOL.'THER');
  850.                         WVMIS = 0.5*DETAVM*((EXCO VARF 'EPSE')
  851.                                     CHAN 'TYPE' 'SCALAIRE');
  852.                     FINSI;
  853.                 SINON;
  854.                     VMI1 = CHAN (0.5*(('VMIS' MOD_MEC_R SIG1 MAT_INST) +
  855.                             ('VMIS' MOD_MEC_R SIGF MAT_INST))) 'TYPE' 'SCALAIRE';
  856.                     SI (BOOL.'COQ' ET BOOL.'EL_LIN') ; VMI1 = VMI1*MOD_MEC_R EPAICH ; FINSI;
  857.                     WPLAS = WPLAS + (VMI1*((EXCO (VARF - VAR1) 'EPSE')
  858.                                 CHAN 'TYPE' 'SCALAIRE'));
  859.                     SI (((DIME MODPLA) '>' 0) ET BOOL.'THER');
  860.                         WVMIS = WVMIS + ((0.5*(DETAV1 + DETAVM))*
  861.                                     ((EXCO (VARF - VAR1) 'EPSE')
  862.                                     CHAN 'TYPE' 'SCALAIRE') );
  863.                     FINSI;
  864.                 FINSI;
  865.                 ENERM = WELAS + WPLAS;
  866.                 SIG11 = SIG1 ; SIG1 = SIGF*1. ; VAR11 = VAR1 ; VAR1 = VARF*1.;
  867.                 SI (((DIME MODPLA) '>' 0) ET BOOL.'THER');
  868.                     DETAV1 = DETAVM;
  869.                 FINSI;
  870.             SINON;
  871.                 ENERM = WELAS;
  872.             FINSI;
  873.         FINSI;
  874.  
  875.  
  876.  
  877.  
  878. *|=====================================================================|
  879. *|=======  II. CRITERES DE DECHARGES  =================================|
  880.  
  881.  
  882. ************************************************************
  883. ****** CRITERE GLOBAL 1 DE DECHARGE DES CONTRAINTES ********
  884. ************************************************************
  885. ***
  886. *** EVALUATION EN ELASTO-PLASTICITE OU THERMO-ELASTO-PLASTICITE
  887. *** PAR COMPARAISON AVEC UN CALCUL EN ELASTICITE NON-LINEAIRE
  888. *** EN PRENANT POUR REFERENCE LES CONTRAINTES DE VON-MISES DU
  889. *** CALCUL RENDU PAR PASAPAS ET LES CONTRAINTES EQUIVALENTES LUES
  890. *** SUR LES COURBES DE TRACTION
  891. ***
  892.         OUICRIT = FAUX;
  893.         SI (EXIS SUPTAB 'CALCUL_CRITERE');
  894.             OUICRIT = SUPTAB.'CALCUL_CRITERE';
  895.         FINSI;
  896.         SI (BOOL.'MESS' ET OUICRIT);
  897.             MESS 'on va calculer les CRITERES DE DECHARGES, modpla=';
  898. *        list modpla;
  899.         FINSI;
  900.  
  901.         SI ((EGA ITYPEF 99) ET BOOL.'PASAPAS' ET OUICRIT);
  902.  
  903.             XCRIT = 1.;
  904.  
  905.             REPE BCMOD0 (DIME TABMOD);
  906.                 EXISCRIT = FAUX;
  907.                 MODI  = TABMOD.&BCMOD0;
  908.                 MATI  = REDU MAT_INST MODI;
  909.                 EPSE1 = EXCO VARF 'EPSE';
  910.                 EPSE1 = EPSE1 CHAN TYPE 'SCALAIRE';
  911.                 EPSET = REDU EPSE1 MODI;
  912.                 MSQ   = MASQ 'SUPERIEUR' EPSET 1.E-6;
  913.  
  914. * VMIS1 = contraintes de Von-Mises en elastoplastique
  915.                 VMIS1 = CHAN ('VMIS' MODI (REDU SIGF MODI) MATI)
  916.                     TYPE 'SCALAIRE';
  917.  
  918.                 SI ('EXIS' MODPLA &BCMOD0);
  919.                     YOU = CHAN 'STRESSES' MODI (EXCO MATI 'YOUN');
  920.                     YOU = YOU CHAN TYPE 'SCALAIRE';
  921.                     SI (EGA MODPLA.&BCMOD0 1);
  922. * modele est plastique isotrope. on utilise la
  923. * courbe de traction TABTRA.&BCMOD0
  924.                         EXISCRIT = VRAI;
  925.                         MATA = VARI 'NUAG' MODI ('MATE' MODI
  926.                                'ECRO' TABTRA.&BCMOD0) TEPINT;
  927.                         EPELAST = EXCO (VMIS1*(YOU**(-1))) 'SCAL' 'EPSE';
  928.                         EPSTOT = EPELAST + EPSET;
  929. * VMIS2 = contraintes deduites des deformations
  930. * equivalentes par la courbe de traction
  931.                         VMIS2 = VARI 'NUAG' MODI (EXCO 'ECRO' MATA 'SIGM')
  932.                                   EPSTOT 'STRESSES' 'SCALAIRE';
  933.                     FINSI;
  934.  
  935.                     SI (EGA MODPLA.&BCMOD0 2);
  936. * modele est plastique cinematique, cas ou
  937. * SIGY et H sont des evolutions
  938.                         EXISCRIT = VRAI;
  939.                         VMIS22 = CHAN 'STRESSES' MODI (EXCO MATI 'SIGY' 'SCAL');
  940.                         HSCAL = EXCO MATI 'H' 'SCAL';
  941.                         HSCAL = HSCAL CHAN TYPE 'SCALAIRE';
  942.                         VMIS2 = VMIS22 + ((CHAN 'STRESSES' MODI HSCAL) * EPSET);
  943.                     FINSI;
  944.  
  945.                     SI (EGA MODPLA.&BCMOD0 3);
  946. * modele est plastique parfait
  947.                         EXISCRIT = VRAI;
  948.                         VMIS2 = CHAN 'STRESSES' MODI ((EXCO MATI 'SIGY' 'SCAL')
  949.                                 CHAN TYPE 'SCALAIRE' );
  950.                     FINSI;
  951.  
  952.                 SINON;
  953. *** modele elastoplastique et modele plastique cinematique
  954. ***  avec caracteristiques independantes de la temperature
  955.  
  956.                     SI (EXIS MATI 'ECRO');
  957. * extraction de la courbe de traction du modele MODI
  958.                         EXISCRIT = VRAI;
  959.                         TRACTI = EXTR MATI 'ECRO' 1 1 1;
  960.                         PEPSO  = EXTR TRACTI 'ABSC';
  961.                         PSIGM  = EXTR TRACTI 'ORDO';
  962.                         TRACTI = 'EVOL' 'MANU' 'EPSE' PEPSO 'SIGM' PSIGM;
  963.                         YOU    = CHAN 'STRESSES' MODI (EXCO MATI 'YOUN');
  964.                         YOU    = YOU CHAN TYPE 'SCALAIRE';
  965.                         EPELAST= EXCO (VMIS1*(YOU**(-1))) 'SCAL' 'EPSE';
  966.                         EPSTOT = EPELAST + EPSET;
  967. * VMIS2 = contraintes deduites des deformations
  968. * equivalentes par la courbe de traction
  969.                         VMIS2 = 'VARI' MODI EPSTOT TRACTI 'STRESSES';
  970. * ?       VMIS2  = VMIS2 CHAN TYPE 'SCALAIRE';
  971.                     FINSI;
  972.  
  973.                     SI ((EXIS MATI 'SIGY') ET (EXIS MATI 'H'));
  974. * modele est plastique cinematique traite ici separement du cas
  975. * ou SIGY et H sont des evolutions c'est inutile car MAT_INST est
  976. * deja instantie en temperature mais il faudra regler le pb de
  977. * MODPLA dans son ensemble avec ZONE et une identification
  978. * automatique de chacun des sous-modes
  979.                         EXISCRIT = VRAI;
  980.                         VMIS22 = CHAN 'STRESSES' MODI (EXCO MATI 'SIGY' 'SCAL');
  981.                         VMIS22 = VMIS22 CHAN TYPE 'SACALAIRE';
  982.                         HSCAL  = EXCO MATI 'H' 'SCAL';
  983.                         HSCAL  = HSCAL CHAN TYPE 'SCALAIRE';
  984.                         VMIS2  = VMIS22 + ((CHAN 'STRESSES' MODI HSCAL) * EPSET);
  985.                     FINSI;
  986.                     SI ((EXIS MATI 'SIGY') ET (NON (EXIS MATI 'H')));
  987. * modele est plastique parfait
  988.                         EXISCRIT = VRAI;
  989.                         VMIS2  = CHAN 'STRESSES' MODI (EXCO MATI 'SIGY' 'SCAL');
  990.                         VMIS2  = VMIS2 CHAN TYPE 'SCALAIRE';
  991.                     FINSI;
  992.  
  993.                 FINSI;
  994.  
  995.                 SI EXISCRIT;
  996.                     VMIS1P = VMIS1 * MSQ;
  997.                     VMIS1S = INTG MODI VMIS1P;
  998.                     VMIS2P = VMIS2 * MSQ;
  999.                     VMIS2S = INTG MODI VMIS2P;
  1000.                     SI ('NEG' VMIS1S 0.);
  1001.                         XCRIT = XCRIT + ((VMIS2S/VMIS1S) - 1.);
  1002.                     FINSI;
  1003.                 FINSI;
  1004.  
  1005.             FIN BCMOD0;
  1006.  
  1007.             SUPTAB.'CRIT_DECHA_GLOBAL1'.IABC = XCRIT;
  1008.  
  1009.         FINSI;
  1010.  
  1011.  
  1012. *********************************************************
  1013. ****** CRITERE LOCAL 1 DE DECHARGE DES CONTRAINTES ******
  1014. *********************************************************
  1015.  
  1016.         SI ((EGA ITYPEF 99) ET BOOL.'PASAPAS' ET (IABC  > 0) ET OUICRIT);
  1017.             SI BOOL.'MESS';
  1018.                 MESS 'CRITERE LOCAL 1';
  1019.             FINSI;
  1020.             EXISCRIT = FAUX;
  1021.             VMITOTF = ZERO MOD_MEC_R STRESSES;
  1022.             VMITOT1 = ZERO MOD_MEC_R STRESSES;
  1023. * initialisation
  1024.  
  1025.             REPE BCMOD0 (DIME TABMOD);
  1026.  
  1027.                 MODI  = TABMOD.&BCMOD0;
  1028.                 MATI  = REDU MAT_INST MODI;
  1029.                 EPSE1 = EXCO VARF 'EPSE';
  1030.                 EPSE1 =  EPSE1 CHAN TYPE 'SCALAIRE';
  1031.                 EPSET = REDU EPSE1 MODI;
  1032.                 MSQ   = 'MASQ' 'SUPERIEUR' EPSET 1.E-6;
  1033.  
  1034.                 SI ('EXIS' MODPLA &BCMOD0);
  1035.                     INST1  = SUPTAB.'SOLUTION_PASAPAS'.'TEMPS'.(IABC-1);
  1036.                     TEPIN1 = TIRE CHAR1 INST1 'T';
  1037.                     TEPIN1 = REDU TEPIN1 ELTETA;
  1038. * TEPIN1 : temperature absolue au pas precedent
  1039.  
  1040. * modele plastique isotrope
  1041.                     SI (EGA MODPLA.&BCMOD0 1);
  1042.                         MATA = 'VARI' 'NUAG' MODI ('MATE' MODI
  1043.                                       'ECRO' TABTRA.&BCMOD0) TEPINT;
  1044.                         VMISF = CHAN ('VMIS' MODI SIGF MATA) TYPE 'SCALAIRE';
  1045. * VMISF : contrainte de Von Mises au pas courant
  1046.                         MATA1 = 'VARI' 'NUAG' MODI ('MATE' MODI
  1047.                                       'ECRO' TABTRA.&BCMOD0) TEPIN1;
  1048.                         VMIS1 = CHAN ('VMIS' MODI SIG11 MATA1) TYPE 'SCALAIRE';
  1049. * VMIS1 : contrainte de Von Mises au pas precedent
  1050.                     FINSI;
  1051.  
  1052. * modele plastique cinematique ou plastique parfait
  1053.                     SI  ((EGA MODPLA.&BCMOD0 2) OU (EGA MODPLA.&BCMOD0 3));
  1054.                         VMISF = CHAN ('VMIS' MODI SIGF MATI) TYPE 'SCALAIRE';
  1055.                         VMIS1 = CHAN ('VMIS' MODI SIG11 MATI) TYPE 'SCALAIRE';
  1056.                     FINSI;
  1057.  
  1058. * pour ces 3 modeles
  1059.                     SI ((EGA MODPLA.&BCMOD0 1) OU
  1060.                         (EGA MODPLA.&BCMOD0 2) OU
  1061.                         (EGA MODPLA.&BCMOD0 3));
  1062.                         EXISCRIT = VRAI;
  1063.                         VMISFP = VMISF * MSQ;
  1064.                         VMIS1P = VMIS1 * MSQ;
  1065. * VMISFP : contrainte de Von Mises aux points d'integration plastifies
  1066. **         au pas courant
  1067. * VMIS1P : contrainte de Von Mises aux points d'integration plastifies
  1068. **         au pas precedent
  1069. * on considere la plastification lorsque EPSET > 1E-6
  1070.                         VMISF1P = VMISFP - VMIS1P;
  1071. * VMISFP : difference entre la contrainte equivalente au temps de
  1072. * calcul t et celle au temps precedent (t-1)
  1073.                         VMITOTF = VMITOTF + VMISFP;
  1074.                         VMITOT1 = VMITOT1 + VMISF1P;
  1075.                     FINSI;
  1076.  
  1077.                 SINON;
  1078.  
  1079.                     SI ('EXIS' MATI 'ECRO');
  1080. * modele elastoplastique avec
  1081. ** caracteristiques independantes de la temperature
  1082.                         VMISF = CHAN ('VMIS' MODI (REDU SIGF MODI) MATI)
  1083.                                      TYPE 'SCALAIRE';
  1084.                         VMIS1 = CHAN ('VMIS' MODI (REDU SIG11 MODI) MATI)
  1085.                                      TYPE 'SCALAIRE';
  1086.                     FINSI;
  1087.                     SI (EXIS MATI 'SIGY');
  1088. * modele plastique cinematique et plastique parfait avec
  1089. ** caracteristiques independantes de la temperature
  1090.                         VMISF = CHAN ('VMIS' MODI SIGF MATI)
  1091.                                      TYPE 'SCALAIRE';
  1092.                         VMIS1 = CHAN ('VMIS' MODI SIG11 MATI)
  1093.                                      TYPE 'SCALAIRE';
  1094.                     FINSI;
  1095.  
  1096.                     SI (('EXIS' MATI 'ECRO') OU (EXIS MATI 'SIGY'));
  1097.                         EXISCRIT = VRAI;
  1098.                         VMISFP   = VMISF * MSQ;
  1099.                         VMIS1P   = VMIS1 * MSQ;
  1100.                         VMISF1P  = VMISFP - VMIS1P;
  1101.                         VMITOTF  = VMITOTF + VMISFP;
  1102.                         VMITOT1  = VMITOT1 + VMISF1P;
  1103.                     FINSI;
  1104.                 FINSI;
  1105.  
  1106.             FIN BCMOD0;
  1107.  
  1108.             SI EXISCRIT;
  1109. *      MSQO = (CHAN 'CHPO' MOD_MEC_R (VMITOT1*((VMITOTF)**(-1))))
  1110. *             'MASQ' 'INFERIEUR' 0.;
  1111. *      SUPTAB.'CRIT_DECHA_LOCAL1'.IABC =
  1112. *         (CHAN 'CHPO' MOD_MEC_R ((VMITOT1*((VMITOTF)**(-1)))) * MSQO);
  1113. * #MC 04/11/98 : pour le MASQ, un produit suffit (pas de risque de /0)
  1114.                 MSQO = (CHAN 'CHPO' MOD_MEC_R (VMITOT1*VMITOTF))
  1115.                         'MASQ' 'INFERIEUR' 0.;
  1116. * #MC 04/11/98 : ou il y a des 0, on met 1.E-10
  1117.                 SUPTAB.'CRIT_DECHA_LOCAL1'.IABC =
  1118.                         (CHAN 'CHPO' MOD_MEC_R ((VMITOT1*((
  1119.                         VMITOTF+(1.E-10*(VMITOTF 'MASQ' 'EGAL' 0.))
  1120.                         )**(-1)))) * MSQO);
  1121. *lorsque la valeur du critere est positive, c'est-a-dire qu'il n'y a
  1122. **pas de decharge, celle-ci est ramenee a zero
  1123.             FINSI;
  1124.  
  1125.         FINSI;
  1126.  
  1127.  
  1128. ************************************************************
  1129. ****** CRITERE GLOBAL 2 DE DECHARGE DES CONTRAINTES ********
  1130. ************************************************************
  1131.  
  1132.         SI ((EGA ITYPEF 99) ET BOOL.'PASAPAS' ET (NON BOOL.'REPRI') ET OUICRIT);
  1133.  
  1134.             SI BOOL.'MESS';
  1135.                 MESS 'CRITERE GLOBAL 2';
  1136.             FINSI;
  1137.  
  1138.             SI ('EXIS' SUPTAB.'SOLUTION_PASAPAS' 'DEFORMATIONS_INELASTIQUES');
  1139.                 SI BOOL.'PERSO1';
  1140.                     EPPLASF = ESTIM . 'DEFORMATIONS_INELASTIQUES';
  1141.                 SINON;
  1142.                     EPPLASF = SUPTAB.'SOLUTION_PASAPAS'.'DEFORMATIONS_INELASTIQUES'
  1143.                                       .IABC;
  1144.                 FINSI;
  1145.  
  1146.                 XCRIT = 1.;
  1147.                 PRO1  = 0.;
  1148.                 PRO2  = 0.;
  1149.                 CRITLOCA = MANU 'CHML' MOD_MEC_R 'SCAL' 1. 'STRESSES';
  1150.                 NUMERA   = ZERO MOD_MEC_R 'STRESSES';
  1151.                 DENOMI   = ZERO MOD_MEC_R 'STRESSES';
  1152. * initialisation
  1153. * glob2 n'est pas calcule si reprise car on ne connait pas i-1
  1154.  
  1155.                 VMISF = CHAN ('VMIS' MOD_MEC_R SIGF MAT_INST) TYPE 'SCALAIRE';
  1156. * VMISF : contrainte de Von Mises au pas courant
  1157.                 SI ('EXIS' SUPTAB VMISMAX);
  1158.                     MQSIG = SUPTAB.VMISMAX MASQ 'SUPERIEUR' VMISF;
  1159.                     VMISF = VMISF + (MQSIG * ((SUPTAB.VMISMAX) - VMISF));
  1160.                 FINSI;
  1161.                 SUPTAB.VMISMAX = VMISF;
  1162.  
  1163.                 REPE BCMOD0 (DIME TABMOD);
  1164.                     EXISCRIT = FAUX;
  1165.                     MODI   = TABMOD.&BCMOD0;
  1166.                     MATI   = REDU MAT_INST MODI;
  1167.                     MAILI  = EXTR MODI 'MAIL';
  1168.                     EPSEI  = REDU (EXCO VARF 'EPSE') MODI;
  1169.                     EPSEI  = EPSEI CHAN TYPE 'SCALAIRE';
  1170. *       EPPLASI = (SUPTAB.'SOLUTION_PASAPAS'.
  1171. *                'DEFORMATIONS_INELASTIQUES'.IABC) REDU MODI;
  1172.                     EPPLASI= REDU EPPLASF MODI;
  1173.                     VMISFI = REDU VMISF   MODI;
  1174.                     SIGFI  = REDU SIGF    MODI;
  1175.                     YOU = CHAN 'STRESSES' MODI (EXCO MATI 'YOUN');
  1176.                     YOU = YOU  CHAN TYPE 'SCALAIRE';
  1177.                     SI ('EXIS' MODPLA &BCMOD0);
  1178.                         SI ((EGA MODPLA.&BCMOD0 1) OU
  1179.                             (EGA MODPLA.&BCMOD0 2) OU
  1180.                             (EGA MODPLA.&BCMOD0 3));
  1181. * modele plastique isotrope
  1182. * modele plastique cinematique
  1183. * modele plastique parfait
  1184.                             lm_dein = EXTR epplasi 'COMP';
  1185.                             lm_defo = EXTR modi 'DEFO';
  1186.                             ep_u    = nomc lm_dein lm_defo epplasi;
  1187.                             ep_u    = changer ep_u type deformations;
  1188. *         PRO1    = PRO1 + (INTG MODI (ENER MODI SIGFI EPPLASI));
  1189.                             PRO1    = PRO1 + (INTG MODI (ENER MODI SIGFI ep_u));
  1190.                             PRO2    = PRO2 + (INTG MODI (VMISFI * EPSEI));
  1191.                             SI (PRO2 'NEG' 0.D0);
  1192.                                 XCRIT = XCRIT + (1. - (PRO1/PRO2));
  1193.                             FINSI;
  1194.                         FINSI;
  1195.                     SINON;
  1196.  
  1197.                         SI (('EXIS' MATI 'ECRO') OU (EXIS MATI 'SIGY'));
  1198. * modele elastoplastique et
  1199. * modele plastique cinematique et plastique parfait
  1200. ** avec caracteristiques independantes de la temperature
  1201.                             lm_dein = EXTR epplasi 'COMP';
  1202.                             lm_defo = EXTR modi 'DEFO';
  1203.                             ep_u    = NOMC lm_dein lm_defo epplasi;
  1204.                             ep_u    = ep_u changer type deformations;
  1205. *         PRO1    = PRO1 + (INTG MODI (ENER MODI  SIGFI EPPLASI));
  1206.                             PRO1    = PRO1 + (INTG MODI (ENER MODI  SIGFI ep_u));
  1207.                             PRO2    = PRO2 + (INTG MODI (VMISFI * EPSEI));
  1208. *         NUMERA  = NUMERA + (ENER MODI  SIGFI EPPLASI);
  1209.                             NUMERA  = NUMERA + (ENER MODI  SIGFI ep_u);
  1210.                             DENOMI  = DENOMI + (VMISFI * EPSEI);
  1211. *         petit traitement pour eviter de diviser par zero
  1212.                             MIN0 = MINI 'ABS' DENOMI;
  1213.                             MIN1 = MINI DENOMI;
  1214.                             MAX1 = MAXI DENOMI;
  1215.                             AMP = MAX1 - MIN1;
  1216.                             SI (AMP < 1.E-15);
  1217.                                 AMP = 1.E-15;
  1218.                             FINSI;
  1219.                             SI (MIN0 < (1.E-15 * AMP));
  1220.                                 DENOMI = DENOMI + (1.E-15 * AMP);
  1221.                             FINSI;
  1222.                             CRITLOCA = CRITLOCA + (1. - (NUMERA / DENOMI));
  1223.                         FINSI;
  1224.                     FINSI;
  1225.                 FIN BCMOD0;
  1226.  
  1227. * Le maxi sert a corriger le probleme castem sur les EPSE
  1228. * (ENER MODI  SIGFI EPPLASI) n est pas toujours egal a
  1229. * (VMISFI * EPSEI) lorsque le chargement est proportionnel
  1230. * A supprimer quand le pb sera resolu
  1231.                 SUPTAB.'CRIT_DECHA_GLOBAL2'  .IABC='MAXI'(prog 0.9999999999 XCRIT);
  1232.                 SUPTAB.'CRIT_DECHA_GLOBAL2_L'.IABC= CRITLOCA;
  1233.  
  1234. * mess 'PRO1' , PRO1 , 'PRO2' , PRO2 ,  'XCRIT' , XCRIT;
  1235.             SINON;
  1236.                 SI BOOL.'MESS';
  1237.                     MESS 'ATTENTION : LES DEFORMATIONS INELASTIQUES N''ONT';
  1238.                     MESS '            PAS ETE SAUVEGARDEES LORS DE PASAPAS.';
  1239.                     MESS '            LE CRITERE GLOBAL 2 NE PEUT DONC PAS';
  1240.                     MESS '            ETRE CALCULE.';
  1241.                 FINSI;
  1242.             FINSI;
  1243.         FINSI;
  1244.  
  1245.  
  1246. *********************************************************
  1247. ****** CRITERE LOCAL 2 DE DECHARGE DES CONTRAINTES ******
  1248. *********************************************************
  1249.  
  1250.         SI ((EGA ITYPEF 99) ET BOOL.'PASAPAS' ET (IABC  > 0) ET OUICRIT);
  1251.             SI BOOL.'MESS' ;   MESS 'CRITERE local 2' ; FINSI;
  1252.  
  1253. *initialisation
  1254.             EXISCRIT = FAUX;
  1255.             CRIT0 = 'ZERO' MOD_MEC_R STRESSES;
  1256.  
  1257.             REPE BCMOD0 (DIME TABMOD);
  1258.                 MODI = TABMOD.&BCMOD0;
  1259.                 MATI = REDU MAT_INST MODI;
  1260.                 EPSE1 = EXCO VARF 'EPSE';
  1261.                 EPSE1 = EPSE1 CHAN TYPE 'SCALAIRE';
  1262.                 EPSET = REDU EPSE1 MODI;
  1263.  
  1264.                 SI (('EXIS' MODPLA &BCMOD0) OU ('EXIS' MATI 'ECRO')
  1265.                     OU ('EXIS' MATI 'SIGY'));
  1266.  
  1267.                     MAT_z = 'MANU' 'CHML' MODI 'YOUN' 1. 'NU' 0. 'EPAI' 1.
  1268.                                   TYPE 'CARACTERISTIQUES' 'RIGIDITE';
  1269.                     EXISCRIT = VRAI;
  1270.                     DSIG = ELAS MODI (SIGF - SIG11) MAT_z;
  1271.                     INV1 = ENER MODI (REDU SIGF MODI) (REDU DSIG MODI);
  1272.                     SIGFTRA = ENER MODI (REDU SIGF MODI)
  1273.                                (REDU (ELAS MODI SIGF MAT_z) MODI);
  1274.                     DSIGTRA = ENER MODI (REDU DSIG MODI)
  1275.                                (ELAS MODI DSIG MAT_z);
  1276.                     NOR1 = SIGFTRA**(1./2);
  1277.                     DNOR = DSIGTRA**(1./2);
  1278.                     DENO = NOR1 * DNOR;
  1279.                     CRIT0 = CRIT0 + (INV1 * (DENO**(-1)));
  1280.  
  1281.                 FINSI;
  1282.  
  1283.             FIN BCMOD0;
  1284.  
  1285.             SI EXISCRIT;
  1286.                 SUPTAB.'CRIT_DECHA_LOCAL2'.IABC = CHAN 'CHPO' MOD_MEC_R CRIT0;
  1287.             FINSI;
  1288.  
  1289.  
  1290.         FINSI;
  1291.  
  1292.  
  1293.  
  1294. *|=====================================================================|
  1295. *|=======  III. TRAITEMENT DES CHAMPS MECANIQUES   ====================|
  1296.  
  1297. ****************************************************
  1298. * ON CHANGE LA TEMPERATURE EN MCHAML AU NOEUD =TEPINT
  1299. ****************************************************
  1300.         SI (EGA (TYPE TEPINT) 'CHPOINT ');
  1301.             TEPINT = REDU TEPINT ELTETA;
  1302.             TEPINT = CHAN 'CHAM' TEPINT MOD_MEC_R 'NOEUD' 'TEMPERATURES';
  1303.         SINON;
  1304.             SI (EGA (TYPE TEPINT) 'MCHAML  ');
  1305.                 TEPINT = REDU TEPINT MOD_MEC_R;
  1306.                 TEPINT = CHAN 'NOEUD' MOD_MEC_R TEPINT;
  1307.             FINSI;
  1308.         FINSI;
  1309.         SI (BOOL.'THER' ET (NON BOOL.'COQ'));
  1310.             EPT1 = EPTH MOD_MEC_R MAT_INST TEPINT;
  1311.             EPT1 VAR2 VAR3 = INVA MOD_MEC_R EPT1;
  1312.             EPT1 = CHAN 'CHAM' (EPT1/3.) MOD_MEC_R 'NOEUD';
  1313.             EPT1 = EPT1 - OBJUTI.'EPTREF';
  1314.         FINSI;
  1315.  
  1316. ***************************************************
  1317. ***** GRADIENT DU DEPLACEMENT DEPINT =GRADEP ******
  1318. ***************************************************
  1319.         GRADEP = GRAD MOD_MEC_R MAT_INST DEPINT;
  1320.         GRADEF = TEXT '        ';
  1321.         SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  1322.             GRADEF = 'GRAF' MOD_MEC_R MAT_INST DEPINT;
  1323.         FINSI;
  1324.  
  1325. ***************************************************
  1326. ***** CAS DU CONTACT FROTTANT : ON CALCULE WSAUTGR = GRADIENT DU SAUT ******
  1327. ***************************************************
  1328.         SI BOOL.'FROT';
  1329. * WDEP = deplacement de la fissure de composante UX ... AX ...
  1330. * [grad(w)] = grad [w] car linearite (le saut [w] est donne par AX ...)
  1331. * on utilise un modele liee a la geo de la fissure (cohesif ou contact)
  1332.             WSAUTGR = GRAD OBJCON WDEP;
  1333. * SIGCON = sigma*n de composantes SMX... homogene a une contrainte
  1334. * supporte sur la levre superieure
  1335.             SI (NEG (TYPE SIGCON) 'MCHAML  ');
  1336.                 SIGCON = REDU SIGCON (extr OBJCON2 'MAILLAGE');
  1337.                 SIGCON = CHAN 'CHAM' SIGCON OBJCON2 'STRESSES' 'CONTRAINTES';
  1338.             FINSI;
  1339. *   Vsigcon = 'VECTEUR' sigcon objcon (1E-8) ('MOTS' 'SMX' 'SMY' 'SMZ');
  1340. *    'TRACER' vsigcon ('EXTRAIRE' objcon 'MAIL');
  1341.             SIGXN = (CHAN (exco SIGCON 'SMX' 'SCAL') TYPE 'SCALAIRE');
  1342.             SIGYN = (CHAN (exco SIGCON 'SMY' 'SCAL') TYPE 'SCALAIRE');
  1343.             SI (EGA GDIME 3);
  1344.                 SIGZN = (CHAN (exco SIGCON 'SMZ' 'SCAL') TYPE 'SCALAIRE');
  1345.             FINSI;
  1346.         FINSI;
  1347.  
  1348. ***************************************************
  1349. ***** GRADIENT DE LA VITESSE VITF   =GRAVIT  ******
  1350. ***************************************************
  1351.         SI  BOOL.'J_DYNA';
  1352.             GRAVIT = GRAD MOD_MEC_R MAT_INST VITF;
  1353.             VITF = CHAN 'CHAM'  MOD_MEC_R VITF 'STRESSES';
  1354.             ACCF = CHAN 'CHAM'  MOD_MEC_R ACCF 'STRESSES';
  1355.         FINSI;
  1356.  
  1357. ***************************************************
  1358. ** GRADIENT TEMPERATURE Grad T pour tous elements =TEPEGR
  1359. ** et Grad Grad T pour les elements massifs seuls (si DJ/DA) =DEPDTGR
  1360. ***************************************************
  1361.         SI BOOL.'THER';
  1362.             SI (NON BOOL.'COQ');
  1363.                 TEPEGR = GRAD MOD_MEC_R MAT_INST (((EXCO 'T' TEPINT MU1)
  1364.                                 CHAN TYPE 'SCALAIRE') + CMD000);
  1365.                 GR_EPTH = GRAD MOD_MEC_R MAT_INST ((NOMC MU1 EPT1) + CMD000);
  1366.                 SI  BOOL.'DJ/DA';
  1367.                     DEPDT = ((EXCO GR1 TEPEGR MU1) + (EXCO GR2 TEPEGR MU2))
  1368.                     CHAN TYPE 'SCALAIRE';
  1369.                     SI (GDIME EGA 3);
  1370.                         DEPDT=DEPDT + ((EXCO GR3 TEPEGR MU3) CHAN TYPE 'SCALAIRE');
  1371.                     FINSI;
  1372.                     DEPDTGR = GRAD MOD_MEC_R MAT_INST (CHAN TYPE
  1373.                                 (CHAN 'NOEUD' MOD_MEC_R DEPDT) 'DEPLACEMENTS');
  1374. *           DEPDTGR = GRAD MOD_MEC_R MAT_INST (CHAN 'CHPO' MOD_MEC_R DEPDT);
  1375.                 FINSI;
  1376.             SINON;
  1377.                 TEPEGR = GRAD MOD_MEC_R MAT_INST ((((EXCO 'TINF' TEPINT MU1)
  1378.                             CHAN TYPE 'SCALAIRE') ET
  1379.                             ((EXCO 'T   ' TEPINT MU2)CHAN TYPE 'SCALAIRE') ET
  1380.                             ((EXCO 'TSUP' TEPINT MU3)CHAN TYPE 'SCALAIRE'))
  1381.                             + CMD000);
  1382.             FINSI;
  1383.         FINSI;
  1384.  
  1385. ***************************************************
  1386. **GRADIENT DE PRESSIONS Grad P (si DJ/DA) =PRESGR
  1387. ***************************************************
  1388.         SI  BOOL.'DJ/DA';
  1389.             SI ('>' (XTX PREINT) 1.E-10);
  1390.                 M1 = EXTR MOD_MEC_R 'FORC';
  1391.                 M2 = EXTR MOD_MEC_R 'DEPL';
  1392.                 REPE B1 (DIME M1);
  1393.                     F1 = DEP000 + (EXCO (EXTR M1 &B1) PREINT (EXTR M2 &B1));
  1394.                 FIN B1;
  1395.                 PRESGR = GRAD MOD_MEC_R MAT_INST F1;
  1396.             FINSI;
  1397.         FINSI;
  1398.  
  1399. ***************************************************
  1400. * PROFIL DE L'ENERGIE DANS L'EPAISSEUR DE LA COQUE
  1401. ***************************************************
  1402.         SI BOOL.'COQ';
  1403.             PEX1 = PROG ; PEN1 = PROG;
  1404.             REPE NBJ7 (DIME OBJUTI.'MODCOU');
  1405.                 MCOU1 = OBJUTI.'MODCOU'.&NBJ7;
  1406.                 EX1 = EXTR (REDU MCOU1 MAT_INST) 'EXCE' 1 1 1;
  1407.                 E1 = EXTR (REDU MCOU1 MAT_INST) 'EPAI' 1 1 1;
  1408.                 SI ('<' (E1 / EPAITO) 1.E-4);
  1409.                     ENR1 = EXTR (REDU MCOU1 ENERM) 'SCAL' 1 1 1;
  1410.                     PEX1 = PEX1 ET ('PROG' EX1);
  1411.                     PEN1 = PEN1 ET ('PROG' ENR1);
  1412.                 FINSI;
  1413.             FIN NBJ7;
  1414.             M1 = MOT ' DANS L EPAISSEUR DE LA COQUE A T =';
  1415.             TITR ('CHAI' 'INTEGRALE ' CHINT M1 INST);
  1416.             EVENR = 'EVOL' 'MANU' 'COOR.Z LOCAL' PEX1 CHINT PEN1;
  1417.             SOM1 = ('INTG' EVENR);
  1418.             SI (EGA SOM1 0.);
  1419.                 SOM1 = SOM1 + 1.E-10;
  1420.             FINSI;
  1421.             EVENR = EVENR * EPAITO / SOM1;
  1422.             NN = DIME (EXTR EVENR 'ORDO' 1);
  1423.             V_SUPE = EXTR NN (EXTR EVENR 'ORDO' 1);
  1424.             V_MOYE = EXTR ((NN - 1) / 2) (EXTR EVENR 'ORDO' 1);
  1425.             V_INFE = EXTR 1 (EXTR EVENR 'ORDO' 1);
  1426.         FINSI;
  1427.  
  1428. ****************************************************
  1429. *  RECUPERATION DU NOMBRE DE CALCULS A FAIRE
  1430. ****************************************************
  1431.         TTHETA = SUPTAB.'TAB_THETA';
  1432.         INDTH = INDE TTHETA;
  1433.         NBOU = DIME TTHETA;
  1434.         SI  BOOL.'DJ/DA';
  1435.             TPI = SUPTAB.'TAB_PI';
  1436.             INDPI = INDE TPI;
  1437.         FINSI;
  1438.  
  1439. ********************************************************
  1440. * DENSITE DE MATERIAU EN CAS DE CALCUL DE J DYNAMIQUE **
  1441. ********************************************************
  1442.         SI  BOOL.'J_DYNA';
  1443.             RHO1 = REDU (EXCO MAT_INST 'RHO' 'SCAL') MOD_MEC_R;
  1444.             RHO1 = (CHAN MOD_MEC_R 'STRESSES' RHO1) CHAN TYPE 'SCALAIRE';
  1445.         FINSI;
  1446.  
  1447.  
  1448.  
  1449. *|=====================================================================|
  1450. *|======= BOUCLE SUR LES NOEUDS A AVANCER VIRTUELLEMENT =============>
  1451.         GCHAM1 = VIDE 'MCHAML';
  1452.         GCHPO1 = VIDE 'CHPOINT'/'DISCRET';
  1453.  
  1454.         REPE BCNOEU NBOU;
  1455. **************************************************
  1456. * RECUP DU CHAMP THETA ASSOCIE AU NOEUD PM DE NUMERO NUNOE
  1457. * ET DU CHAMP PI (SI DJ/DA)
  1458. **************************************************
  1459.  
  1460.             IND0 = INDTH.&BCNOEU;
  1461.             CHTHETA = TTHETA.IND0 + DEP000;
  1462.             SI  BOOL.'DJ/DA';
  1463.                 CHPI = TPI.(INDPI.&BCNOEU);
  1464.             FINSI;
  1465.  
  1466.  
  1467. **************************************************
  1468. * GRADIENT, DIVERGENCE DU CHAMP THETA =TETAGR, DIVTETA
  1469. * CHAMELEM THETA =(TETX,TETY,TETZ)
  1470. **************************************************
  1471.             TETAGR = SUPTAB.'GRTHETA'.IND0;
  1472.             DIVTETA = SUPTAB.'DIVTHETA'.IND0;
  1473. * btrolle 2013 : ajout de TETAX, TETAY et TETAZ
  1474.             TETAX= CHAN 'CHAM' MOD_MEC_R (EXCO MU1 CHTHETA 'SCAL') 'SCALAIRE';
  1475.             TETAY= CHAN 'CHAM' MOD_MEC_R (EXCO MU2 CHTHETA 'SCAL') 'SCALAIRE';
  1476.             TETX = CHAN 'CHAM' MOD_MEC_R (EXCO MU1 CHTHETA 'SCAL') 'STRESSES';
  1477.             TETY = CHAN 'CHAM' MOD_MEC_R (EXCO MU2 CHTHETA 'SCAL') 'STRESSES';
  1478.             TETX = TETX CHAN TYPE'SCALAIRE';
  1479.             TETY = TETY CHAN TYPE'SCALAIRE';
  1480.             THET_GR = ZERO MOD_MEC_R 'GRADIENT';
  1481.             THET_GR = THET_GR + (NOMC GR1 TETX) + (NOMC GR2 TETY);
  1482.             SI (GDIME EGA 3);
  1483.                 TETAZ= CHAN 'CHAM' MOD_MEC_R (EXCO MU3 CHTHETA 'SCAL') 'SCALAIRE';
  1484.                 TETZ = CHAN 'CHAM' MOD_MEC_R (EXCO MU3 CHTHETA 'SCAL') 'STRESSES';
  1485.                 TETZ = TETZ CHAN TYPE'SCALAIRE';
  1486.                 THET_GR = THET_GR + (NOMC GR3 TETZ);
  1487.             FINSI;
  1488.  
  1489.  
  1490. **************************************************
  1491. * GRADIENT, DIVERGENCE DU CHAMP PI =PIGR, DIVPI
  1492. * CHAMELEM PI =(PIX,PIY,PIZ)
  1493. * ...
  1494. **************************************************
  1495.             SI  BOOL.'DJ/DA';
  1496.                 NORM1 = ((EXCO MU1 CHPI 'SCAL')**2) + ((EXCO MU2 CHPI 'SCAL')**2);
  1497.                 SI (EGA GDIME 3);
  1498.                     NORM1 = NORM1 + ((EXCO MU3 CHPI 'SCAL')**2);
  1499.                 FINSI;
  1500.                 CHPI = CHPI + DEP000;
  1501.                 CHPI = CHPI / ('MAXI' (NORM1**0.5));
  1502.                 PIGR = GRAD MOD_MEC_R MAT_INST CHPI;
  1503.                 DIVPI = (EXCO GR1 PIGR 'SCAL') +
  1504.                          (EXCO GR5 PIGR 'SCAL') +
  1505.                          (EXCO GR9 PIGR 'SCAL');
  1506.                 DIVPI = DIVPI CHAN TYPE 'SCALAIRE';
  1507.                 PITAGR = (MOD_MEC_R PIGR * TETAGR);
  1508.                 DIVPITA = (EXCO GR1 PITAGR 'SCAL') +
  1509.                             (EXCO GR5 PITAGR 'SCAL') +
  1510.                             (EXCO GR9 PITAGR 'SCAL');
  1511.                 DIVPITA = DIVPITA CHAN TYPE 'SCALAIRE';
  1512.                 ADJ = (DIVPITA - (DIVPI * DIVTETA));
  1513.                 PIX = CHAN 'CHAM' MOD_MEC_R (EXCO MU1 CHPI 'SCAL') 'STRESSES';
  1514.                 PIY = CHAN 'CHAM' MOD_MEC_R (EXCO MU2 CHPI 'SCAL') 'STRESSES';
  1515.                 PIX= PIX CHAN TYPE'SCALAIRE';
  1516.                 PIY= PIY CHAN TYPE'SCALAIRE';
  1517.                 SI (GDIME EGA 3);
  1518.                     PIZ = CHAN 'CHAM' MOD_MEC_R (EXCO MU3 CHPI 'SCAL') 'STRESSES';
  1519.                     PIZ= PIZ CHAN TYPE'SCALAIRE';
  1520.                 FINSI;
  1521.             FINSI;
  1522.  
  1523. ********************************************************
  1524. *********** SI LE MATERIAU N'EST PAS CONSTANT **********
  1525. * YOU1 = YOUGR * THETA = (grad E) * THETA
  1526. * SIGPRIM = (grad D)*THETA*(EPSI elas)   ou grad D =D(grad E,nu) =DMAT
  1527. * ALF1 = ALFGR*THETA = (grad Alpha)*THETA
  1528. * DMAT = D(1,nu,ALF1)
  1529. ********************************************************
  1530.             SI BOOL.'GRADPROP';
  1531. *** Le coefficient de Poisson est constant ***
  1532. *    NU1 = REDU (EXCO MAT_INST 'NU' 'SCAL') MOD_MEC_R;
  1533. *    NU1 = EXCO NU1 'SCAL' 'NU';
  1534.                 NU1 = REDU (EXCO MAT_INST 'NU') MOD_MEC_R;
  1535.                 NU1 = NU1 CHAN TYPE 'SCALAIRE';
  1536. ****** Gradient de Module d'young ******
  1537.                 SI BOOL.'GRADYOUN';
  1538.                     YOU1 = REDU (EXCO MAT_INST 'YOUN' 'SCAL') MOD_MEC_R;
  1539.                     YOU1 = YOU1   CHAN TYPE 'SCALAIRE';
  1540.                     YOUGR = GRA000 ; I = 0;
  1541.                     REPE NBJ2 (DIME TABMOD);
  1542.                         I = I + 1;
  1543.                         YO1 = CHAN 'STRESSES' TABMOD.I
  1544.                                 (REDU ((EXCO MAT_INST 'YOUN' MU1)
  1545.                                 CHAN TYPE 'SCALAIRE') TABMOD.I);
  1546.                         YOUGR = YOUGR + (GRAD TABMOD.I MAT_INST (YO1 +
  1547.                                 (REDU CMD001 TABMOD.I)));
  1548. *       YO1 = CHAN 'CHPO' TABMOD.I
  1549. *            (REDU (EXCO MAT_INST 'YOUN' 'SCAL') TABMOD.I);
  1550. *       YOUGR = YOUGR + (GRAD TABMOD.I MAT_INST ((NOMC MU1 YO1)
  1551. *               + (REDU DEP000 (EXTR YO1 'MAIL'))));
  1552.                     FIN NBJ2;
  1553.                     YOU1 = (((EXCO GR1 YOUGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1554.                             MOD_MEC_R TETX) +
  1555.                             (((EXCO GR2 YOUGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1556.                             MOD_MEC_R TETY);
  1557.                     SI (GDIME EGA 3);
  1558.                         YOU1 = YOU1 + (((EXCO GR3 YOUGR 'SCAL')
  1559.                         CHAN TYPE 'SCALAIRE') * MOD_MEC_R TETZ);
  1560.                     FINSI;
  1561.                     YOU1 = (EXCO YOU1 'SCAL' 'YOUN') CHAN TYPE 'SCALAIRE';
  1562.                     DMAT = 'MATE' MOD_MEC_R 'YOUN' YOU1 'NU' NU1;
  1563.                     SIGPRIM = (HOOK MOD_MEC_R DMAT)*MOD_MEC_R
  1564.                                 (ELAS MOD_MEC_R SIGF MAT_INST);
  1565.                 FINSI;
  1566. ****** Gradient de Coefficient de Dilatation ******
  1567.                 SI (BOOL.'THER' ET BOOL.'GRADALPH');
  1568.                     ALF1 = REDU (EXCO MAT_INST 'ALPH' 'SCAL') MOD_MEC_R;
  1569.                     ALF1 = ALF1 CHAN TYPE 'SCALAIRE';
  1570.                     ALFGR = GRA000 ; I = 0;
  1571.                     REPE NBJ3 (DIME TABMOD);
  1572.                         I = I + 1;
  1573.                         AL1 = CHAN 'STRESSES' TABMOD.I
  1574.                                 (REDU (EXCO MAT_INST 'ALPH' MU1) TABMOD.I);
  1575.                         AL1 = AL1 CHAN TYPE 'SCALAIRE';
  1576.                         ALFGR = ALFGR + (GRAD TABMOD.I MAT_INST (AL1 +
  1577.                                 (REDU CMD001 TABMOD.I)));
  1578. *!       AL1 = CHAN 'CHPO' TABMOD.I
  1579. *!             (REDU (EXCO MAT_INST 'ALPH' 'SCAL') TABMOD.I);
  1580. *!       ALFGR = ALFGR + (GRAD TABMOD.I MAT_INST ((NOMC MU1 AL1)
  1581. *!               + (REDU DEP000 (EXTR AL1 'MAIL'))));
  1582.                     FIN NBJ3;
  1583.                     ALF1 = (((EXCO GR1 ALFGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1584.                             MOD_MEC_R TETX) +
  1585.                             (((EXCO GR2 ALFGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1586.                             MOD_MEC_R TETY);
  1587.  
  1588.                     SI (GDIME EGA 3);
  1589.                         ALF1 = ALF1 + (((EXCO GR3 ALFGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1590.                                 MOD_MEC_R TETZ);
  1591.                     FINSI;
  1592.                     ALF1 = EXCO ALF1 'SCAL' 'ALPH';
  1593.                     ALF1 = ALF1 CHAN TYPE 'SCALAIRE';
  1594.                     DMAT = 'MATE' MOD_MEC_R 'YOUN' 1. 'NU' NU1 'ALPH' ALF1;
  1595.                 FINSI;
  1596.             FINSI;
  1597.  
  1598. ***********************************************
  1599. * TEMU  = (Grad T)*THETA
  1600. * TEMU1 = (Grad T)*PI
  1601. * TEMU2 = (Grad (Grad T))*PI*THETA
  1602. * EPSTU = D^-1 sigma^th
  1603. *         avec sigma^th = (-3lambda-2mu)*alpha*(grad T)*THETA*I
  1604. * GR_EPTH_THET = (grad epsilon_th)*THETA
  1605. ***********************************************
  1606.             SI BOOL.'THER';
  1607.                 SI (NON BOOL.'COQ');
  1608.                     TEMU = PSCA TEPEGR THET_GR MGI MGI;
  1609.                     TEMU = CHAN TYPE (EXCO 'SCAL' TEMU 'T') 'TEMPERATURES';
  1610.                     GR_EPTH_THET = PSCA GR_EPTH THET_GR MGI MGI;
  1611.                     GR_EPTH_THET = NOMC 'T' GR_EPTH_THET;
  1612.                     GR_EPTH_THET = CHAN 'TYPE' GR_EPTH_THET 'TEMPERATURES';
  1613.                     MAT0 = MATE MOD_MEC_R 'YOUN' 1. 'NU' 0. 'ALPH' 1.
  1614.                             'TALP' 0. 'TREF' 0.;
  1615.                     GR_EPTH_THET = EPTH MOD_MEC_R MAT0 GR_EPTH_THET;
  1616.                 SINON;
  1617.                     T1 = (((EXCO GR1 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1618.                             MOD_MEC_R TETX) +
  1619.                             (((EXCO GR2 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1620.                             MOD_MEC_R TETY) +
  1621.                             (((EXCO GR3 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1622.                             MOD_MEC_R TETZ);
  1623.                     T2 = (((EXCO GR4 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1624.                             MOD_MEC_R TETX) +
  1625.                             (((EXCO GR5 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1626.                             MOD_MEC_R TETY) +
  1627.                             (((EXCO GR6 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1628.                             MOD_MEC_R TETZ);
  1629.                     T3 = (((EXCO GR7 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1630.                             MOD_MEC_R TETX) +
  1631.                             (((EXCO GR8 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1632.                             MOD_MEC_R TETY) +
  1633.                             (((EXCO GR9 TEPEGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1634.                             MOD_MEC_R TETZ);
  1635.                     TEMU = CHAN TYPE ((EXCO 'SCAL' T1 'TINF') ET
  1636.                             (EXCO 'SCAL' T2 'T   ') ET
  1637.                             (EXCO 'SCAL' T3 'TSUP')) 'TEMPERATURES';
  1638.                 FINSI;
  1639.                 EPSTU = ELAS MOD_MEC_R (THET MOD_MEC_R MAT_INST TEMU) MAT_INST;
  1640.                 SI  BOOL.'DJ/DA';
  1641.                     TEMU1 = (((EXCO GR1 TEPEGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1642.                                 MOD_MEC_R PIX) + (((EXCO GR2 TEPEGR 'SCAL')
  1643.                                 CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIY);
  1644.                     SI (GDIME EGA 3);
  1645.                         TEMU1 = TEMU1 + (((EXCO GR3 TEPEGR 'SCAL')
  1646.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIZ);
  1647.                     FINSI;
  1648.                     SI BOOL.'COQ';
  1649.                         TEMU1 = CHAN TYPE ((EXCO 'SCAL' TEMU1 'T') ET
  1650.                                 (EXCO 'SCAL' TEMU1 'TINF') ET
  1651.                                 (EXCO 'SCAL' TEMU1 'TSUP')) 'TEMPERATURES';
  1652.                     SINON;
  1653.                         TEMU1 = CHAN TYPE (EXCO 'SCAL' TEMU1 'T')
  1654.                                 'TEMPERATURES';
  1655.                     FINSI;
  1656.                     EPSTU1 = ELAS MOD_MEC_R (THET MOD_MEC_R MAT_INST TEMU1)
  1657.                                 MAT_INST;
  1658.                     TXXPIX = ((EXCO GR1 DEPDTGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1659.                                 MOD_MEC_R PIX;
  1660.                     TYXPIY = ((EXCO GR2 DEPDTGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1661.                                 MOD_MEC_R PIY;
  1662.                     TXYPIX = ((EXCO GR4 DEPDTGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1663.                                 MOD_MEC_R PIX;
  1664.                     TYYPIY = ((EXCO GR5 DEPDTGR 'SCAL')CHAN TYPE 'SCALAIRE') *
  1665.                                 MOD_MEC_R PIY;
  1666.                     TEMU2 = (TETX*MOD_MEC_R (TXXPIX + TYXPIY)) +
  1667.                                 (TETY*MOD_MEC_R (TXYPIX + TYYPIY));
  1668.                     SI (GDIME EGA 3);
  1669.                         TEMU1 = TEMU1 + (((EXCO GR3 TEPEGR 'SCAL')
  1670.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIZ);
  1671.                         TZXPIZ = ((EXCO GR3 DEPDTGR 'SCAL')
  1672.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIZ;
  1673.                         TZYPIZ = ((EXCO GR6 DEPDTGR 'SCAL')
  1674.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIZ;
  1675.                         TXZPIX = ((EXCO GR7 DEPDTGR 'SCAL')
  1676.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIX;
  1677.                         TYZPIY = ((EXCO GR8 DEPDTGR 'SCAL')
  1678.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIY;
  1679.                         TZZPIY = ((EXCO GR9 DEPDTGR 'SCAL')
  1680.                                     CHAN TYPE 'SCALAIRE') * MOD_MEC_R PIZ;
  1681.                         TEMU2 = (TETX*MOD_MEC_R (TXXPIX + TYXPIY + TZXPIZ)) +
  1682.                                 (TETY*MOD_MEC_R (TXYPIX + TYYPIY + TZYPIZ)) +
  1683.                                 (TETZ*MOD_MEC_R (TXZPIX + TYZPIY + TZZPIZ));
  1684.                     FINSI;
  1685.                     SI BOOL.'COQ';
  1686.                         TEMU2 = CHAN TYPE ((EXCO 'SCAL' TEMU2 'T') ET
  1687.                                     (EXCO 'SCAL' TEMU2 'TINF') ET
  1688.                                     (EXCO 'SCAL' TEMU2 'TSUP')) 'TEMPERATURES';
  1689.                     SINON;
  1690.                         TEMU2 = CHAN TYPE (EXCO 'SCAL' TEMU2 'T') 'TEMPERATURES';
  1691.                     FINSI;
  1692.                     EPSTU2 = ELAS MOD_MEC_R (THET MOD_MEC_R MAT_INST TEMU2) MAT_INST;
  1693.                 FINSI;
  1694.             FINSI;
  1695.  
  1696. * modif sm
  1697. ***********************************************
  1698. * CUMDEFI = SIG_{IJ} * (deps_{ij} / dx_{,k}) * thet_{k}
  1699. ***********************************************
  1700.             CUMDEFI = ZERO MOD_MEC_R 'STRESSES';
  1701.             SI (BOOL.'DEF_IMP' ET (NON BOOL.'COQ'));
  1702.                 LMOEP = EXTR MOD_MEC_R 'DEFO';
  1703.                 LMOSI = EXTR MOD_MEC_R 'CONT';
  1704.                 LMOGR = EXTR MOD_MEC_R 'GRAD';
  1705.                 NIDEF = DIME LMOSI;
  1706.                 REPETER BDEFI NIDEF;
  1707.                     MOEP = EXTR LMOEP &BDEFI;
  1708.                     MOSI = EXTR LMOSI &BDEFI;
  1709.                     EIJ  = EXCO DEFI MOEP  MU1;
  1710.                     SMIJ = EXCO SIGF   MOSI 'SCAL';
  1711.                     GREIJ = GRAD MOD_MEC_R MAT_INST
  1712.                                 ((CHAN (CHAN 'NOEUD' MOD_MEC_R EIJ)
  1713.                                 'TYPE' 'SCALAIRE') + CMD000);
  1714.                     DEIJX = (CHAN (CHAN 'STRESSES' MOD_MEC_R
  1715.                                 (EXCO GREIJ (EXTR LMOGR 1) 'SCAL'))
  1716.                                 TYPE 'SCALAIRE') *
  1717.                                 (CHAN SMIJ TYPE 'SCALAIRE') * TETX;
  1718.                     DEIJY = (CHAN (CHAN 'STRESSES' MOD_MEC_R
  1719.                                 (EXCO GREIJ (EXTR LMOGR 2) 'SCAL'))
  1720.                                 TYPE 'SCALAIRE') *
  1721.                                 (CHAN SMIJ TYPE 'SCALAIRE') * TETY;
  1722.                     CUMDEFI = CUMDEFI + DEIJX + DEIJY;
  1723.                     SI (GDIME EGA 3);
  1724.                         DEIJZ = (CHAN (CHAN 'STRESSES' MOD_MEC_R
  1725.                                     (EXCO GREIJ (EXTR LMOGR 3) 'SCAL'))
  1726.                                     TYPE 'SCALAIRE') *
  1727.                                     (CHAN SMIJ TYPE 'SCALAIRE') * TETZ;
  1728.                         CUMDEFI = CUMDEFI + DEIJZ;
  1729.                     FINSI;
  1730.                 FIN BDEFI;
  1731.             FINSI;
  1732.  
  1733. ***********************************************
  1734. * PEMU1 = (Grad P)*TETA
  1735. * PEMU2 = (Grad P)*(Grad PI)*TETA
  1736. ***********************************************
  1737.             SI  BOOL.'DJ/DA';
  1738.                 SI ((XTX PREINT) > 1.E-10);
  1739. * NOUVELLE IMPLEMENTATION JB :
  1740. *                   PEMU = VIDE 'CHPOINT'/'DISCRET';
  1741. *                   REPE ICOMP GDIME;
  1742. *                           IDEB = 1 + (3*(&ICOMP - 1));
  1743. *                           IFIN = IDEB + GDIME - 1;
  1744. *                       LMO1 = EXTR MGI (LECT IDEB PAS 1 IFIN);
  1745. *                       LMO2 = EXTR MUI (LECT 1 PAS GDIME);
  1746. *                       FI = PSCA PRESGR PI LMO1 LMO2;
  1747. *                       FI = NOMC (EXTR MUI &ICOMP) FI;
  1748. *                       PEMU = PEMU + (CHAN 'CHPO' MOD_MEC_R FI);
  1749. *                   FIN ICOMP;
  1750. * CETTE SECTION N'EST PAS TESTEE ACTUELLEMENT DANS LA BASE DE CAS-TESTS
  1751. * IL FAUT DONC AJOUTER UN CAS-TEST AVANT DE POUVOIR REMPLACER CE QUI SUIT
  1752. * PAR LES LIGNES COMMENTEES CI-DESSUS
  1753.                     F1 = (((EXCO GR1 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1754.                             MOD_MEC_R PIX) +
  1755.                             (((EXCO GR2 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1756.                             MOD_MEC_R PIY);
  1757.                     F2 = (((EXCO GR4 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1758.                             MOD_MEC_R PIX) +
  1759.                             (((EXCO GR5 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1760.                             MOD_MEC_R PIY);
  1761.                     PEMU = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F1 MF1) ET
  1762.                             (EXCO 'SCAL' F2 MF2));
  1763.                     SI (EGA GDIME 3);
  1764.                         F1 = F1 +
  1765.                             (((EXCO GR3 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1766.                             MOD_MEC_R PIZ);
  1767.                         F2 = F2 +
  1768.                             (((EXCO GR6 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1769.                             MOD_MEC_R PIZ);
  1770.                         F3 = (((EXCO GR7 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1771.                             MOD_MEC_R PIX) +
  1772.                             (((EXCO GR8 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1773.                             MOD_MEC_R PIY) +
  1774.                             (((EXCO GR9 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1775.                             MOD_MEC_R PIZ);
  1776.                         PEMU = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F1 MF1) ET
  1777.                                 (EXCO 'SCAL' F2 MF2) ET (EXCO 'SCAL' F3 MF3));
  1778.                     FINSI;
  1779.                     F1 = (((EXCO GR1 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1780.                             MOD_MEC_R TETX) +
  1781.                             (((EXCO GR2 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1782.                             MOD_MEC_R TETY);
  1783.                     F2 = (((EXCO GR4 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1784.                             MOD_MEC_R TETX) +
  1785.                             (((EXCO GR5 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1786.                             MOD_MEC_R TETY);
  1787.                     PEMU1 = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F1 MF1) ET
  1788.                             (EXCO 'SCAL' F2 MF2));
  1789.                     SI (EGA GDIME 3);
  1790.                         F1 = F1 +
  1791.                             (((EXCO GR3 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1792.                             MOD_MEC_R TETZ);
  1793.                         F2 = F2 +
  1794.                             (((EXCO GR6 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1795.                             MOD_MEC_R TETZ);
  1796.                         F3 = (((EXCO GR7 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1797.                             MOD_MEC_R TETX) +
  1798.                             (((EXCO GR8 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1799.                             MOD_MEC_R TETY) +
  1800.                             (((EXCO GR9 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1801.                             MOD_MEC_R TETZ);
  1802.                         PEMU1 = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F1 MF1) ET
  1803.                                 (EXCO 'SCAL' F2 MF2) ET (EXCO 'SCAL' F3 MF3));
  1804.                     FINSI;
  1805.                     F1 = (((EXCO GR1 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1806.                             MOD_MEC_R TETX) +
  1807.                             (((EXCO GR2 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1808.                             MOD_MEC_R TETY);
  1809.                     F2 = (((EXCO GR4 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1810.                             MOD_MEC_R TETX) +
  1811.                             (((EXCO GR5 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1812.                             MOD_MEC_R TETY);
  1813.                     SI (EGA GDIME 3);
  1814.                         F1 = F1 +
  1815.                             (((EXCO GR3 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1816.                             MOD_MEC_R TETZ);
  1817.                         F2 = F2 +
  1818.                             (((EXCO GR6 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1819.                             MOD_MEC_R TETZ);
  1820.                         F3 = (((EXCO GR7 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1821.                             MOD_MEC_R TETX) +
  1822.                             (((EXCO GR8 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1823.                             MOD_MEC_R TETY) +
  1824.                             (((EXCO GR9 PIGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1825.                             MOD_MEC_R TETZ);
  1826.                     FINSI;
  1827.                     F4 = (((EXCO GR1 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1828.                             MOD_MEC_R F1) +
  1829.                             (((EXCO GR2 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1830.                             MOD_MEC_R F2);
  1831.                     F5 = (((EXCO GR4 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1832.                             MOD_MEC_R F1) +
  1833.                             (((EXCO GR5 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1834.                             MOD_MEC_R F2);
  1835.                     PEMU2 = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F4 MF1) ET
  1836.                             (EXCO 'SCAL' F5 MF2));
  1837.                     SI (EGA GDIME 3);
  1838.                         F4 = F4 +
  1839.                             (((EXCO GR3 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1840.                             MOD_MEC_R F3);
  1841.                         F5 = F5 +
  1842.                             (((EXCO GR6 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1843.                             MOD_MEC_R F3);
  1844.                         F6 = (((EXCO GR7 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1845.                             MOD_MEC_R F1) +
  1846.                             (((EXCO GR8 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1847.                             MOD_MEC_R F2) +
  1848.                             (((EXCO GR9 PRESGR 'SCAL') CHAN TYPE 'SCALAIRE') *
  1849.                             MOD_MEC_R F3);
  1850.                         PEMU2 = CHAN 'CHPO' MOD_MEC_R ((EXCO 'SCAL' F4 MF1) ET
  1851.                                 (EXCO 'SCAL' F5 MF2) ET (EXCO 'SCAL' F6 MF3));
  1852.                     FINSI;
  1853.                 FINSI;
  1854.             FINSI;
  1855.  
  1856. ***********************************************
  1857. * DANS LE CAS DE CALCUL DE DJ/DA
  1858. * U^aux=A_DEPI  et  SIGMA^aux=A_SIGF
  1859. ***********************************************
  1860.             SI  BOOL.'DJ/DA';
  1861.                 GRAD11 = (MOD_MEC_R GRADEP * PIGR);
  1862.                 EPXX1 = (EXCO GR1 GRAD11 'SCAL') CHAN TYPE 'SCALAIRE';
  1863.                 EPYY1 = (EXCO GR5 GRAD11 'SCAL') CHAN TYPE 'SCALAIRE';
  1864.                 EPZZ1 = (EXCO GR9 GRAD11 'SCAL') CHAN TYPE 'SCALAIRE';
  1865.                 GAXY1 = ((EXCO GR2 GRAD11 'SCAL') + (EXCO GR4 GRAD11 'SCAL'))
  1866.                             CHAN TYPE 'SCALAIRE';
  1867.                 GAXZ1 = ((EXCO GR3 GRAD11 'SCAL') + (EXCO GR7 GRAD11 'SCAL'))
  1868.                             CHAN TYPE 'SCALAIRE';
  1869.                 GAYZ1 = ((EXCO GR6 GRAD11 'SCAL') + (EXCO GR8 GRAD11 'SCAL'))
  1870.                             CHAN TYPE 'SCALAIRE';
  1871.                 SI (GDIME EGA 3);
  1872.                     EPSIA1 = MANU 'CHML' MOD_MEC_R EP1 EPXX1 EP2
  1873.                                 EPYY1 EP3 EPZZ1 EP4 GAXY1 EP5 GAXZ1 EP6
  1874.                                 GAYZ1 TYPE 'DEFORMATIONS' 'STRESSES';
  1875.                 SINON;
  1876.                     EPSIA1 = MANU 'CHML' MOD_MEC_R EP1 EPXX1 EP2
  1877.                                 EPYY1 EP3 EPZZ1 EP4 GAXY1
  1878.                                 TYPE 'DEFORMATIONS' 'STRESSES';
  1879.                 FINSI;
  1880.                 SI BOOL.'THER' ; EPSIA1 = EPSIA1 + EPSTU1 ; FINSI;
  1881.                 F11 = BSIG MOD_MEC_R (((HOOK MOD_MEC_R MAT_INST)*MOD_MEC_R EPSIA1)
  1882.                         - (MOD_MEC_R SIGF*DIVPI)) + (FOFI MOD_MEC_R SIGF PIGR);
  1883.                 SI ((XTX PREINT) > 1.E-10);
  1884.                     F11 = F11 + PEMU + (PREINT*(CHAN 'CHPO' MOD_MEC_R DIVPI));
  1885.                 FINSI;
  1886.                 A_PREI = FOR000;
  1887.                 A_DEPI = REDU (RESO F11 RIGTOT) ELTETA;
  1888.                 A_SIGF = MOD_MEC_R (HOOK MOD_MEC_R MAT_INST) *
  1889.                             ((EPSI MOD_MEC_R A_DEPI) - EPSIA1);
  1890.                 A_DEPGR = GRAD MOD_MEC_R MAT_INST A_DEPI;
  1891.                 SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  1892.                     A_DEPGF = 'GRAF' MOD_MEC_R MAT_INST A_DEPI;
  1893.                 SINON;
  1894.                     A_DEPGF = TEXT '        ';
  1895.                 FINSI;
  1896.             FINSI;
  1897.  
  1898. ***********************************************
  1899. * DEP0 = (grad U)*THETA
  1900. ***********************************************
  1901.             LO1 = ((BOOL.'J') OU  BOOL.'C*'  OU  BOOL.'C*H'
  1902.                     OU  BOOL.'DJ/DA'  OU  BOOL.'J_DYNA' )
  1903.                     ET ('>' (XTX PREINT) 1.E-10);
  1904.             LO2 = FAUX;
  1905.             SI  BOOL.'DECOUPLAGE';
  1906.                 LO2 = (XTX A_PREI) > 1.E-10;
  1907.             FINSI;
  1908.             SI (LO1 OU LO2);
  1909.                 GRADCH = CHAN 'CHPO' MOD_MEC_R GRADEP;
  1910. *  mess 'gcalcul : CHAN CHPO grad(U)';
  1911. *bp : on se ramene a un chpoint pour faire XTY avec preint ensuite
  1912. *     on moyenne avce CHAN CHPO, pourrait on l'eviter?
  1913.                 DEPLX = ((EXCO GR1 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  1914.                         ((EXCO GR2 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL'));
  1915.                 DEPLY = ((EXCO GR4 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  1916.                         ((EXCO GR5 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL'));
  1917.                 DEP0 = (NOMC DEPLX MU1) + (NOMC DEPLY MU2);
  1918.                 SI (GDIME EGA 3);
  1919.                     DEPLX = DEPLX +
  1920.                             ((EXCO GR3 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  1921.                     DEPLY = DEPLY +
  1922.                             ((EXCO GR6 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  1923.                     DEPLZ = ((EXCO GR7 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  1924.                             ((EXCO GR8 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL')) +
  1925.                             ((EXCO GR9 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  1926.                     DEP0 = (NOMC DEPLX MU1) + (NOMC DEPLY MU2) +
  1927.                             (NOMC DEPLZ MU3);
  1928.                 FINSI;
  1929.                 SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  1930.                     GRAFCH = CHAN 'CHPO' MOD_MEC_R GRADEF;
  1931.                     BXX = EXCO 'BX,X' GRAFCH 'SCAL';
  1932.                     BXY = EXCO 'BX,Y' GRAFCH 'SCAL';
  1933.                     BYX = EXCO 'BY,X' GRAFCH 'SCAL';
  1934.                     BYY = EXCO 'BY,Y' GRAFCH 'SCAL';
  1935.                     DEPFX = NOMC 'RX' ( (BXX*(EXCO 'UX' CHTHETA 'SCAL')) +
  1936.                             (BXY*(EXCO 'UY' CHTHETA 'SCAL')) );
  1937.                     DEPFY = NOMC 'RY' ( (BYX*(EXCO 'UX' CHTHETA 'SCAL')) +
  1938.                             (BYY*(EXCO 'UY' CHTHETA 'SCAL')) );
  1939.                     DEP0 = DEP0 + DEPFX + DEPFY;
  1940.                 FINSI;
  1941.             FINSI;
  1942.  
  1943.  
  1944. ***************************************************************
  1945. * S'il y a une pression sur la fissure, on calcule
  1946. * GRUTE = (grad U)*THETA sur les elements du modele de pression
  1947. * et dans la zone d'etude (ou le champ TETA est definit)
  1948. ***************************************************************
  1949.             SI BOOL.'PRES_FISS';
  1950. * on isole les elements de la fissure ou la pression s'applique et ou le
  1951. * champ teta est definit
  1952.                 FISSP = EXTR MODPRE 'MAIL';
  1953.                 PFISSP = CHAN 'POI1' FISSP;
  1954.                 FISSP = FISSP ELEM 'APPU' 'STRI' MAILMOD;
  1955.                 MODPFT = VIDE 'MMODEL';
  1956.                 GRADEPF = VIDE 'MCHAML';
  1957. * on interpole le gradient de deplacement (GRADEP) sur les elements du
  1958. * modele de pression touchant la levre inferieure
  1959.                 SI (EXIS SUPTAB 'LEVRE_INFERIEURE');
  1960.                     FISI = INTE FISSP (SUPTAB . 'LEVRE_INFERIEURE');
  1961.                     MODPFI = REDU MODPF FISI;
  1962.                     MP1 = DIFF (CHAN 'POI1' FISI) FF1;
  1963.                     EL1 = MAILMOD ELEM 'APPU' 'LARG' MP1;
  1964.                     MOD_MEC_R1 = REDU MOD_MEC_R EL1;
  1965.                     GRADEP1 = REDU GRADEP MOD_MEC_R1;
  1966.                     GRADEP1 = CHAN 'CHAM' GRADEP1 MOD_MEC_R1 'NOEUD';
  1967.                     GRUI = PROI GRADEP1 MODPFI 'STRESSES';
  1968.                     MODPFT = MODPFT ET MODPFI;
  1969.                     GRADEPF = GRADEPF ET GRUI;
  1970.                 FINSI;
  1971. * on interpole le gradient de deplacement (GRADEP) sur les elements du
  1972. * modele de pression touchant la levre superieure
  1973.                 SI (EXIS SUPTAB 'LEVRE_SUPERIEURE');
  1974.                     FISS = INTE FISSP (SUPTAB . 'LEVRE_SUPERIEURE');
  1975.                     MODPFS = REDU MODPF FISS;
  1976.                     MP1 = DIFF (CHAN 'POI1' FISS) FF1;
  1977.                     EL1 = MAILMOD ELEM 'APPU' 'LARG' MP1;
  1978.                     MOD_MEC_R1 = REDU MOD_MEC_R EL1;
  1979.                     GRADEP1 = REDU GRADEP MOD_MEC_R1;
  1980.                     GRADEP1 = CHAN 'CHAM' GRADEP1 MOD_MEC_R1 'NOEUD';
  1981.                     GRUS = PROI GRADEP1 MODPFS 'STRESSES';
  1982.                     MODPFT = MODPFT ET MODPFS;
  1983.                     GRADEPF = GRADEPF ET GRUS;
  1984.                 FINSI;
  1985.                 GRADEPF = REDU GRADEPF MODPFT;
  1986. * on interpole le champ theta (THETA) sur les elements du modele de
  1987. * pression ==> TETAF
  1988.                 TETAF = REDU CHTHETA FISSP;
  1989.                 TETAF = CHAN 'CHAM' MODPFT TETAF 'STRESSES';
  1990. * on fait ensuite le produit (GRADEPF * TETAF) ==> GRUTE
  1991.                 LCT = EXTR TETAF   'COMP';
  1992.                 LCG = EXTR GRADEPF 'COMP';
  1993.                 SI (EGA GDIME 2);
  1994.                     LCG12 = EXTR LCG (LECT 1 2);
  1995.                     LCG45 = EXTR LCG (LECT 4 5);
  1996.                     GRUTE1 = PSCA GRADEPF TETAF LCG12 LCT;
  1997.                     GRUTE2 = PSCA GRADEPF TETAF LCG45 LCT;
  1998.                     GRUTE  = (NOMC (EXTR LCT 1) GRUTE1) ET
  1999.                                 (NOMC (EXTR LCT 2) GRUTE2);
  2000.                 FINSI;
  2001.                 SI (EGA GDIME 3);
  2002.                     LCG123 = EXTR LCG (LECT 1 2 3);
  2003.                     LCG456 = EXTR LCG (LECT 4 5 6);
  2004.                     LCG789 = EXTR LCG (LECT 7 8 9);
  2005.                     GRUTE1 = PSCA GRADEPF TETAF LCG123 LCT;
  2006.                     GRUTE2 = PSCA GRADEPF TETAF LCG456 LCT;
  2007.                     GRUTE3 = PSCA GRADEPF TETAF LCG789 LCT;
  2008.                     GRUTE  = (NOMC (EXTR LCT 1) GRUTE1) ET
  2009.                                 (NOMC (EXTR LCT 2) GRUTE2) ET
  2010.                                 (NOMC (EXTR LCT 3) GRUTE3);
  2011.                 FINSI;
  2012.                 GRUTE = CHAN 'TYPE' GRUTE 'FORCES';
  2013.             FINSI;
  2014.  
  2015.  
  2016. ***********************************************
  2017. * DEP1 = (grad A_DEPI)*THETA
  2018. ***********************************************
  2019.             LO1 =  BOOL.'DJ/DA'  ET ('>' (XTX PREINT) 1.E-10);
  2020.             LO2 = FAUX;
  2021.             SI  BOOL.'DECOUPLAGE';
  2022.                 LO2 = ('>' (XTX A_PREI) 1.E-10) OU ('>' (XTX PREINT) 1.E-10);
  2023.             FINSI;
  2024.             SI (LO1 OU LO2);
  2025. *  mess 'gcalcul : CHAN CHPO grad(U^aux)';
  2026.                 GRADCH = CHAN 'CHPO' MOD_MEC_R A_DEPGR;
  2027. *bp : on se ramene a un chpoint pour faire XTY avec preint ensuite
  2028. *     on moyenne avec CHAN CHPO, pourrait on l'eviter?
  2029.                 DEPLX = ((EXCO GR1 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  2030.                         ((EXCO GR2 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL'));
  2031.                 DEPLY = ((EXCO GR4 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  2032.                         ((EXCO GR5 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL'));
  2033.                 DEP1 = (NOMC DEPLX MU1) + (NOMC DEPLY MU2);
  2034.                 SI (GDIME EGA 3);
  2035.                     DEPLX = DEPLX +
  2036.                             ((EXCO GR3 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  2037.                     DEPLY = DEPLY +
  2038.                             ((EXCO GR6 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  2039.                     DEPLZ = ((EXCO GR7 GRADCH 'SCAL')*(EXCO MU1 CHTHETA 'SCAL')) +
  2040.                             ((EXCO GR8 GRADCH 'SCAL')*(EXCO MU2 CHTHETA 'SCAL')) +
  2041.                             ((EXCO GR9 GRADCH 'SCAL')*(EXCO MU3 CHTHETA 'SCAL'));
  2042.                     DEP1 = (NOMC DEPLX MU1) + (NOMC DEPLY MU2) +
  2043.                             (NOMC DEPLZ MU3);
  2044.                 FINSI;
  2045.                 SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  2046.                     GRAFCH = CHAN 'CHPO' MOD_MEC_R GRADEF;
  2047.                     BXX = EXCO 'BX,X' GRAFCH 'SCAL';
  2048.                     BXY = EXCO 'BX,Y' GRAFCH 'SCAL';
  2049.                     BYX = EXCO 'BY,X' GRAFCH 'SCAL';
  2050.                     BYY = EXCO 'BY,Y' GRAFCH 'SCAL';
  2051.                     DEPFX = NOMC 'RX' ( (BXX*(EXCO 'UX' CHTHETA 'SCAL')) +
  2052.                             (BXY*(EXCO 'UY' CHTHETA 'SCAL')) );
  2053.                     DEPFY = NOMC 'RY' ( (BYX*(EXCO 'UX' CHTHETA 'SCAL')) +
  2054.                             (BYY*(EXCO 'UY' CHTHETA 'SCAL')) );
  2055.                     DEP1 = DEP1 + DEPFX + DEPFY;
  2056.                 FINSI;
  2057.             FINSI;
  2058. ***********************************************
  2059. * Termes supplemenetaire en Dynamique
  2060. * VCARE = V*V
  2061. * GRUTV = (grad U)*THETA*V      (Attigui)
  2062. * GRVTV = V^T * (grad V)*THETA  (BP)
  2063. * GRWTU = W^T * (grad U)*THETA  (BP)
  2064. ***********************************************
  2065.             SI  BOOL.'J_DYNA';
  2066.                 VCARE = PSCA VITF VITF MUI MUI;
  2067. * NOUVELLE IMPLEMENTATION JB :
  2068. *               CHML_TETA = CHAN 'CHAM' MOD_MEC_R TETA 'STRESSES';
  2069. *               GRUTV = MANU 'CHML' MOD_MEC_R 'SCAL' 0.
  2070. *                           'TYPE' 'DEPLACEM' 'STRESSES';
  2071. *               GRVTV = COPI GRUTV;
  2072. *               GRWTU = COPI GRUTV;
  2073. *               REPE ICOMP GDIME;
  2074. * CALCUL DE DEPFI ET VITFI
  2075. *                   IDEB = 1 + (3*(&ICOMP - 1));
  2076. *                   IFIN = IDEB + GDIME - 1;
  2077. *                   LMO1 = EXTR MGI (LECT IDEB PAS 1 IFIN);
  2078. *                   LMO2 = MUI;
  2079. *                   DEPFI = PSCA GRADEP CHML_TETA LMO1 LMO2;
  2080. *                   VITFI = PSCA GRAVIT CHML_TETA LMO1 LMO2;
  2081. * CALCUL DE GRUTV
  2082. *                   MO1 = EXTR MUI &ICOMP;
  2083. *                   GRUTV = GRUTV + ((EXCO MO1 VITF 'SCAL') * DEPFI);
  2084. * CALCUL DE GRVTV
  2085. *                   GRVTV = GRVTV + ((EXCO MO1 VITF 'SCAL') * VITFI);
  2086. * CALCUL DE GRWTU
  2087. *                   GRWTU = GRWTU + ((EXCO MO1 ACCF 'SCAL') * DEPFI);
  2088. *               FIN ICOMP;
  2089. * CETTE SECTION N'EST PAS ASSEZ TESTEE ACTUELLEMENT DANS LA BASE DE CAS-TESTS
  2090. * IL FAUT DONC AJOUTER DES CAS-TESTS AVANT DE POUVOIR REMPLACER CE QUI SUIT
  2091. * PAR LES LIGNES COMMENTEES CI-DESSUS
  2092.                 DEPFX = (((EXCO GR1 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE') *TETX) +
  2093.                         (((EXCO GR2 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE') *TETY);
  2094.                 DEPFY = (((EXCO GR4 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE') *TETX) +
  2095.                         (((EXCO GR5 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE') *TETY);
  2096.                 VITFX = (((EXCO GR1 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE') *TETX) +
  2097.                         (((EXCO GR2 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE') *TETY);
  2098.                 VITFY = (((EXCO GR4 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE') *TETX) +
  2099.                         (((EXCO GR5 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE') *TETY);
  2100.                 SI (EGA GDIME 3);
  2101.                     DEPFX=DEPFX +(((EXCO GR3 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2102.                     DEPFY=DEPFY +(((EXCO GR6 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2103.                     DEPFZ = (((EXCO GR7 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE')*TETX) +
  2104.                             (((EXCO GR8 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE')*TETY) +
  2105.                             (((EXCO GR9 GRADEP 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2106.                     VITFX=VITFX +(((EXCO GR3 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2107.                     VITFY=VITFY +(((EXCO GR6 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2108.                     VITFZ = (((EXCO GR7 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE')*TETX) +
  2109.                             (((EXCO GR8 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE')*TETY) +
  2110.                             (((EXCO GR9 GRAVIT 'SCAL')CHAN TYPE 'SCALAIRE')*TETZ);
  2111.                     GRUTV = ((EXCO MU1 VITF 'SCAL')*DEPFX) +
  2112.                             ((EXCO MU2 VITF 'SCAL')*DEPFY) +
  2113.                             ((EXCO MU3 VITF 'SCAL')*DEPFZ);
  2114.                     GRWTU = ((EXCO MU1 ACCF 'SCAL')*DEPFX) +
  2115.                             ((EXCO MU2 ACCF 'SCAL')*DEPFY) +
  2116.                             ((EXCO MU3 ACCF 'SCAL')*DEPFZ);
  2117.                     GRVTV = ((EXCO MU1 VITF 'SCAL')*VITFX) +
  2118.                             ((EXCO MU2 VITF 'SCAL')*VITFY) +
  2119.                             ((EXCO MU3 VITF 'SCAL')*VITFZ);
  2120.                 SINON;
  2121.                     GRUTV = ((EXCO MU1 VITF 'SCAL')*DEPFX) +
  2122.                             ((EXCO MU2 VITF 'SCAL')*DEPFY);
  2123.                     GRWTU = ((EXCO MU1 ACCF 'SCAL')*DEPFX) +
  2124.                             ((EXCO MU2 ACCF 'SCAL')*DEPFY);
  2125.                     GRVTV = ((EXCO MU1 VITF 'SCAL')*VITFX) +
  2126.                             ((EXCO MU2 VITF 'SCAL')*VITFY);
  2127.                 FINSI;
  2128.             FINSI;
  2129.  
  2130.  
  2131. *|=====================================================================|
  2132. *|========  IV. CALCUL DE J,C*,C*(h) ou J_DYNA  =======================|
  2133.  
  2134. ***********************************************
  2135. * S10 = w*(div THETA)
  2136. * S20 = sigma*(grad U)*(grad THETA)
  2137. * S40 = Tr(sigma)*Alpha*(Grad T)*THETA
  2138. * S50 = F*(grad U)*THETA
  2139. * S60 = 0.5*(grad D)*THETA*(EPSI elas)*(EPSI elas)
  2140. * S70 = Tr(sigma)*T*(Grad Alpha)*THETA
  2141. * S100 = (W(b) - W(a))*THETA(x)
  2142. * S110 = SIGF*n*[ (dU/dX)(b) - (dU/dX)(a) ]*THETA(x)
  2143. * S120 = wvmis*(Grad T)*THETA
  2144. *     ou wvmis = SOME d(Von_mises)/d(Temperature) d(EPSE)
  2145. ***********************************************
  2146. * Termes supplementaires pour le J dynamique (Formulation de Attigui)
  2147. * S130 = 0.5*RHO*(V^2)*(div THETA)
  2148. * S140 = [Delta (RHO*V*(grad U)*THETA)]/(Delta Temps)
  2149. * Termes supplementaires pour le J dynamique (Formulation de BP)
  2150. * S130 = -0.5*RHO*(V^2)*(div THETA)
  2151. * S140 =  RHO*W*(grad U)*THETA
  2152. * S141 = -RHO*V*(grad V)*THETA
  2153. ***********************************************
  2154. * Termes supplementaires pour le J en grands-deplacements
  2155. * S150 = sigma*((grad U)t)*(grad U)*(grad THETA)
  2156. ***********************************************
  2157. ***********************************************
  2158. * Termes supplementaires pour un chaergement en deformation imposee (modif sm)
  2159. * S160 = sigma*(deps/dx)*(THETA)
  2160. *      = SIG_{IJ} * (deps^{imp}_{ij} / dx_{,k}) * thet_{k}
  2161. ***********************************************
  2162. * Termes supplementaires pour le contact frottant (modif BP,BT)
  2163. * S111 = SIGF*n*[ (dU/dX)(b) - (dU/dX)(a) ]*THETA(x)
  2164. ***********************************************
  2165.  
  2166.  
  2167.             SI ((BOOL.'J') OU  BOOL.'C*' OU BOOL.'C*H' OU  BOOL.'J_DYNA' );
  2168.                 GMCANI = 0.;
  2169.                 GTERMI = 0.;
  2170.                 GPRESS = 0.;
  2171.  
  2172.                 S10 = INTG MOD_MEC_R (ENERM*MOD_MEC_R DIVTETA) MAT2;
  2173.                 GMCANI = GMCANI - S10;
  2174.                 SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  2175.                     S20 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2176.                             (GRADEP*MOD_MEC_R TETAGR)
  2177.                             (GRADEF*MOD_MEC_R TETAGR));
  2178.                 SINON;
  2179.                     S20 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2180.                             (GRADEP*MOD_MEC_R TETAGR)) MAT2;
  2181.                 FINSI;
  2182.                 GMCANI = GMCANI + S20;
  2183.                 SI BOOL.'GRANDS_DEP';
  2184.                     SI (BOOL.'COQ' ET BOOL.'EL_LIN');
  2185.                         S150 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2186.                                 (((TAGR GRADEP)*MOD_MEC_R GRADEP)*MOD_MEC_R TETAGR)
  2187.                                 (((TAGR GRADEF)*MOD_MEC_R GRADEF)*MOD_MEC_R TETAGR));
  2188.                     SINON;
  2189.                         S150 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2190.                                 (((TAGR GRADEP)*MOD_MEC_R GRADEP)*MOD_MEC_R TETAGR)) MAT2;
  2191.                     FINSI;
  2192.                     GMCANI = GMCANI + S150;
  2193.                 FINSI;
  2194.                 SI (BOOL.'GRADPROP' ET BOOL.'GRADYOUN');
  2195.                     S60 = INTG MOD_MEC_R (0.5*(ENER MOD_MEC_R
  2196.                             SIGPRIM (ELAS MOD_MEC_R SIGF MAT_INST))) MAT2;
  2197.                     GMCANI = GMCANI - S60;
  2198.                 FINSI;
  2199.                 SI (((DIME LINTER) > 0) ET (NON BOOL.'PARAL'));
  2200.                     I = 0 ; IND1 = INDE LINTER;
  2201.                     REPE NBJ4 (DIME IND1);
  2202.                         I = I + 1;
  2203.                         LE1 = IND1.&NBJ4;
  2204.                         L1 = LINTER.LE1;
  2205.                         M1 = TABMOD.(EXTR LE1 1);
  2206.                         M2 = TABMOD.(EXTR LE1 2);
  2207.                         OBJINT = MODE L1 'MECANIQUE' 'ELASTIQUE';
  2208.                         TETXL = REDU L1 (EXCO MU1 CHTHETA 'SCAL');
  2209.                         TETXLC = CHAN 'CHAM' OBJINT TETXL 'STRESSES';
  2210. ***
  2211.                         ENEMA = REDU L1 (CHAN 'CHPO' M1 (REDU M1 ENERM));
  2212.                         ENEMB = REDU L1 (CHAN 'CHPO' M2 (REDU M2 ENERM));
  2213.                         ENRMAL = CHAN 'CHAM' OBJINT ENEMA 'STRESSES';
  2214.                         ENRMBL = CHAN 'CHAM' OBJINT ENEMB 'STRESSES';
  2215.                         S100 = S100 + (INTG OBJINT
  2216.                                 ((ENRMBL - ENRMAL) * OBJINT TETXLC) MAT2);
  2217. ***
  2218.                         GRADA = REDU L1 (CHAN 'CHPO' M1 (REDU M1 GRADEP));
  2219.                         GRADB = REDU L1 (CHAN 'CHPO' M2 (REDU M2 GRADEP));
  2220.                         UXXAL = CHAN 'CHAM' OBJINT (EXCO GR1 GRADA 'SCAL')
  2221.                                 'STRESSES';
  2222.                         UXXBL = CHAN 'CHAM' OBJINT (EXCO GR1 GRADB 'SCAL')
  2223.                                 'STRESSES';
  2224.                         UYXAL = CHAN 'CHAM' OBJINT (EXCO GR4 GRADA 'SCAL')
  2225.                                 'STRESSES';
  2226.                         UYXBL = CHAN 'CHAM' OBJINT (EXCO GR4 GRADB 'SCAL')
  2227.                                 'STRESSES';
  2228.                         SIGML = REDU L1 (CHAN 'CHPO' MOD_MEC_R SIGF);
  2229.                         SIXXL = CHAN 'CHAM' OBJINT (EXCO SM1 SIGML 'SCAL')
  2230.                                 'STRESSES';
  2231.                         SIXYL = CHAN 'CHAM' OBJINT (EXCO SM4 SIGML 'SCAL')
  2232.                                 'STRESSES';
  2233.                         AAAA1 = (SIXXL * OBJINT (UXXBL - UXXAL)) +
  2234.                                 (SIXYL * OBJINT (UYXBL - UYXAL));
  2235.                         S110 = S110 + (INTG OBJINT (AAAA1*OBJINT TETXLC) MAT2);
  2236.                     FIN NBJ4;
  2237.                     GMCANI = GMCANI - S100 + S110;
  2238.                 FINSI;
  2239. * Termes supplementaire en Dynamique **********
  2240.                 SI  BOOL.'J_DYNA';
  2241.                     S130 = INTG MOD_MEC_R (0.5*(RHO1 * VCARE * DIVTETA)) MAT2;
  2242.                     S140 = INTG MOD_MEC_R (RHO1 * GRWTU) MAT2;
  2243.                     S141 = INTG MOD_MEC_R (RHO1 * GRVTV) MAT2;
  2244.                     GMCANI = GMCANI - S130 + S140 - S141;
  2245.                 FINSI;
  2246. * Termes supplementaire pour le contact frottant (btrolle 19/02/2013)
  2247.                 SI (BOOL.'FROT');
  2248. * teta
  2249.                     TETXC = PROI OBJCON2 TETAX 'STRESSES';
  2250.                     TETYC = PROI OBJCON2 TETAY 'STRESSES';
  2251.                     SI (EGA GDIME 3);
  2252.                         TETZC = PROI OBJCON2 TETAZ 'STRESSES';
  2253.                     FINSI;
  2254. * [grad(w)] = grad [w] = WSAUTGR
  2255. * sigma*n
  2256.                     AAAAX = (SIGXN * (CHAN (exco WSAUTGR AX,X 'SCAL') TYPE 'SCALAIRE'))
  2257.                             + (SIGYN * (CHAN (exco WSAUTGR AY,X 'SCAL') TYPE 'SCALAIRE'));
  2258.                     AAAAY = (SIGXN * (CHAN (exco WSAUTGR AX,Y 'SCAL') TYPE 'SCALAIRE'))
  2259.                             + (SIGYN * (CHAN (exco WSAUTGR AY,Y 'SCAL') TYPE 'SCALAIRE'));
  2260.                     SI (EGA GDIME 3);
  2261.                         AAAAX = AAAAX
  2262.                                 + (SIGZN *  (CHAN(exco WSAUTGR AZ,X) TYPE 'SCALAIRE'));
  2263.                         AAAAY = AAAAY
  2264.                                 + (SIGZN *  (CHAN(exco WSAUTGR AZ,Y) TYPE 'SCALAIRE'));
  2265.                         AAAAZ = (SIGXN *  (CHAN(exco WSAUTGR AX,Z) TYPE 'SCALAIRE'))
  2266.                                 + (SIGYN *  (CHAN(exco WSAUTGR AY,Z) TYPE 'SCALAIRE'))
  2267.                                 + (SIGZN *  (CHAN(EXCO WSAUTGR AZ,Z) TYPE 'SCALAIRE'));
  2268.                         AAAA111 = (AAAAX * OBJCON2 TETXC) + (AAAAY * OBJCON2 TETYC)
  2269.                                     + (AAAAZ * OBJCON2 TETZC);
  2270.                     SINON;
  2271.                         AAAA111 = (AAAAX * OBJCON2 TETXC) + (AAAAY * OBJCON2 TETYC);
  2272.                     FINSI;
  2273. *    AAAA111 = 'MANUEL' CHML objcon 'SCAL' 1 TYPE 'SCALAIRE' 'STRESSES';
  2274.                     S111 = INTG OBJCON2 AAAA111 ; mess 'S111=' S111;
  2275.                     GMCANI = GMCANI - S111;
  2276.                 SINON;
  2277.                     S111 = 0.0;
  2278.                 FINSI;
  2279. * fin du cas contact frottant (btrolle 19/02/2013)
  2280.  
  2281.                 S50 = 0.;
  2282.                 SI ((XTX PREINT) > 1.E-10);
  2283.                     S50 = XTY PREINT DEP0 MFI MUI;
  2284.                 FINSI;
  2285.                 SI BOOL.'PRES_FISS';
  2286.                     PNF = REDU PNF MODPFT;
  2287.                     LC1 = EXTR PNF   'COMP';
  2288.                     LC2 = EXTR GRUTE 'COMP';
  2289.                     PGRU = MANU 'CHML' MODPFT 'SCAL' 0. 'STRESSES';
  2290.                     REPE B1 (DIME LC1);
  2291.                         PGRU = PGRU + ((EXCO (EXTR LC1 &B1) PNF   'SCAL') *
  2292.                                 (EXCO (EXTR LC2 &B1) GRUTE 'SCAL'));
  2293.                     FIN B1;
  2294.                     S50 = S50 + (INTG MODPFT PGRU);
  2295.                 FINSI;
  2296.                 GPRESS = GPRESS - S50;
  2297. * Termes supplementaire pour un chargement en deformation imposee (SM) *********
  2298.                 S160 = 0.;
  2299.                 SI (BOOL.'J' ET BOOL.'DEF_IMP');
  2300.                     S160 = INTG MOD_MEC_R CUMDEFI MAT2;
  2301.                     GPRESS = GPRESS + S160;
  2302.                 FINSI;
  2303.  
  2304.                 SI BOOL.'THER';
  2305.                     SI BOOL.'COQ';
  2306.                         S40 = INTG MOD_MEC_R (ENER MOD_MEC_R SIGF EPSTU) MAT2;
  2307.                         GTERMI = GTERMI + S40;
  2308.                         SI BOOL.'GRADALPH';
  2309.                             S70 = INTG MOD_MEC_R (ENER MOD_MEC_R SIGF (ELAS
  2310.                                     MOD_MEC_R (THET MOD_MEC_R TEPINT DMAT) DMAT)) MAT2;
  2311.                             GTERMI = GTERMI + S70;
  2312.                         FINSI   ;
  2313.                     SINON;
  2314.                         S41 = INTG MOD_MEC_R (ENER MOD_MEC_R SIGF GR_EPTH_THET) MAT2;
  2315.                         GTERMI = GTERMI + S41;
  2316.                     FINSI;
  2317.                     SI ((DIME MODPLA) > 0);
  2318.                         TEMU = CHAN TYPE (EXCO 'T' TEMU 'SCAL') 'SCALAIRE';
  2319.                         S120 = INTG MOD_MEC_R (WVMIS * TEMU) MAT2;
  2320.                         GTERMI = GTERMI - S120   ;
  2321.                     FINSI;
  2322.                 FINSI;
  2323.  
  2324. * somme des termes ***************************
  2325.                 GTOTA = (GMCANI + GTERMI + GPRESS)*FACT1;
  2326.             FINSI;
  2327.  
  2328.  
  2329.  
  2330. *|=====================================================================|
  2331. *|=======  V. CALCUL DE DJ/DA  ========================================|
  2332.  
  2333. ***********************************************
  2334. * S10 = -SIGF*(Grad U)*(Grad PI)*(Grad TETA)
  2335. * S20 = -SIGF*(Grad U)*(Grad TETA)*(Grad PI)
  2336. * S30 = SIGF*(Grad U)*(Grad TETA)*(Div PI)
  2337. * S40 = SIGF*(Grad U)*(Grad PI)*(Div TETA)
  2338. * S50 = ENEGIE*(ADJ TETA*PI)
  2339. * S60 = ALPH*SIGF*(Grad (Grad T))*PI*TETA
  2340. * S70 = ALPH*SIGF*((Grad T)*PI)*(Div TETA)
  2341. * S80 = ALPH*SIGF*((Grad T)*TETA)*(Div PI)
  2342. * S90 = SIG11*(Grad U)*(Grad TETA)
  2343. * S100= SIGF*(Grad U1)*(Grad TETA)
  2344. * S110= -SIGF*(Grad U1)*(Div TETA)
  2345. * S120= ALPH*SIG11*((Grad T)*TETA)
  2346. * S130= -PRESSION*(grad A_DEPI)*THETA
  2347. * S140= -(Grad PRESSION)*(Grad PI)*TETA*U
  2348. * S150= (Grad PRESSION)*TETA*U*(Div PI)
  2349. * S160= -(Grad PRESSION)*PI*(Grad U)*TETA
  2350. ***********************************************
  2351.             SI  BOOL.'DJ/DA';
  2352.                 S10 = 0. - (INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2353.                         (MOD_MEC_R GRADEP * (MOD_MEC_R PIGR * TETAGR))));
  2354.                 S20 = 0. - (INTG MOD_MEC_R (WORK MOD_MEC_R SIGF
  2355.                         (MOD_MEC_R GRADEP * (MOD_MEC_R TETAGR * PIGR))));
  2356.                 S30 = INTG MOD_MEC_R (MOD_MEC_R (WORK MOD_MEC_R
  2357.                         SIGF (MOD_MEC_R GRADEP * TETAGR)) * DIVPI);
  2358.                 S40 = INTG MOD_MEC_R (MOD_MEC_R (WORK MOD_MEC_R
  2359.                         SIGF (MOD_MEC_R GRADEP * PIGR)) * DIVTETA);
  2360.                 S50 = INTG MOD_MEC_R (ENERM * ADJ);
  2361.                 SI BOOL.'THER';
  2362.                     S60 = INTG MOD_MEC_R (ENER MOD_MEC_R SIGF EPSTU2);
  2363.                     S70 = INTG MOD_MEC_R ((ENER MOD_MEC_R SIGF EPSTU1)*DIVTETA);
  2364.                     S80 = INTG MOD_MEC_R ((ENER MOD_MEC_R SIGF EPSTU)*DIVPI);
  2365.                     S120 = INTG MOD_MEC_R (ENER MOD_MEC_R A_SIGF EPSTU);
  2366.                 FINSI;
  2367.                 SI ((XTX PREINT) > 1.E-10);
  2368.                     S130 = XTY PREINT DEP1 MFI MUI;
  2369.                     S140 = XTY PEMU2 (CHAN 'CHPO' MOD_MEC_R DEPINT) MFI MUI;
  2370.                     S150 = XTY (PEMU1*(CHAN 'CHPO' MOD_MEC_R DIVPI))
  2371.                             (CHAN 'CHPO' MOD_MEC_R DEPINT) MFI MUI;
  2372.                     S160 = XTY PEMU DEP0 MFI MUI;
  2373.                 FINSI;
  2374.                 S90 = INTG MOD_MEC_R (WORK MOD_MEC_R A_SIGF (MOD_MEC_R GRADEP * TETAGR));
  2375.                 S100 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF (MOD_MEC_R A_DEPGR * TETAGR));
  2376.                 S110 = 0. - (INTG MOD_MEC_R (MOD_MEC_R (WORK
  2377.                         MOD_MEC_R SIGF A_DEPGR) * DIVTETA));
  2378.                 GMCANI = S10 + S20 + S30 + S40 + S50 + S90 + S100 + S110;
  2379.                 GTERMI = S60 + S70 + S80 + S120;
  2380.                 GPRESS = S150 - S130 - S140 - S160;
  2381.                 GTOTA = GMCANI + GTERMI + GPRESS;
  2382.             FINSI;
  2383.  
  2384.  
  2385.  
  2386. *|=====================================================================|
  2387. *|======  VI. CALCUL DES FACTEURS D INTENSITE DES CONTRAINTES  =======|
  2388.  
  2389. ***********************************************
  2390. * En pratique on les deduit de l integrale d interaction
  2391. * M(u,u^aux) = 2/E^* (K1*K1^aux + K2*K2^aux)
  2392. * On calcule donc :
  2393. *  J1 = 1/E^* K1^2 = M(u,u^aux_1)**2 / 4*J(u^aux_1,u^aux_1)
  2394. *  J2 = 1/E^* K2^2 = M(u,u^aux_2)**2 / 4*J(u^aux_2,u^aux_2)
  2395. ***********************************************
  2396. * l'integrale J(u^aux, u^aux) est la somme de :
  2397. * S10 = 0.5*Tr(A_sigf*(grad A_depi))*(div THETA)
  2398. * S20 = Tr[A_sigf*(grad A_depi)*(grad THETA)] *
  2399. * S50 = A_prei*(grad A_depi)*THETA
  2400. ***********************************************
  2401. * l'integrale M(u, u^aux) et la somme de :
  2402. * S60 = Tr[A_sigf*(Grad U)*(Grad THETA)]
  2403. * S70 = Tr[SIGF*(Grad A_depi)*(Grad THETA)]
  2404. * S80 = Tr[SIGF*(Grad A_depi)*(Div THETA)]
  2405. * S90 = PREINT*(grad A_depi)*THETA
  2406. * S100= A_prei*(grad U)*THETA
  2407. * S110= ALPH*A_sigf*((Grad T)*TETA)
  2408. ***********************************************
  2409. * Termes supplementaires pour le contact frottant (modif BP,BT)
  2410. * S111 = SIGF*n*[ (dU^aux/dX)(b) - (dU^aux/dX)(a) ]*TETA(x)
  2411. ***********************************************
  2412.  
  2413.  
  2414.             SI  BOOL.'DECOUPLAGE';
  2415. *    si(BOOL.'XFEM');
  2416. * *  REM: pour les elements XFEM on a contruit les champs aux. tq
  2417. * *      (K_I^aux, K_II^aux)  =  (1,0)  et (0,1)
  2418. * *      => inutile de calculer J(u^aux,u^aux) (= C_MATE)
  2419. *bp 07/07/2011 : cela est faux dans le cas d'une fissure courbee
  2420. *      COE_M2K = 2. * C_MATE;
  2421. *    SINON;
  2422.                 S10 = 0.5*( INTG MOD_MEC_R
  2423.                         (MOD_MEC_R (WORK MOD_MEC_R A_SIGF A_DEPGR) * DIVTETA) );
  2424.                 S20 = INTG MOD_MEC_R
  2425.                         (WORK MOD_MEC_R A_SIGF (A_DEPGR*MOD_MEC_R TETAGR) ) MAT2;
  2426.                 SI ((XTX A_PREI) > 1.E-10);
  2427.                     S50 = XTY A_PREI DEP1 MFI MUI;
  2428.                 FINSI;
  2429.                 JETOILE = 'ABS' (S20 - S10 - S50);
  2430.                 SI ((EGA &BOUCMIX 1) OU (EGA &BOUCMIX 2));
  2431.                     FACTK = 0.5 / ((C_MATE * JETOILE)**0.5);
  2432.                 SINON;
  2433.                     FACTK = 0.5 * ((2. * MU_1 / JETOILE)**0.5);
  2434.                 FINSI;
  2435. *    FINSI;
  2436. *  integrale M(u, u^aux)
  2437.                 S60 = INTG MOD_MEC_R (WORK MOD_MEC_R A_SIGF (MOD_MEC_R GRADEP * TETAGR));
  2438.                 S70 = INTG MOD_MEC_R (WORK MOD_MEC_R SIGF (MOD_MEC_R A_DEPGR * TETAGR));
  2439.                 S80 = INTG MOD_MEC_R (MOD_MEC_R (WORK MOD_MEC_R SIGF A_DEPGR) * DIVTETA);
  2440. *rem: on pourrait calculer M avec les 2 lignes ci dessous:
  2441. *    S81 = INTG MOD_MEC_R (MOD_MEC_R (WORK MOD_MEC_R A_SIGF GRADEP) * DIVTETA);
  2442. *    S80 = 0.5*(S80+S81);
  2443. * Termes supplementaire pour le contact frottant (btrolle 19/02/2013)
  2444. * on calcule WSAUTGR^aux = GRADIENT DU SAUT^aux
  2445.                 SI (BOOL.'FROT' 'ET' BOOL.'XFEM');
  2446. * WDEP = deplacement de la fissure de composante UX ... AX ...
  2447. * [grad(w)] = grad [w] car linearite (le saut [w] est donne par AX ...)
  2448. * on utilise un modele liee a la geo de la fissure (cohesif ou contact)
  2449. * mess 'I avec contact frottant';
  2450. * SIGCON = sigma*n de composantes SMX... homogene a une contrainte
  2451. * supporte sur la levre superieure
  2452.                     SI (NEG (TYPE SIGCON) 'MCHAML  ');
  2453.                         SIGCON = REDU SIGCON (extr OBJCON2 'MAILLAGE');
  2454.                         SIGCON = CHAN 'CHAM' SIGCON OBJCON2 'STRESSES' 'CONTRAINTES';
  2455.                     FINSI;
  2456.                     SIGXN = (CHAN (exco SIGCON 'SMX' 'SCAL') TYPE 'SCALAIRE');
  2457.                     SIGYN = (CHAN (exco SIGCON 'SMY' 'SCAL') TYPE 'SCALAIRE');
  2458.                     SI (EGA GDIME 3);
  2459.                         SIGZN = (CHAN (exco SIGCON 'SMZ' 'SCAL') TYPE 'SCALAIRE');
  2460.                     FINSI;
  2461. * teta
  2462.                     TETXC = PROI OBJCON2 TETAX 'STRESSES';
  2463.                     TETYC = PROI OBJCON2 TETAY 'STRESSES';
  2464.                     SI (EGA GDIME 3);
  2465.                         TETZC = PROI OBJCON2 TETAZ 'STRESSES';
  2466.                     FINSI;
  2467. * [grad(w)] = grad [w] = WSAUTGR
  2468. * sigma*n
  2469.                     AAAAX= (SIGXN * (CHAN (exco B_DEPGR AX,X 'SCAL') TYPE 'SCALAIRE'))
  2470.                     + (SIGYN * (CHAN (exco B_DEPGR AY,X 'SCAL') TYPE 'SCALAIRE'));
  2471.                     AAAAY= (SIGXN * (CHAN (exco B_DEPGR AX,Y 'SCAL') TYPE 'SCALAIRE'))
  2472.                     '+' (SIGYN * (CHAN (exco B_DEPGR AY,Y 'SCAL') TYPE 'SCALAIRE'));
  2473.                     SI (EGA GDIME 3);
  2474.                         AAAAX = AAAAX
  2475.                                 + (SIGZN *  (CHAN(EXCO B_DEPGR AZ,X) TYPE 'SCALAIRE'));
  2476.                         AAAAY = AAAAY
  2477.                                 + (SIGZN *  (CHAN(EXCO B_DEPGR AZ,Y) TYPE 'SCALAIRE'));
  2478.                         AAAAZ = (SIGXN *  (CHAN(EXCO B_DEPGR AX,Z) TYPE 'SCALAIRE'))
  2479.                                 + (SIGYN *  (CHAN(EXCO B_DEPGR AY,Z) TYPE 'SCALAIRE'))
  2480.                                 + (SIGZN *  (CHAN(EXCO B_DEPGR AZ,Z) TYPE 'SCALAIRE'));
  2481.                         AAAA111 = (AAAAX * OBJCON2 TETXC)
  2482.                                     + (AAAAY * OBJCON2 TETYC)
  2483.                                     + (AAAAZ * OBJCON2 TETZC);
  2484.                     SINON;
  2485.                         AAAA111 = (AAAAX * OBJCON2 TETXC)
  2486.                                     + (AAAAY * OBJCON2 TETYC);
  2487.                     FINSI;
  2488.                     S111 = INTG OBJCON2 AAAA111;
  2489.                 SINON;
  2490.                     S111 = 0.0;
  2491.                 FINSI;
  2492. * fin du cas contact frottant (btrolle 19/02/2013)
  2493.                 SI ((XTX PREINT) > 1.E-10);
  2494.                     S90 = XTY PREINT DEP1 MFI MUI;
  2495.                 FINSI;
  2496.                 SI ((XTX A_PREI) > 1.E-10);
  2497.                     S100 = XTY A_PREI DEP0 MFI MUI;
  2498.                 FINSI;
  2499.                 SI BOOL.'THER';
  2500.                     S110 = INTG MOD_MEC_R (ENER MOD_MEC_R A_SIGF EPSTU);
  2501.                 FINSI;
  2502. *  facteurs d intensite des contraintes
  2503.                 GMCANI = (S60 + S70 - S80 + S111) * FACTK;
  2504.                 GTERMI = (S110) * FACTK;
  2505.                 GPRESS = (-1.*(S100 + S90)) * FACTK;
  2506.                 GTOTA = GMCANI + GTERMI + GPRESS;
  2507.             FINSI;
  2508.  
  2509.  
  2510. *|=====================================================================|
  2511. *|=======  VII. STOCKAGE DES RESULTATS ET IMPRESSIONS  ===============|
  2512.  
  2513.             SI ((NBOU > 1) ET (EGA &BCNOEU NBOU));
  2514.                 NUNOE = CHAI 'GLOBAL';
  2515.             SINON;
  2516.                 SI ((EGA GDIME 2) OU BOOL.'COQ');
  2517.                     PM = FF1 POIN 1;
  2518.                     NUNOE = CHAI (NOEU PM)*NDEC;
  2519.                 SINON;
  2520.                     SI BOOL.'XFEM';
  2521.                         NUNOE = &BCNOEU;
  2522.                     SINON;
  2523.                         FTHETA = REDU CHTHETA FF1;
  2524.                         NTHETA = (PSCA FTHETA FTHETA MUI MUI)**0.5;
  2525.                         PM = (NTHETA POIN 'MAXI') POIN 1;
  2526.                         NUNOE = CHAI (NOEU PM)*NDEC;
  2527.                     FINSI;
  2528.                 FINSI;
  2529.             FINSI;
  2530.  
  2531. ***************************************************
  2532. ** PROFILE DE G DANS L EPAISSEUR EN CAS DE COQUE **
  2533. ***************************************************
  2534.             SI BOOL.'COQ';
  2535.                 SI BOOL.'PASAPAS';
  2536.                     SUPTAB.'EPAISSEUR_RESULTATS'.IABC = EVENR * GTOTA;
  2537.                 SINON;
  2538.                     SUPTAB.'EPAISSEUR_RESULTATS' = EVENR * GTOTA;
  2539.                 FINSI;
  2540.             FINSI;
  2541.  
  2542. ****************************
  2543. ** AFFICHAGE DES RESULTATS**
  2544. ****************************
  2545.             CHARES = CHAI;
  2546.             SI BOOL.'PASAPAS';
  2547.                 CHARES = CHAI CHARES IABC*NDPAS;
  2548.             FINSI;
  2549.             SI BOOL.'DECOUPLAGE';
  2550.                 CHARES = CHAI CHARES MOTMIA*NDDEC;
  2551.             FINSI;
  2552.             SI ((EGA GDIME 3) ET (NON BOOL.'COQ'));
  2553.                 CHARES = CHAI CHARES NUNOE*NDFRO;
  2554.             FINSI;
  2555.             SI BOOL.'COQ';
  2556.                 PVAL = PROG V_SUPE V_MOYE V_INFE 1.;
  2557.                 LMVAL = MOTS 'Superi' 'Median' 'Inferi' 'GLOBAL';
  2558.                 REPE IVAL 4;
  2559.                     XVAL = EXTR PVAL &IVAL;
  2560.                     MVAL = EXTR LMVAL &IVAL;
  2561.                     CHARES = CHAI CHARES MVAL*NDCOQ;
  2562.                     MESS CHARES (GMCANI*XVAL)*NDMEC (GTERMI*XVAL)*NDTHE
  2563.                          (GPRESS*XVAL)*NDVOL (GTOTA*XVAL)*NDINT;
  2564.                 FIN IVAL;
  2565.             SINON;
  2566.                 MESS CHARES GMCANI*NDMEC GTERMI*NDTHE GPRESS*NDVOL
  2567.                      GTOTA*NDINT;
  2568.             FINSI;
  2569.  
  2570. ***************************************************
  2571. ** STOCKAGE DES RESULTATS DANS SUPTAB.'RESULTATS'**
  2572. ***************************************************
  2573.             SI BOOL.'PASAPAS';
  2574. * CAS PASAPAS
  2575.                 SI (EGA GDIME 2);
  2576.                     SI  BOOL.'DECOUPLAGE';
  2577.                         TABRES.MOTMIX.IABC = GTOTA;
  2578.                     SINON;
  2579.                         TABRES.IABC = GTOTA;
  2580.                     FINSI;
  2581.                 FINSI;
  2582.                 SI ((EGA GDIME 3) ET (NON BOOL.'COQ'));
  2583.                     SI  BOOL.'DECOUPLAGE';
  2584.                         TABRES.MOTMIX.IABC.NUNOE = GTOTA;
  2585.                     SINON;
  2586.                         TABRES.IABC.NUNOE = GTOTA;
  2587.                     FINSI;
  2588.                 FINSI;
  2589.                 SI BOOL.'COQ';
  2590.                     SI  BOOL.'DECOUPLAGE';
  2591.                         TABRES.MOTMIX = GTOTA;
  2592.                     SINON;
  2593.                         TABRES.IABC.'SUPERI' = GTOTA*V_SUPE;
  2594.                         TABRES.IABC.'MEDIAN' = GTOTA*V_MOYE;
  2595.                         TABRES.IABC.'INFERI' = GTOTA*V_INFE;
  2596.                         TABRES.IABC.'GLOBAL' = GTOTA;
  2597.                     FINSI;
  2598.                 FINSI;
  2599. * CAS RESOU
  2600.             SINON;
  2601.                 SI (EGA GDIME 2);
  2602.                     SI  BOOL.'DECOUPLAGE';
  2603.                         TABRES.MOTMIX = GTOTA;
  2604.                     SINON;
  2605.                         SUPTAB.'RESULTATS' = GTOTA;
  2606.                     FINSI;
  2607.                 FINSI;
  2608.                 SI ((EGA GDIME 3) ET (NON BOOL.'COQ'));
  2609.                     SI  BOOL.'DECOUPLAGE';
  2610.                         TABRES.MOTMIX.NUNOE = GTOTA;
  2611.                     SINON;
  2612.                         TABRES.NUNOE = GTOTA;
  2613.                     FINSI;
  2614.                 FINSI;
  2615.                 SI BOOL.'COQ';
  2616.                     SI  BOOL.'DECOUPLAGE';
  2617.                         TABRES.MOTMIX = GTOTA;
  2618.                     SINON;
  2619.                         TABRES.'SUPERI' = GTOTA*V_SUPE;
  2620.                         TABRES.'MEDIAN' = GTOTA*V_MOYE;
  2621.                         TABRES.'INFERI' = GTOTA*V_INFE;
  2622.                         TABRES.'GLOBAL' = GTOTA;
  2623.                     FINSI;
  2624.                 FINSI;
  2625.             FINSI;
  2626.  
  2627. ****************************
  2628. ** AJOUT AU CHPO OU CHAML **
  2629. ****************************
  2630.             SI ((&BCNOEU < NBOU) OU (EGA NBOU 1));
  2631.                 SI (BOOL.'XFEM' ET (EGA GDIME 3));
  2632.                     GCHAM1 = GCHAM1 ET (MANU 'CHML' IND0 MOCOMP GTOTA);
  2633.                 SINON;
  2634.                     GCHPO1 = GCHPO1 + (NOMC MOCOMP (GTOTA * IND0));
  2635.                 FINSI;
  2636.             FINSI;
  2637.  
  2638.         FIN BCNOEU;
  2639. *<== FIN DE BOUCLE SUR LES NOEUDS A AVANCER VIRTUELLEMENT =============|
  2640. *|=====================================================================|
  2641.  
  2642.  
  2643.         SI (BOOL.'XFEM' ET (EGA GDIME 3));
  2644. * EN XFEM 3D ON A LE RESULTAT UNIQUEMENT SOUS FORME DE CHAMELEM
  2645. * ON LE TRANSFORME DONC EN CHPO
  2646.             EFJ = INTE (EXTR GCHAM1 'MAILLAGE') ELTETA;
  2647.             MOD_MEC_RJ = REDU MOD_MEC_R EFJ;
  2648.             GCHPO1 = CHAN 'CHPO' GCHAM1 MOD_MEC_RJ 'MOYE';
  2649.             GCHPO1 = INT_COMP ELTETA GCHPO1 SUPTAB.'FRONT_FISSURE';
  2650.         SINON;
  2651. * EN STD ON REDUIT LE CHAMP RESULTAT AU FRONT DE FISSURE
  2652.             GCHPO1 = REDU GCHPO1 SUPTAB.'FRONT_FISSURE';
  2653.         FINSI;
  2654.  
  2655. * ON AJOUTE LES COMPOSANTES DANS L'EPAISSEUR DANS LE CAS DES COQUES
  2656.         SI BOOL.'COQ';
  2657.             GCHPO1 = NOMC 'GLOB' GCHPO1;
  2658.             GCHPO2 = NOMC 'SUPE' (GCHPO1*V_SUPE);
  2659.             GCHPO3 = NOMC 'MEDI' (GCHPO1*V_MOYE);
  2660.             GCHPO4 = NOMC 'INFE' (GCHPO1*V_INFE);
  2661.             GCHPO1 = GCHPO2 ET GCHPO3 ET GCHPO4 ET GCHPO1;
  2662.         FINSI;
  2663.  
  2664. *********************************************************************
  2665. ** STOCKAGE DES CHAMPS RESULTATS (+ logique qu'une table a priori) **
  2666. *********************************************************************
  2667. *CAS PASAPAS
  2668.         SI (BOOL.'PASAPAS');
  2669.             SUPTAB.'CHPO_RESULTATS'.IABC
  2670.                     = SUPTAB.'CHPO_RESULTATS'.IABC ET GCHPO1;
  2671.             SI (NON (VIDE GCHAM1) );
  2672.                 SUPTAB.'CHAM_RESULTATS'.IABC
  2673.                     = SUPTAB.'CHAM_RESULTATS'.IABC ET GCHAM1;
  2674.             FINSI;
  2675. *CAS RESOU
  2676.         SINON;
  2677.             SUPTAB.'CHPO_RESULTATS' = SUPTAB.'CHPO_RESULTATS' ET GCHPO1;
  2678.             SI (NON (VIDE GCHAM1) );
  2679.                 SUPTAB.'CHAM_RESULTATS' = SUPTAB.'CHAM_RESULTATS' ET GCHAM1;
  2680.             FINSI;
  2681.         FINSI;
  2682.  
  2683. * ON SE PREPARE A PARTIR...
  2685.         SI (BOOL.'PASAPAS' ET BOOL.'COQ');
  2687.         FINSI;
  2688.         SI (BOOL.'PASAPAS' ET (NBOU '>' 1));
  2690.         FINSI;
  2691.         SI (BOOL.'PASAPAS' ET (NBOU EGA 1) ET (NON BOOL.'COQ'));
  2692.             SI (EGA ((&BOUCEXT/10)*10) &BOUCEXT);
  2693.                 'SAUT' 'LIGNE';
  2694.             FINSI;
  2695.         FINSI;
  2696.  
  2697.  
  2698.     FIN BOUCMIX;
  2699. * FIN DE BOUCLE SUR LES INTEGRALES A CALCULER ========================*
  2700.  
  2701. ****************************************************
  2702. ******* FIN DE BOUCLE SUR LES PAS DE CALCUL ********
  2703. ****************************************************
  2704. FIN BOUCEXT;
  2705.  
  2706.  
  2707. ****************************************************
  2708. ** STOCKAGE DES RESULTATS DANS L OBJET EVOLUTIONS **
  2709. ****************************************************
  2710. * en plus de ce qui existe dans SUPTAB.'RESULTATS'
  2711. * et dans CHPO_RESULTATS
  2712. SI (BOOL.'PASAPAS' ET (NON BOOL.'PERSO1'));
  2713. * TITRE DES EVOLUTIONS
  2714.     SI BOOL.'DECOUPLAGE';
  2715.         CHATIT = CHAI 'F.I.C. Ki';
  2716.     SINON;
  2717.         CHAINT = MOBJ;
  2718.         SI BOOL.'J_DYNA';
  2719.             CHAINT = CHAI 'J DYNAMIQUE';
  2720.         FINSI;
  2721.         CHATIT = CHAI 'INTEGRALE' ' ' CHAINT;
  2722.     FINSI;
  2723.     CHATIT = CHAI CHATIT ' EN FONCTION DU TEMPS';
  2724.     TITR CHATIT;
  2725.     PINST = PROG;
  2726.     TINST = SUPTAB.'SOLUTION_PASAPAS'.'TEMPS';
  2727.     LCHPO1 = VIDE 'LISTCHPO';
  2728.     REPE IINST (DIME TINST);
  2729.         PINST = PINST ET (PROG TINST.(&IINST - 1));
  2730.         CHPO1 = SUPTAB.'CHPO_RESULTATS'.(&IINST - 1);
  2731.         LCHPO1 = LCHPO1 ET (SUIT CHPO1);
  2732.     FIN IINST;
  2733.     MCOMP = EXTR CHPO1 'COMP';
  2734.     SI (EGA (DIME MCOMP) 1);
  2735. * MCOMP EST UN LISTMOT, ON LE TRANSFORME EN MOT S'IL Y EN A QU'UN
  2736.         MCOMP = EXTR MCOMP 1;
  2737.     FINSI;
  2738.     SI ((EGA GDIME 2) OU BOOL.'COQ');
  2739. * EN 2D ET 3D COQUE L'INDICE EVOLUTION_RESULTATS EST UNE EVOLUTION
  2740.         POIN1 = (FF1 ELEM 1) POIN 1;
  2741.         EVO1 = EVOL 'TEMP' LCHPO1 PINST MCOMP POIN1;
  2742.         SUPTAB.'EVOLUTION_RESULTATS' = EVO1;
  2743.     SINON;
  2744. * SINON C'EST UNE TABLE INDICEE PAR LES POINTS DU FRONT
  2745.         REPE INOEU (NBEL FF1);
  2746.             POIN1 = (FF1 ELEM &INOEU) POIN 1;
  2747.             EVO1 = EVOL 'TEMP' LCHPO1 PINST MCOMP POIN1;
  2748.             SUPTAB.'EVOLUTION_RESULTATS'.POIN1 = EVO1;
  2749.         FIN INOEU;
  2750. * ET IL Y A LE RESULTAT GLOBAL
  2751.         PG = PROG ;
  2752.         REPE IINST (DIME TINST) ;
  2753.             G0 = SUPTAB.'RESULTATS'.(&IINST - 1).'GLOBAL' ;
  2754.             PG = PG ET (PROG G0) ;
  2755.         FIN IINST ;
  2756.         EVO1 = EVOL 'MANU' 'TEMPS' PINST MCOMP PG ;
  2757.         SUPTAB.'EVOLUTION_RESULTATS'.'GLOBAL' = EVO1 ;
  2758.     FINSI;
  2759. FINSI;
  2760.  
  2761.  
  2762. ********************************************************
  2763. **** STOCKAGE POUR UNE EVENTUELLE REPRISE DE CALCUL ****
  2764. ********************************************************
  2765. SI BOOL.'PASAPAS';
  2766.     SUPTAB.'OBJ1' = MOT SUPTAB.'OBJECTIF';
  2767.     SUPTAB.'IABC' = IABC;
  2768.     SUPTAB.'MAT_INST' = MAT_INST;
  2769.     SUPTAB.'END1' = ENERM;
  2770.     SI (((DIME MODPLA) '>' 0) ET BOOL.'THER');
  2771.         SUPTAB.'ENV1' = WVMIS;
  2772.     FINSI;
  2773.     SI (EGA ITYPEF 2);
  2774.         SUPTAB.'VDI1' = VDI1;
  2775.     FINSI;
  2776. FINSI;
  2777.  
  2778. ********************************************************
  2779. ************* OBJETS POUR REPRISE ET XFEM **************
  2780. ********************************************************
  2781. SI (EXIS SUPTAB 'COUCHE');
  2782.     SUPTAB.'COU1' = SUPTAB.'COUCHE';
  2783. FINSI;
  2784.  
  2785. *bp: soyons coherent... CHAMP_THETA est deja renseigne
  2786. SI (EXIS SUPTAB 'CHAMP_THETA');
  2787.     SUPTAB.'CHAMP_THET1' = SUPTAB.'CHAMP_THETA';
  2788. FINSI;
  2789. *OTER SUPTAB 'CHAMP_THETA';
  2790. OTER SUPTAB 'GRTHETA';
  2791. OTER SUPTAB 'DIVTHETA';
  2792.  
  2793. FINP;
  2794.  
  2795.  
  2796.  
  2797.  
  2798.  
  2799.  
  2800.  
  2801.  
  2802.  
  2803.  
  2804.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales