Télécharger topoptim_08.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier topoptim_08.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a simple 2D structure subjected to a
  7. ** mechanical loading, with an axial periodicity restriction.
  8. **
  9. ** Author:
  10. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  11. **
  12. ** Version:
  13. ** V1.0 2017/04/18 Original version compatible with TOPOPTIM V2.1
  14. ************************************************************************
  15.  
  16. * General options
  17. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' QUA4 ;
  18. OPTI 'TRAC' 'PSC' ;
  19.  
  20. * Mesh
  21. nelx0 = 120 ;
  22. nely0 = 30 ;
  23. p0 = 0.0 0.0 ;
  24. p1 = 0.0 (FLOT nely0) ;
  25. p2 = (FLOT nelx0) 0.0 ;
  26. lgn0 = DROI nely0 p0 p1 ;
  27. msh0 = TRAN lgn0 nelx0 p2 ;
  28. p2 = msh0 POIN 'PROC' p2 ;
  29. msh1 = msh0 ELEM 'APPU' 'STRI' (msh0 POIN 'DROI' p0 p1 90.1) ;
  30. DEPL 'TOUR' 20.0 p0 msh0 ;
  31.  
  32. * Model and material
  33. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  34. mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  35.  
  36. * Boundary conditions and loading
  37. bc0 = (BLOQ 'UX' lgn0) ET (BLOQ 'UY' p2) ;
  38. load0 = FORC (0.0 -1.0) p1 ;
  39.  
  40. * Factor evolutions
  41. pfct0 = EVOL 'MANU' 'CYCLES' (PROG 5 15) 'P' (PROG 1.0 3.0) ;
  42. qfct0 = EVOL 'MANU' 'CYCLES' (PROG 25 105) 'Q' (PROG 1.0 5.0) ;
  43.  
  44. * Finite element model table
  45. mdl0 = TABL ;
  46. mdl0.'MODELE' = mod0 ;
  47. mdl0.'CARACTERISTIQUES' = mat0 ;
  48. mdl0.'BLOCAGES_MECANIQUES' = bc0 ;
  49. mdl0.'CHARGEMENT' = load0 ;
  50.  
  51. * Optimization table
  52. tab0 = TABL ;
  53. tab0.'RESOLUTION_LINEAIRE' = mdl0 ;
  54. tab0.'FRACTION_VOLUME' = 0.5 ;
  55. tab0.'FACTEUR_P' = pfct0 ;
  56. tab0.'FACTEUR_Q' = qfct0 ;
  57. tab0.'RESTRICTIONS' = TABL ;
  58. tab0.'RESTRICTIONS'.(1) = TABL ;
  59. tab0.'RESTRICTIONS'.(1).'ZONE' = msh1 ;
  60. tab0.'RESTRICTIONS'.(1).'TYPE' = 'PERIODICITE_AXIALE' ;
  61. tab0.'RESTRICTIONS'.(1).'PERIODES' = 3 ;
  62. tab0.'RESTRICTIONS'.(1).'POIN1' = p0 ;
  63. tab0.'RESTRICTIONS'.(1).'POIN2' = p2 / 4.0 ;
  64.  
  65. * Optimization
  66. TOPOPTIM tab0 ;
  67.  
  68. * Plot to screen
  69. topo0 = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  70. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  71. TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  72. (PROG 0.0 'PAS' (1.0 / 56.0) 1.0) ;
  73.  
  74. FIN ;
  75.  
  76.  
  77.  
  78.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales