Télécharger ther62.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ther62.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. SAUT PAGE ;
  6. *-------------------------------------------------------------------*
  7. * TEST THER62
  8. * *
  9. * TEST DES CL DE TEMPERATURE POUR coq4 ET coq3 *
  10. * ------------------------------------------------------------ *
  11. * *
  12. * TEMPERATURE IMPOSEE + CONVECTION *
  13. * + FLUX *
  14. * + SOURCE *
  15. * *
  16. * Ce test permet de v{rifier le bon fonctionnement des divers *
  17. * op{rateurs thermiques de CASTEM2000 dans le cas des {l{ments *
  18. * coq4 et coq3 . *
  19. * *
  20. * UNE PLAQUE RECTANGULAIRE CONSTITUEE D'{L{ments COQ3 et coq4 est *
  21. * soumise @ une temp{rature impos{e @ une de ses extr{mit{s et suc- *
  22. * essivement @ une condition de convection forc{e, @ une condition *
  23. * de flux impos{ et @ une condition de source volumique impos{e. *
  24. * *
  25. * Les r{sultats sont compar{s a ceux obtenus *
  26. * par un calcul {quivalent utilisant les {l{ments massifs. Le mail- *
  27. * -lage n'utilise que des cub8 et est oriente differement pour sim- *
  28. * -plifier le calcul. *
  29. * On compare les temperatures sur la face superieure; le long de la *
  30. * ligne AS2 DS2 *
  31. * Test elabore par Mr Dowlatyari 03/91. *
  32. * Test modifie le 14/05/91 *
  33. * *
  34. * *
  35. * *
  36. *-------------------------------------------------------------------*
  37. ********************************************************************
  38. **************** 1/ calcul en massif *******************************
  39. ********************************************************************
  40. OPTION DIME 3 ELEM QUA4 ;
  41. *qua3 ;
  42. opti elem cub8;
  43. opti trac bens;
  44. graph = 'N';
  45. TEMPS ;
  46. *
  47. *------------- CREATION DE LA GEOMETRIE: POINTS SUPPORTS DES ELEMENTS --
  48. *
  49. As1= 0.25 0. 0.; AS2 =0.25 1.5 0. ; AS3 = 0.25 3. 0.;
  50.  
  51. BS1= 0.25 0. 2.; BS2 =0.25 1.5 2.; BS3 = 0.25 3. 2.;
  52.  
  53. CS1= 0.25 0. 4.; CS2 =0.25 1.5 4; CS3 = 0.25 3. 4.;
  54.  
  55. DS1= 0.25 0. 6.; DS2 =0.25 1.5 6.; DS3 = 0.25 3. 6.;
  56.  
  57.  
  58. *------------- CREATION DES SURFACES ET VOLUMES ------------------ -
  59. *
  60. DAD = AS3 d 3 DS3;
  61. DDD = DS3 D 2 DS1;
  62. DDA = DS1 D 3 AS1;
  63. DAA = AS1 D 2 AS3;
  64. QTOTS = DALL DAD DDD DDA DAA;
  65. V = -0.5 0. 0.;
  66. QTOT = QTOTS VOLU 1 TRAN V;
  67.  
  68. OEIL = 5. 1.5 3.;
  69.  
  70. ge0 = face 1 qtot;
  71. scon = elem ge0 appu larg ddd;
  72.  
  73. ge1 = face 3 qtot;
  74. dfa = qtot poin proc ( 0. 1.5 0. );
  75. sinf = elem ge1 appu larg dfa;
  76.  
  77.  
  78. ssou = elem qtot appu larg ddd;
  79.  
  80.  
  81. si ( NEG GRAPH 'N' );
  82. trac oeil qtot;
  83. trac oeil scon;
  84. trac oeil sinf;
  85. finsi;
  86.  
  87. *--------------- DONNEES DU PROBLEME DE THERMIQUE -----------------------
  88. *
  89. *-------------- MODELISATION -------------------------------------------
  90. *
  91. MOD1 = MODE QTOT THERMIQUE ISOTROPE ;
  92. MOD2 = MODE SCON thermique CONVECTION ;
  93. *
  94. *--------------- DONNEES DES CARACTERISTIQUES DU MATERIAU ---------------
  95. *
  96. MAT1 = MATE MOD1 'K' 100. ;
  97. MAT2 = MATE MOD2 'H' 15. ;
  98. *
  99. *--------------- CREATION DES MATRICES DE CONDUCTIVITE ------------------
  100. *
  101. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  102. CND2 = CONDUCTIVITE MOD2 MAT2 ;
  103. *
  104. *--------------- TEMPERATURES IMPOSEES: BLOQUE + DEPI -------------------
  105. *
  106. BB1 = BLOQUE SINF 'TINF' ;
  107. EE1 = DEPI BB1 10. ;
  108. BB2 = BLOQUE SINF 'TSUP' ;
  109. EE2 = DEPI BB2 10. ;
  110. BB3 = BLOQUE SINF 'T ' ;
  111. EE3 = DEPI BB3 10. ;
  112. BB = BB1 ET BB2 ET BB3 ;
  113. EE = EE1 ET EE2 ET EE3 ;
  114. *
  115. *--------------- FLUX EQUIVALENTS A LA CONDITION DE CONVECTION ----------
  116. *
  117. CNV1 = CONVECTION MOD2 MAT2 'T' 200. ;
  118. *
  119. *--------------- FLUX IMPOSE --------------------------------------------
  120. *
  121. FLU1 = FLUX MOD1 200. SCON;
  122. *
  123. *--------------- SOURCE DE CHALEUR --------------------------------------
  124. *
  125. S1 = SOURCE MOD1 MAT1 1000. SSOU ;
  126. *
  127. *---------------- ASSEMBLAGE DES TERMES DE CONDUCTIVITE -----------------
  128. *
  129. CCC1 = CND1 ET CND2 ET BB ;CCC2 = CND1 ET BB ;
  130. *
  131. *---------------- ASSEMBLAGE DES TERMES DE FLUX EQUIVALENTS -------------
  132. *
  133. FFF1 = EE ET CNV1 ;FFF2 = EE ET FLU1 ;FFF3 = EE ET S1 ;
  134. *
  135. *---------------- 1ERE RESOLUTION : CONVECTION --------------------------
  136. *
  137. CHTER1 = RESOUDRE CCC1 FFF1 ;
  138. *
  139. *---------------- 2EME RESOLUTION : FLUX --------------------------------
  140. *
  141. CHTER2 = RESOUDRE CCC2 FFF2 ;
  142. *
  143. *---------------- 3EME RESOLUTION: SOURCE -------------------------------
  144. *
  145. CHTER3 = RESOUDRE CCC2 FFF3 ;
  146. *
  147. *---------------- POST-TRAITEMENT: -
  148. *---------------- EXTRACTION DES VALEURS CARACTERISTIQUES -----------
  149. *
  150. *LISTE CHTER1 ;
  151. *LISTE CHTER2 ;
  152. *LISTE CHTER3 ;
  153. *
  154. AS2 = QTOT POIN PROC ( 0.25 1.5 0.);
  155. BS2 = QTOT POIN PROC ( 0.25 1.5 2.);
  156. CS2 = QTOT POIN PROC ( 0.25 1.5 4.);
  157. DS2 = QTOT POIN PROC ( 0.25 1.5 6.);
  158.  
  159.  
  160. T1Aq = EXTR CHTER1 T AS2 ;T1Bq =EXTR CHTER1 T BS2 ;
  161. T1Cq = EXTR CHTER1 T CS2 ;T1Dq =EXTR CHTER1 T DS2 ;
  162. T2Aq = EXTR CHTER2 T AS2 ;T2Bq =EXTR CHTER2 T BS2 ;
  163. T2Cq = EXTR CHTER2 T CS2 ;T2Dq =EXTR CHTER2 T DS2 ;
  164. T3Aq = EXTR CHTER3 T AS2 ;T3Bq =EXTR CHTER3 T BS2 ;
  165. T3Cq = EXTR CHTER3 T CS2 ;T3Dq =EXTR CHTER3 T DS2;
  166.  
  167.  
  168. LCON = PROG T1Aq T1Bq T1Cq T1Dq;
  169. LFLU = PROG T2Aq T2Bq T2Cq T2Dq;
  170. LSOU = PROG T3Aq T3Bq T3Cq T3Dq;
  171. *LIST LCON; LIST LFLU; LIST LSOU;
  172.  
  173. *******************************************************************
  174. ********************* 2/ CALCUL EN COQ3 ET COQ4 *******************
  175. *******************************************************************
  176.  
  177.  
  178. TITRE 'C.L. DE TEMPERATURE - ELEMENTS COQ3 COQ4' ;
  179. OPTION DIME 3 ELEM QUA4 ;
  180. *TRI3 ;
  181. TEMPS ;
  182. *
  183. *------------- CREATION DE LA GEOMETRIE: POINTS SUPPORTS DES ELEMENTS --
  184. *
  185. A1 = 0. 0. 0. ; A2 = 0. 1.5 0. ;
  186. B1 = 1.4142 0. 1.4142 ; B2 = 1.4142 1.5 1.4141 ;
  187. C1 = 2.8284 0. 2.8284 ; C2 = 2.8284 1.5 2.8284 ;
  188. D1 = 4.2426 0. 4.2426 ; D2 = 4.2426 1.5 4.2426 ;
  189. A3 = 0. 3. 0. ;
  190. B3 = 1.4142 3. 1.4142 ;
  191. C3 = 2.8284 3. 2.8284 ;
  192. D3 = 4.2426 3. 4.2426 ;
  193. *------------- CREATION DES QUADRANGLES ET TRIANGLES -------------------
  194. *
  195. QQ01 = MANU QUA4 A1 A2 B2 B1 ;
  196. QQ02 = MANU TRI3 B1 B2 C2 ;
  197. QQ03 = MANU TRI3 B1 C2 C1 ;
  198. QQ04 = MANU QUA4 C1 C2 D2 D1 ;
  199. QQ05 = MANU QUA4 A2 A3 B3 B2 ;
  200. QQ06 = MANU TRI3 B2 B3 C3 ;
  201. QQ07 = MANU TRI3 B2 C3 C2 ;
  202. QQ08 = MANU QUA4 C2 C3 D3 D2 ;
  203. *
  204. QTOT = QQ01 ET QQ02 ET QQ03 ET QQ04 ET QQ05 ET QQ06 ET QQ07 ET QQ08 ;
  205.  
  206. SI ( NEG GRAPH 'N');
  207. OEIL = -1000. 0. 1000. ;
  208. TRACE OEIL QTOT ;
  209. FINSI;
  210.  
  211. QSOUR = QQ04 ET QQ08 ;
  212.  
  213. *
  214. DD3 = D 1 A3 A2 ;
  215. DD4 = D 1 A2 A1 ;
  216. L_INF = DD3 ET DD4 ;
  217. *
  218. S_COT = QQ04 ET QQ08 ;
  219. *
  220. * ATTENTION : il faut r{orienter les {l{ments (OPERATEUR ORIENT)
  221. * si on n'est pas sur que tous les elements sont orientes d'une
  222. * facon coh{rante
  223. *
  224. *--------------- DONNEES DU PROBLEME DE THERMIQUE -----------------------
  225. *
  226. *-------------- MODELISATION -------------------------------------------
  227. *
  228. MOD1 = MODE QTOT THERMIQUE ISOTROPE COQ4 COQ3 ;
  229. MOD2 = MODE S_COT thermique CONVECTION SUPERIEURE COQ4 COQ3 ;
  230. *
  231. *--------------- DONNEES DES CARACTERISTIQUES DU MATERIAU ---------------
  232. *
  233. MAT1 = MATE MOD1 'K' 100. 'EPAI' 0.5 ;
  234. MAT2 = MATE MOD2 'H' 15. ;
  235. *
  236. *--------------- CREATION DES MATRICES DE CONDUCTIVITE ------------------
  237. *
  238. CND1 = CONDUCTIVITE MOD1 MAT1 ;
  239. CND2 = CONDUCTIVITE MOD2 MAT2 ;
  240. *
  241. *--------------- TEMPERATURES IMPOSEES: BLOQUE + DEPI -------------------
  242. *
  243. BB1 = BLOQUE L_INF 'TINF' ;
  244. EE1 = DEPI BB1 10. ;
  245. BB2 = BLOQUE L_INF 'TSUP' ;
  246. EE2 = DEPI BB2 10. ;
  247. BB3 = BLOQUE L_INF 'T ' ;
  248. EE3 = DEPI BB3 10. ;
  249. BB = BB1 ET BB2 ET BB3 ;
  250. EE = EE1 ET EE2 ET EE3 ;
  251. *
  252. *--------------- FLUX EQUIVALENTS A LA CONDITION DE CONVECTION ----------
  253. *
  254. CNV1 = CONVECTION MOD2 MAT2 'TSUP' 200.;
  255. *
  256. *--------------- FLUX IMPOSE --------------------------------------------
  257. *
  258. FLU1 = FLUX MOD1 200. S_COT SUPE ;
  259. *
  260. *--------------- SOURCE DE CHALEUR --------------------------------------
  261. *
  262. S1 = SOURCE MOD1 MAT1 1000. QSOUR ;
  263. *
  264. *---------------- ASSEMBLAGE DES TERMES DE CONDUCTIVITE -----------------
  265. *
  266. CCC1 = CND1 ET CND2 ET BB ;CCC2 = CND1 ET BB ;
  267. *
  268. *---------------- ASSEMBLAGE DES TERMES DE FLUX EQUIVALENTS -------------
  269. *
  270. FFF1 = EE ET CNV1 ;FFF2 = EE ET FLU1 ;FFF3 = EE ET S1 ;
  271. *
  272. *---------------- 1ERE RESOLUTION : CONVECTION --------------------------
  273. *
  274. CHTER1 = RESOUDRE CCC1 FFF1 ;
  275. *
  276. *---------------- 2EME RESOLUTION : FLUX --------------------------------
  277. *
  278. CHTER2 = RESOUDRE CCC2 FFF2 ;
  279. *
  280. *---------------- 3EME RESOLUTION: SOURCE -------------------------------
  281. *
  282. CHTER3 = RESOUDRE CCC2 FFF3 ;
  283. *
  284. *---------------- POST-TRAITEMENT: TRACE DES CHAMPS RESULTATS -----------
  285. *---------------- ET EXTRACTION DES VALEURS CARACTERISTIQUES -----------
  286. *
  287. *LISTE CHTER1 ;
  288. *LISTE CHTER2 ;
  289. *LISTE CHTER3 ;
  290. *
  291. OEIL= -1000. 0. 1000. ;
  292. *
  293. SI ( NEG GRAPH 'N');
  294.  
  295. TITRE 'ELEMENTS COQ3,COQ4 : CONVECTION' ;
  296. CHTR1I = 'EXCO' CHTER1 'TINF' 'NOID' 'TINF' ;
  297. TRACER OEIL QTOT CHTR1I ;
  298. TITRE 'ELEMENTS COQ3,COQ4 : FLUX IMPOSE' ;
  299. CHTR2I = 'EXCO' CHTER2 'TINF' 'NOID' 'TINF' ;
  300. TRACER OEIL QTOT CHTR2I ;
  301. TITRE 'ELEMENTS COQ3,COQ4 : SOURCE' ;
  302. CHTR3I = 'EXCO' CHTER3 'TINF' 'NOID' 'TINF' ;
  303. TRACER OEIL QTOT CHTR3I ;
  304.  
  305. FINSI;
  306. *
  307. T1A = EXTR CHTER1 TSUP A2 ;T1B=EXTR CHTER1 TSUP B2 ;
  308. T1C = EXTR CHTER1 TSUP C2 ;T1D=EXTR CHTER1 TSUP D2 ;
  309. T2A = EXTR CHTER2 TSUP A2 ;T2B=EXTR CHTER2 TSUP B2 ;
  310. T2C = EXTR CHTER2 TSUP C2 ;T2D=EXTR CHTER2 TSUP D2 ;
  311. T3A = EXTR CHTER3 TSUP A2 ;T3B=EXTR CHTER3 TSUP B2 ;
  312. T3C = EXTR CHTER3 TSUP C2 ;T3D=EXTR CHTER3 TSUP D2 ;
  313. *
  314. *************************************************************
  315. ********************* 3/ comparaison entre les 2 calculs ****
  316. *************************************************************
  317. si ( NEG graph 'N');
  318. DIST = PROG 0. 2. 4. 6. ;
  319.  
  320. TEMPC1= PROG T1A T1B T1C T1D ;
  321. EV1R = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' lcon ;
  322. EV1C = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' TEMPC1 ;
  323. TAB = 'TABLE' ;
  324. TAB.1 = 'MARQ PLUS' ;
  325. TAB.2 = 'MARQ ETOI' ;
  326. TITRE 'COQ3 ET COQ4 ;TEMPERATURE + CONVECTION ;+ : MASSIF,* : COQUE' ;
  327. DESSIN TAB (EV1R ET EV1C ) ;
  328.  
  329. TEMPC2= PROG T2A T2B T2C T2D ;
  330. EV2R = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' lflu ;
  331. EV2C = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' TEMPC2 ;
  332. TITRE 'COQ3 ET COQ4;TEMPERATURE + FLUX IMPOSE ;+ : MASSIF,* : COQUE';
  333. DESSIN TAB (EV2R ET EV2C ) ;
  334. TEMPC3= PROG T3A T3B T3C T3D ;
  335. EV3R = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' lsou ;
  336. EV3C = EVOL MANU 'DISTANCE' DIST 'TEMPERATURE' TEMPC3 ;
  337. TITRE 'COQ3 ET COQ4 ;TEMPERATURE + SOURCE ;+ MASSIF,* : COQUE ';
  338. DESSIN TAB (EV3R ET EV3C ) ;
  339. TEMPS ;
  340. finsi;
  341. *************************************************************
  342. *************** 4/ TEST DE FONCTIONNEMENT *******************
  343. *************************************************************
  344.  
  345. ERCA= ABS (( T1A-T1Aq)/T1A);
  346. ERCB= ABS (( T1B-T1Bq)/T1B);
  347. ERCC= ABS (( T1C-T1Cq)/T1C);
  348. ERCD= ABS (( T1D-T1Dq)/T1D);
  349. ERFA= ABS (( T2A-T2Aq)/T2A);
  350. ERFB= ABS (( T2B-T2Bq)/T2B);
  351. ERFC= ABS (( T2C-T2Cq)/T2C);
  352. ERFD= ABS (( T2D-T2Dq)/T2D);
  353. ERSA= ABS (( T3A-T3Aq)/T3A);
  354. ERSB= ABS (( T3B-T3Bq)/T3B);
  355. ERSC= ABS (( T3C-T3Cq)/T3C);
  356. ERSD= ABS (( T3D-T3Dq)/T3D);
  357.  
  358. ERTOT = PROG ERCA ERCB ERCC ERCD ERFA ERFB ERFC ERFD ERSA ERSB
  359. ERSC ERSD;
  360. ermax = maxi ertot;
  361. temps;
  362. SI ( ERMAX <EG 0.05 );
  363. ERRE 0;
  364. SINON;
  365. ERRE 5;
  366. FINSI;
  367. fin;
  368.  
  369.  
  370.  
  371.  
  372.  
  373.  
  374.  
  375.  
  376.  
  377.  
  378.  
  379.  
  380.  
  381.  
  382.  
  383.  
  384.  
  385.  
  386.  
  387.  
  388.  
  389.  
  390.  
  391.  
  392.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales