Télécharger @rccmtrv.procedur

Retour à la liste

Numérotation des lignes :

  1. * @RCCMTRV PROCEDUR MO 97/11/28 21:16:36 2950
  2. * @RCCMTRV PROCEDURE 96/10/01 09:10:00
  3. * ----------------------------------------------------------------------
  4. ****** PROCEDURE @RCCMTRV ******
  5. * ----------------------------------------------------------------------
  6. *
  7. * CETTE PROCEDURE PERMET D'EFFECTUER LE CALCUL DU TRESCA ET DU
  8. * VON MISES A PARTIR DES CONTRAINTES ELEMENTAIRES
  9. * 6 valeurs a rentre :
  10. * -----> 4 valeurs pour un modele 2D + 2 valeurs nulles
  11. * -----> 6 valeurs pour un modele 3D
  12. *
  13. * ----------------------------------------------------------------------
  14. *
  15. * LES DONNEES SONT :
  16. * ----> les 4 ou 6 contraintes elementaires
  17. *
  18. * EN SORTIE :
  19. * ----> le TRESCA
  20. * ----> le VON MISES
  21. *
  22. * ----------------------------------------------------------------------
  23. * PAR Jean-Marc PIETTE
  24. * ----------------------------------------------------------------------
  25. 'DEBPROC' @RCCMTRV SX*FLOTTANT SY*FLOTTANT SZ*FLOTTANT SXY*FLOTTANT
  26. SYZ/FLOTTANT SZX/FLOTTANT ;
  27. SI (NON (EXISTE SYZ)) ;
  28. SYZ = 0. ;
  29. FINSI ;
  30. SI (NON (EXISTE SZX)) ;
  31. SZX = 0. ;
  32. FINSI ;
  33. CC = SX + SY + SZ / 3. ;
  34. SG1 = SX - CC ;
  35. SG2 = SY - CC ;
  36. SG3 = SZ - CC ;
  37.  
  38. C2 = SG1*SG1 +(SG2*SG2)+(SG3*SG3) * .5;
  39. C2= SXY*SXY+(SYZ*SYZ)+(SZX*SZX) + C2;
  40. C3A = SG2*SG3 - (SYZ*SYZ) * SG1 ;
  41. C3B = SYZ*SZX - (SXY*SG3) * SXY;
  42. C3C = SXY*SYZ - (SG2*SZX) * SZX;
  43. C3 = C3A + C3B + C3C ;
  44. T = C2 * 2. / 3. ** .5 ;
  45. SI (T < 1.E-10) ;
  46. XTRES = 0. ;
  47. XVMIS = 0. ;
  48. RESPRO XTRES ;
  49. RESPRO XVMIS ;
  50. QUITTER @RCCMTRV ;
  51. FINSI ;
  52. A = C3 * (2. ** 0.5) / ( T*T*T ) ;
  53. SI ( ( ABS A ) > 1. ) ;
  54. A = SIGNE 'FLOTTANT' A ;
  55. FINSI ;
  56. TCS = ( 1. - ( A * A ) ) ** 0.5 ;
  57. A = ATG TCS A;
  58. A = A / 3. ;
  59. T = T * (2 ** 0.5) ;
  60. * ----------------------------------------------------------------------
  61. * calcul des contraintes principales
  62. * ----------------------------------------------------------------------
  63. AUX = 120. ;
  64. AA3 = A + AUX ;
  65. AA4 = A - AUX ;
  66. S1 = COS A * T + CC;
  67. S2 = COS AA3 * T + CC;
  68. S3 = COS AA4 * T + CC;
  69. SSS = PROG S1 S2 S3 ;
  70. * ----------------------------------------------------------------------
  71. * calcul du TRESCA et du VON MISES
  72. * ----------------------------------------------------------------------
  73. XTMAX = MAXI SSS ;
  74. XTMIN = MINI SSS ;
  75. XTRES = XTMAX - XTMIN ;
  76. XVMIS = ( ( S1 * S1 ) + ( S2 * S2 ) + ( S3 * S3 ) - ( S1 * S2 )
  77. - ( S2 * S3 ) - ( S1 * S3 ) ) ** .5 ;
  78. RESPRO XTRES ;
  79. RESPRO XVMIS ;
  80. FINPROC ;
  81.  
  82.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales