Télécharger vari-youn-4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : vari-youn-4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. **************************************************************
  5. *
  6. * C'est un k-test dont le but est de tester le fonctionnement
  7. * de PASAPAS avec la variation des données matérielles.
  8. *
  9. * Il s'agit d'une barre en traction simple. Son module de Young
  10. * dépend linéairement du paramètre d'évolution (à la fin du
  11. * chargement on descend à 10% de la valeur initiale).
  12. *
  13. * Pour la résolution, on utilise le mécanisme de traitement
  14. * des matériaux variables implanté dans PASAPAS. La variable
  15. * utilisée par cette mécanique porte le nom T, ce chargement
  16. * est donc considéré comme un chargement thermique. On impose
  17. * la valeur de T en effectuant un calcul thermique très
  18. * simple (température uniforme imposée partout).
  19. *
  20. **************************************************************
  21.  
  22. *** Options ...
  23.  
  24. opti dime 2 mode plan defo elem seg2 echo 1 ;
  25. graph = faux ;
  26.  
  27. *** Paramètres ...
  28.  
  29. L = 10. ;
  30. H = 1. ;
  31. S = H * 1. ;
  32.  
  33. E_0 = 2.E+11 ;
  34. * E_1 = (2.0 * E_0) / (0.01 * L) ;
  35. E_1 = (-0.5 * E_0) / (0.1 * L) ;
  36.  
  37. * F = 1.E+10 ;
  38. F = 9.9E+9 ;
  39.  
  40. nbdiv = 1 ;
  41.  
  42. *** Points ...
  43.  
  44. dens (L / nbdiv) ;
  45.  
  46. p1 = 0 0 ;
  47. p2 = 0 H ;
  48.  
  49. *** Ligne ...
  50.  
  51. li1 = p1 d 1 p2 ;
  52.  
  53. *** Surface ...
  54.  
  55. opti elem qua4 ;
  56.  
  57. vectx = L 0 ;
  58. su1 = li1 tran nbdiv vectx ;
  59. pu = su1 poin proc vectx ;
  60.  
  61. titr 'Le maillage du modele' ;
  62. si(graph) ;
  63. trac su1 ;
  64. finsi ;
  65.  
  66. *** Modèle ...
  67.  
  68. listdepl = prog (-0.2 * L) (0.2 * L) ;
  69. listyoun = prog ;
  70. lon = dime listdepl ;
  71. repeter surdpl lon ;
  72. valdep = extr listdepl &surdpl ;
  73. valyou = E_0 + (E_1 * valdep) ;
  74. listyoun = listyoun et (prog valyou) ;
  75. fin surdpl ;
  76. titr 'Module de Young (deplacement)' ;
  77. evyou = evol manu T listdepl YOUN listyoun ;
  78. si(graph) ;
  79. dess evyou ;
  80. finsi ;
  81.  
  82. mo1 = mode su1 mecanique elastique ;
  83. mo1t = mode su1 thermique CONS 'partie_thermique' ;
  84. ma1 = mate mo1 NU 0.0 YOUN evyou ALPH 0. 'TALP' 0. 'TREF' 0. ;
  85. ma1t = mate mo1t K 1000 RHO 1000 'C' 1000 ;
  86.  
  87. *** Préparation de la table pour PASAPAS ...
  88.  
  89. tabnl = table ;
  90. * tabnl . GRANDS_DEPLACEMENTS = vrai ;
  91. tabnl . HYPOTHESE_DEFORMATIONS = 'LINEAIRE';
  92. tabnl . MODELE = mo1 et mo1t ;
  93. tabnl . CARACTERISTIQUES = ma1 et ma1t ;
  94. cl1 = (bloq ux li1) et (bloq uy p1) ;
  95. tabnl . BLOCAGES_MECANIQUES = cl1 ;
  96.  
  97. ordmax = 1.8 ;
  98. * ldpl0 = manu CHML mo1 T 1.0 STRESSES ;
  99. evconst = evol manu 't' (prog 0. 1.)
  100. 'f(t)' (prog 0. ordmax) ;
  101. * chavar0 = char T ldpl0 evconst ;
  102. * tbabsc = table ;
  103. * tbabsc . 0 = 0. ;
  104. * tbabsc . 1 = 1.000000001 ;
  105. * tbordo = table ;
  106. * tbordo . 0 = manu chpo su1 1 T 0. ;
  107. * tbordo . 1 = manu chpo su1 1 T ordmax ;
  108. * chavar0 = char T tbabsc tbordo ;
  109. blt = bloq T su1 ;
  110. tim = depi blt 1. ;
  111. chavar0 = char TIMP tim evconst ;
  112.  
  113. fobid = forc fx F (cote 3 su1) ;
  114. lr1 = prog 0. 1. ;
  115. lr2 = prog 0. 1. ;
  116. evbid = evol manu 't' lr1 'f(t)' lr2 ;
  117. chabid = char fobid evbid MECA ;
  118. tabnl . CHARGEMENT = chavar0 et chabid ;
  119. tabnl . BLOCAGES_THERMIQUES = blt ;
  120.  
  121. nb_dt = 5 ;
  122. dt = 1.0 / nb_dt ;
  123. tabnl . TEMPS_CALCULES = prog 0. PAS dt 1. ;
  124.  
  125. *** Le calcul ...
  126.  
  127. pasapas tabnl ;
  128.  
  129. *** Petit post-traitement ...
  130.  
  131. listt = prog ;
  132. listux = prog ;
  133. listuxt = prog ;
  134. listfx = prog ;
  135. nbpas = dime (tabnl . TEMPS) ;
  136. repeter surpas nbpas ;
  137. lindice = &surpas - 1 ;
  138. listt = listt et (prog (tabnl . TEMPS . lindice)) ;
  139. laforc = F * (tabnl . TEMPS . lindice) ;
  140. listfx = listfx et (prog laforc) ;
  141. fauxdepl = ipol (tabnl . TEMPS . lindice) (extr evconst
  142. ABSC) (extr evconst ORDO) ;
  143. mess '-------------------------------------' ;
  144. mess 'fauxdepl = ' fauxdepl ;
  145. E_act = E_0 + (E_1 * fauxdepl) ;
  146. mess 'E_act = ' E_act ;
  147. uxbid = (laforc * L) / (E_act * S) ;
  148. listuxt = listuxt et (prog uxbid) ;
  149. depact = tabnl . DEPLACEMENTS . lindice ;
  150. ledepl = extr depact UX pu ;
  151. listux = listux et (prog ledepl) ;
  152. fin surpas ;
  153.  
  154. titr 'La deformee' ;
  155. defo0 = defo su1 depact 0.0 ;
  156. defo1 = defo su1 depact ROUG ;
  157. si(graph) ;
  158. trac (defo0 et defo1) ;
  159. finsi ;
  160.  
  161. titr 'Courbe de traction provenant de PASAPAS' ;
  162. courbetr = evol manu 'FX' listfx 'UX' listux ;
  163. si(graph) ;
  164. dess courbetr ;
  165. finsi ;
  166.  
  167. titr 'Courbes de traction PASAPAS + théorique' ;
  168. courbteo = evol ROUG manu 'FX' listfx 'UX' listuxt ;
  169. si(graph) ;
  170. dess (courbetr et courbteo) ;
  171. finsi ;
  172.  
  173. *** Vérification de la précision du calcul ...
  174.  
  175. chtit = chai 'Difference entre le depl. fourni par PASAPAS'
  176. ' et le depl. analytique' ;
  177. titr chtit ;
  178. ladiff = courbetr - courbteo ;
  179. ladiff = evol manu (extr ladiff ABSC) (abs (extr ladiff ORDO)) ;
  180. si(graph) ;
  181. dess ladiff ;
  182. finsi ;
  183. precis = maxi (extr ladiff ORDO) ;
  184. mess 'Écart maxi = ' precis ;
  185.  
  186. si(precis > 1.e-8) ;
  187. erre 5 ;
  188. finsi ;
  189.  
  190. *** Bye ...
  191.  
  192. fin ;
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  
  202.  
  203.  
  204.  
  205.  
  206.  
  207.  
  208.  
  209.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales