Télécharger topoptim_02.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier topoptim_02.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a simple 2D structure subjected to a
  7. ** mechanical loading, with penalty factor and GSF.
  8. **
  9. ** Author:
  10. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  11. **
  12. ** Version:
  13. ** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
  14. ** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
  15. ************************************************************************
  16.  
  17. graph0 = FAUX ;
  18.  
  19. * General options
  20. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' QUA4 ;
  21.  
  22. * Mesh
  23. nelx0 = 90 ;
  24. nely0 = 30 ;
  25. p0 = 0.0 0.0 ;
  26. p1 = 0.0 (FLOT nely0) ;
  27. p2 = (FLOT nelx0) 0.0 ;
  28. lgn0 = DROI nely0 p0 p1 ;
  29. msh0 = TRAN lgn0 nelx0 p2 ;
  30. p2 = msh0 POIN 'PROC' p2 ;
  31.  
  32. * Model and material
  33. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  34. mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  35.  
  36. * Boundary conditions and loading
  37. bc0 = (BLOQ 'UX' lgn0) ET (BLOQ 'UY' p2) ;
  38. load0 = FORC (0.0 -1.0) p1 ;
  39.  
  40. * Factor evolutions
  41. pfct0 = EVOL 'MANU' 'CYCLES' (PROG 5 15) 'P' (PROG 1.0 3.0) ;
  42. qfct0 = EVOL 'MANU' 'CYCLES' (PROG 25 105) 'Q' (PROG 1.0 5.0) ;
  43.  
  44. * Finite element model table
  45. mdl0 = TABL ;
  46. mdl0.'MODELE' = mod0 ;
  47. mdl0.'CARACTERISTIQUES' = mat0 ;
  48. mdl0.'BLOCAGES_MECANIQUES' = bc0 ;
  49. mdl0.'CHARGEMENT' = load0 ;
  50.  
  51. * Optimization table
  52. tab0 = TABL ;
  53. tab0.'RESOLUTION_LINEAIRE' = mdl0 ;
  54. tab0.'TAUX_FILTRAGE' = 10 ;
  55. tab0.'FACTEUR_P' = pfct0 ;
  56. tab0.'FACTEUR_Q' = qfct0 ;
  57. tab0.'TRAC' = graph0 ;
  58.  
  59. * Optimization
  60. TOPOPTIM tab0 ;
  61.  
  62. * Plot to screen
  63. topo0 = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  64. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  65. SI graph0 ;
  66. TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  67. (PROG 0.0 'PAS' (1.0 / 56.0) 1.0) ;
  68. FINS ;
  69.  
  70. FIN ;
  71.  
  72.  
  73.  
  74.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales