Télécharger vibr14_fourier.dgibi

Retour à la liste

Numérotation des lignes :

  1. *
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * VIBR14_FOURIER
  6. *
  7. * Objectif : Calcul des modes propres d'un tube mince orthotrope
  8. * axisymetrique encastre - encastre
  9. * Elements : coque mince COQ2, et massif QUA8
  10. * Creation : BP, 2017-03-01
  11. * Reference : Intercomparaison avec modele 3D CAST3M (vibr14_3d)
  12. *
  13. ************************************************************************
  14. *
  15. * DIMENSION dans le plan (XOY)
  16. *
  17. * solide
  18. * Y
  19. * Y=L | . . . D __ B
  20. * | | |
  21. * | | |
  22. * | | |
  23. * | | |
  24. * | | |
  25. * | | |
  26. * | | |
  27. * | . . . |__| -----> X
  28. * O C A
  29. * R=Ri R=Re
  30. *
  31. * | |
  32. * <-->
  33. * t
  34. *
  35. * la coque mince est definie sur Rmoy=(Re+Ri)/2
  36. *
  37. *
  38. * ORTHOTROPIE dans le plan (Y,Theta)
  39. *
  40. * Y
  41. * |
  42. * V2 beta |
  43. * \ |
  44. * \ |
  45. * \ |
  46. * \ |
  47. * \ |
  48. * \|
  49. * Z-------------+X
  50. *
  51. ************************************************************************
  52.  
  53. GRAPH = FAUX ;
  54. * GRAPH = VRAI ; OPTI TRAC PSC POTR HELVETICA_16 EPTR 5;
  55.  
  56. ************************************************************************
  57. * OPTIONS ET DONNEES
  58. ************************************************************************
  59.  
  60. * options
  61. typEF = mot 'QUA8';
  62. OPTI DIME 2 MODE FOUR NOHA ELEM typEF;
  63.  
  64.  
  65. * geometrie
  66. L = 0.3048;
  67. t = 0.254E-3;
  68. Re = 0.0762;
  69. Ri = Re - t;
  70. Rmoy = 0.5 * (Ri + Re);
  71.  
  72. * nz et nR = nombre d elements selon Z et R
  73. nz = 20; nR = 1;
  74.  
  75. * materiau
  76. Eyl = 206.E9;
  77. nult = 0.3;
  78. rho1 = 7850.;
  79. Eyt = Eyl / 10.;
  80. Glt = Eyt / (2. * (1. + nult));
  81. Gtt = Glt;
  82. nutt = 0.3;
  83. nutl = nult * Eyt / Eyl;
  84. mess Eyl Eyt Glt Gtt nutt;
  85. beta=30.;
  86.  
  87. * nombre de modes calcules
  88. nmod = 2;
  89.  
  90.  
  91. ************************************************************************
  92. * MAILLAGE
  93. ************************************************************************
  94.  
  95. p0 = 0. 0. ;
  96. vaxe = 0. 1. ;
  97. vx = 1. 0. ;
  98.  
  99. * maillage solide
  100. p1i = Ri 0. ;
  101. p1e = Re 0. ;
  102. p2i = Ri L ;
  103. p2e = Re L ;
  104. d1 = p1i droi nR p1e;
  105. d2 = p2i droi nR p2e;
  106.  
  107. mesh8 = REGL d1 nZ d2 ;
  108.  
  109. * maillage coq2
  110. OPTI ELEM SEG2;
  111. p1 = Rmoy 0.;
  112. p2 = Rmoy L;
  113. mesh2 = p1 droi nZ p2;
  114.  
  115.  
  116. ************************************************************************
  117. * MODELEs
  118. ************************************************************************
  119.  
  120. mod2 = MODE mesh2 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'COQ2'
  121. 'CONS' 'couche 1';
  122. mod8 = MODE mesh8 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE';
  123.  
  124. *=======================================================================
  125. *===> BOUCLE SUR LES HARMONIQUES DE FOURIER
  126. *=======================================================================
  127. nHlect = lect 3 4 5 6 7 8 9 10;
  128. nnH = DIME nHlect;
  129.  
  130. w2vibr = prog;
  131. w8vibr = prog;
  132. * tables pour FOUR2TRI
  133. TFOU2 = TABL;
  134. TFOU2 . 'MODELE' = mod2;
  135. TFOU8 = TABL;
  136. TFOU8 . 'MODELE' = mod8;
  137.  
  138. REPE BnH nnH;
  139.  
  140. nH = extr nHlect &BnH;
  141. MESS ' ';
  142. MESS '______________________________________________';
  143. MESS ' ';
  144. MESS '>>>>>>>>>>>>>>>> nH=' nH '<<<<<<<<<<<<<<<<<<<';
  145. MESS '______________________________________________';
  146. MESS ' ';
  147. OPTI MODE FOUR nH;
  148.  
  149. MESS '==================== \b=' beta '====================';
  150. TITRE (chai '\b =' (enti beta)- n_{H}='nH);
  151.  
  152.  
  153.  
  154. ************************************************************************
  155. * MATERIAUx
  156. ************************************************************************
  157.  
  158. mat2 = MATE mod2 'YG1' Eyl 'YG2' Eyt 'NU12' nult 'G12' Glt
  159. 'RHO' rho1 'EPAI' t
  160. 'DIRE' vaxe 'INCL' beta ;
  161.  
  162. mat8 = MATE mod8 'YG1' Eyt 'YG2' Eyl 'YG3' Eyt
  163. 'NU12' nutl 'NU13' nutt 'NU23' nult
  164. 'G12' Glt 'G13' Gtt 'G23' Glt
  165. 'RHO' rho1 'DIRE' vx 'INCL' 0. beta;
  166.  
  167. * verification graphique de l'orientation des fibres
  168. v2 = chan (VLOC mod2 mat2) 'GRAVITE' mod2;
  169. v8 = chan (VLOC mod8 mat8) 'GRAVITE' mod8;
  170.  
  171. SI GRAPH;
  172. xv2 = 0.1 / nZ;
  173. vv2 = vect v2 xv2 mod2 (mots V1R V1Z V2R V2Z V3R V3Z)
  174. (mots 'BLEU' 'BRON' 'ROUG');
  175. TRAC vv2 mesh2 ;
  176. vv8 = vect v8 xv2 mod8 (mots V1R V1Z V2R V2Z V3R V3Z)
  177. (mots 'BLEU' 'BRON' 'ROUG');
  178. TRAC vv8 mesh8 ;
  179. FINSI;
  180.  
  181.  
  182. ************************************************************************
  183. * MATRICES
  184. ************************************************************************
  185.  
  186. * solide :
  187. cl1 = BLOQ 'DEPL' d1;
  188. cl2y = BLOQ 'UZ' d2;
  189. cl2 = BLOQ 'UR' 'UT' d2;
  190. cl_8 = cl1 et cl2 et cl2y;
  191. K8 = RIGI mod8 mat8;
  192. M8 = MASS mod8 mat8;
  193. Ktot8 = K8 et cl_8;
  194.  
  195. * coque :
  196. cl1 = BLOQ 'DEPL' p1;
  197. cl2y = BLOQ 'UZ' p2;
  198. cl2 = BLOQ 'UR' 'UT' p2;
  199. cl_2 = cl1 et cl2 et cl2y;
  200. K2 = RIGI mod2 mat2;
  201. M2 = MASS mod2 mat2;
  202. Ktot2 = K2 et cl_2;
  203.  
  204.  
  205. ************************************************************************
  206. * ANALYSE MODALE
  207. ************************************************************************
  208. NMOD = 2;
  209. TMOD_2 = VIBR 'IRAM' 100. NMOD Ktot2 M2 ;
  210. TMOD_8 = VIBR 'IRAM' 100. NMOD Ktot8 M8 ;
  211.  
  212. * stockage
  213. w2vibr = w2vibr et (TMOD_2 . 'MODES' . 1 . 'FREQUENCE');
  214. w8vibr = w8vibr et (TMOD_8 . 'MODES' . 1 . 'FREQUENCE');
  215.  
  216. * en prevision de FOUR2TRI
  217. INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  218. TFOU2 . INDICE_NH = TABL;
  219. TFOU8 . INDICE_NH = TABL;
  220. REPE BB NMOD;
  221. TFOU2 . INDICE_NH . &BB = TMOD_2 . 'MODES' . &BB . 'DEFORMEE_MODALE';
  222. TFOU8 . INDICE_NH . &BB = TMOD_8 . 'MODES' . &BB . 'DEFORMEE_MODALE';
  223. FIN BB;
  224.  
  225. FIN BnH;
  226. *=======================================================================
  227.  
  228.  
  229. ************************************************************************
  230. * post-traitement FOUR2TRI
  231. ************************************************************************
  232.  
  233. * on monte jusqu'a l'harmonique 10 -> besoin de finesse circonferentielle
  234. prteta = prog 0. PAS 3. 360.;
  235. TFOU2 . 'ANGLES' = prteta;
  236. TFOU8 . 'ANGLES' = prteta;
  237.  
  238. * --- coque ---
  239.  
  240. * creation du maillage 3D
  241. OPTI 'MODE' 'FOUR' 'NOHA';
  242. FOUR2TRI TFOU2 ;
  243. mesh2_3d = TFOU2 . 'MAILLAGE_3D';
  244. list TFOU2 2;
  245. SI GRAPH; TRAC mesh2_3d TITRE 'maillage 3D coque issu de FOUR2TRI'; FINSI;
  246.  
  247. * creation des deformees modales 3D
  248. REPE BnH nnH;
  249.  
  250. nH = extr nHlect &BnH;
  251. TITRE (chai 'Modes - n_{H}='nH);
  252. INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  253. TFOU2 . 'DEPLACEMENTS' = TFOU2 . INDICE_NH;
  254. FOUR2TRI TFOU2 nH ;
  255.  
  256. SI GRAPH;
  257. TMOD_2 . 'MODES' . 'MAILLAGE' = mesh2_3d;
  258. REPE BB NMOD;
  259. TMOD_2 . 'MODES' . &BB . 'DEFORMEE_MODALE'
  260. = TFOU2 . 'DEPLACEMENTS_3D' . &BB;
  261. FIN BB;
  262. POSTVIBR TMOD_2;
  263. FINSI;
  264. FIN BnH;
  265.  
  266. * --- massif ---
  267.  
  268. * creation du maillage 3D
  269. OPTI 'MODE' 'FOUR' 'NOHA';
  270. FOUR2TRI TFOU8 ;
  271. mesh8_3d = TFOU8 . 'MAILLAGE_3D';
  272. list TFOU8 2;
  273. SI GRAPH; TRAC mesh8_3d TITRE 'maillage 3D massif issu de FOUR2TRI'; FINSI;
  274.  
  275. * creation des deformees modales 3D
  276. REPE BnH nnH;
  277.  
  278. nH = extr nHlect &BnH;
  279. TITRE (chai 'Modes - n_{H}='nH);
  280. INDICE_NH = chai 'DEFORMEES_MODALES_' nH;
  281. TFOU8 . 'DEPLACEMENTS' = TFOU8 . INDICE_NH;
  282. FOUR2TRI TFOU8 nH ;
  283.  
  284. SI GRAPH;
  285. TMOD_8 . 'MODES' . 'MAILLAGE' = mesh8_3d;
  286. REPE BB NMOD;
  287. TMOD_8 . 'MODES' . &BB . 'DEFORMEE_MODALE'
  288. = TFOU8 . 'DEPLACEMENTS_3D' . &BB;
  289. FIN BB;
  290. POSTVIBR TMOD_8;
  291. FINSI;
  292.  
  293. FIN BnH;
  294.  
  295.  
  296. ************************************************************************
  297. * TEST DE BON FONCTIONNEMENT
  298. ************************************************************************
  299. * REM : On teste que les harmoniques de Fourier sont 6, 7, 5 et 8.
  300. nHref = lect 6 7 5 8;
  301.  
  302. w_2 nHjj_2 = ORDO w2vibr nHlect;
  303. list nHjj_2;
  304. list w_2;
  305.  
  306. w_8 nHjj_8 = ORDO w8vibr nHlect;
  307. list nHjj_8;
  308. list w_8;
  309.  
  310. * on ne teste que les 4 premiers modes
  311. nHdiff_2 = (extr nHjj_2 (lect 1 2 3 4)) - nHref;
  312. nHdiff_8 = (extr nHjj_8 (lect 1 2 3 4)) - nHref;
  313.  
  314. SI ( ((MAXI nHdiff_2 'ABS') >EG 1)
  315. OU ((MAXI nHdiff_8 'ABS') >EG 1) );
  316. ERRE 5;
  317. SINON;
  318. ERRE 0;
  319. FINSI;
  320.  
  321. TEMP 'IMPR' 'MAXI' 'HORL' ;
  322.  
  323. FIN ;
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales