Télécharger rupt9.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt9.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Rupt9.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. ****************************************************
  8. * *
  9. * VALIDATION DE LA PROCEDURE G_THETA SUR UNE *
  10. * PLAQUE EN TRACTION PURE *
  11. * - *
  12. * SOLUTION DE REFERENCE : *
  13. * COMPENDIUM OF STRESS INTENSITY FACTORS, *
  14. * by Rooke & Cartwright. *
  15. * *
  16. * *
  17. * GEOMETRIE : *
  18. * *
  19. * longueur de la plaque : 250. MM *
  20. * largeur de la plaque : 100. MM *
  21. * lonqueur de la fissure : 50. MM *
  22. * Inclinaison de la fissure : 45.0 degrés *
  23. * *
  24. * MATERIAU : *
  25. * *
  26. * Module d'Young : 2.E5 MPA *
  27. * Coefficient de poisson : 0.3 *
  28. * *
  29. * CHARGEMENT : *
  30. * *
  31. * Traction pure : 1.0 daN/MM**2 *
  32. * *
  33. * SOLUTION ANALYTIQUE : *
  34. * *
  35. * Les facteurs d'intensité de contraintes *
  36. * K1 = 150.37 daN/mm**(-3/2) *
  37. * K2 = -71.4 daN/mm**(-3/2) *
  38. * *
  39. ****************************************************
  40.  
  41. * I - OPTIONS ET DONNEES
  42. * ----------------------
  43.  
  44. * OPTIONS
  45. OPTI 'DIME' 2 'ELEM' 'QUA8' ;
  46. * SI BTRAC = VRAI ON TRACE LE MAILLAGE
  47. BTRAC = FAUX ;
  48.  
  49. * DONNEES
  50. * L1 = LONGUEUR DE LA PLAQUE
  51. * H1 = LARGEUR DE LA PLAQUE
  52. * LF = LONGUEUR DE LA FISSURE
  53. * ANG1 = INCLINAISON DE LA FISSURE
  54. * XF = ABSCISSE OU LA FISSURE DEBOUCHE
  55. L1 = 250. ;
  56. H1 = 100. ;
  57. LF = 50. ;
  58. ANG1 = 45. ;
  59. XF = 100. ;
  60.  
  61. * PROPRIÉTÉS MATÉRIAU
  62. MYOU = 2.E5 ;
  63. POI = 0.3 ;
  64.  
  65.  
  66. * II - MAILLAGE
  67. * -------------
  68.  
  69. * PARAMETRES DU MAILLAGE
  70. DENS1 = 10. ;
  71. DENS DENS1 ;
  72. PREC1 = DENS1 * 1.E-10 ;
  73. NROT = ENTI (2.*PI*LF / DENS1 / 8.) ;
  74.  
  75. * MAILLAGE CIRCULAIRE AUTOUR DE LA POINTE DE FISSURE (UN HUITIEME)
  76. P1I = XF 0. ;
  77. PF = P1I PLUS (LF * ((COS ANG1) (SIN ANG1))) ;
  78. P2I = 0.5*(P1I PLUS PF) ;
  79. D1 = DROI P2I PF 'DFIN' (DENS1 / (8*NROT)) ;
  80. S1 = D1 ROTA NROT 45. PF ;
  81. X Y = COOR S1 ;
  82. DFRO = (((X - (COOR 1 PF))**2) + ((Y - (COOR 2 PF))**2))**0.5 ;
  83. PFRO = DFRO POIN 'EGINFE' PREC1 ;
  84. ELIM PFRO PREC1 ;
  85. S1 = REGE S1 ;
  86.  
  87. * MAILLAGE ENTRE LE HUITIEME DE CERCLE ET LE BAS DU RECTANGLE
  88. D2 = D1 TOUR 45. PF ;
  89. ELIM S1 D2 PREC1 ;
  90. CER1 = DIFF (CONT S1) (D1 ET D2) ;
  91. P3 = (COOR 1 PF) 0. ;
  92. D3 = DROI (NBEL CER1) P3 P1I ;
  93. S1 = S1 ET (CER1 REGL D3) ;
  94.  
  95. * 3 SYMETRIES POUR OBTENIR LE MAILLAGE COMPLET AUTOUR DE LA POINTE
  96. * (ON PREND GARDE DE NE PAS FAIRE ELIM ENTRE S1 ET S2 POUR AVOIR LA FISSURE)
  97. S2 = S1 SYME 'DROI' P1I PF ;
  98. S3 = (S1 ET S2) SYME 'DROI' PF (PF PLUS (1. 0.)) ;
  99. ELIM (S2 ET S3) PREC1 ;
  100. S4 = (S1 ET S2 ET S3) SYME 'DROI' PF (PF PLUS (0. 1.)) ;
  101. ELIM (S3 ET S4) PREC1 ;
  102. ELIM S4 S1 PREC1 ;
  103.  
  104. * STOT = SURFACE TOTALE
  105. STOT = S1 ET S2 ET S3 ET S4 ;
  106.  
  107. * EXTENSION JUSQU'EN HAUT DU RECTANGLE
  108. PHAU = (COOR 2 STOT) POIN 'MAXI' ;
  109. DHAU = (CONT STOT) ELEM 'APPUYE' PHAU ;
  110. S5 = DHAU TRAN (0. (H1 - (MAXI (COOR 2 STOT)))) ;
  111. STOT = STOT ET S5 ;
  112.  
  113. * EXTENSION JUSQU'AU BORD DROIT DU RECTANGLE
  114. PDROI = (COOR 1 STOT) POIN 'MAXI' ;
  115. DDROI = (CONT STOT) ELEM 'APPUYE' PDROI ;
  116. S6 = DDROI TRAN ((L1 - (MAXI (COOR 1 STOT))) 0.) ;
  117. STOT = STOT ET S6 ;
  118.  
  119. * EXTENSION JUSQU'AU BORD GAUCHE DU RECTANGLE
  120. PGAU = (COOR 1 STOT) POIN 'MINI' ;
  121. DGAU = (CONT STOT) ELEM 'APPUYE' PGAU ;
  122. S7 = DGAU TRAN ((0. - (MINI (COOR 1 STOT))) 0.) ;
  123. STOT = STOT ET S7 ;
  124.  
  125. * LEVRES ET FRONT
  126. PSUP = S2 POIN 'DROI' P1I PF PREC1 ;
  127. LVSUP = (CONT S2) ELEM 'APPUYE' PSUP ;
  128. LVSUP = ORDO LVSUP ;
  129. PINF = S1 POIN 'DROIT' P1I PF PREC1 ;
  130. LVINF = (CONT S1) ELEM 'APPUYE' PINF ;
  131. LVINF = ORDO LVINF ;
  132. MFRO1 = INTE (CHAN 'POI1' LVSUP) (CHAN 'POI1' LVINF) ;
  133. FRO1 = MFRO1 POIN 1 ;
  134.  
  135.  
  136. * III - MODELE, MATERIAU, CLS ET RESOLUTION
  137. * -----------------------------------------
  138.  
  139. * MODELE ET MATERIAU
  140. MOD1 = MODE STOT 'MECANIQUE' 'ELASTIQUE' ;
  141. MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
  142. RIG1 = RIGI MAT1 MOD1 ;
  143.  
  144. * CONDITIONS AUX LIMITES ET CHARGEMENT
  145. P0 = 0. 0. ;
  146. P1 = L1 0. ;
  147. ELIM STOT (P0 ET P1) PREC1 ;
  148. BLO1 = BLOQ 'DEPL' P0 ;
  149. BLO2 = BLOQ 'UY' P1 ;
  150. BLO0 = BLO1 ET BLO2 ;
  151. PG = STOT POIN 'DROI' (0. 0.) (0. 1.) PREC1 ;
  152. LG = (CONT STOT) ELEM 'APPUYE' PG ;
  153. PD = STOT POIN 'DROI' (L1 0.) (L1 1.) PREC1 ;
  154. LD = (CONT STOT) ELEM 'APPUYE' PD ;
  155. F1 = PRES 'MASS' MOD1 -10. LG ;
  156. F2 = PRES 'MASS' MOD1 -10. LD ;
  157. F0 = F1 ET F2 ;
  158.  
  159. * RESOLUTION
  160. U0 = RESO (RIG1 ET BLO0) F0 ;
  161.  
  162. SI BTRAC ;
  163. TRAC (STOT ET (LVSUP COUL 'ROUG') ET (MFRO1 COUL 'BLEU')) ;
  164. DEF0 = DEFO STOT U0 0. ;
  165. DEF1 = DEFO STOT U0 'ROUG' ;
  166. TRAC (DEF0 ET DEF1) ;
  167. FINSI ;
  168.  
  169.  
  170. * IV - POST-TRAITEMENT
  171. * --------------------
  172.  
  173. * APPEL A G_THETA
  174. SUPTAB = TABL ;
  175. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  176. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  177. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  178. SUPTAB.'FRONT_FISSURE' = FRO1 ;
  179. SUPTAB.'MODELE' = MOD1 ;
  180. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  181. SUPTAB.'SOLUTION_RESO' = U0 ;
  182. SUPTAB.'CHARGEMENTS_MECANIQUES' = F0 ;
  183. SUPTAB.'COUCHE' = 3 ;
  184. SUPTAB.'METH_AUX' = MOT 'UANA' ;
  185. G_THETA SUPTAB ;
  186. KNUM = SUPTAB.'RESULTATS' ;
  187.  
  188. * SOLUTION ANALYTIQUE
  189. KANA = TABL ;
  190. KANA.'I' = 150.37 ;
  191. KANA.'II' = -71.4 ;
  192.  
  193. * RESULTATS
  194. ACC1 = 0.02 ;
  195. SAUT 'LIGNE' ;
  196. REPE IMOD 2 ;
  197. * ON ITERE SUR LES MODES
  198. MMOD = EXTR 'II' 1 &IMOD ;
  199. KN = KNUM.MMOD ;
  200. KA = KANA.MMOD ;
  201. ERR1 = ABS ((KA - KN)/KA) ;
  202. MESS 'ERREUR RELATIVE SUR K' MMOD ' :' (ERR1 * 100.) '%' ;
  203. SI (ERR1 > ACC1) ;
  204. MESS 'LA SOLUTION NUMERIQUE EST TROP ELOIGNEE DE LA SOLUTION' ;
  205. MESS 'ANALYTIQUE POUR LE CALCUL DU FIC EN MODE' ' ' MMOD ;
  206. ERRE 5 ;
  207. FINSI ;
  208. FIN IMOD ;
  209.  
  210. FIN ;
  211.  
  212.  
  213.  
  214.  
  215.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales