Télécharger la plaquette Cast3M


fr en

Télécharger rupt14-weib.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rupt14-weib.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------
  5. *----------------------------------------------------------------
  6. *                                                               *
  7. *       Test du critère de Weibull pour un cylindre             *
  8. *       en traction modelisé en axisymétrique et en 3D          *
  9. *                                                               *
  10. *----------------------------------------------------------------
  11. *----------------------------------------------------------------
  12. *                                                               *
  13. graph = faux ;
  14. *
  15. opti echo 1     ; monop=faux;                                   ;
  16. *               paramètres pour calculer sigma w                *
  17. m = 22. ; v0 = 0.000125 ; sigu = 2530. ; ic = 1. ; n = 2.       ;
  18. *                                                               *
  19. *****************************************************************
  20. *                                                               *
  21. *                       MODELE AXISYMETRIQUE                    *
  22. *                                                               *
  23. *****************************************************************
  24. *
  25. *****************************************************************
  26. *               Maillage                                        *
  27. *****************************************************************
  28. opti elem qua8 dime 2 mode axis                                 ;
  29. *                                                               *
  30. *               densites utilisees                              *
  31. l1 = 0.25 ;d1 = 50e-3 ; d2 = 120e-3 ; d11 = d1/10.              ;
  32. *                                                               *
  33. *               coordonnees des points                          *
  34. po = 0. 0. ; pb = l1 0. ; pc = 0. d1 ; pd = 0. l1               ;
  35. pa = d1 0.                                                      ;
  36. *                                                               *
  37. *               definition des lignes                           *
  38. ligoa = droi po pa 1                                            ;
  39. ligab = droi pa pb  'DINI' 0.08 'DFIN' 0.12                     ;
  40. ligob = ligoa et ligab                                          ;
  41. surf1 = ligob tran 1 pc                                         ;
  42. *
  43. lig1 = cote 3 surf1                                             ;
  44. *                                                               *
  45. *               création de la surface                          *
  46. surf3 = lig1 tran 'DINI' 0.08 'DFIN' 0.12 (0. (l1-d1))          ;
  47. surf2 = surf1 et surf3                                          ;
  48. *                                                               *
  49. *               extraction des lignes                           *
  50. lib = cote 1 surf2                                              ;
  51. lic = cote 3 surf2                                              ;
  52. *                                                               *
  53. elim surf2 1e-3                                                 ;
  54. *                                                               *
  55. *****************************************************************
  56. *               création du modéle                              *
  57. *****************************************************************
  58. mod1 = mode surf2 mecanique elastique plastique                 ;
  59. *                                                               *
  60. *****************************************************************
  61. *               définition du matériau                          *
  62. *****************************************************************
  63. *                                                               *
  64. * young :
  65. ym1  = 503./0.0026 ;
  66. *               courbe de traction                              *
  67. peps = prog 0. 0.0026 0.0027 0.0030 0.0035 0.0045 0.0065 0.0085  0.0105 0.0125 0.0176 0.0227 0.0329                       ;
  68. psig = prog 0. 503. 503. 503. 503. 503. 503. 503. 503. 516. 538.  557. 594.                                                ;
  69. tracevt = evol manu 'eps' peps 'sig' psig                       ;
  70. lsm1 = psig enle 1 ;
  71. lep1 = (peps enle 1) - (lsm1 / ym1) ;
  72. evec = evol vert manu eps lep1 sig lsm1 ;
  73. si graph ;
  74.   dess (tracevt et evec) titr ' Courbes de traction et d ecrouissage (vert)' ;
  75. fins ;
  76. *                                                               *
  77. mat1 = mate mod1 youn ym1 nu 0.3 ecro evec ;
  78. *                                                               *
  79. *****************************************************************
  80. *               rigidité                                        *
  81. *****************************************************************
  82. cdl0 = bloq uz lib                                              ;
  83. cdl2 = bloq uz lic                                              ;
  84. dep1 = depi cdl2 4e-3                                           ;
  85. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.)           ;
  86. fo1 = char 'DIMP' dep1 forcevt                                  ;
  87. *                                                               *
  88. *****************************************************************
  89. *               definition de la table d'entree                 *
  90. *****************************************************************
  91. tab1 = table                                                    ;
  92. tab1.caracteristiques = mat1                                    ;
  93. tab1.modele = mod1                                              ;
  94. tab1.blocages_mecaniques = cdl0 et cdl2                         ;
  95. tab1.chargement = fo1                                           ;
  96. tab1.temps_calcules = (prog 0. pas 0.5 1.)                      ;
  97. *                                                               *
  98. *****************************************************************
  99. *               procedure de calcul                             *
  100. *****************************************************************
  101. TMASAU=table;
  102. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  103. TMASAU .'DEFTO'=VRAI;
  104. TMASAU .'DEFIN'=VRAI;
  105. tab1.'NB_EL_PARA'= 2;
  106. pasapas tab1                                                    ;
  107. *                                                               *
  108. *****************************************************************
  109. *               Calcul de la contrainte de Weibull axi          *
  110. *****************************************************************
  111. *                                                               *
  112. *               zone du critere                                 *
  113. surfcrit = elem surf2 1                                         ;
  114. zone1 = redu mod1 surfcrit;
  115. *                                                               *
  116. enttab1 = table                                                 ;
  117. enttab1.'XMULT' = 2.                                            ;
  118. enttab1.'OBJMO' = zone1                                         ;
  119. enttab1.'WEIBULL' = vrai                                        ;
  120. enttab1.'TNONL' = tab1                                          ;
  121. enttab1.'M' = m ; enttab1.'V0' = v0 ; enttab1.'SIGU' = sigu     ;
  122. enttab1.'IC' = ic ; enttab1.'N' = n                             ;
  123. enttab1.'TEMPER' = 0                                            ;
  124. *                                                               *
  125. sortab1 = critloc enttab1;
  126. *                                                               *
  127. sigwaxi = (sortab1.'SIGW').1.                                   ;
  128. *                                                               *
  129. *****************************************************************
  130. *                                                               *
  131. *                       MODELE 3D                               *
  132. *                                                               *
  133. *****************************************************************
  134. *
  135. *****************************************************************
  136. *               Maillage                                        *
  137. *****************************************************************
  138. opti dime 3 elem cu20 mode trid                                 ;
  139. *                                                               *
  140. *               variables                                       * 
  141. a1 = 2**(-0.5)                                                  ;
  142. l1 = 50e-3 ; l2 = 250e-3 ; oeil = 2 -1000 300                   ;
  143. *                                                               *
  144. *               coordonnees des points                          *
  145. pb1 = 0. 0. 0. ; pba = l1 0. 0. ; pbc = 0. l1 0.                ;
  146. pbb = l1 l1 0. ; pb2 = l2 0. 0. ; pb3 = (l2*a1) (l2*a1) 0.      ;
  147. pb4 = 0. l2 0.; ph1 = 0. 0. l2                                  ;
  148. *                                                               *
  149. *               densites utilisees                              *
  150. d1 = 80e-3 ; d2 = 120e-3                                        ;
  151. *                                                               *
  152. *               definition des lignes                           *
  153. ligb1a = droit 1 pb1 pba                                        ;
  154. ligbab = droit 1 pba pbb                                        ;
  155. ligbbc = droit 1 pbb pbc                                        ;
  156. ligbc1 = droit 1 pbc pb1                                        ;
  157. ligba2 = droit pba pb2 dini d1 dfin d2                          ;
  158. ligb3b = droit 2 pb3 pbb                                        ;
  159. ligbc4 = droit pbc pb4 dini d1 dfin d2                          ;
  160. arcb23 = cerc 1 pb2 pb1 pb3                                     ;
  161. arcb43 = cerc 1 pb4 pb1 pb3                                     ;
  162. *                                                               *
  163. *               definition de la surface du bas                 *
  164. surfb1 = dall ligb1a ligbab ligbbc ligbc1 plan                  ;
  165. surfb2 = dall ligb3b ligbbc ligbc4 arcb43 plan                  ;
  166. surfb3 = dall ligba2 arcb23 ligb3b ligbab plan                  ;
  167. surfbas = surfb1 et surfb2 et surfb3                            ;
  168. *                                                               *
  169. *               creation du volume                              *
  170. volu1 = surfbas volu dini l1 dfin d2 tran ph1                   ;
  171. surfhaut = face 2 volu1                                         ;
  172. surflat = face 3 volu1                                          ;
  173. *                                                               *
  174. *               extraction des surfaces laterales               *
  175. *surface oxz                                                    *
  176. poxz = poin surflat plan pb1 (2. 0. 2.) (0. 0. 2.) (1e-3)       ;
  177. surfl1 = elem surflat appu strict poxz                          ;
  178. *surface poyz                                                   *
  179. poyz = poin surflat plan pb1 pb4 ph1 (1e-3)                     ;
  180. surfl2 = elem surflat appu strict poyz                          ;
  181. *                                                               *
  182. elim volu1 (1e-3)                                               ;
  183. elim (surfbas et surfhaut et surfl1 et surfl2) (1e-3)           ;
  184. *                                                               *
  185. *****************************************************************
  186. *               conditions de symetrie                          *
  187. *****************************************************************
  188. condi1 = symt depl pb1 ph1 pb2 volu1 (1e-3)                     ;
  189. condi2 = symt depl pb1 ph1 pb4 volu1 (1e-3)                     ;
  190. condi3 = symt depl pb1 pb2 pb4 volu1 (1e-3)                     ;
  191. condit = condi1 et condi2 et condi3                             ;
  192. *                                                               *
  193. *****************************************************************
  194. *               creation du modele                              *
  195. *****************************************************************
  196. mod2 = MODE volu1 mecanique elastique plastique                 ;
  197. *                                                               *
  198. *****************************************************************
  199. *               definition du materiau                          *
  200. *****************************************************************
  201. *                                                               *
  202. mate2 = MATE mod2 young (503./0.0026) nu 0.3 ecro evec ;
  203. *                                                               *
  204. *****************************************************************
  205. *               rigidite                                        *
  206. *****************************************************************
  207. blo1 = bloq uz surfbas                                          ;
  208. rig1 = condit et blo1                                           ;
  209. rig2 = bloq uz surfhaut                                         ;
  210. rigt = rig1 et rig2                                             ;
  211. dep2 = depi rig2 (4e-3)                                         ;
  212. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.)           ;
  213. fo2 = char 'DIMP' dep2 forcevt                                  ;
  214. *                                                               *
  215. *****************************************************************
  216. *               definition de la table d'entree                 *
  217. *****************************************************************
  218. tab2 = table                                                    ;
  219. tab2.'CARACTERISTIQUES' = mate2                                 ;
  220. tab2.'MODELE' = mod2                                            ;
  221. tab2.'BLOCAGES_MECANIQUES' = rigt                               ;
  222. tab2.'CHARGEMENT' = fo2                                         ;
  223. tab2.'TEMPS_CALCULES' = (prog 0. pas 0.5 1.)                    ;
  224. *                                                               *
  225. *****************************************************************
  226. *               procedure de calcul                             ;
  227. *****************************************************************
  228. TMASAU=table;
  229. tab2 . 'MES_SAUVEGARDES'=TMASAU;
  230. TMASAU .'DEFTO'=VRAI;
  231. TMASAU .'DEFIN'=VRAI;
  232.  
  233. pasapas tab2                                                    ;
  234. *                                                               *
  235. *****************************************************************
  236. *               Calcul de la contrainte de Weibull 3D           *
  237. *****************************************************************
  238. *                                                               *
  239. *               zone du critere                                 *
  240. volucrit = volu1 elem contenant pb1                             ;
  241. zone2 = redu mod2 volucrit;
  242. *                                                               *
  243. enttab2 = table                                                 ;
  244. enttab2.'XMULT' = 8.                                            ;
  245. enttab2.'OBJMO' = zone2                                         ;
  246. enttab2.'WEIBULL' = vrai                                        ;
  247. enttab2.'TNONL' = tab2                                          ;
  248. enttab2.'M' = m ; enttab2.'V0' = v0 ; enttab2.'SIGU' = sigu     ;
  249. enttab2.'IC' = ic ; enttab2.'N' = n                             ;
  250. enttab2.'TEMPER' = 0                                            ;
  251. *                                                               *
  252. sortab2 = critloc enttab2                                       ;
  253. *                                                               *
  254. sigw3d = (sortab2.'SIGW').1.                                    ;
  255. *                                                               *
  256. *****************************************************************
  257. *               Test d'erreur                                   *
  258. *****************************************************************
  259. ecart = ( abs(sigwaxi-sigw3d) ) / sigwaxi                       ;
  260. mess 'ecart relatif : ' (ecart*100.) '%'                        ;
  261. si (ecart < 0.1 )                                               ;
  262.         erre 0                                                  ;
  263. sinon                                                           ;
  264.         erre 5                                                  ;
  265. finsi                                                           ;
  266. *                                                               *
  267. fin                                                             ;
  268. *---------------------------------------------------------------- 
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales