Télécharger @clpd.procedur

Retour à la liste

Numérotation des lignes :

  1. * @CLPD PROCEDUR PV 09/12/24 10:30:57 6593
  2. ****************************************************
  3. ****************************************************
  4. *
  5. * PROCEDURE POUR CONDITIONS AUX LIMITES
  6. *
  7. * PERIODIQUE EN DEFORMATION IMPOSEE
  8. *
  9. * L.GELEBART, G. TREGO 10/06
  10. ****************************************************
  11. *****************************************************
  12. DEBPROC @CLPD MAIL0*MAILLAGE DEF0*TABLE;
  13. EXX = DEF0 . 1; EYY = DEF0 . 2; EZZ = DEF0 . 3;
  14. EXY = DEF0 . 4; EXZ = DEF0 . 5; EYZ = DEF0 . 6;
  15. MOD0 = MODE MAIL0 MECANIQUE ELASTIQUE;
  16. *
  17. * Identification des points et surfaces exterieures
  18. * pour application des CL
  19. *=====================================================
  20. ENVE0 = ENVE MAIL0;
  21. elim0 = 1.e-4;
  22. ENVE_PT0 = CHANGE ENVE0 POI1;
  23. XMAX = MAXI (COOR 1 ENVE0);XMIN = MINI (COOR 1 ENVE0);
  24. YMAX = MAXI (COOR 2 ENVE0);YMIN = MINI (COOR 2 ENVE0);
  25. ZMAX = MAXI (COOR 3 ENVE0);ZMIN = MINI (COOR 3 ENVE0);
  26. LX0 = XMAX - XMIN; LY0 = YMAX - YMIN; LZ0 = ZMAX - ZMIN;
  27. PXMIN = ENVE_PT0 POIN 'PLAN'
  28. (XMIN 0. 0.) (XMIN 1. 0.) (XMIN 0. 1.) (LX0 * elim0);
  29. PYMIN = ENVE_PT0 POIN 'PLAN'
  30. (0. YMIN 0.) (1. YMIN 0.) (0. YMIN 1.) (LY0 * elim0);
  31. PZMIN = ENVE_PT0 POIN 'PLAN'
  32. (0. 0. ZMIN) (1. 0. ZMIN) (0. 1. ZMIN) (LZ0 * elim0);
  33. *
  34. SURFX0 = ENVE0 ELEM APPUYE STRICTEMENT PXMIN;
  35. SURFY0 = ENVE0 ELEM APPUYE STRICTEMENT PYMIN;
  36. SURFZ0 = ENVE0 ELEM APPUYE STRICTEMENT PZMIN;
  37. SURFX1 = SURFX0 PLUS (LX0 0. 0.);
  38. SURFY1 = SURFY0 PLUS (0. LY0 0.);
  39. SURFZ1 = SURFZ0 PLUS (0. 0. LZ0);
  40. elim SURFX1 MAIL0 (LX0 * elim0);
  41. elim SURFY1 MAIL0 (LX0 * elim0);
  42. elim SURFZ1 MAIL0 (LX0 * elim0);
  43. *trac (SURFX0 ET SURFY0 ET SURFZ0);
  44. *trac (SURFX1 ET SURFY1 ET SURFZ1);
  45. *
  46. A1 = ENVE_PT0 POIN PROC (XMIN YMIN ZMIN);
  47. *
  48. * Blocage du mvt de corps rigide
  49. *===========================================
  50. BL1 = BLOQUE UX UY UZ A1;
  51. *BL1 = @CORIGI ENVE0;
  52. *
  53. * Application des conditions de periodicite
  54. *===========================================
  55. RIGCLP = BL1;
  56. *deplacements imposes*
  57. *faces perpendiculaires a X
  58. CLP1X = RELA 1. UX SURFX1 - 1. UX SURFX0;
  59. depCLP1X = DEPI CLP1X (EXX * LX0);
  60. CLP1Y = RELA 1. UY SURFX1 - 1. UY SURFX0;
  61. depCLP1Y = DEPI CLP1Y (EXY * LX0);
  62. CLP1Z = RELA 1. UZ SURFX1 - 1. UZ SURFX0;
  63. depCLP1Z = DEPI CLP1Z (EXZ * LX0);
  64. CLP1 = CLP1X ET (CLP1Y ET CLP1Z);
  65. depCLP1 = depCLP1X ET (depCLP1Y ET depCLP1Z);
  66. *faces perpendiculaires a Y
  67. CLP2X = RELA 1. UX SURFY1 - 1. UX SURFY0;
  68. depCLP2X = DEPI CLP2X (EXY * LY0);
  69. CLP2Y = RELA 1. UY SURFY1 - 1. UY SURFY0;
  70. depCLP2Y = DEPI CLP2Y (EYY * LY0);
  71. CLP2Z = RELA 1. UZ SURFY1 - 1. UZ SURFY0;
  72. depCLP2Z = DEPI CLP2Z (EYZ * LY0);
  73. CLP2 = CLP2X ET (CLP2Y ET CLP2Z);
  74. depCLP2 = depCLP2X ET (depCLP2Y ET depCLP2Z);
  75. *faces perpendiculaires Z
  76. CLP3X = RELA 1. UX SURFZ1 - 1. UX SURFZ0;
  77. depCLP3X = DEPI CLP3X (EXZ * LZ0);
  78. CLP3Y = RELA 1. UY SURFZ1 - 1. UY SURFZ0;
  79. depCLP3Y = DEPI CLP3Y (EYZ * LZ0);
  80. CLP3Z = RELA 1. UZ SURFZ1 - 1. UZ SURFZ0;
  81. depCLP3Z = DEPI CLP3Z (EZZ * LZ0);
  82. CLP3 = CLP3X ET (CLP3Y ET CLP3Z);
  83. depCLP3 = depCLP3X ET (depCLP3Y ET depCLP3Z);
  84. *
  85. DEPTOT = depCLP1 et (depCLP2 et depCLP3 );
  86. RIGCLP = RIGCLP et (CLP1 et (CLP2 et CLP3));
  87. *
  88. FINPROC RIGCLP DEPTOT;
  89. *********************************************
  90. * FIN DE LA PROCEDURE CLPD
  91. *********************************************
  92.  
  93.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales