Procédures | Cast3M

* @USINIB   PROCEDUR  MB234859  23/12/21    21:15:04     11815          
***********************************************************************
*                         PROCEDURE @USINIB
*
*   Procedure qui initialise les indices de la table 'BOITES_USURE' ou
*   seront stockes les resultats de calcul
*
* Entrees :
*   T1    : Table de PASAPAS
*   ID_BU : Entier donnant le numero de la BOITE D'USURE a considerer
*
* Appelee par @USURE
*
***********************************************************************
'DEBP' @USINIB T1*'TABLE' ID_BU*'ENTIER' ;
*
  BOITE_US = T1.'BOITES_USURE' ;
  SUR_APPL = BOITE_US. ID_BU .'SURFACE_APPLICATION' ;
  'SI' ('NON' ('EXIS' (BOITE_US. ID_BU) 'CYCLE_DE_FRETTING')) ;
*
*----------------------------------------------------------------------*
*   - INITIALISATIONS DE DEBUT DE CALCUL                               *
*----------------------------------------------------------------------*
*   Informations communes aux boites d'usure
    'SI' ('EGA' ID_BU 1) ;
*
*     Verification qu'il y a un nombre pair d'increments a calculer
      NbIncCy = 'ENTI' (BOITE_US.'DONNEES'.'INCREMENTS_CYCLE') ;
      'SI' ('NEG' (@MOD NbIncCy 2) 0) ;
        'MESS' 'Nombre d increment par cycle incorrect' ;
        'ERRE' 21 ;
      'FINSI' ;
* 
*     Compteur cycle, increment par cycle, traces debug
      BOITE_US.'INFOS' = 'TABLE' ;
      BOITE_US.'INFOS'.'INDICE_CYCLE_ACTUEL' = 1 ;
      BOITE_US.'INFOS'.'INDICE_INCREMENT_ACTUEL' = 1 ;
      BOITE_US.'INFOS'.'NB_INCREMENTS_PAR_CYCLE' = NbIncCy ;
      BOITE_US.'INFOS'.'NB_CYCLES_RESTANTS' = 
        'ENTI' (BOITE_US.'DONNEES'.'NB_CYCLES');
      BOITE_US.'INFOS'.'TRACE_DEBUG' = FAUX ;
      BOITE_US.'INFOS'.'UNSURT' = 1. '/' BOITE_US.'DONNEES'.'PERIODE' ;
*   
*     Doit-on recalculer les pas de temps
      BOITE_US.'INFOS'.'CALCUL_PAS' = VRAI ;
      'SI' ('EXIS' BOITE_US.'DONNEES' 'CALCUL_TEMPS') ;
        BOITE_US.'INFOS'.'CALCUL_PAS' = BOITE_US.'DONNEES'.'CALCUL_TEMPS';
      'FINSI' ; 
*    
*     Dimension du calcul effectue
      BOITE_US.'INFOS'.'ITRID' = 'EGA' ('VALE' 'DIME') 3 ;
*    
*     Listes de composantes et de valeurs (pour @USCALC)
      MODEME = 'EXTR' T1.'MODELE' 'FORM' 'MECANIQUE' ;
      LCOMPF = 'EXTR' MODEME 'FORC' ;
      BOITE_US.'INFOS'.'LFORCE' = LCOMPF ;
      BOITE_US.'INFOS'.'LDEPLA' = 'EXTR' MODEME 'DEPL' ;
      BOITE_US.'INFOS'.'LVALE0' = 'PROG' ('DIME' LCOMPF) * 0. ;
      BOITE_US.'INFOS'.'LVALE1' = 'PROG' ('DIME' LCOMPF) * 1. ;
      BOITE_US.'INFOS'.'LSCAL'  = 'MOTS' ('DIME' LCOMPF) * 'SCAL' ;
*    
*     Informations sur le chargement en deplacement impose
      CGDEPI = 'EXTR' TAB1.'CHARGEMENT' 'DIMP' ;
      CHDEPI = 'EXTR' CGDEPI 'CHAM' ;
      EVDEPI = 'EXTR' CGDEPI 'EVOL' ;
*     --- Instant de debut du chargement
      ORDEPI = 'EXTR' EVDEPI 'ORDO' ;
      MASQUZ = 'MASQ' ORDEPI 'DIFFERENT' 0. ;
      POSIUN = 'POSI' 1. 'DANS' MASQUZ ;
      TDEDEP = 'EXTR' ('EXTR' EVDEPI 'ABSC') (POSIUN - 1) ;
      BOITE_US.'INFOS'.'T_DEBUT_DEPI' = TDEDEP ;
*     --- Valeur max. du chargement
      ORDMAX = 'MAXI' ORDEPI ;
      FLXVAL = 'EXTR' ('EXTR' CHDEPI 'VALE') 1 ;
      BOITE_US.'INFOS'.'DEPLA_IMPOSE' = ORDMAX '*' FLXVAL ;
*     --- Composante concernee
      MDEP = 'EXTR' CHDEPI 'MAIL' ;
      MBLO = 'EXTR' TAB1.'BLOCAGES_MECANIQUES' 'MAIL' ;
      ELTR = MBLO 'ELEM' 'CONTENANT' (MDEP 'POIN' 1) ;
      RIGD = 'REDU' TAB1.'BLOCAGES_MECANIQUES' ELTR ;
      BOITE_US.'INFOS'.'COMP_DEPI' = 'EXTR' ('EXTR' RIGD 'COMP') 2 ;
      BOITE_US.'INFOS'.'PTSZ_DEPI' = ('EXTR' RIGD 'MAIL' 'NOMU') 
        'POIN' 1 ;
*    
*     Indices et temps des cycles
      BOITE_US.'POST' = 'TABLE' ;
      BOITE_US.'POST'.'INDICES_CYCLE'        = 'TABLE' ; 
      BOITE_US.'POST'.'CYCLES_CALCULES'      = 'PROG' ;
      BOITE_US.'POST'.'CYCLES_REELS'         = 'PROG' ; 
      BOITE_US.'POST'.'FACTEUR_ACCELERATION' = 'LECT' ;
*    
*     Nom du fichier de sauvegarde
      BOITE_US.'INFOS'.'ISAVE' = FAUX ;
      'SI' ('EXIS' BOITE_US.'DONNEES' 'ISAVE') ;
        BOITE_US.'INFOS'.'ISAVE' = BOITE_US.'DONNEES'.'ISAVE' ;
        'SI' (BOITE_US.'INFOS'.'ISAVE') ;
          NOMFIC = 'CHAI' 'calcul_usure.sauv' ;
          'SI' ('EXIS' BOITE_US.'DONNEES' 'NOM_SVGD') ;
            NOMFIC = BOITE_US.'DONNEES'.'NOM_SVGD' ;
          'FINSI' ; 
          BOITE_US.'INFOS'.'NOM_SVGD' = NOMFIC;
        'FINSI' ;
      'FINSI' ;
*
    'FINSI' ;
*
    CZERO = 'MANU' 'CHPO' SUR_APPL 1 'SCAL' 0. 'NATURE' 'DISCRET' ;
    BOITE_US. ID_BU .'CZERO' = CZERO;
*    
*   Indices remplis dans @USCALC
    BOITE_US. ID_BU .'GLISSEMENT'            = 'TABLE' 'ESCLAVE' ;
    BOITE_US. ID_BU .'CISAILLEMENT'          = 'TABLE' 'ESCLAVE' ;
    BOITE_US. ID_BU .'PRESSION_CONTACT'      = 'TABLE' 'ESCLAVE' ;
    BOITE_US. ID_BU .'DENS_ENER_DISS_CYCLE'  = 'CHAN' 'COMP' CZERO 'ED';
    BOITE_US. ID_BU .'DENS_ENER_DISS_TOTALE' = 'CHAN' 'COMP' CZERO 'ED';
    BOITE_US. ID_BU .'DELTAS'                = 'PROG' ; 
    BOITE_US. ID_BU .'FORCES_TANGENTIELLES'  = 'PROG' ;
    BOITE_US. ID_BU .'CYCLE_DE_FRETTING'     = 'TABLE' ;  
    BOITE_US. ID_BU .'PRESSION_MAX_INC'      = 'PROG' ;
    BOITE_US. ID_BU .'CISAILLEMENT_MAX_INC'  = 'PROG' ;
*    
*   Indices remplis dans @USPROF
    BOITE_US. ID_BU .'USURE_TOTALE'     = CZERO ;  
    BOITE_US. ID_BU .'EVO_USURE_TOTALE' = 'TABLE' ;    
*    
*   Indices remplis dans @USPOST
    BOITE_US. ID_BU .'PRESSION_MAX_CYCLE'       = 'PROG' ;
    BOITE_US. ID_BU .'CISAILLEMENT_MAX_CYCLE'   = 'PROG' ;
    BOITE_US. ID_BU .'DELTA_G'                  = 'PROG' ;
    BOITE_US. ID_BU .'DELTA_T'                  = 'PROG' ;
    BOITE_US. ID_BU .'ENERGIE_DISSIPEE_CYCLE'   = 'PROG' ;
    BOITE_US. ID_BU .'ENERGIE_DISSIPEE_TOTALE'  = 'PROG' 0. ;
    BOITE_US. ID_BU .'VOLUME_USE_CYCLE'         = 'PROG' ;
    BOITE_US. ID_BU .'VOLUME_USE_TOTAL'         = 'PROG' 0. ;
    BOITE_US. ID_BU .'PROF_USEE_MAX_CYCLE'      = 'PROG' ;
    BOITE_US. ID_BU .'PROF_USEE_MAX_TOTALE'     = 'PROG' ;
    BOITE_US. ID_BU .'LARGEUR_CONTACT_CYCLE'    = 'PROG' ;
    BOITE_US. ID_BU .'PRESSION_MOYENNE_CYCLE'   = 'TABLE' ;
    BOITE_US. ID_BU .'CISAILLEMENT_MOYEN_CYCLE' = 'TABLE' ;
    BOITE_US. ID_BU .'GLISSEMENT_CYCLE'         = 'TABLE' ;    
*
*   Creation de maillages utilises dans @USDEPL
    'SI' (BOITE_US.'INFOS'.'ITRID') ;
      TATMP = 'PART' 'SEPA' ('CONT' SUR_APPL) 'ANGL' 10. ;
      MESHZ = TATMP. 1 ;
    'SINON' ;
      MESHZ = SUR_APPL 'POIN' 'INIT' ;
    'FINSI' ;
    BOITE_US. ID_BU .'MAIL_PSIP' = MESHZ ;
*
*   Modele utilise pour les calculs avec INTG
    MODINTG = 'MODE' SUR_APPL 'MECANIQUE' 'ELASTIQUE' ;
    BOITE_US. ID_BU .'MODINTG' = MODINTG ;
*
*   Direction selon laquelle est appliquee l'usure    
    MODREPA = 'REDU' T1.'MODELE' BOITE_US. ID_BU .'VOLUME_REPARTITION';
    CHVNINT = 'PRES' 'MASS' SUR_APPL MODREPA 1. ; 
    LCOMPF  = BOITE_US.'INFOS'.'LFORCE' ;
    NORVINT = 'PSCA' CHVNINT CHVNINT LCOMPF LCOMPF ;
    NORVINT = NORVINT ** 0.5 ;
    CHVNINT = CHVNINT '/' NORVINT ;
    CHVNINT = 'CHAN' 'ATTRIBUT' CHVNINT 'NATURE' 'DISCRET' ;
    BOITE_US. ID_BU .'VNORM_INTE' = CHVNINT ;
*
*   Direction(s) tangentielle(s) pour le cycle d'usure
*   VTANGENT n'est pas utilise mais on le conserve pour le moment
    'SI' (BOITE_US.'INFOS'.'ITRID') ;
      CHPTTMP = 'MANU' 'CHPO' SUR_APPL LCOMPF ('PROG' 0. 0. 1.) ;
      CHVTGT1 = 'PVEC' CHVNINT CHPTTMP LCOMPF LCOMPF LCOMPF ;
      NORVTG1 = 'PSCA' CHVTGT1 CHVTGT1 LCOMPF LCOMPF ;
      NORMAXI = ('MAXI' NORVTG1) ** 0.5 ;
      NORMINI = ('MINI' NORVTG1) ** 0.5 ;
      'SI' (('&lt;EG' NORMAXI 1.E-6) 'OU' ('&lt;EG' NORMINI 1.E-6)) ; 
        CHPTTMP = 'MANU' 'CHPO' SUR_APPL LCOMPF ('PROG' 0. 1. 0.) ;
        CHVTGT1 = 'PVEC' CHVNINT CHPTTMP LCOMPF LCOMPF LCOMPF ;
        NORVTG1 = 'PSCA' CHVTGT1 CHVTGT1 LCOMPF LCOMPF ;
      'FINSI' ;
      NORVTG1 = NORVTG1 ** 0.5 ;
      CHVTGT1 = CHVTGT1 '/' NORVTG1 ;
      CHVTGT1 = 'CHAN' 'ATTRIBUT' CHVTGT1 'NATURE' 'DISCRET' ;
      CHVTGT2 = 'PVEC' CHVNINT CHVTGT1 LCOMPF LCOMPF LCOMPF ; 
      NORVTG2 = 'PSCA' CHVTGT2 CHVTGT2 LCOMPF LCOMPF ;
      NORVTG2 = NORVTG2 ** 0.5 ;
      CHVTGT2 = CHVTGT2 '/' NORVTG2 ;
      CHVTGT2 = 'CHAN' 'ATTRIBUT' CHVTGT2 'NATURE' 'DISCRET' ;
      BOITE_US. ID_BU .'VTANGEN1' = CHVTGT1 ;
      BOITE_US. ID_BU .'VTANGEN2' = CHVTGT2 ;
    'SINON' ;
      CHTANGT = 'PVEC' CHVNINT LCOMPF LCOMPF ;
      BOITE_US. ID_BU .'VTANGENT' = CHTANGT ;
    'FINSI' ;
*
*   Direction pour calculer la reaction tangentielle du cycle d'usure
    LCOMPU = BOITE_US.'INFOS'.'LDEPLA' ;
    POSIND = 'POSI' BOITE_US.'INFOS'.'COMP_DEPI' 'DANS' LCOMPU ;
    LVALEU = 'PROG' ('DIME' LCMPF) 0. ;
    'REMP' LVALEU POSIND 1. ;
    CHREACT = 'MANU' 'CHPO' SUR_APPL LCOMPF LVALEU ;
    BOITE_US. ID_BU .'DIRE_REACTION' = CHREACT ;
*
  'SINON' ;
*
*----------------------------------------------------------------------*
*   - REINITIALISATIONS A LA FIN DE CHAQUE CYCLE                       *
*----------------------------------------------------------------------*
    'SI' (BOITE_US.'INFOS'.'FINCYCLE') ;
      BOITE_US. ID_BU .'GLISSEMENT'       = 'TABLE' 'ESCLAVE' ;
      BOITE_US. ID_BU .'CISAILLEMENT'     = 'TABLE' 'ESCLAVE' ;
      BOITE_US. ID_BU .'PRESSION_CONTACT' = 'TABLE' 'ESCLAVE' ;
      BOITE_US. ID_BU .'PRESSION_MAX_INC' = 'PROG' ;
      BOITE_US. ID_BU .'CISAILLEMENT_MAX_INC' = 'PROG' ;
      CHPINI = 'CHAN' 'COMP' BOITE_US. ID_BU .'CZERO' 'ED' ;
      BOITE_US. ID_BU .'DENS_ENER_DISS_CYCLE' = CHPINI ;
    'FINSI' ;   
  'FINSI' ; 
*  
'FINP' ;