Télécharger calculer.procedur

Retour à la liste

Numérotation des lignes :

  1. * CALCULER PROCEDUR FANDEUR 14/10/10 21:15:12 8178
  2. 'DEBPROCEDURE' CALCULER ;
  3. *
  4. * CETTE PROCEDURE PERMET UNE SAISIE ASSISTEE DES DONNEES POUR
  5. * EFFECTUER UN CALCUL SIMPLE EN 2D ACTUELLEMENT
  6. *
  7. 'SAUTER' 'PAGE';
  8. 'SAUTER' 2 'LIGN' ;
  9. 'MESS' ' ************************* ';
  10. 'MESS' ' * PROCEDURE CALCULER * ';
  11. 'MESS' ' ************************* ';
  12. 'SAUTE' 2 'LIGN' ;
  13. 'MESS' ' CETTE PROCEDURE PERMET UNE SAISIE ASSISTEE DES DONNEES ';
  14. 'MESS' ' NECESSAIRES POUR EFFECTUER UN CALCUL ';
  15. 'MESS' ' EN ELASTICITE LINEAIRE BIDIMENSIONNELLE ';
  16. 'SAUTER' 2 'LIGN' ;
  17. 'MESS' ' DEFINITION DU TYPE DE CALCUL ' ;
  18. 'MESS' ' ---------------------------- ' ;
  19. 'SAUTER' 2 'LIGN' ;
  20. 'MESS' 'CALCUL EN CONTRAINTES PLANES (REPONDEZ 1)' ;
  21. 'MESS' 'OU EN DEFORMATIONS PLANES (REPONDEZ 2) ? ';
  22. 'REPETER' BLOC1;
  23. 'OBTENIR' REP*'ENTIER' ;
  24. 'SI' ('EGA' REP 1);
  25. 'OPTIO' 'MODEL' 'PLAN' 'CONTR';
  26. 'QUITTER' BLOC1;
  27. 'FINSI';
  28. 'SI' ('EGA' REP 2);
  29. 'OPTIO' 'MODEL' 'PLAN' 'DEFOR';
  30. 'QUITTER' BLOC1;
  31. 'FINSI';
  32. 'MESS' 'REPONDEZ PAR 1 OU 2';
  33. 'FIN' BLOC1 ;
  34. *
  35. MOTMOD = 'TEXT' 'MECANIQUE ELASTIQUE';
  36. *
  37. LICOUL='TABLE';
  38. LICOUL.1 LICOUL.2 LICOUL.3 LICOUL.4 LICOUL.5 LICOUL.6 LICOUL.7 =
  39. 'VERT' 'JAUNE' 'BLEU' 'TURQ' 'BLAN' 'ROSE' 'ROUGE' ;
  40. I=0;
  41. DEB=VRAI ;
  42. 'SAUTER' 'PAGE';
  43. 'SAUTER' 2 'LIGN' ;
  44. 'MESS' ' DEFINITION DES PROPRIETES MATERIELLES ' ;
  45. 'MESS' ' ------------------------------------- ' ;
  46. 'SAUTER' 2 'LIGN' ;
  47. 'REPETER' BLOC2;
  48. 'SI' ( 'EGA' I 0 ) ;
  49. 'MESS' 'DONNEZ LE NOM D UNE ZONE GEOMETRIQUE CONSTITUEE D UN ' ;
  50. 'MESS' ' MATERIAU HOMOGENE ' ;
  51. 'SAUTER' 1 'LIGN' ;
  52. 'FINSI' ;
  53. 'SI' ( > I 0 );
  54. 'SAUTER' 'PAGE' ;
  55. 'SAUTER' 3 'LIGN' ;
  56. 'MESS' 'DONNEZ LE NOM D UNE AUTRE ZONE GEOMETRIQUE CONSTITUEE D UN ' ;
  57. 'MESS' ' MATERIAU HOMOGENE ' ;
  58. 'SAUTER' 1 'LIGN' ;
  59. 'MESS' 'OU REPONDEZ NON SI IL N Y EN N A PLUS'; FINSI ;
  60. I = I + 1; 'SI' ( 'EGA' I 7) ; I = 1; 'FINSI';
  61. 'OBTENIR' ZONE ;
  62. 'SI' ('NON'('EGA' (TYPE ZONE) MAILLAGE )) ;
  63. 'QUITTER' BLOC2;
  64. 'FINSI';
  65. ZONE = ZONE 'COULEUR' LICOUL.I;
  66. MOD1='MODE' ZONE MOTMOD 'QUA4' 'TRI3' 'COQ2' 'TRI6' 'QUA8';
  67. *
  68. 'SAUTER' 2 'LIGN' ;
  69. 'MESS' 'DONNEZ LA VALEUR DU MODULE D YOUNG';
  70. Y=LIREFLOT 1E-30 1E30;
  71. 'MESS' 'DONNEZ LA VALEUR DU COEFFICIENT DE POISSON';
  72. P=LIREFLOT 0.0 0.4999999 ;
  73. MA1= 'MATE' MOD1 'YOUNG' Y 'NU' P;
  74. 'SI' DEB;
  75. TOTO = ZONE ;
  76. DEB=FAUX;
  77. MAT=MA1;
  78. MODT=MOD1 ;
  79. 'SINON' ;
  80. MAT =MAT 'ET' MA1;
  81. MODT=MODT 'ET' MOD1 ;
  82. TOTO = TOTO 'ET' ZONE ;
  83. 'FINSI';
  84. 'FIN' BLOC2 ;
  85. *
  86. * CALCUL DE LA RAIDEUR DE LA STRUCTURE
  87. RI = 'RIGIDITE' MODT MAT;
  88. *
  89. * ENTREE DES CONDITIONS AUX LIMITES
  90. 'OPTIO' 'COUL' LICOUL.7;
  91. 'SAUTER' 'PAGE';
  92. 'SAUTER' 2 'LIGN' ;
  93. IMIL = 0 ;
  94. 'MESS' ' DEFINITION DES CONDITIONS AUX LIMITES ' ;
  95. 'MESS' ' ------------------------------------- ' ;
  96. 'SAUTER' 2 'LIGN' ;
  97. 'REPETER' BLOC3;
  98. 'SI' ( IMIL 'EGA' 0 ) ;
  99. 'MESS' 'DONNEZ LE NOM D UNE ZONE GEOMETRIQUE OU IL FAUT IMPOSER ' ;
  100. 'MESS' ' DES BLOCAGES ' ;
  101. 'FINSI' ;
  102. 'SI' ( IMIL > 0 ) ;
  103. 'SAUTER' 'PAGE' ;
  104. 'SAUTER' 3 'LIGN' ;
  105. 'MESS' 'DONNEZ LE NOM D UNE AUTRE ZONE GEOMETRIQUE OU IL FAUT IMPOSER';
  106. 'MESS' ' DES BLOCAGES ' ;
  107. 'SAUTER' 'LIGN' ;
  108. 'MESS' 'OU REPONDEZ NON SI IL N Y EN N A PLUS';
  109. 'FINSI' ;
  110. IMIL = IMIL + 1 ;
  111. TYP= 'TYPE' (0. 0. );
  112. 'OBTENIR' ZONE ;
  113. 'SI' ('ET' ('NON'('EGA' ('TYPE' ZONE) MAILLAGE ))
  114. ('NON'('EGA' ('TYPE' ZONE) TYP)));
  115. 'QUITTER' BLOC3;
  116. 'FINSI';
  117. 'MESS' 'DONNEZ LE TYPE DE BLOCAGES. LES REPONSES POSSIBLES SONT :';
  118. 'SAUTER' 'LIGN' ;
  119. 'MESS' ' DEPL ... POUR BLOQUER TOUTES LES TRANSLATIONS';
  120. 'MESS' ' ROTA ... POUR BLOQUER TOUTES LES ROTATIONS';
  121. 'MESS' ' UX ... POUR BLOQUER LES TRANSLATIONS SELON X ' ;
  122. 'MESS' ' UY ... POUR BLOQUER LES TRANSLATIONS SELON Y ' ;
  123. 'REPETER' BLOC4;
  124. 'OBTENIR' TYPE*'MOT';
  125. 'SI' ('EGA' TYPE 'DEPL');
  126. RI1= 'BLOQUER' ZONE 'DEPLA';
  127. RI=RI 'ET' RI1;
  128. 'QUITTE' BLOC4;
  129. 'FINSI';
  130. 'SI' ('EGA' TYPE 'ROTA');
  131. RI1= 'BLOQUER' ZONE 'ROTA' ;
  132. RI=RI 'ET' RI1;
  133. 'QUITTER' BLOC4;
  134. 'FINSI';
  135. 'SI' ('EGA' TYPE 'UX' );
  136. RI1= 'BLOQUER' ZONE 'UX' ;
  137. RI=RI 'ET' RI1;
  138. 'QUITTER' BLOC4;
  139. 'FINSI';
  140. 'SI' ('EGA' TYPE 'UY' );
  141. RI1= 'BLOQUER' ZONE 'UY' ;
  142. RI=RI 'ET' RI1;
  143. 'QUITTER' BLOC4;
  144. 'FINSI';
  145. 'MESS' 'DONNEZ UNE REPONSE CORRECTE ...';
  146. 'FIN' BLOC4;
  147. 'FIN' BLOC3;
  148. *
  149. 'SAUTER' 'PAGE';
  150. 'SAUTER' 2 'LIGN' ;
  151. 'MESS' ' DEFINITION DES FORCES PONCTUELLES ' ;
  152. 'MESS' ' --------------------------------- ' ;
  153. 'SAUTER' 2 'LIGN' ;
  154. 'REPETER' DEFFORC;
  155. DEB=VRAI;
  156. 'REPETE' BLOC5;
  157. 'SI' DEB;
  158. 'MESS' 'DONNEZ LE NOM D UN POINT SUR LEQUEL APPLIQUER UNE FORCE ';
  159. 'SINON'; 'SAUTER' 'PAGE'; 'SAUTER' 2 'LIGN' ;
  160. 'MESS' 'DONNEZ LE NOM D UN AUTRE POINT SUR LEQUEL APPLIQUER UNE FORCE ';
  161. 'SAUTER' LIGN ;
  162. 'MESS' 'OU REPONDEZ NON SI IL N Y EN A PLUS';
  163. 'FINSI' ;
  164. 'OBTENIR' ZONE*'POINT';
  165. 'SI' ('EGA' ZONE 'NON');
  166. 'QUITTER' BLOC5;
  167. 'FINSI';
  168. 'SAUTER' 'LIGN' ;
  169. 'MESS' 'DONNEZ LES 2 COMPOSANTES DU VECTEUR FORCE ' ;
  170. 'SAUTER' 'LIGN' ;
  171. 'MESS' 'PAR EXEMPLE : 2.45 -0.51 ' ;
  172. 'OBTENIR' X*'FLOTTANT' Y*'FLOTTANT';
  173. FO = 'FORCE' (X Y) ZONE;
  174. 'SI' DEB;
  175. FOR = FO ;
  176. DEB=FAUX;
  177. 'SINON';
  178. FOR = FOR 'ET' FO;
  179. 'FINSI';
  180. 'FIN' BLOC5;
  181. 'SAUTER' 'PAGE';
  182. 'SAUTER' 2 'LIGN' ;
  183. 'MESS' ' VISUALISATION DES DONNEES ' ;
  184. 'MESS' ' ------------------------- ' ;
  185. 'REPETE' DESFO;
  186. 'SAUTER' 2 'LIGN' ;
  187. 'MESS' 'DONNEZ LE COEFFICIENT D AMPLIFICATION DES FORCES POUR LE TRACE';
  188. CO1 = LIREFLOT 1E-30 1E30;
  189. V1='VECTEUR' FOR CO1 'FX' 'FY' 'ROUGE';
  190. * IL FAUDRAIT EXTRAIRE DE RI LE MAILLAGE
  191. 'TRAC' 'FACE' V1 RI ;
  192. 'SAUTER' 3 'LIGN' ;
  193. 'MESS' 'VOULEZ-VOUS CHANGER LE COEFFICIENT D AMPLIFICATION ? (OUI/NON)';
  194. 'OBTENIR' REP*'MOT';
  195. 'SI' ( 'EGA' REP 'NON');
  196. 'QUITTER' DESFO;
  197. 'FINSI';
  198. 'FIN' DESFO;
  199. 'SAUTE' 'LIGN' ;
  200. 'MESS' 'VOULEZ-VOUS CORRIGER LES FORCES ? (OUI/NON)';
  201. 'OBTENIR' REP*'MOT';
  202. 'SI' ('EGA' REP 'NON');
  203. 'QUITTER' DEFFORC;
  204. 'FINSI';
  205. 'FIN' DEFFORC;
  206. 'SAUTER' 'LIGN' ;
  207. 'MESS' 'VOULEZ-VOUS INTERROMPRE LE CALCUL ? (OUI NON)';
  208. 'OBTENIR' REP*'MOT';
  209. 'REPETER' FINCAL 1;
  210. 'SI' ('EGA' REP 'OUI');
  211. 'MESS' 'INTERRUPTION DU CALCUL';
  212. 'QUITTER' FINCAL;
  213. 'FINSI';
  214. 'SAUTER' 'PAGE' ;
  215. 'SAUTER' 2 'LIGN' ;
  216. 'MESS' 'DEBUT DE LA RESOLUTION ' ;
  217. DE='RESOU' RI FOR;
  218. 'SAUTE' 2 'LIGN' ;
  219. 'MESS' 'FIN DU CALCUL DES DEPLACEMENTS';
  220. RE='REAC' DE RI;
  221. 'SAUTER' 2 'LIGN' ;
  222. 'MESS' 'FIN DU CALCUL DES REACTIONS AUX APPUIS ';
  223. SIG = 'SIGMA' MODT MAT DE;
  224. 'SAUTER' 2 'LIGN' ;
  225. 'MESS' 'FIN DU CALCUL DES CONTRAINTES ';
  226. VMIC='VMISES' MODT SIG;
  227. 'SAUTER' 'PAGE';
  228. 'SAUTER' 2 'LIGN' ;
  229. 'MESS' ' VISUALISATION DES RESULTATS' ;
  230. 'MESS' ' --------------------------- ' ;
  231. 'REPETE' DESTOT;
  232. 'SAUTER' 2 'LIGN' ;
  233. 'MESS' ' DONNEZ LE COEFFICIENT D AMPLIFICATION DE LA DEFORMEE';
  234. CO2 = LIREFLOT 1E-30 1E30;
  235. V2='VECTEUR' RE CO1 'FX' 'FY' 'BLEU';
  236. DEF='DEFOR' TOTO DE (V1 'ET' V2) CO2 'JAUN';
  237. 'TRAC' MODT VMIC DEF;
  238. 'SAUTER' 2 'LIGN' ;
  239. 'MESS' 'VOULEZ-VOUS CHANGER LE COEFFICIENT D AMPLIFICATION ?(OUI/NON)';
  240. 'OBTENIR' REP*'MOT';
  241. 'SI' ( 'EGA' REP 'NON') ;
  242. 'QUITTER' DESTOT;
  243. 'FINSI';
  244. 'FIN' DESTOT;
  245. 'FIN' FINCAL;
  246. 'SAUTER' 'PAGE';
  247. 'SAUTER' 4 'LIGN' ;
  248. 'MESS' ' ****************************************** ';
  249. 'MESS' ' * FIN DE LA PROCEDURE "" CALCULER "" * ';
  250. 'MESS' ' ****************************************** ';
  251. 'FINPROC';
  252.  
  253.  
  254.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales