Télécharger @rccmco2.procedur

Retour à la liste

Numérotation des lignes :

  1. * @RCCMCO2 PROCEDUR CHAT 03/09/23 21:15:03 4697
  2. DEBPROC @RCCMCO2 NNE*ENTIER NNC*ENTIER PP1*POINT PP2*POINT
  3. NSEG*ENTIER SIG1*MCHAML MOD1*MMODEL EPAI*FLOTTANT
  4. GRAPL*LOGIQUE ECRI*LOGIQUE NOM*MOT PP3*POINT ;
  5. * ----------------------------------------------------------------------
  6. *
  7. * CETTE PROCEDURE PERMET D'EFFECTUER UNE COUPE DANS UN MODELE 2D OU 3D
  8. * POUR OBTENIR LES CONTRAINTES ELEMENTAIRES A CHAQUE POINT ET DANS
  9. * LE REPERE LOCAL DE CELLE-CI.
  10. * CETTE PROCEDURE PERMET EGALEMENT LE TRACE DE CHAQUE CONTRAINTE
  11. * ELEMENTAIRE ET DE SA DECOMPOSITION LE LONG DE CETTE COUPE PAR
  12. * APPEL A LA PROCEDURE DECOMP
  13. *
  14. * ----------------------------------------------------------------------
  15. *
  16. * LES DONNEES SONT :
  17. * ----> le numero d'etat
  18. * ----> le numero de la coupe
  19. * ----> les 2 points extremes de la coupe
  20. * ----> le nombre de sous-divisions de la coupe
  21. * ----> le champ de contraintes aux elements (points de GAUSS)
  22. * ----> la geometrie
  23. * ----> l'epaisseur du trait de la coupe lors du trace
  24. * ----> le Logique GRAPL permettant ou non les traces
  25. * ----> le mot NOM (optionnel) permettant ou non la sortie d'un
  26. * fichier pour NOCLIB
  27. * ----> Pour le 3D PP3 DIRECTION (type point) definissant
  28. * l axe OY du repere ( OX etant le segment d appui ) en 2D
  29. * il ne servira a rien ( mais obligatoire tout de meme
  30. * EN SORTIE :
  31. *
  32. * ----> le champ de contraintes dans la coupe
  33. * ----> les contraintes elementaires x distances a chaque point
  34. * par rapport au milieu de la coupe
  35. * ----> les contraintes 'TOT..' aux extremites de la coupe
  36. * ----> les evolutions la decomposition de chaque contrainte elementaire
  37. * la coupe si GRAPL est VRAI
  38. *
  39. * ----> eventuellement un fichier pour NOCLIB
  40. * ( voir NOTA ci-dessous )
  41. *
  42. * %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  43. *
  44. * NOTA : Les contraintes du fichier NOCLIB sont dans le repere General
  45. *
  46. *
  47. * %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  48. * ----------------------------------------------------------------------
  49. * PAR Jean-Marc PIETTE
  50. * ---------------------------------------------------------------------
  51. 'OPTION' 'ELEM' 'SEG2' ;
  52. LIG2 = D NSEG PP1 PP2 'COUL' 'ROUG' ;
  53. NBDC = LIG2 'NBNO' ;
  54. IDIM = 'VALE' DIME ;
  55. *
  56. 'SI' ( 'EGA' IDIM 2 ) ;
  57. 'OPTION' 'ELEM' 'QUA4' ;
  58. VECT = PP2 MOINS PP1 ;LONG = NORME VECT ;
  59.  
  60. 'SI' GRAPL ;
  61. PTC = PP1 PLUS ( ( VECT / LONG ) * EPAI ) ;
  62. PTD = PTC 'TOURNER' -90. PP1 ;
  63. PTE = PTC 'TOURNER' 90. PP1 ;
  64. PTF = PTD 'PLUS' VECT ;
  65. PTG = PTE 'PLUS' VECT ;
  66. MAILCOU = PTD DROI 1 PTF DROI 1 PTG DROI 1 PTE DROI 1 ;
  67. L1M = MAILCOU elem 'COMP' PTD PTF ;
  68. L2M = MAILCOU elem 'COMP' PTF PTG ;
  69. L3M = MAILCOU elem 'COMP' PTG PTE ;
  70. L4M = MAILCOU elem 'COMP' PTE PTD ;
  71. MAILCOU = L1M L2M L3M L4M DALLER 'PLAN' ;
  72. MAILCOU = MAILCOU 'COULEUR' 'ROSE' ;
  73. MAILZ = 'EXTR' MOD1 MAIL ;
  74. TRACER ( MAILZ ET MAILCOU ET (LIG2 COUL ROSE) ) ;
  75. 'FINSI' ;
  76. CHAMRT = RTENS SIG1 MOD1 VECT ;
  77. CHAMRT = CHAN 'CHPO' MOD1 CHAMRT ;
  78. CHAMRT = CHAN 'CHAM' CHAMRT MOD1 'NOEUD' ;
  79. SINON ;
  80. * ----------------------------------------------------------------------
  81. * Le calcul est donc tridimensionnel
  82. * ----------------------------------------------------------------------
  83. OPTION ELEMENT CUB8 ;
  84. V1 = ( PP2 MOINS PP1 ) ;
  85. 'SI' GRAPL ;
  86. V2 = PP3 ;
  87. VH1 = V2 PVEC V1 ;
  88. VH1 = VH1 * EPAI / ( NORME VH1 ) ;
  89. PH1 = PP1 PLUS VH1 ;
  90. PH2 = PP2 PLUS VH1 ;
  91. D1 = PP1 DROI 1 PP2 ;
  92. D2 = PP2 DROI 1 PH2 ;
  93. D3 = PH2 DROI 1 PH1 ;
  94. D4 = PH1 DROI 1 PP1 ;
  95. SS = DALL D1 D2 D3 D4 'PLAN' ;
  96. VO1 = VOLU SS 8 ROTA 179.99 PP1 PP2 ;
  97. VO2 = VOLU SS 8 ROTA -179.99 PP1 PP2 ;
  98. MAILCOU = VO1 ET VO2 ;
  99. MAILCOU = MAILCOU COULEUR ROSE ;
  100. mailz = extr MOD1 mail ;
  101. TRACER ( MAILZ ET MAILCOU ET (LIG2 COUL ROSE) ) ;
  102. 'FINSI' ;
  103. V1 = V1/(NORM V1) ;
  104. V3 = V1 PVEC PP3 ;V3 = V3/ ( NORME V3) ;
  105. V2 = V3 PVEC V1 ;
  106. CHAMRT = RTENS SIG1 MOD1 V1 V2 ;
  107. CHAMRT = CHAN 'CHPO' MOD1 CHAMRT ;
  108. CHAMRT = CHAN 'CHAM' CHAMRT MOD1 'NOEUD' ;
  109. FINSI ;
  110. *-----------------------------------------------------------------------
  111. * projection du champ de contraintes sur le segment d appui
  112. *-----------------------------------------------------------------------
  113.  
  114.  
  115. CHCOU = 'PROI' LIG2 CHAMRT -.01;
  116. NPRO = ('EXTR' CHCOU MAILLAGE) NBNO ;
  117. 'SI' ('EGA' ( NSEG+1) NPRO ) ;
  118.  
  119. SI ECRI ;
  120. LIST CHCOU ;
  121. FINSI ;
  122. LCOMP = 'EXTR' CHCOU COMP ;NCC = 'DIME' LCOMP ;
  123. * ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  124. * eventuel fichier pour NOCLIB
  125. *~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  126. SI ( NEG NOM 'BLANC' ) ;
  127. NBNDC = LIG2 NBNO ;
  128. VA_IMP = 'VALE' IMPR ;
  129. OPTION 'IMPR' NOM ;
  130. MESSAGE ' COORDONNEES GLOBALES ----> NB DE POINTS = '
  131. NBNDC ;
  132. REPETER BOUCLN NBNDC ;
  133. I = &BOUCLN ;
  134. P = LIG2 POIN I ;
  135. VECTD = P MOINS PP1 ;
  136. LONGD = NORME VECTD ;
  137. *~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  138. * ecriture des coordonnees
  139. *~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  140. MESSAGE LONGD ' 0. 0. ' ;
  141. FIN BOUCLN ;
  142. * ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  143. * ecriture des contraintes elementaires pour NOCLIB
  144. *~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  145. TTT1 = CHAIN ' COUPE No ' NNC ' ' ;
  146. repeter bib NCC;
  147. TTT1 = CHAIN ttt1 (extr LCOMP &bib) ' ' ;
  148. fin bib ;
  149. MESSAGE TTT1 ;
  150. REPETER BOUCLC ( NBNDC ) ;
  151. I = &BOUCLC ;
  152. P = LIG2 POIN I ;
  153. TTT2 = CHAIN (EXTRAIRE CHCOU (extr LCOMP 1) P) ' ' ;
  154. repeter bib (NCC - 1);
  155. TTT2 = CHAIN TTT2 (EXTRAIRE CHCOU (extr LCOMP ( &bib + 1)) P) ' ' ;
  156. fin bib ;
  157. MESSAGE TTT2 ;
  158. FIN BOUCLC ;
  159. 'OPTION' 'IMPR' VA_IMP ;
  160. FINSI ;
  161. 'SI' GRAPL ;
  162. LTRAC = 'MOTS' ETOI CARR TRIA LOSA CERC CROI ;
  163. LCOU = 'MOTS' BLAN VERT ROUG BLEU ROSE TURQ ;
  164. *
  165. TITRE 'Contraintes segment appui no' nnc 'Etat' nne ;
  166.  
  167. TTTT = TABLE ;
  168. TABLEG = TABLE ;
  169. TTTT.'TITRE' = TABLEG ;
  170. 'REPETER' BIB NCC ;
  171. CCC = 'EXTR' LCOMP &BIB ;
  172. TTTT.&BIB= 'CHAIN' 'MARQ ' ('EXTR' LTRAC &BIB ) ;
  173. TABLEG.&BIB = CCC ;
  174. 'SI' ( 'EGA' &BIB 1) ;
  175. EVS = 'EVOL' ('EXTR' LCOU &BIB) 'CHPO' CHCOU CCC LIG2 ;
  176. 'SINON' ;
  177. EVS = EVS ET
  178. ('EVOL' ('EXTR' LCOU &BIB) 'CHPO' CHCOU CCC LIG2) ;
  179. 'FINSI' ;
  180. 'FIN' BIB ;
  181. *
  182. 'DESS' EVS 'LEGE' TTTT AXES;
  183. 'FINSI' ;
  184.  
  185. *----------------------------------------------------------------------
  186. * decomposition en membrane flexion etc --- des contraintes
  187. *----------------------------------------------------------------------
  188. TABV = PMPB CHCOU LIG2 GRAPL nnc nne ;
  189. 'SINON' ;
  190. MESS '*---------------------------------------------------*' ;
  191. MESS ' POINTS DU SEGMENT D APPUI ' NNC ' HORS DU DOMAINE ' ;
  192. MESS '*---------------------------------------------------*' ;
  193. TABV= 'ARRET' ;
  194. 'FINSI' ;
  195. FINPROC TABV ;
  196.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales