Télécharger la plaquette Cast3M


fr en

Télécharger uo2_cas1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  uo2_cas1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test uo2_cas1.dgibi: Jeux de donnees            
  6. *     ------------------------------------
  7. *
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11. 'OPTI' 'DIME' 3 'MODE' 'TRID'        ;
  12. 'OPTI' 'ELEM' 'CUB8'                 ;
  13. 'OPTI' 'TRAC' 'PSC'                  ;
  14. 'TEMPS' 'ZERO'                       ;
  15. L = 'MOT' LIST ; F = 'MOT' FIN ;
  16. *                                                                               
  17. **********************************************************         
  18. *                TEST DE VALIDATION                      *
  19. *                ------------------                      *
  20. *                   MODELE UO2                           *
  21. *   (COUPLAGE DES MODELES GATT_MONERIE ET OTTOSEN)       *
  22. *  UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE      *
  23. *                                                        *
  24. *  MAILLAGE:                                             *
  25. *     CUBE                                               *
  26. *                                                        *
  27. *  CHARGEMENT:                                           *
  28. *     DEPLACEMENTS IMPOSES A VITESSES CTE EN  TRACTION   *
  29. *     SELON LES DIRECTIONS Z ET X :                      *
  30. *     VIT DE DEF EN X = 0.8 * (VIT DE DEF EN Z)          *
  31. *     TEMPERATURE         CTE                            *
  32. *     DENSITE DE FISSIONS CTE                            *
  33. *     OTTOSEN ACTIVE (FISSURATIONS PUIS RUPTURES DS LES  *
  34. *     DEUX DIRECTIONS (D ABORD Z PUIS X)                 *
  35. *     VISCOPLASTICITE SIMPLIFIEE (VIA CHOIX DES COEFS)   *
  36. *     ACTIVEE                                            *
  37. *     GONFLEMENT ACTIVE                                  *
  38. *     PAS DE DENSIFICATION                               *
  39. **********************************************************        
  40. *
  41. DESSI = FAUX ;
  42. *
  43. * -----------------------------*
  44. * MAILLAGE D UN CUBE DE COTE 1 *
  45. * -----------------------------*
  46.    HS2  = 2E-5                                                 ;
  47. *
  48.    OO   = 0.     0.         0.                                 ;
  49.    A1   = HS2    0.         0.                                 ;
  50.    A2   = HS2    0.         HS2                                ;
  51.    A3   = 0.     0.         HS2                                ;
  52. *
  53.    LB   = 'DROIT' 1  OO A1                                     ;
  54.    LD   = 'DROIT' 1  A1 A2                                     ;
  55.    LH   = 'DROIT' 1  A2 A3                                     ;
  56.    LG   = 'DROIT' 1  A3 OO                                     ;
  57. *
  58.    SUA  = 'DALL' LB  LD  LH  LG  'PLAN'                        ;
  59.    SU2  = SUA 'PLUS' (0. HS2 0.)                               ;
  60.    VOL1 = 'VOLU' 1 SUA SU2                                     ;
  61.    'ELIM' (HS2/1000.) VOL1                                     ;
  62. *
  63.    SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  64.    SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  65.    LG  = 'POIN' ('COOR' 1 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  66.    LD  = 'POIN' ('COOR' 1 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  67. *
  68.    VOL2 = VOL1 'TOUR' 45. OO (0 HS2 0);
  69.    SUB2 = SUB  'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUB2;
  70.    SUH2 = SUH  'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUH2;
  71.    LG2  = LG   'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 LG2 ;
  72.    LD2  = LD   'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 LD2 ;
  73.    SUA2 = SUA  'TOUR' 45. OO (0 HS2 0); 'ELIM' (HS2/1000.) vol2 SUA2;
  74.    VOL1 = VOL2                        ;
  75.  
  76.    VX2 = (1 0 0) 'TOUR' 45. OO (0 HS2 0);
  77.    VZ2 = (0 0 1) 'TOUR' 45. OO (0 HS2 0);
  78. * -----------------------------------------------------*
  79. * Conditions aux limites + deplacement impose sur CLZH *
  80. * -----------------------------------------------------*
  81. CLZB = 'BLOQ' SUB2 'DIRECTION'  VZ2                 ;
  82. CLZH = 'BLOQ' SUH2 'DIRECTION'  VZ2                 ;
  83. CLXG = 'BLOQ' LG2  'DIRECTION'  VX2                 ;
  84. CLXD = 'BLOQ' LD2  'DIRECTION'  VX2                 ;
  85. CLYG = 'BLOQ' UY SUA2                               ;
  86. CLT  = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLXD 'ET' CLYG ;
  87. * -------*
  88. * Modele *
  89. * -------*
  90. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 ;
  91. *
  92. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt');
  93. *
  94. * Temperature moyenne (cte au cours du calcul)
  95. * --------------------------------------------
  96.   TE1 = 1420. + 273.  ;
  97. *
  98. * Porosite initiale
  99. * -----------------
  100.   PO   = 4.52E-2      ;
  101. *
  102. * Densite de fission (cte au cours du calcul)
  103. * -------------------------------------------
  104.   PHI1 = 3E20 ;
  105. *
  106.    RHO0 = 1. - TA.'POR0'                      ;
  107.    TAU0 = TA.'EFIS'*270./238./10950./RHO0     ;
  108. *
  109. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  110. *
  111. *
  112. * --------------------------------------*
  113. * 'YOUN' constant ou fonction de T et f *
  114. * --------------------------------------*
  115.  MATREE = MATE MODL1 'YOUN' (TA.'YOUN')          ;
  116.  EE     = 'VARI' 'NUAG' MODL1 MATREE PP          ;
  117. * EE     = (TA.'YOUN')                            ;
  118.  MATREE = MATE MODL1 'YOUN' EE                   ;
  119. * ------------------------------------*
  120. * 'NU' constant ou fonction de T et f *
  121. * ------------------------------------*
  122.  MATRUU = MATE MODL1 'NU' (TA.'NU')              ;
  123.  UU     = 'VARI' 'NUAG' MODL1 MATRUU PP          ;
  124. * UU     = (TA.'NU')                              ;
  125. * --------------------------------------*
  126. * 'ALPH' constant ou fonction de T et f *
  127. * --------------------------------------*
  128.  MATRAA = MATE MODL1 'ALPH' (TA.'ALPH')          ;
  129.  XALFA  = 'VARI' 'NUAG' MODL1 MATRAA PP          ;
  130. * XALFA  = (TA.'ALPH')                            ;
  131.  MATRAA = MATE MODL1 'ALPH' XALFA                ;
  132. * -----------------------------------------------------------------*
  133. * Temperature de reference et temperature de reference pour 'ALPH' *
  134. * -----------------------------------------------------------------*
  135.  TREF   = TE1 ;
  136.  TALPHA = 0.  ;
  137. * ----------------------------------------*
  138. * 'ALPH' pour la temperature de reference *
  139. * ----------------------------------------*
  140.  PP       = 'MANU' 'CHML' MODL1 'T' TREF 'PORO' PO RIGIDITE ;
  141.  ALFATREF = 'MAXI' ('VARI' 'NUAG' MODL1 MATRAA PP)          ;
  142. *
  143. * -----------------------------*
  144. * Materiau partie GATT_MONERIE *
  145. * -----------------------------*
  146. * fluage primaire (negligeable devant le fluage d'irradiation)
  147.   TA.'AP'   = 1                             ;
  148.   TA.'BP'   = 0                             ;
  149. * fluage secondaire (2 mecanismes)
  150.   TA.'N1'   = 1.                  ;
  151.   TA.'N2'   = 1.                  ;
  152. * fluage d"irradiation
  153.   TA.'N3'   = 1.                  ;
  154. * fonction de couplage
  155.   TA.'OMEG' = 0.                  ;
  156. * densification/gonflement
  157.   TA.'BUMI' = 5E3 * (TA.'BUMI')   ;
  158. *
  159. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' UU 'RHO' (TA.'RHO')  'ALPH' XALFA 'TALP' TALPHA 'TREF' TREF;
  160. *
  161. MATR12 = 'MATE' MODL1  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DG') 'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1')  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2')  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA') 'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3') 'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  162. *
  163. MATR13 = 'MATE' MODL1  'KP' (TA.'KPUO')   'AP' (TA.'AP')   'BP' (TA.'BP')     'QP' (TA.'QP') ;
  164. *
  165. MATR14 = 'MATE' MODL1  'ADEN' (TA.'ADEN')   'KGON' (TA.'KGON')  'POR0' (TA.'POR0')   'BUMI' (TA.'BUMI')  'EFIS' (TA.'EFIS')                                ;
  166. *
  167. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  168. * COMP = 0. combustible compressible   sinon incompressible
  169. * DYN  = 0. couplage statique          sinon dynamique
  170. *
  171. * -----------------------------*
  172. * Materiau partie OTTOSEN      *
  173. * -----------------------------*
  174.  MATR16 = 'TAIL' MODL1 ;
  175. *
  176. * Resistance au cisaillement 'GS  ' par defaut: 'YOUN'*1.8E-4
  177. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  178. * Relation bilineaire 'BILI' = 0 --> 'BILI' = 0 (ouverture)
  179. *
  180.  XGFTR = 1.8   ; XGFTR1=XGFTR ; XGFTR2=XGFTR ; XGFTR3=XGFTR ;
  181.  XLTR  = 150E6 ; XLTR1 =XLTR  ; XLTR2 =XLTR  ; XLTR3 =XLTR  ;
  182.  XBTR  = 0.2   ;
  183. *
  184.  MATR17 = 'MATE' MODL1  'GFTR' XGFTR    'LTR ' XLTR     'BTR ' XBTR 'WRUP' 0.       'BILI' 0. 'GFT1' XGFTR1   'GFT2' XGFTR2   'GFT3' XGFTR3 'GS1 ' 0.       'GS2 ' 0.       'GS3 ' 0. 'LTR1' XLTR1    'LTR2' XLTR2    'LTR3' XLTR3 'WRU1' 0.       'WRU2' 0.       'WRU3' 0. 'BIL1' 0.       'BIL2' 0.       'BIL3' 0.     ;
  185. *
  186. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET' MATR16 'ET' MATR17  ;
  187. *
  188. *
  189. ************************************************************************
  190. 'DEBP' XFONC  FN*'FLOTTANT' XFN1*'FLOTTANT'       DT*'FLOTTANT' SXN*'FLOTTANT'  SZN*'FLOTTANT' PAX*'FLOTTANT'  PAZ*'FLOTTANT'  EX*'FLOTTANT'   EZ*'FLOTTANT' NU_SUR_E*'FLOTTANT' C12*'FLOTTANT'   C3*'FLOTTANT'                      ;
  191.  
  192.  UNTIER = 1. / 3. ;  DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  193.  
  194.  det = (EX * EZ)  - (NU_SUR_E ** 2)  ;
  195.  AX  = (EZ * PAX) + (NU_SUR_E * PAZ) ;
  196.  AZ  = (EX * PAZ) + (NU_SUR_E * PAX) ;
  197.  
  198.  A   = XFN1 / (1. - XFN1)                     ;
  199.  B   = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  200.  
  201.  X   =  UNTIER   * C12 * A                    ;
  202.  Y   = (DEUXTIER * C12 * B) + (UNDEMI * C3)   ;
  203.  
  204.  GDT = DT / det ;  GDT2 = GDT**2   ;
  205.  
  206.  GDET1a = 2. * NU_SUR_E * (Y - X)            ;
  207.  GDET1b = (EX + EZ) * (X + (2.*Y))           ;
  208.  GDET1  = GDT * (GDET1a - GDET1b)            ;
  209.  GDET2  = 3. * GDT2 * det * Y * (Y + (2.*X)) ;
  210.  GDET   = (1. - GDET1) + GDET2               ;
  211.  
  212.  FONC1a = 3. * Y * GDT * (NU_SUR_E - EX)        ;
  213.  FONC1a = 1. - FONC1a                           ;
  214.  FONC1b = (GDT * AX) + SXN                      ;
  215.  FONC1c = 3. * Y * GDT * (NU_SUR_E - EZ)        ;
  216.  FONC1c = 1. - FONC1c                           ;
  217.  FONC1d = (GDT * AZ) + SZN                      ;
  218.  FONC1e = (FONC1b * FONC1a) + (FONC1d * FONC1c) ;
  219.  FONC1  = DT * C12 * XFN1 * FONC1e              ;
  220.  FONC2  = GDET * (XFN1 - FN)                    ;
  221.  VFONC  = FONC1 - FONC2                         ;
  222.  TFONC  = ('ABS' VFONC) / FONC1                 ;
  223. 'FINP' VFONC TFONC FONC1e GDET ;
  224. ************************************************************************
  225. *
  226. ************************************************************************
  227. 'DEBP' FCTNUL   FN*'FLOTTANT'                       DT*'FLOTTANT' SXN*'FLOTTANT'  SZN*'FLOTTANT' PAX*'FLOTTANT'  PAZ*'FLOTTANT'  EX*'FLOTTANT'   EZ*'FLOTTANT' NU_SUR_E*'FLOTTANT' C12*'FLOTTANT'   C3*'FLOTTANT'                      ;
  228.  
  229.  XFN1 = FN                           ;
  230.  V1 TES1 FONCe1 GDET1  = XFONC   FN   XFN1   DT   SXN   SZN PAX  PAZ    EX   EZ    NU_SUR_E C12  C3  ;
  231.  XFN2a = GDET1 * FN                  ;
  232.  XFN2b = GDET1 - (DT * C12 * FONCe1) ;
  233.  XFN2 = XFN2a / XFN2b                ;
  234. *--
  235.  'REPETER' STRU1 ;
  236. *--
  237.  V2 TES2 FONCe2 GDET2  = XFONC   FN   XFN2   DT   SXN   SZN PAX  PAZ    EX   EZ    NU_SUR_E C12  C3  ;
  238.  PREC = 1E-4            ;
  239.  'SI' ('<EG' TES2 PREC) ;
  240.      FN1   = XFN2       ;
  241.      GDET1 = GDET2      ;
  242.     'QUIT' STRU1        ;
  243.  'FINSI'                ;
  244.  
  245. * 'SI' ('>' &STRU1 100)                                  ;
  246. *    'MESS' 'PAS DE SOLUTION DANS FCTNUL: &STRU1' &STRU1 ;
  247. * 'FINSI'                                                ;
  248.  
  249. * 'SI' ( ('>' (V1 * V2) 0.) 'ET' ('EGA' &STRU1 1) )                   ;
  250. *    'MESS' 'MAUVAISE ESTIMATION INITIALE DANS FCTNUL: V1 V2 =' V1 V2 ;
  251. * 'FINSI'                                                             ;
  252.  
  253.  XX  = V1 / (V1 - V2)              ;
  254.  XXF = ((XFN2 - XFN1) * XX) + XFN1 ;
  255.  'SI' ('<EG' (V1 * V2) 0.)         ;
  256.     XFN2 = XXF                     ;
  257.  'SINON'                           ;
  258.     XFN1 = XXF                     ;
  259.  'FINSI'                           ;
  260. *--
  261.  'FIN' STRU1 ;
  262. *-- 
  263. 'FINP' FN1 GDET1 ;
  264. ************************************************************************
  265. *
  266. ************************************************************************
  267. 'DEBP' CONT  XFN1*'FLOTTANT'  GDET1*'FLOTTANT'  DT*'FLOTTANT'        SXN*'FLOTTANT'    SZN*'FLOTTANT' PAX*'FLOTTANT'    PAZ*'FLOTTANT'  EX*'FLOTTANT'     EZ*'FLOTTANT'  NU_SUR_E*'FLOTTANT' C12*'FLOTTANT'     C3*'FLOTTANT'                      ;
  268.  
  269.  UNTIER = 1. / 3. ;  DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  270.  
  271.  det = (EX * EZ)  - (NU_SUR_E ** 2)  ;
  272.  AX  = (EZ * PAX) + (NU_SUR_E * PAZ) ;
  273.  AZ  = (EX * PAZ) + (NU_SUR_E * PAX) ;
  274.  
  275.  A   = XFN1 / (1. - XFN1)                     ;
  276.  B   = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  277.  
  278.  X   =  UNTIER   * C12 * A                    ;
  279.  Y   = (DEUXTIER * C12 * B) + (UNDEMI * C3)   ;
  280.  
  281.  GDT = DT / det ;
  282.  
  283.  SZN1a = (GDT * AZ) + SZN             ;
  284.  SZN1b = NU_SUR_E * (Y - X)           ;
  285.  SZN1c = EZ * (X + (2. * Y))          ;
  286.  SZN1d = 1. - (GDT * (SZN1b - SZN1c)) ;
  287.  SZN1e = SZN1a * SZN1d                ;
  288.  SZN1a = (GDT * AX) + SXN             ;
  289.  SZN1b = NU_SUR_E * (X + (2. * Y))    ;
  290.  SZN1c = EX * (Y - X)                 ;
  291.  SZN1d = GDT * (SZN1c - SZN1b)        ;
  292.  SZN1  = SZN1e + (SZN1a * SZN1d)      ;
  293.  SZN1  = SZN1 / GDET1                 ;
  294.  
  295.  SXN1a = (GDT * AX) + SXN             ;
  296.  SXN1b = NU_SUR_E * (Y - X)           ;
  297.  SXN1c = EX * (X + (2. * Y))          ;
  298.  SXN1d = 1. - (GDT * (SXN1b - SXN1c)) ;
  299.  SXN1e = SXN1a * SXN1d                ;
  300.  SXN1a = (GDT * AZ) + SZN             ;
  301.  SXN1b = NU_SUR_E * (X + (2. * Y))    ;
  302.  SXN1c = EZ * (Y - X)                 ;
  303.  SXN1d = GDT * (SXN1b - SXN1c)        ;
  304.  SXN1  = SXN1e - (SXN1a * SXN1d)      ;
  305.  SXN1  = SXN1 / GDET1                 ;
  306.  
  307. 'FINP' SXN1 SZN1 ;
  308. ************************************************************************
  309. *
  310. ************************************************************************
  311. 'DEBP' FISZ      XFN1*'FLOTTANT' SXN1*'FLOTTANT' PAX*'FLOTTANT'        PAZ*'FLOTTANT' EX*'FLOTTANT'   NU_SUR_E*'FLOTTANT'  C12*'FLOTTANT'         C3*'FLOTTANT'   ;
  312.  
  313.  UNTIER = 1. / 3. ;  DEUXTIER = 2. / 3. ; UNDEMI = 1. / 2. ;
  314.  
  315.  AZ  = (EX * PAZ) + (NU_SUR_E * PAX) ;
  316.  
  317.  A   = XFN1 / (1. - XFN1)                     ;
  318.  B   = (1. + (DEUXTIER * XFN1)) / (1. - XFN1) ;
  319.  
  320.  X   =  UNTIER   * C12 * A                    ;
  321.  Y   = (DEUXTIER * C12 * B) + (UNDEMI * C3)   ;
  322.  
  323.  VFZ1     = NU_SUR_E * (X + (2. * Y)) ;
  324.  VFZ1     = VFZ1 + ((X - Y) * EX)     ;
  325.  VFZ1     = SXN1 * VFZ1               ;
  326.  VEPSFZN1 = (AZ - VFZ1) / EX          ;
  327.  
  328. 'FINP' VEPSFZN1 ;
  329. ************************************************************************
  330. *
  331. CONVSIG = 1E6                      ;
  332. CONVTO  = 24.*3600E3               ;
  333. *
  334. TFIN  = 1E5                        ;
  335. TMIL  = TFIN / 2.                  ;
  336. *
  337. * ------------------------------*
  338. * Chargement en temperature cte *
  339. * ------------------------------*
  340. TP1      = 1E-4                                                 ;
  341. TE0      = 1320. + 273.                                         ;
  342. TE2      = (TP1*TFIN) + TE0                                     ;
  343. CHTEMP   = 'MANU' 'CHPO' VOL1 1 'T' 1.                          ;
  344. EVT      = 'EVOL' 'MANU' ('PROG' 0.  TFIN)  ('PROG' TE1 TE1)    ;
  345. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                                ;
  346. * -------------------------------------*
  347. * Chargement en densite de fission cte *
  348. * -------------------------------------*
  349. PHIP1    = 3E14                                                 ;
  350. PHI2     = PHIP1 * TFIN                                         ;
  351. CHFISS   = 'MANU' 'CHPO' VOL1 1 'DFIS' 1.                       ;
  352. EVF      = 'EVOL' 'MANU' ('PROG' 0.  TFIN) ('PROG' PHI1 PHI1)   ;
  353. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF                             ;
  354. *
  355. *
  356. TE  = TE1                                  ;
  357. PHI = PHI1                                 ;
  358. UN  = 1.                                   ;
  359. *
  360. * --------------------------------------------------------------------
  361. * Coefficients pour la viscoplasticite, l"elasticite et la fissuration
  362. * --------------------------------------------------------------------
  363. *
  364. * Facteurs multiplicatifs dus au dopage par le Chrome      
  365. *
  366. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  367. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) )       ;
  368. CV  = 180. / PI                                  ;
  369. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') )   ;
  370. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2             ;
  371. *
  372. CP  = -1. * (TA.'QP') / (TA.'R') / TE ;
  373. CP  = TA.'KPUO' * ('EXP' CP)          ;
  374. *
  375. C1 = -1. * (TA.'Q1') / (TA.'R') / TE       ;
  376. C1 = ( (TA.'DG')**(TA.'M1') ) * ('EXP' C1) ;
  377. C1 = (TA.'K1') / ((TA.'N1') + 1) * C1      ;
  378. C1 = WC1 * C1                              ;
  379. *
  380. C2 = -1. * (TA.'Q2') / (TA.'R') / TE       ;
  381. C2 = WC2 * ('EXP' C2)                      ;
  382. C2 = (TA.'K2') / ((TA.'N2') + 1) * C2      ;
  383. *
  384. C3 = -1. * (TA.'Q3') / (TA.'R') / TE       ;
  385. C3 = (TA.'A') * PHI * ('EXP' C3)           ;
  386. C3 = C3 + (PHI * CP)                       ;
  387. *
  388. TETA = 'TANH' (TE / (TA.'H'))              ;
  389. TETA = 0.5 * (TA.'BETA') * (UN + TETA)     ;
  390. *
  391. GROPHI = UN + ((TA.'K') * PHI)             ;
  392. *
  393. C12 = ((UN - TETA) * C1) + (TETA * C2)     ;
  394. C12 = 1.5 * GROPHI * C12                   ;
  395. *
  396. E    = 'MAXI' EE    ;
  397. NU   = 'MAXI' UU    ;
  398. NU_SUR_E = NU / E   ;
  399. ALFA = 'MAXI' XALFA ;
  400. *
  401. LZ    = 'MAXI' ('EXCO' MATR16 'LZZ')          ;
  402. PENTZ = -1. * ( (XLTR1**2) / (2.*XGFTR1) )    ;
  403. JZ    = 1./(LZ*PENTZ)                         ;
  404. JX    = JZ                                    ;
  405. JX0   = JX                                    ;
  406. *
  407. COEF     = 0.8                            ;
  408. EPSZ_PT  = 3E-7                           ; EPSX_PT  = COEF * EPSZ_PT ;
  409. EPSTH_PT = 0.                             ;
  410. EPSG_PT  = TA.'KGON' * TAU0 * PHI / 3.    ;
  411. PAZ      = EPSZ_PT - (EPSTH_PT + EPSG_PT) ;
  412. PAX      = EPSX_PT - (EPSTH_PT + EPSG_PT) ;
  413. *
  414. *
  415. PRECIS = 1E-3 ;
  416. SXN = 0.    ; SZN = 0.    ; FN = PO ; TN = 0. ;
  417. EPSFZN = 0. ; EPSFXN = 0. ;
  418. *
  419. LTIME  = 'PROG' TN  ;
  420. LSX    = 'PROG' SXN ; LSZ   = 'PROG' SZN  ;
  421. LF     = 'PROG' FN  ;
  422. LEPSFX = 'PROG' 0.  ; LEPSFZ = 'PROG' 0.  ;
  423. LEPSVX = 'PROG' 0.  ; LEPSVZ = 'PROG' 0.  ;
  424. *
  425. * -----------
  426. * t <= TFISS1
  427. * -----------
  428. EX  = 1./E ; EZ  = 1./E ;
  429. *
  430. DT  = 20. ;
  431. *--
  432. 'REPE' BLO1 ;
  433. *--
  434.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  435.  
  436.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  437.  
  438.    LIMZ = (1. + PRECIS) * XLTR1              ;
  439.    'SI' ('>' SZN1 LIMZ)                      ;
  440.       DT = DT * (XLTR1 - SZN) / (SZN1 - SZN) ;
  441.       'ITERER' BLO1                          ;
  442.    'FINSI'                                   ;
  443.  
  444.    TN1 = TN + DT  ;
  445.  
  446.    EPSFZN1 = 0. ; EPSFXN1 = 0. ;
  447. *
  448.    LTIME  = LTIME  'ET' ('PROG' TN1)   ;
  449.    LF     = LF     'ET' ('PROG' FN1)   ;
  450.    LSX    = LSX    'ET' ('PROG' SXN1)  ;
  451.    LSZ    = LSZ    'ET' ('PROG' SZN1)  ;
  452.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1) ;
  453.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1) ;
  454. *
  455.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  456.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  457. *
  458.    TESTZ = 'ABS' ((SZN1 - XLTR1) / XLTR1) ;
  459.    'SI' ('&lt;EG' TESTZ PRECIS)              ;
  460.       'QUIT' BLO1                         ;
  461.    'FINSI'                                ;
  462. *--
  463. 'FIN' BLO1 ;
  464. *--
  465. * --------------------
  466. * TFISS1 < t <= TFISS2
  467. * --------------------
  468. EZ  = (1./E) + JZ                     ;
  469. *
  470. DT  = 20. ;
  471. *--
  472. 'REPE' BLO2 ;
  473. *--
  474.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  475.  
  476.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  477.  
  478.    LIMZ = -0.5E6                          ;
  479.    'SI' ('<' SZN1 LIMZ)                   ;
  480.       DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  481.       'ITERER' BLO2                       ;
  482.    'FINSI'                                ;
  483.  
  484.    LIMX = (1. + PRECIS) * XLTR1              ;
  485.    'SI' ('>' SXN1 LIMX)                      ;
  486.       DT = DT * (XLTR1 - SXN) / (SXN1 - SXN) ;
  487.       'ITERER' BLO2                          ;
  488.    'FINSI'                                   ;
  489.  
  490.    TN1 = TN + DT  ;
  491.  
  492.    EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ; EPSFXN1 = 0. ;
  493. *
  494.    LTIME  = LTIME  'ET' ('PROG' TN1)      ;
  495.    LF     = LF     'ET' ('PROG' FN1)      ;
  496.    LSX    = LSX    'ET' ('PROG' SXN1)     ;
  497.    LSZ    = LSZ    'ET' ('PROG' SZN1)     ;
  498.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1)  ;
  499.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1)  ;
  500. *
  501.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  502.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  503. *
  504.    TESTZ = 'ABS' SZN1                   ;
  505.    'SI' ('&lt;EG' TESTZ ('ABS' LIMZ))      ;
  506.       'QUIT' BLO2                       ;
  507.    'FINSI'                              ;
  508.  
  509.    TESTX = 'ABS' ((SXN1 - XLTR1) / XLTR1) ;
  510.    'SI' ('&lt;EG' TESTX PRECIS)              ;
  511.       'QUIT' BLO2                         ;
  512.    'FINSI'                                ;
  513. *--
  514. 'FIN' BLO2 ;
  515. *--
  516. * -----------------------------
  517. * TFISS1 < TFISS2 < t <= TRUPT1
  518. * -----------------------------
  519. EX  = (1./E) + JX                     ;
  520. *
  521. DT  = 20. ;
  522. *--
  523. 'REPE' BLO3 ;
  524. *--
  525.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  526.  
  527.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  528.  
  529.    LIMZ = -0.5E6                          ;
  530.    'SI' ('<' SZN1 LIMZ)                   ;
  531.       DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  532.       'ITERER' BLO3                       ;
  533.    'FINSI'                                ;
  534.  
  535.    'SI' ('>' (SXN1 - SXN) 0.)             ;
  536.       'QUIT' BLO3                         ;
  537.    'FINSI'                                ;
  538.  
  539.    LIMX = -0.5E6                          ;
  540.    'SI' ('<' SXN1 LIMX)                   ;
  541.       DT = DT * (0. - SXN) / (SXN1 - SXN) ;
  542.       'ITERER' BLO3                       ;
  543.    'FINSI'                                ;
  544.  
  545.    TN1 = TN + DT  ;
  546.  
  547.    EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  548.    EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ;
  549. *
  550.    LTIME  = LTIME  'ET' ('PROG' TN1)      ;
  551.    LF     = LF     'ET' ('PROG' FN1)      ;
  552.    LSX    = LSX    'ET' ('PROG' SXN1)     ;
  553.    LSZ    = LSZ    'ET' ('PROG' SZN1)     ;
  554.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1)  ;
  555.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1)  ;
  556. *
  557.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  558.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  559. *
  560.    TESTZ = 'ABS' SZN1                   ;
  561.    'SI' ('&lt;EG' TESTZ ('ABS' LIMZ))      ;
  562.       'QUIT' BLO3                       ;
  563.    'FINSI'                              ;
  564.  
  565.     TESTX = 'ABS' SXN1                  ;
  566.    'SI' ('&lt;EG' TESTX ('ABS' LIMX))      ;
  567.       'QUIT' BLO3                       ;
  568.    'FINSI'                              ;
  569. *--
  570. 'FIN' BLO3 ;
  571. * -------------------------------------------------------
  572. * t <= TRUPT1 < TRUPT2 et fermeture de la fissure selon X
  573. * -------------------------------------------------------
  574. SMAX    = SXN                              ;
  575. EMAX    = EPSFXN                           ;
  576. WMAX    = EMAX * LZ                        ;
  577. WFERM   = XBTR * WMAX                      ;
  578. EFERM   = XBTR * EMAX                      ;
  579. JX      = (EMAX - EFERM) / SMAX            ;
  580. EX      = (1./E) + JX                      ;
  581. *
  582. DT  = 20. ;
  583. *--
  584. 'REPE' BLO4 ;
  585. *--
  586.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  587.  
  588.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  589.  
  590.    LIMZ = -0.5E6                          ;
  591.    'SI' ('<' SZN1 LIMZ)                   ;
  592.       DT = DT * (0. - SZN) / (SZN1 - SZN) ;
  593.       'ITERER' BLO4                       ;
  594.    'FINSI'                                ;
  595.  
  596.    TN1 = TN + DT  ;
  597.  
  598.    EPSFXN1 = EPSFXN + (JX * (SXN1 - SXN)) ;
  599.    EPSFZN1 = EPSFZN + (JZ * (SZN1 - SZN)) ;
  600.  
  601.    TESTX = (SXN1 - SXN) * (EPSFXN1 - EPSFXN) ;
  602.    'SI' ('<' TESTX 0.)                       ;
  603.       'QUIT' BLO4                            ;
  604.    'FINSI'                                   ;
  605. *
  606.    LTIME  = LTIME  'ET' ('PROG' TN1)      ;
  607.    LF     = LF     'ET' ('PROG' FN1)      ;
  608.    LSX    = LSX    'ET' ('PROG' SXN1)     ;
  609.    LSZ    = LSZ    'ET' ('PROG' SZN1)     ;
  610.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1)  ;
  611.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1)  ;
  612. *
  613.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  614.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  615. *
  616.    TESTZ = 'ABS' SZN1                   ;
  617.    'SI' ('&lt;EG' TESTZ ('ABS' LIMZ))      ;
  618.       'QUIT' BLO4                       ;
  619.    'FINSI'                              ;
  620. *--
  621. 'FIN' BLO4 ;
  622. * ------------------------------------------------
  623. * TRUPT1 <= t et reouverture de la fissure selon X
  624. * ------------------------------------------------
  625. SZN1 = 0. ; SZN = SZN1 ;
  626. EZ      = E ;
  627. *
  628. DT  = 20. ;
  629. *--
  630. 'REPE' BLO5 ;
  631. *--
  632.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  633.  
  634.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  635.  
  636.  
  637.    TN1 = TN + DT  ;
  638.  
  639.    EPSFXN1  = EPSFXN + (JX * (SXN1 - SXN))        ;
  640.    VEPSFZN1 = FISZ   FN1  SXN1      PAX  PAZ EX   NU_SUR_E  C12  C3       ;
  641.    EPSFZN1 = EPSFZN + (DT * VEPSFZN1)             ;
  642.  
  643.    'SI' ('>' SXN1 SMAX)                      ;
  644.       'QUIT' BLO5                            ;
  645.    'FINSI'                                   ;
  646. *
  647.    LTIME  = LTIME  'ET' ('PROG' TN1)      ;
  648.    LF     = LF     'ET' ('PROG' FN1)      ;
  649.    LSX    = LSX    'ET' ('PROG' SXN1)     ;
  650.    LSZ    = LSZ    'ET' ('PROG' SZN1)     ;
  651.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1)  ;
  652.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1)  ;
  653. *
  654.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  655.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  656. *--
  657. 'FIN' BLO5 ;
  658. * ---------------------------------------------------
  659. * TRUPT1 < t <= TRUPT2
  660. * (reouverture de la fissure selon X jusqu a rupture)
  661. * ---------------------------------------------------
  662. * Le calcul est conduit jusqu a TEND seulement:
  663. TEND = 2E4        ;
  664. *
  665. SXN    = SMAX       ;
  666. EPSFXN = EMAX       ;
  667. *
  668. JX   = JX0          ;
  669. EX   = (1./E) + JX  ;
  670. *
  671. DT  = 100. ;
  672. *--
  673. 'REPE' BLO6 ;
  674. *--
  675.    FN1 GDET1 = FCTNUL   FN   DT   SXN        SZN   PAX   PAZ EX   EZ   NU_SUR_E   C12   C3         ;
  676.  
  677.    SXN1 SZN1 = CONT     FN1  GDET1  DT        SXN    SZN   PAX    PAZ  EX   EZ     NU_SUR_E  C12    C3               ;
  678.  
  679.  
  680.    TN1 = TN + DT  ;
  681.  
  682.    'SI' ('>' TN1 TEND)  ;
  683.       'QUIT' BLO6       ;
  684.    'FINSI'              ;
  685.  
  686.  
  687.    EPSFXN1  = EPSFXN + (JX * (SXN1 - SXN))        ;
  688.    VEPSFZN1 = FISZ   FN1  SXN1      PAX  PAZ EX   NU_SUR_E  C12  C3       ;
  689.    EPSFZN1 = EPSFZN + (DT * VEPSFZN1)             ;
  690.  
  691.    LIMX = -0.5E6                          ;
  692.    'SI' ('<' SXN1 LIMZ)                   ;
  693.       'QUIT' BLO6                         ;
  694.    'FINSI'                                ;
  695. *
  696.    LTIME  = LTIME  'ET' ('PROG' TN1)      ;
  697.    LF     = LF     'ET' ('PROG' FN1)      ;
  698.    LSX    = LSX    'ET' ('PROG' SXN1)     ;
  699.    LSZ    = LSZ    'ET' ('PROG' SZN1)     ;
  700.    LEPSFX = LEPSFX 'ET' ('PROG' EPSFXN1)  ;
  701.    LEPSFZ = LEPSFZ 'ET' ('PROG' EPSFZN1)  ;
  702. *
  703.    TN = TN1 ; SXN = SXN1 ; SZN = SZN1 ; FN = FN1 ;
  704.    EPSFZN = EPSFZN1 ; EPSFXN = EPSFXN1 ;
  705. *--
  706. 'FIN' BLO6 ;
  707. *
  708. EV_SX    ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'SIGX(MPa)'  (LSX/CONVSIG);
  709. EV_SZ    ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'SIGZ(MPa)' (LSZ/CONVSIG);
  710. EV_F     ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Porosite' LF          ;
  711. EV_EPSFX ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Def Fiss X' LEPSFX    ;
  712. EV_EPSFZ ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'Def Fiss Z' LEPSFZ    ;
  713. EV_WX    ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'WX(m)'     (LZ*LEPSFX);
  714. EV_WZ    ='EVOL' 'ROUG' 'MANU' 'Temps(s)' LTIME 'WZ(m)'     (LZ*LEPSFZ);
  715. EV_FISX  ='EVOL' 'ROUG' 'MANU' 'WX(m)'   (LZ*LEPSFX) 'SIGX(MPa)' (LSX/CONVSIG);
  716. EV_FISZ  ='EVOL' 'ROUG' 'MANU' 'WZ(m)'   (LZ*LEPSFZ)  'SIGZ(MPa)' (LSZ/CONVSIG);
  717. * ---------------------------------*
  718. * Chargement en deplacement impose *
  719. * ---------------------------------*
  720. EPS_TFIN = EPSZ_PT * TFIN                                      ;
  721. DEPZ     = 'DEPI' CLZH 1                                      ;
  722. DEPX     = 'DEPI' CLXD 1                                      ;
  723. LDEPX    = 'PROG' 0  TFIN                                     ;
  724. LDEPY    = ('PROG' 0  EPS_TFIN) * HS2                         ;
  725. 'TITR' 'DEPLACEMENT IMPOSE'                                   ;
  726. EVDEP    = 'EVOL' 'MANU' 'Temps (s)' LDEPX   'Dep (m)'  LDEPY ;
  727. 'SI' DESSI ; 'DESS' EVDEP ; 'FINSI' ;
  728. CHARMECZ = 'CHAR' 'DIMP' DEPZ EVDEP                           ;
  729. CHARMECX = 'CHAR' 'DIMP' DEPX (COEF*EVDEP)                    ;
  730. CHARMECA = CHARMECZ 'ET' CHARMECX                             ;
  731. *-------------------*
  732. * Instants calcules *
  733. *-------------------*
  734. LIST1 = 'PROG' 0. 'PAS' 200.  TEND ;
  735. *
  736. * ---------------------------------------*
  737. * Variables internes initiales 'PORO'=PO *
  738. * ---------------------------------------*
  739. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  740. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO  'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  741. VAR0 = VAR00 + VAR01                                               ;
  742. *
  743. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS             ;
  744. *
  745.  TAB1                          = TABLE   ;
  746.  TAB1.'VARIABLES_INTERNES'     = TABLE   ;
  747.  TAB1.'BLOCAGES_MECANIQUES'    = CLT     ;
  748.  TAB1.'MODELE'                 = MODL1   ;
  749.  TAB1.'CHARGEMENT'             = CHARTOT ;
  750.  TAB1.'VARIABLES_INTERNES' . 0 = VAR0    ;
  751.  TAB1.'CARACTERISTIQUES'       = MATR1   ;
  752.  TAB1.'TEMPS_CALCULES'         = LIST1   ;
  753.  TAB1.'TEMPS_SAUVES'           = LIST1   ;
  754. *
  755. TMASAU=table;
  756. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  757. TMASAU .'DEFTO'=VRAI;
  758. TMASAU .'DEFIN'=VRAI;
  759.  PASAPAS TAB1                            ;
  760. *
  761. *
  762. * -----------------------*
  763. * Controle des resultats *
  764. * -----------------------*
  765. TT    = TAB1 . 'TEMPS'                      ;
  766. SS    = TAB1 . 'CONTRAINTES'                ;
  767. VV    = TAB1 . 'VARIABLES_INTERNES'         ;
  768. IN    = TAB1 . 'DEFORMATIONS_INELASTIQUES'  ;
  769. NCONT = 'DIME' TAB1 . 'CONTRAINTES'         ;
  770. *
  771. LZEIT  = 'PROG' ;
  772. LSIGX  = 'PROG' ;
  773. LSIGZ  = 'PROG' ;
  774. LW1    = 'PROG' ;
  775. LW2    = 'PROG' ;
  776. LW3    = 'PROG' ;
  777. LPORO  = 'PROG' ;
  778. LEFX   = 'PROG' ;
  779. LEFZ   = 'PROG' ;
  780. *
  781. MI = 'MOTS' 'EIXX' 'EIYY' 'EIZZ' 'GIXY' 'GIXZ' 'GIYZ' ;
  782. MV = 'MOTS' 'EVXX' 'EVYY' 'EVZZ' 'GVXY' 'GVXZ' 'GVYZ' ;
  783. ME = 'MOTS' 'EPXX' 'EPYY' 'EPZZ' 'GAXY' 'GAXZ' 'GAYZ' ;
  784. *
  785. *
  786. 'REPE' BLOC NCONT ;
  787. *
  788.   IND  = &BLOC - 1         ;
  789.   ZEIT = TT.IND            ;
  790. *
  791.   SIG  = SS.IND            ;
  792.   SIG  = 'RTENS' SIG MODL1 VX2 (0 1 0)                ;
  793.   SIGX = 'EXCO' SIG 'SMXX' ;
  794.   SIGX_MAX = 'MAXI' SIGX   ; SIGX_MIN = 'MINI' SIGX   ;
  795.   SIGZ = 'EXCO' SIG 'SMZZ' ;
  796.   SIGZ_MAX = 'MAXI' SIGZ   ; SIGZ_MIN = 'MINI' SIGZ   ;
  797. *
  798.   VI    = VV.IND                                           ;
  799.   EI    = IN.IND                                           ;
  800.   EI    = 'CHANG' 'TYPE' ('EXCO' MI EI ME) 'DEFORMATIONS'  ;
  801. *
  802.   EPS_VP = 'CHANG' 'TYPE' ('EXCO' MV VI ME) 'DEFORMATIONS' ;
  803.   DIF    = EI - EPS_VP                                     ;
  804.   DIF    = 'RTENS' DIF MODL1 VX2 (0 1 0)                   ;
  805. *
  806.   PORO  = 'MAXI' ('EXCO' VI 'PORO')     ;
  807.   W1    = 'MAXI' ('EXCO' VI 'W1')       ;
  808.   W2    = 'MAXI' ('EXCO' VI 'W2')       ;
  809.   W3    = 'MAXI' ('EXCO' VI 'W3')       ;
  810. *
  811.   LZEIT  = LZEIT  'ET' ('PROG' ZEIT)                        ;
  812.   LSIGX  = LSIGX  'ET' ('PROG' SIGX_MAX)                    ;
  813.   LSIGZ  = LSIGZ  'ET' ('PROG' SIGZ_MAX)                    ;
  814.   LW1    = LW1    'ET' ('PROG' W1)                          ;
  815.   LW2    = LW2    'ET' ('PROG' W2)                          ;
  816.   LW3    = LW3    'ET' ('PROG' W3)                          ;
  817.   LEFX   = LEFX   'ET' ('PROG' ('MAXI' ('EXCO' DIF 'EPXX')));
  818.   LEFZ   = LEFZ   'ET' ('PROG' ('MAXI' ('EXCO' DIF 'EPZZ')));
  819.   LPORO  = LPORO  'ET' ('PROG' PORO)                        ;
  820. *
  821. 'FIN' BLOC ;
  822. *
  823. * ----------------------
  824. * CONTROLE DES RESULTATS
  825. * ----------------------
  826. LSOUS   = 'PROG' 1E3 'PAS' 1E3 (TEND - 1E3) ;
  827. UN      = 'PROG' ('DIME' LSOUS)*1           ;
  828. *
  829. SX_CAL  = 'IPOL' LSOUS LZEIT LSIGX; SX_ANA  = 'IPOL' LSOUS LTIME LSX   ;
  830. SZ_CAL  = 'IPOL' LSOUS LZEIT LSIGZ; SZ_ANA  = 'IPOL' LSOUS LTIME LSZ   ;
  831. PO_CAL  = 'IPOL' LSOUS LZEIT LPORO; PO_ANA  = 'IPOL' LSOUS LTIME LF    ;
  832. EFX_CAL = 'IPOL' LSOUS LZEIT LEFX ; EFX_ANA = 'IPOL' LSOUS LTIME LEPSFX;
  833. EFZ_CAL = 'IPOL' LSOUS LZEIT LEFZ ; EFZ_ANA = 'IPOL' LSOUS LTIME LEPSFZ;
  834. *
  835. PREX = 5E-3                                                       ;
  836. T_SX =  (SX_ANA - SX_CAL) / (SX_ANA + UN)                         ;
  837. T_SX = 'MAXI' ('ABS' T_SX)                                        ;
  838. 'SI' ( T_SX '&lt;EG' PREX )                                          ;
  839.    'ERRE' 0                                                       ;
  840. 'SINO'                                                            ;
  841.    'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON X = ' T_SX ' > ' PREX ;
  842.    'ERRE' 5                                                       ;
  843. 'FINS'                                                            ;
  844. *
  845. T_SZ = (SZ_ANA - SZ_CAL) / (SZ_ANA + UN)                          ;
  846. T_SZ = 'MAXI' ('ABS' T_SZ)                                        ;
  847. 'SI' ( T_SZ '&lt;EG' PREX )                                          ;
  848.    'ERRE' 0                                                       ;
  849. 'SINO'                                                            ;
  850.    'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON Z = ' T_SZ ' > ' PREX ;
  851.    'ERRE' 5                                                       ;
  852. 'FINS'                                                            ;
  853. *
  854. PREX = 1E-4                                             ;
  855. T_LF = (PO_ANA - PO_CAL) / PO_ANA                       ;
  856. T_LF = 'MAXI' ('ABS' T_LF)                              ;
  857. 'SI' ( T_LF '&lt;EG' PREX )                                ;
  858.    'ERRE' 0                                             ;
  859. 'SINO'                                                  ;
  860.    'MESS' 'ERREUR MAXIMALE POROSITE = ' T_LF ' > ' PREX ;
  861.    'ERRE' 5                                             ;
  862. 'FINS'                                                  ;
  863. *
  864. WRUPT   = (2.*XGFTR1) / XLTR1                          ;
  865. ERUPT   = WRUPT / LZ                                   ;
  866. NONZERO = (ERUPT / 1E6) * UN                           ;
  867. PREX  = 1E-1                                           ;
  868. T_FX  = (EFX_ANA - EFX_CAL) / (EFX_ANA +  NONZERO)     ;
  869. T_FX  = 'MAXI' ('ABS' T_FX)                            ;
  870. 'SI' ( T_FX '&lt;EG' PREX )                               ;
  871.    'ERRE' 0                                            ;
  872. 'SINO'                                                 ;
  873.    'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION  SELON X = ' T_FX ' > ' PREX                            ;
  874.    'ERRE' 5                                            ;
  875. 'FINS'                                                 ;
  876. *
  877. PREX = 1E-2                                            ;
  878. T_FZ = (EFZ_ANA - EFZ_CAL) / (EFZ_ANA +  NONZERO)      ;
  879. T_FZ = 'MAXI' ('ABS' T_FZ)                             ;
  880. 'SI' ( T_FZ '&lt;EG' PREX )                               ;
  881.    'ERRE' 0                                            ;
  882. 'SINO'                                                 ;
  883.    'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION  SELON Z = ' T_FZ ' > ' PREX                 ;
  884.    'ERRE' 5                                            ;
  885. 'FINS'                                                 ;
  886. *
  887. *
  888. TAB               = 'TABLE'               ;
  889. TAB . 'TITRE'     = 'TABLE'               ;
  890. TAB . 'TITRE' . 1 = 'Solution Analytique' ;
  891. TAB . 'TITRE' . 2 = 'Solution Calculee'   ;
  892. *
  893. *
  894. EVSIGX = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'SIGX(MPa)' (LSIGX/CONVSIG);
  895. EVSIGZ = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'SIGZ(MPa)' (LSIGZ/CONVSIG);
  896. 'SI' DESSI                                 ;
  897.    'TITR' 'CONTRAINTE DANS LA DEUXIEME DIRECTION DE FISSURATION' ;
  898.    'DESS' (EV_SX 'ET' EVSIGX) TAB 'LEGE'                         ;
  899.    'TITR' 'CONTRAINTE DANS LA PREMIERE DIRECTION DE FISSURATION' ;
  900.    'DESS' (EV_SZ 'ET' EVSIGZ) TAB 'LEGE'                         ;
  901. 'FINSI'                                                          ;
  902. *
  903. EVPORO = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'Porosite' LPORO ;
  904. 'SI' DESSI                                 ;
  905.    'TITR' 'POROSITE'                       ;
  906.    'DESS' (EV_F 'ET' EVPORO) TAB 'LEGE'    ;
  907. 'FINSI'                                    ;
  908. *
  909. EVWX  = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'WX(m)' LW2            ;
  910. EVWZ  = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'WZ(m)' LW1            ;
  911. 'SI' DESSI                                                      ;
  912.    'TITR' 'OUVERTURE DANS LA DEUXIEME DIRECTION DE FISSURATION' ;
  913.    'DESS' (EV_WX 'ET' EVWX) TAB 'LEGE'                          ;
  914.    'TITR' 'OUVERTURE DANS LA PREMIERE DIRECTION DE FISSURATION' ;
  915.    'DESS' (EV_WZ 'ET' EVWZ) TAB 'LEGE'                          ;
  916. 'FINSI'                                                         ;
  917. *
  918. EVEPSFX = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'Def Fiss X' LEFX    ;
  919. EVEPSFZ = 'EVOL' 'MANU' 'Temps (s)' LZEIT  'Def Fiss Z' LEFZ    ;
  920. 'SI' DESSI                                                      ;
  921.    'TITR' 'DEFORMATION DE FISS. DANS LA DIRECTION DE FISS. N_2' ;
  922.    'DESS' (EV_EPSFX 'ET' EVEPSFX) TAB 'LEGE'                    ;
  923.    'TITR' 'DEFORMATION DE FISS. DANS LA DIRECTION DE FISS. N_1' ;
  924.    'DESS' (EV_EPSFZ 'ET' EVEPSFZ) TAB 'LEGE'                    ;
  925. 'FINSI'                                                         ;
  926. *
  927. EVFISX = 'EVOL' 'MANU' 'WX(m)' LW2 'SIGX(MPa)' (LSIGX/CONVSIG)       ;
  928. EVFISZ = 'EVOL' 'MANU' 'WZ(m)' LW1 'SIGZ(MPa)' (LSIGZ/CONVSIG)       ;
  929. 'SI' DESSI                                                           ;
  930.    'TITR' 'RELATION CONTR./OUVERTURE DANS LA DIRECTION DE FISS. N_2' ;
  931.    'DESS' (EV_FISX 'ET' EVFISX) TAB 'LEGE'                           ;
  932.    'TITR' 'RELATION CONTR./OUVERTURE DANS LA DIRECTION DE FISS. N_1' ;
  933.    'DESS' (EV_FISZ 'ET' EVFISZ) TAB 'LEGE'                           ;
  934. 'FINSI'                                                              ;
  935. *
  936. 'FIN';
  937.  
  938.  
  939.  
  940.  
  941.  
  942.  
  943.  
  944.  
  945.  
  946.  
  947.  
  948.  
  949.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales