Télécharger rupt15-rice.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rupt15-rice.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------
  5. *----------------------------------------------------------------
  6. * *
  7. * Test du critère de Rice pour un cylindre *
  8. * en traction modelisé en axisymétrique et en 3D *
  9. * *
  10. *----------------------------------------------------------------
  11. *----------------------------------------------------------------
  12. * *
  13. graph = faux ;
  14.  
  15. opti echo 1 ;
  16. * paramètres du modele *
  17. alpha = 0.283 ; beta = 1.5 ; epsc = 1.d-6 ;
  18. * *
  19. *****************************************************************
  20. * *
  21. * MODELE AXISYMETRIQUE *
  22. * *
  23. *****************************************************************
  24. *
  25. *****************************************************************
  26. * Maillage *
  27. *****************************************************************
  28. opti elem qua8 dime 2 mode axis ;
  29. * *
  30. * densites utilisees *
  31. l1 = 1. ; d1 = 0.2 ; d2 = 0.65 ; d11 = d1/10. ;
  32. * *
  33. * coordonnees des points *
  34. po = 0. 0. ; pb = l1 0. ; pc = 0. d1 ; pd = 0. l1 ;
  35. pa = d1 0. ;
  36. * *
  37. * definition des lignes *
  38. ligoa = droi po pa 1 ;
  39. ligab = droi pa pb dini 0.45 dfin d2 ;
  40. ligob = ligoa et ligab ;
  41. surf1 = ligob tran 1 pc ;
  42. * *
  43. lig1 = cote 3 surf1 ;
  44. * *
  45. * création de la surface *
  46. surf3 = lig1 tran 'DINI' 0.45 'DFIN' d2 (0. (l1-d1)) ;
  47. surf2 = surf1 et surf3 ;
  48. * *
  49. * extraction des lignes *
  50. lib = cote 1 surf2 ;
  51. lic = cote 3 surf2 ;
  52. * *
  53. elim surf2 1e-3 ;
  54. * *
  55. *****************************************************************
  56. * création du modéle *
  57. *****************************************************************
  58. mod1 = mode surf2 mecanique elastique plastique ;
  59. * *
  60. *****************************************************************
  61. * définition du matériau *
  62. *****************************************************************
  63. * *
  64. * young :
  65. ym1 = 503./0.0026 ;
  66.  
  67. * courbe de traction *
  68. peps = prog 0. 0.0026 0.0027 0.0030 0.0035 0.0045 0.0065 0.0085 0.0105 0.0125 0.0176 0.0227 0.0329 ;
  69. psig = prog 0. 503. 503. 503. 503. 503. 503. 503. 503. 516. 538. 557. 594. ;
  70. tracevt = evol manu 'eps' peps 'sig' psig ;
  71. lsm1 = psig enle 1 ;
  72. lep1 = (peps enle 1) - (lsm1 / ym1) ;
  73. evec = evol vert manu eps lep1 sig lsm1 ;
  74. si graph ;
  75. dess (tracevt et evec) titr ' Courbes de traction et d ecrouissage (vert)' ;
  76. fins ;
  77. * *
  78. mat1 = mate mod1 youn ym1 nu 0.3 ecro evec ;
  79. * *
  80. *****************************************************************
  81. * rigidité *
  82. *****************************************************************
  83. cdl0 = bloq uz lib ;
  84. cdl2 = bloq uz lic ;
  85. dep1 = depi cdl2 2e-2 ;
  86. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.) ;
  87. fo1 = char 'DIMP' dep1 forcevt ;
  88. * *
  89. *****************************************************************
  90. * definition de la table d'entree *
  91. *****************************************************************
  92. tab1 = table ;
  93. tab1.caracteristiques = mat1 ;
  94. tab1.modele = mod1 ;
  95. tab1.blocages_mecaniques = cdl0 et cdl2 ;
  96. tab1.chargement = fo1 ;
  97. tab1.temps_calcules = (prog 0. pas 0.5 1.) ;
  98. * *
  99. *****************************************************************
  100. * procedure de calcul *
  101. *****************************************************************
  102. TMASAU=table;
  103. tab1. 'MES_SAUVEGARDES'=TMASAU;
  104. TMASAU .'DEFTO'=VRAI;
  105. TMASAU .'DEFIN'=VRAI;
  106. pasapas tab1 ;
  107. * *
  108. *****************************************************************
  109. * Calcul du taux de croissance axi *
  110. *****************************************************************
  111. * *
  112. * zone du critere *
  113. surfcrit = elem surf2 1 ;
  114. zone1 = redu mod1 surfcrit ;
  115. * *
  116. enttab1 = table ;
  117. enttab1.'OBJMO' = zone1 ;
  118. enttab1.'RICE' = vrai ;
  119. enttab1.'TNONL' = tab1 ;
  120. enttab1.'EPSILON' = vrai ; enttab1.'ALPHA' = alpha ;
  121. enttab1.'BETA' = beta ; enttab1.'EPSC' = epsc ;
  122. * *
  123. sortab1 = critloc enttab1 ;
  124. * *
  125. tauxaxi = ((sortab1.'RAPPORT').1.) ;
  126. taxipb1 = extr tauxaxi scal 1 1 1 ;
  127. * *
  128. *****************************************************************
  129. * *
  130. * MODELE 3D *
  131. * *
  132. *****************************************************************
  133. *
  134. *****************************************************************
  135. * Maillage *
  136. *****************************************************************
  137. opti dime 3 elem cu20 mode trid ;
  138. * *
  139. * variables *
  140. a1 = 2**(-0.5) ;
  141. l1 = 0.2 ; l2 = 1. ; oeil = 2 -1000 300 ;
  142. * *
  143. * coordonnees des points *
  144. pb1 = 0. 0. 0. ; pba = l1 0. 0. ; pbc = 0. l1 0. ;
  145. pbb = l1 l1 0. ; pb2 = l2 0. 0. ; pb3 = (l2*a1) (l2*a1) 0. ;
  146. pb4 = 0. l2 0.; ph1 = 0. 0. l2 ;
  147. * *
  148. * densites utilisees *
  149. d1 = 0.45 ; d2 = 0.65 ;
  150. * *
  151. * definition des lignes *
  152. ligb1a = droit 1 pb1 pba ;
  153. ligbab = droit 1 pba pbb ;
  154. ligbbc = droit 1 pbb pbc ;
  155. ligbc1 = droit 1 pbc pb1 ;
  156. ligba2 = droit pba pb2 dini d1 dfin d2 ;
  157. ligb3b = droit 2 pb3 pbb ;
  158. ligbc4 = droit pbc pb4 dini d1 dfin d2 ;
  159. arcb23 = cerc 1 pb2 pb1 pb3 ;
  160. arcb43 = cerc 1 pb4 pb1 pb3 ;
  161. * *
  162. * definition de la surface du bas *
  163. surfb1 = dall ligb1a ligbab ligbbc ligbc1 plan ;
  164. surfb2 = dall ligb3b ligbbc ligbc4 arcb43 plan ;
  165. surfb3 = dall ligba2 arcb23 ligb3b ligbab plan ;
  166. surfbas = surfb1 et surfb2 et surfb3 ;
  167. * *
  168. * creation du volume *
  169. volu1 = surfbas volu dini l1 dfin d2 tran ph1 ;
  170. surfhaut = face 2 volu1 ;
  171. surflat = face 3 volu1 ;
  172. * *
  173. * extraction des surfaces laterales *
  174. *surface oxz *
  175. poxz = poin surflat plan pb1 (2. 0. 2.) (0. 0. 2.) (1e-3) ;
  176. surfl1 = elem surflat appu strict poxz ;
  177. *surface poyz *
  178. poyz = poin surflat plan pb1 pb4 ph1 (1e-3) ;
  179. surfl2 = elem surflat appu strict poyz ;
  180. * *
  181. elim volu1 (1e-3) ;
  182. elim (surfbas et surfhaut et surfl1 et surfl2) (1e-3) ;
  183. * *
  184. *****************************************************************
  185. * conditions de symetrie *
  186. *****************************************************************
  187. condi1 = symt depl pb1 ph1 pb2 volu1 (1e-3) ;
  188. condi2 = symt depl pb1 ph1 pb4 volu1 (1e-3) ;
  189. condi3 = symt depl pb1 pb2 pb4 volu1 (1e-3) ;
  190. condit = condi1 et condi2 et condi3 ;
  191. * *
  192. *****************************************************************
  193. * creation du modele *
  194. *****************************************************************
  195. mod2 = MODE volu1 mecanique elastique plastique ;
  196. * *
  197. *****************************************************************
  198. * definition du materiau *
  199. *****************************************************************
  200. * *
  201. mate2 = MATE mod2 young (503./0.0026) nu 0.3 ecro evec ;
  202. * *
  203. *****************************************************************
  204. * rigidite *
  205. *****************************************************************
  206. blo1 = bloq uz surfbas ;
  207. rig1 = condit et blo1 ;
  208. rig2 = bloq uz surfhaut ;
  209. rigt = rig1 et rig2 ;
  210. dep2 = depi rig2 (2e-2) ;
  211. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.) ;
  212. fo2 = char 'DIMP' dep2 forcevt ;
  213. * *
  214. *****************************************************************
  215. * definition de la table d'entree *
  216. *****************************************************************
  217. tab2 = table ;
  218. tab2.'CARACTERISTIQUES' = mate2 ;
  219. tab2.'MODELE' = mod2 ;
  220. tab2.'BLOCAGES_MECANIQUES' = rigt ;
  221. tab2.'CHARGEMENT' = fo2 ;
  222. tab2.'TEMPS_CALCULES' = (prog 0. pas 0.5 1.) ;
  223. * *
  224. *****************************************************************
  225. * procedure de calcul ;
  226. *****************************************************************
  227. TMASAU=table;
  228. tab2 . 'MES_SAUVEGARDES'=TMASAU;
  229. TMASAU .'DEFTO'=VRAI;
  230. TMASAU .'DEFIN'=VRAI;
  231. pasapas tab2 ;
  232. * *
  233. *****************************************************************
  234. * Calcul du taux de croissance 3D *
  235. *****************************************************************
  236. * *
  237. * zone du critere *
  238. volucrit = volu1 elem 1 ;
  239. zone2 = redu mod2 volucrit ;
  240. * *
  241. enttab2 = table ;
  242. enttab2.'OBJMO' = zone2 ;
  243. enttab2.'RICE' = vrai ;
  244. enttab2.'TNONL' = tab2 ;
  245. enttab2.'EPSILON' = vrai ; enttab2.'ALPHA' = alpha ;
  246. enttab2.'BETA' = beta ; enttab2.'EPSC' = epsc ;
  247. * *
  248. sortab2 = critloc enttab2 ;
  249. * *
  250. taux3d = ((sortab2.'RAPPORT').1.) ;
  251. t3dpb1 = extr taux3d scal 1 1 1 ;
  252. * *
  253. *****************************************************************
  254. * Comparaison des résultats *
  255. *****************************************************************
  256. ecart = ( abs(taxipb1-t3dpb1) ) / taxipb1 ;
  257. mess 'ecart relatif : ' (ecart*100.) '%' ;
  258. si (ecart < 0.1 ) ;
  259. erre 0 ;
  260. sinon ;
  261. erre 5 ;
  262. finsi ;
  263. * *
  264. fin ;
  265. *----------------------------------------------------------------
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales