Télécharger soret_5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soret_5.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * CAS TEST soret_5.dgibi *
  7. ************************************************************************
  8. * Test effet Soret
  9. * - 2D PLAN
  10. * - ELEMENTS FINIS TESTES : 'TRI3'
  11. * - Regime permanent
  12. * - C(X0) = C0
  13. * - C(X1) = C1
  14. * - GRAD(T) choisi lineaire (T=A*(X**2) / 2.D0 ==> GRAD(T)= A*X)
  15. * - CONDUCTION et SORET sont en concurrence
  16. ************************************************************************
  17.  
  18.  
  19. ************************************************************************
  20. * OPTIONS & REGLAGES
  21. ************************************************************************
  22. GRAPH = 'N' ;
  23. 'OPTI' 'DIME' 2 'ELEM' 'TRI3' ;
  24.  
  25. 'SI' ('NEG' GRAPH 'N');
  26. 'OPTI' 'TRAC' 'X';
  27. 'SINO';
  28. 'OPTI' 'TRAC' 'PSC';
  29. 'FINS';
  30.  
  31. NBE1 = 15 ;
  32. NBE2 = 15 ;
  33.  
  34. K = -7.D0;
  35. A = 1.D0;
  36.  
  37. X0 = -0.5 ;
  38. X1 = 1. ;
  39.  
  40. C0 = 1. ;
  41. C1 = 2. ;
  42.  
  43. ************************************************************************
  44. * MAILLAGE
  45. ************************************************************************
  46. P1 = X0 0. ;
  47. P2 = X0 1. ;
  48. P3 = X1 1. ;
  49. P4 = X1 0. ;
  50.  
  51. L1 ='DROI' NBE1 P1 P2;
  52. L2 ='DROI' NBE1 P4 P3;
  53.  
  54. S1 ='REGL' NBE2 L1 L2;
  55. L3 ='COTE' 2 S1;
  56.  
  57. 'TRAC' 'QUAL' S1;
  58.  
  59. ************************************************************************
  60. * MODELE & MATERIAU
  61. ************************************************************************
  62. MOD1 ='MODE' S1 'DIFFUSION' 'FICK' 'INCO' 'HI ' 'QHI ';
  63. MAT1 ='MATE' MOD1 'KD ' 1.D0 ;
  64. MAT2 ='MANU' 'CHML' MOD1 'SCAL' K 'RIGIDITE' ;
  65.  
  66. ************************************************************************
  67. * Champ de temperature pour que le GRAD(T) soit constant
  68. ************************************************************************
  69. COO1 ='COOR' 1 S1 ;
  70. EVO1 ='EVOL' 'BLEU' 'CHPO' COO1 'SCAL' L3 ;
  71. LRX ='EXTR' EVO1 'ORDO' 1 ;
  72. TEMP1 ='CHAN' 'COMP' (A / 2.D0 * (COO1 ** 2)) 'T' ;
  73. 'TITR' 'Evolution de la TEMPERATURE avec (abscisse curviligne)';
  74. EVOT ='EVOL' 'BLEU' 'CHPO' TEMP1 'T' L3 ;
  75. 'DESS' EVOT ;
  76.  
  77. ************************************************************************
  78. * RIGIDITE
  79. ************************************************************************
  80. RIG1 ='COND' MOD1 MAT1;
  81. RIG2 ='SORE' MOD1 MAT1 MAT2 TEMP1;
  82.  
  83. ************************************************************************
  84. * CONDITIONS AUX LIMITES
  85. ************************************************************************
  86. CLIM1 ='BLOQ' 'HI' L1 ;
  87. CLIM2 ='BLOQ' 'HI' L2 ;
  88.  
  89.  
  90. CIMP1 ='DEPI' CLIM1 C0 ;
  91. CIMP2 ='DEPI' CLIM2 C1 ;
  92.  
  93. ************************************************************************
  94. * RESOLUTION
  95. ************************************************************************
  96. SOL1 ='RESO' (RIG1 ET RIG2 ET CLIM1 ET CLIM2) (CIMP1 ET CIMP2);
  97. 'TITR' 'Isovaleurs de concentration en HI';
  98. 'TRAC' SOL1 S1;
  99.  
  100. ************************************************************************
  101. * POST-TRAITEMENT
  102. ************************************************************************
  103. * Solution NUMERIQUE
  104. EVONUM ='EVOL' 'ROUG' 'CHPO' SOL1 'HI ' L3 ;
  105. LCNUM ='EXTR' EVONUM 'ORDO' 1 ;
  106. EVONUM ='EVOL' 'ROUG' 'MANU' 'X' LRX 'HI' LCNUM;
  107.  
  108. * Solution ANALYTIQUE
  109. EVO2 ='EVOL' 'CHPO' TEMP1 'T' L3 ;
  110. FLO1 = ((-2*K*A)**0.5)/2. ;
  111. XDENO= ( 'EXP'(K/2.*A*(LRX**2)) ) *
  112. (('ERF'(FLO1*X1)) - ('ERF'(FLO1*X0)));
  113. LNUME= (('ERF'(FLO1*LRX))*C1*('EXP'(K/2.*A*(X1**2))))-
  114. (('ERF'(FLO1*LRX))*C0*('EXP'(K/2.*A*(X0**2))))+
  115. (('ERF'(FLO1*X1 ))*C0*('EXP'(K/2.*A*(X0**2))))-
  116. (('ERF'(FLO1*X0 ))*C1*('EXP'(K/2.*A*(X1**2))));
  117.  
  118. LCANA = LNUME / XDENO;
  119.  
  120. EVOANA ='EVOL' 'BLEU' 'MANU' 'X' LRX 'HICA' LCANA;
  121. 'DESS' (EVONUM ET EVOANA);
  122.  
  123. * Comparaison
  124. LCDIFF = LCNUM - LCANA ;
  125. 'TITR' 'Difference entre la Solutions NUMERIQUE et ANALYTIQUE';
  126. EVODIF ='EVOL' 'VERT' 'MANU' 'X' LRX 'HICA' LCDIFF;
  127. 'DESS' EVODIF;
  128.  
  129.  
  130. * Critere d'erreur
  131. 'OPTI' 'ECHO' 0;
  132. ERRABS ='MAXI' 'ABS' LCDIFF;
  133. ERRREL = ERRABS / (('MAXI' LCANA) - ('MINI' LCANA)) ;
  134. 'MESS' '*********************************************' ;
  135. 'MESS' '* Erreur MAXIMALE absolue :' ERRABS '*';
  136. 'MESS' '* Erreur MAXIMALE relative :' ERRREL '*';
  137. 'MESS' '*********************************************' ;
  138. 'SI' (ERRREL >EG 1.5D-2);
  139. 'ERRE' 5;
  140. 'FINS';
  141.  
  142. 'FIN';
  143.  
  144.  
  145.  
  146.  
  147.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales