Télécharger stru3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : stru3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. OPTI ECHO 1;
  5. GRAPH = 'N';
  6. *
  7. *********************************************************************
  8. * TEST : SSLS34/91 DE LA COMMISSION "STRUCTURES ASSEMBLEES" *
  9. * ---- *
  10. * *
  11. * DESCRIPTION : PLAQUE ORTHOTROPE RAIDIE SUR APPUIS SIMPLES, *
  12. * SOUS UNE CHARGE UNIFORMEMENT REPARTIE. *
  13. * Elements DKT *
  14. * *
  15. * *
  16. * REF. : JL. BATOZ,J.CHATELAIN,JP. JAMEUX *
  17. * ETUDE D'UNE PLAQUE RAIDIE - BULLETIN DU CLUB S.A.P - *
  18. * VOLUME VIII, N1. *
  19. * Comparaison avec les codes CA.ST.OR, ASELF, ELFINI, PERMAS *
  20. * Test envoye pour evolution le 17/09/92 *
  21. * *
  22. *********************************************************************
  23. OPTI ECHO 1;
  24. OPTI ELEM tri3;
  25. *
  26. * QUELQUES DONNEES
  27. *
  28. OEIL = 10000 -10000 10000;
  29. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  30. * GEOMETRIE *
  31. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  32. *
  33. * PLAQUE SUPERIEURE
  34. *
  35. PA = 0 .5 0; PB =1. .5 0; PD = 1. 0 0; PC = 0 0 0;
  36. PF = .6667 0 0; PE = .3333 0 0;
  37. *
  38. DAB = PA DROIT 36 PB; DBD = PB DROIT 20 PD;
  39. DDC = PD DROIT 36 PC; DCA = PC DROIT 20 PA;
  40. SU1 = DALLER DAB DBD DDC DCA PLAN;
  41. *
  42. * RAIDISSEUR CENTRAL
  43. *
  44. PA2 = 0 .5 -.1; PC2 = 0 0 -.1;
  45. D1 = PA DROIT 20 PC;
  46. D3 = PC2 DROIT 20 PA2;
  47. D2 = PC DROIT 4 PC2;
  48. D4 = PA2 DROIT 4 PA;
  49. RA1 = DALL D1 D2 D3 D4 PLAN;
  50. *
  51. * SEGMENTS DE DROITES POUR CONDITIONS DE SYMETRIE
  52. *
  53. D5 = D2 PLUS (.33333 0. 0.);
  54. D6 = D2 PLUS (.66667 0. 0.);
  55. *
  56. * RAIDISSEURS 2 ET 3
  57. *
  58. RA2 = RA1 PLUS (.33333 0 0);
  59. RA3 = RA1 PLUS (.66667 0 0);
  60. SURF = SU1 ET RA1 ET RA2 ET RA3;
  61. ELIM (SURF ET D1 ET D2 ET D3 ET D4 ET D5 ET D6) .001;
  62. *
  63. SI (NEG GRAPH 'N');
  64. TRAC OEIL SURF;
  65. FINSI;
  66. *
  67. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  68. * MODELE
  69. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  70. *
  71. MODL1 = MODE RA1 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  72. MODL2 = MODE RA2 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  73. MODL3 = MODE RA3 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  74. MODL4 = MODE SU1 MECANIQUE ELASTIQUE ORTHOTROPE dkt;
  75. MODL5 = MODL1 ET MODL2 ET MODL3 ET MODL4;
  76.  
  77. *
  78. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  79. * MATERIAUX - CARACTERISTIQUES *
  80. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  81. *
  82. DIR1 = 0. 1. 0.;
  83. *
  84. MAT1 = MATE MODL1 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11 NU12 .3 G12 .222E11 EPAI 0.005;
  85. *
  86. MAT2 = MATE MODL2 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11 NU12 .3 G12 .222E11 EPAI 0.01 ;
  87. *
  88. MAT3 = MATE MODL3 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11 NU12 .3 G12 .222E11 EPAI 0.01 ;
  89. *
  90. MAT4 = MATE MODL4 DIRECTION DIR1 PARALLELE YG1 2.E11 YG2 0.74E11 NU12 .3 G12 .222E11 EPAI 0.006 ;
  91.  
  92. MAT = MAT1 ET MAT2 ET MAT3 ET MAT4;
  93. *
  94.  
  95. *
  96. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  97. * CONDITIONS AUX LIMITES *
  98. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  99. *
  100. CL1 = BLOQUE DAB UZ;
  101. CL2 = BLOQUE DAB RY;
  102. CL3 = BLOQUE DBD UZ;
  103. CL4 = BLOQUE DBD RX;
  104. CL5 = SYMT DEPL ROTA (0 0 0) (0 1 0) (0 0 1) SURF 0.0001;
  105. CL6 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 0 1) SURF 0.0001;
  106. CL = CL1 ET CL2 ET CL3 ET CL4 ET CL5 ET CL6;
  107. *
  108. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  109. * CHARGEMENT *
  110. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  111. *
  112. MOP = 'MODE' SU1 'CHARGEMENT' 'PRESSION' 'DKT' ;
  113. MAP = 'PRES' MOP 'PRES' 5.E4 ;
  114. CH = 'BSIG' MOP MAP ;
  115. *
  116. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  117. * RESOLUTION - CALCUL ELASTIQUE *
  118. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  119. *
  120. RI = RIGI MODL5 MAT;
  121. RIG = RI ET CL ;
  122. DEP = RESO RIG CH ;
  123. *
  124. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  125. * RESULTATS *
  126. *+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  127. *
  128. NOSURF = NBNO SURF ;
  129. ELSURF = NBEL SURF ;
  130. *
  131. SI (NEG GRAPH 'N');
  132. TITR ' PLAQUE RAIDIE : DEFORMEE ' ;
  133. DEF0 = DEFO SURF DEP 0. ;
  134. DEF1 = DEFO SURF DEP 25. ROUGE;
  135. TRACE OEIL (DEF0 ET DEF1) ;
  136. OEIL =0.25 -1.E6 0.;
  137. TRACE OEIL (DEF0 ET DEF1) ;
  138. FINSI ;
  139. *
  140. UZC = EXTR DEP UZ PC ;
  141. UZC1 = -.603e-3;
  142. ERG1 = ABS ((UZC - UZC1) / UZC1) * 100 ;
  143. *
  144. DZ = EXCO DEP UZ;
  145. ZMIN = MINI DZ;
  146. ZMIN1 = -.319e-2;
  147. ERG2 = ABS ((ZMIN - ZMIN1) / ZMIN1) * 100 ;
  148.  
  149.  
  150. *
  151. X1 = DZ POIN 'MINI';
  152. XX = MAXI ( COOR 1 X1);
  153. XX1 = 0.833;
  154. ERG3 = ABS ((XX - XX1) / XX1) * 100 ;
  155.  
  156. SAUT PAGE ;
  157. OPTI ECHO 1;
  158. *
  159. MESS ' TEST : SSLS34/90 (FICHIER stru3.DGIBI)';
  160. MESS ' ----';
  161. MESS ' PLAQUE ORTHOTROPE RAIDIE CHARGEE UNIFORMEMENT SUR APPUIS SIMPLES ' * SAUT 2 LIGN ;
  162. MESS ' RESULTATS ';
  163. MESS ' --------- ';
  164. *
  165. MESS ' DEPLACEMENT THEORIQUE AU POINT PC : ' UZC1 'METRES';
  166. MESS ' DEPLACEMENT CALCULE AU POINT PC : ' UZC 'METRES' ;
  167. MESS ' SOIT UN ECART DE : ' ERG1 '%' ;
  168. *
  169. MESS ' DEPLACEMENT THEORIQUE MAXIMUM (ABS) : ' ZMIN1 'METRES';
  170. MESS ' DEPLACEMENT CALCULE MAXIMUM (ABS) : ' ZMIN 'METRES';
  171. MESS ' SOIT UN ECART DE : ' ERG2 '%' ;
  172. *
  173. SAUT 1 LIGNE;
  174. MESS ' ABSICE DU POINT OU SE TROUVE LE MAXIMUM : ' ;
  175. MESS ' - ABSICE THEORIQUE : ' XX1 'METRES';
  176. MESS ' - ABSICE CALCULEE : ' XX 'METRES';
  177. MESS ' SOIT UN ECART DE : ' ERG3 '%' ;
  178. *
  179. SAUT 1 LIGNE;
  180. MESS ' NOMBRE DE NOEUDS : ' NOSURF ;
  181. MESS ' NOMBRE D ELEMENTS : ' ELSURF ;
  182. *
  183. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  184. * CODE FONCTIONNEMENT *
  185. *++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++*
  186. *
  187. ERGMAX = MAXI (PROG ERG1 ERG2);
  188. *
  189. * Il y a erreur si un des pourcentages ERG* est suprieur 5%
  190. *
  191. *
  192. SI (ERGMAX <EG 5.);
  193. ERRE 0 ;
  194. SINON;
  195. ERRE 5 ;
  196. FINSI;
  197. *
  198. TEMPS;
  199. *
  200. FIN;
  201.  
  202.  
  203.  
  204.  
  205.  
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales