Télécharger @USDEPL.procedur

Retour à la liste

Numérotation des lignes :

  1. * @USDEPL PROCEDUR MB234859 21/10/21 21:15:01 11111
  2. ************************************************************************
  3. * PROCEDURE @USDEPL
  4. *
  5. * Application du profil d'usure au maillage
  6. *
  7. * Entrees :
  8. * T1 : Table de PASAPAS
  9. * ID_BU : Entier donnant le numero de la BOITE D'USURE a considerer
  10. *
  11. * Appelee par @USURE
  12. *
  13. ************************************************************************
  14. 'DEBP' @USDEPL T1*'TABLE' ID_BU*'ENTIER';
  15. *
  16. BOITE_US = T1.'BOITES_USURE' ;
  17. BUSURE = BOITE_US. ID_BU ;
  18. VOL_REPA = BUSURE.'VOLUME_REPARTITION' ;
  19. SUR_APPL = BUSURE.'SURFACE_APPLICATION' ;
  20. LF = BOITE_US.'INFOS'.'LFORCE' ;
  21. LU = BOITE_US.'INFOS'.'LDEPLA' ;
  22. LS = BOITE_US.'INFOS'.'LSCAL' ;
  23. *
  24. *----------------------------------------------------------------------*
  25. * - FACTEUR MULTIPLICATIF POUR APPLIQUER L'USURE DANS VOL_REPA *
  26. *----------------------------------------------------------------------*
  27. MAIL3 = BUSURE.'MAIL_PSIP' ;
  28. 'SI' (BOITE_US.'INFOS'.'ITRID') ;
  29. CDIST CDISN CDISP = 'PSIP' VOL_REPA SUR_APPL 'TROIS' MAIL3 ;
  30. CDISP = 'ABS' CDISP ;
  31. NOMDISP = 'EXTR' ('EXTR' CDISP 'COMP') 1;
  32. 'SINON' ;
  33. CDIST CDISN = 'PSIP' VOL_REPA SUR_APPL 'DEUX' MAIL3 ;
  34. 'FINSI' ;
  35. CDIST = 'ABS' CDIST ;
  36. CDISN = 'ABS' CDISN ;
  37. NOMDISN = 'EXTR' ('EXTR' CDISN 'COMP') 1;
  38. NOMDIST = 'EXTR' ('EXTR' CDIST 'COMP') 1;
  39. EPBOX = -1. * ('MAXI' CDISN) ;
  40. CHPUN = 'MANU' 'CHPO' VOL_REPA 1 NOMDISN 1. ;
  41. TauxU = (CDISN / EPBOX) '+' CHPUN ;
  42. TauxU = 'CHAN' TauxU 'COMP' 'SCAL' ;
  43. *
  44. *----------------------------------------------------------------------*
  45. * - PROFIL D USURE A APPLIQUER EN CHAQUE NOEUD DE VOL_REPA *
  46. *----------------------------------------------------------------------*
  47. CHUSURE = BUSURE.'USURE_CYCLE' '*' BUSURE.'VNORM_INTE' LS LF LU ;
  48. ChProf = 'VIDE' 'CHPOINT' ;
  49. *
  50. 'SI' (BOITE_US.'INFOS'.'ITRID') ;
  51. CDISTS = 'REDU' CDIST SUR_APPL ;
  52. CDISPS = 'REDU' CDISP SUR_APPL ;
  53. CDISTL = 'REDU' CDISP MAIL3 ;
  54. LCMP2 = 'EXTR' CDISTL 'VALE' ;
  55. LCMP2 = 'ORDO' LCMP2 'CROI' ;
  56. 'REPE' BCOMP ('DIME' LU) ;
  57. NOMCOMP = 'EXTR' LU &BCOMP ;
  58. VALCOMP = 'EXCO' CHUSURE NOMCOMP NOMCOMP ;
  59. VALETMP = 'EXTR' VALCOMP 'VALE' ;
  60. LVALUS = 'PROG' ;
  61. *
  62. 'REPE' BVAL ('NBNO' MAIL3) ;
  63. VALZ = 'EXTR' LCMP2 &BVAL ;
  64. PTSZ = CDISPS 'POIN' 'EGAL' VALZ ;
  65. CHPZ = 'MANU' 'CHPO' PTSZ 1 'SCAL' 0. 'NATURE' 'DISCRET' ;
  66. ABS1 = 'REDU' CDISTS PTSZ ;
  67. ABS1 = ('CHAN' 'COMP' CHPZ NOMDIST) 'ET'
  68. ('CHAN' 'ATTRIBUT' ABS1 'NATURE' 'DISCRET') ;
  69. ORDD = 'REDU' VALCOMP PTSZ ;
  70. ORDD = ('CHAN' 'COMP' CHPZ NOMCOMP) 'ET'
  71. ('CHAN' 'ATTRIBUT' ORDD 'NATURE' 'DISCRET') ;
  72. LABS1 = 'EXTR' ABS1 'VALE' ;
  73. LORD1 = 'EXTR' ORDD 'VALE' ;
  74. EVVV = 'ORDO' ('EVOL' 'MANU' LABS1 LORD1) 'CROI' ;
  75. LCMP1 = 'EXTR' EVVV 'ABSC' ;
  76. LORD3 = 'EXTR' EVVV 'ORDO' ;
  77. LVALUS = LVALUS 'ET' LORD3 ;
  78. 'FIN' BVAL ;
  79. *
  80. NUAGTMP = 'NUAG' 'COMP' NOMDIST LCMP1 'COMP' NOMDISP LCMP2
  81. 'COMP' NOMCOMP LVALUS ;
  82. CHPOTMP = 'IPOL' (CDIST 'ET' CDISP) NUAGTMP 'GRILL' ;
  83. ChProf = ChProf 'ET' CHPOTMP ;
  84. 'FIN' BCOMP ;
  85. *
  86. 'SINON' ;
  87. *
  88. VALDIST = 'REDU' CDIST SUR_APPL ;
  89. VALDIST = ('CHAN' 'COMP' BUSURE.'CZERO' NOMDIST) 'ET'
  90. ('CHAN' 'ATTRIBUT' VALDIST 'NATURE' 'DISCRET') ;
  91. ABSDIST = 'EXTR' VALDIST 'VALE' ;
  92. 'REPE' BCOMP ('DIME' LU) ;
  93. NOMCOMP = 'EXTR' LU &BCOMP ;
  94. VALCOMP = 'EXCO' CHUSURE NOMCOMP NOMCOMP ;
  95. VALETMP = 'EXTR' VALCOMP 'VALE' ;
  96. **** EVOLTMP = 'EVOL' 'MANU' ABSDIST VALETMP ;
  97. **
  98. *** LABSC = 'PROG' ; LORDO = 'PROG' ;
  99. *** 'REPE' BNOEUD ('NBNO' SUR_APPL) ;
  100. *** NODE = SUR_APPL 'POIN' &BNOEUD ;
  101. *** LABSC = LABSC 'ET' ('EXTR' VALDIST 'VALE' NODE) ;
  102. *** LORDO = LORDO 'ET' ('EXTR' VALCOMP 'VALE' NODE) ;
  103. *** 'FIN' BNOEUD ;
  104. *** EVOLTMP = 'EVOL' 'MANU' LABSC LORDO ;
  105. **
  106. **** CHPOTMP = 'IPOL' CDIST EVOLTMP ;
  107. **** ChProf = ChProf 'ET' ('CHAN' 'COMP' CHPOTMP NOMCOMP) ;
  108. **
  109. NUAGTMP = 'NUAG' 'COMP' NOMDIST ABSDIST 'COMP' NOMCOMP VALETMP ;
  110. CHPOTMP = 'IPOL' NUAGTMP CDIST 'GRILL' ;
  111. ChProf = ChProf 'ET' CHPOTMP ;
  112. **
  113. 'FIN' BCOMP ;
  114. 'FINSI' ;
  115. *
  116. CHPO_Dep = TauxU * ChProf ;
  117. *
  118. *----------------------------------------------------------------------*
  119. * - MODIFICATIONS DU CHAMP DE DEPLACEMENTS ET DE LA CONFIGURATION *
  120. *----------------------------------------------------------------------*
  121. T1.'ESTIMATION'.'DEPLACEMENTS' =
  122. (T1.'ESTIMATION'.'DEPLACEMENTS') + CHPO_Dep ;
  123. *
  124. * Deplacement des noeuds dans la configuration deformee
  125. 'FORM' (T1.'WTABLE'.'GE0_DEB') ;
  126. 'DEPL' VOL_REPA 'PLUS' CHPO_Dep ;
  127. 'FORM' (T1.'WTABLE'.'FOR0') ;
  128. *
  129. 'FINP' ;
  130.  
  131.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales