Télécharger tran14.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : tran10.dgibi
  2. *
  3. * Copie du cas-test "tran8.dgibi" pour tester
  4. * la donnee a PASAPAS d'une :
  5. * - CAPACITE_CONSTANTE
  6. * - CONDUCTIVITE_CONSTRANTE
  7. * et resolution par la procedure DUPONT
  8.  
  9. * Calcul avec des EF TRI6 (au lieu de QUA4)
  10.  
  11. *******************************************
  12. *******************************************
  13.  
  14. *******************************************
  15. * Test tran10.dgibi: jeux de données *
  16. * --------------------------------- *
  17. *******************************************
  18.  
  19. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  20. * SINON SI GRAPH DIFFERENT DE N TOUS
  21. * LES GRAPHIQUES SONT AFFICHES
  22.  
  23. GRAPH = 'N' ;
  24.  
  25. SAUT PAGE;
  26. SI (NEG GRAPH 'N') ;
  27. OPTI ECHO 1 ;
  28. OPTI TRAC PSC ;
  29. SINO ;
  30. OPTI ECHO 0 ;
  31. FINSI ;
  32.  
  33. SAUT PAGE;
  34.  
  35. *******************************************
  36. * tran10 *
  37. * *
  38. * THERMIQUE TRANSITOIRE LINEAIRE EN 2D *
  39. * *
  40. * Test NAFEMS numero T3 *
  41. * *
  42. * *
  43. * description *
  44. * ----------- *
  45. * *
  46. * A C B *
  47. * <_0.02_> *
  48. * | | | *
  49. * |=================================| *
  50. * | | *
  51. * <______________0.1 m______________> *
  52. * ---> axe X *
  53. * *
  54. * *
  55. * conditions aux limites *
  56. * ---------------------- *
  57. * *
  58. * - temperature imposee au point A : *
  59. * TA = 0 *
  60. * *
  61. * - temperature imposee au point B : *
  62. * TB = 100 * sin (PI * temps / 40) *
  63. * *
  64. *******************************************
  65. OPTI ELEM TRI6 ;
  66.  
  67. *---------- geometrie : maillage ---------*
  68.  
  69. PA1 = 0. 0.; PB1 = 0.1 0. ;
  70. PA2 = 0. 0.01; PB2 = 0.1 0.01;
  71.  
  72. N = 10;
  73. D1 = PA1 DROI N PB1;
  74. D2 = PB1 DROI 1 PB2;
  75. D3 = PB2 DROI N PA2;
  76. D4 = PA2 DROI 1 PA1;
  77.  
  78. SUR1 = DALL D1 D2 D3 D4 PLAN;
  79.  
  80. PC = POIN SUR1 PROC (0.08 0.);
  81.  
  82.  
  83. SI (NEG GRAPH 'N');
  84. TITR 'TRAN10 : MAILLAGE';
  85. TRAC 'QUAL' SUR1;
  86. FINSI;
  87.  
  88. *--------- modeles - materiaux -----------*
  89. MODL1 = MODE SUR1 THERMIQUE ISOTROPE ;
  90. MATR1 = MATE MODL1 'RHO' 7200 'K' 20.0 'C' 240.5 ;
  91.  
  92. * test de l'option 'CAPACITE_CONSTANTE'
  93. * de PASAPAS :
  94. MATR2 = MATE MODL1 'RHO' 7200 'K' 15.0 'C' 200.0 ;
  95. CAP2 = CAPA MODL1 MATR2 ;
  96. CND2 = COND MODL1 MATR2 ;
  97.  
  98. * temperatures imposees : fonction du temps
  99. *
  100. * - Cote PA : temperature constante
  101. * de 0 degres celcius
  102. * - Cote PB : temperature variable
  103. * en fonction du temps
  104.  
  105. BLOCD4 = BLOQ D4 'T';
  106. BLOCD2 = BLOQ D2 'T';
  107.  
  108. TEMPD4 = DEPI BLOCD4 1.;
  109. TEMPD2 = DEPI BLOCD2 1.;
  110.  
  111. * Un pas toutes les secondes,
  112. * temps maximum 40. s.
  113. LTEMPS = PROG 0. PAS 1. 40.;
  114.  
  115. LD4 = PROG 41 * 0.;
  116. LD2 = PROG SINU (1. / 80.) AMPL 100 LTEMPS;
  117.  
  118. EVOLD4 = EVOL MANU TEMPS LTEMPS THETA LD4;
  119. EVOLD2 = EVOL MANU TEMPS LTEMPS THETA LD2;
  120.  
  121. CHAD4 = CHAR 'TIMP' TEMPD4 EVOLD4;
  122. CHAD2 = CHAR 'TIMP' TEMPD2 EVOLD2;
  123.  
  124. * Creation d'un flux nul (type chargement)
  125. FLU0 = MANU CHPO (D1 ET D3) 1 Q 0.;
  126.  
  127. EVOL3= EVOL MANU TEMP LTEMPS FLUX (PROG 41 * 1.);
  128. FLU1 = CHAR 'Q' FLU0 EVOL3;
  129.  
  130. *--- objets pour la procedure PASAPAS ----*
  131. BLOCT = (BLOCD2 ET BLOCD4);
  132. CHART = (FLU1 ET CHAD4 ET CHAD2);
  133.  
  134. TAB1 = TABL;
  135. TAB1.'TEMPERATURES' = TABL;
  136. TAB1.'TEMPERATURES' . 0 = MANU CHPO SUR1 1 T 0.;
  137. TAB1.'BLOCAGES_THERMIQUES' = BLOCT;
  138. TAB1.'CHARGEMENT' = CHART;
  139. TAB1.'MODELE' = MODL1;
  140. TAB1.'CARACTERISTIQUES' = MATR1;
  141. TAB1.'TEMPS_SAUVES' = PROG 0. PAS 1. 32.;
  142. TAB1.'TEMPS_CALCULES' = PROG 0. PAS 1. 32.;
  143. TAB1.'PROCEDURE_THERMIQUE' = DUPONT ;
  144. TAB1.'CAPACITE_CONSTANTE' = CAP2 ;
  145. TAB1.'CONDUCTIVITE_CONSTANTE' = CND2 ;
  146.  
  147. PASAPAS TAB1;
  148.  
  149. *------- extraction des resultats --------*
  150. * Temperature du point C a t = 32 s.
  151.  
  152. * Construction de l'evolution de T au cours
  153. * du temps
  154.  
  155. LTEMPE = VIDE 'LISTREEL';
  156. LTEMPS = VIDE 'LISTREEL';
  157. NBPAS = DIME (TAB1. 'TEMPS') ;
  158. REPE SURPAS NBPAS;
  159. INDICE = &SURPAS;
  160. LTEMPS = LTEMPS ET (PROG (TAB1.'TEMPS'. (INDICE - 1)));
  161. LTEMPE = LTEMPE ET (PROG (EXTR TAB1.'TEMPERATURES'. (INDICE - 1) T (SUR1 POIN PROC (0.08 0.))));
  162. FIN SURPAS;
  163.  
  164. EVTEMPE = EVOL BLEU MANU LTEMPS LTEMPE;
  165.  
  166.  
  167. THET1 = EXTR LTEMPE NBPAS;
  168. THET2 = 36.6;
  169.  
  170. ERG =100 * (ABS ((THET2 - THET1) / THET2));
  171.  
  172. * Trace facultatif de la repartition
  173. * de temperature a t = 32 s
  174. SI (NEG GRAPH 'N');
  175. TITR 'TRAN10 : Temperature a t = 32 s';
  176. CHPO3 = PECHE TAB1 'TEMPERATURES' TAB1. 'TEMPS' . (NBPAS - 1);
  177. TRAC SUR1 CHPO3;
  178. TITR 'Evolution de la temperature en fonction du temps : ';
  179. DESS EVTEMPE ;
  180. FINSI;
  181.  
  182. *-------- Test Reactions dans solution -------*
  183. IREAC1 = 'EXIS' TAB1 'REACTIONS_THERMIQUES' ;
  184.  
  185. *-------- affichage des resultats --------*
  186.  
  187. MESS ' RESULTATS ';
  188. MESS ' --------- ';
  189.  
  190. MESS 'Temperature theorique :' THET2' C';
  191. MESS 'Temperature calculee :' THET1' C';
  192. MESS ' Soit un ecart de : ' ERG '%';
  193.  
  194. *------- code fonctionnement -------------*
  195. SI ((ERG &lt;EG 5) et IREAC1);
  196. ERRE 0;
  197. SINON;
  198. 'SI' ('NON' IREAC1) ;
  199. 'MESS' '***** ERREUR : il manque les reactions thermiques ! ' ;
  200. 'FINS' ERRE 5;
  201. FINSI;
  202.  
  203. TEMPS;
  204.  
  205. FIN;
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales