Télécharger ricrag_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. *******************************************************
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas test de l'implantation numérique du modele
  5. * RICRAG 3D LOCAL/NON LOCAL
  6. *******************************************************
  7. * Développé par :
  8. * Benjamin Richard
  9. *******************************************************
  10. * Les cas de charges sont entrés :
  11. * - 1 : Traction monotone
  12. * - 2 : Compression monotone
  13. * - 3 : Traction cyclique
  14. * - 4 : Compression cyclique
  15. * - 5 : Traction/compression cyclique
  16. *******************************************************
  17. * Choix du cas de charge
  18. ncas = 5;
  19. graph=mot 'N';
  20. * Test du fichier compatible avec le non local
  21. * nloc0 = 0; Cas local
  22. * nloc0 = 1; Cas non local
  23.  
  24. nloc0 = 0;
  25. *******************************************************
  26.  
  27. *
  28. *-------------- Options de calcul ---------------------
  29. *
  30. OPTION DIME 3 ELEM CUB8;
  31.  
  32. *
  33. *-------------- Definition de la geometrie ------------
  34. *
  35. P1 = 0. 0. 0.;
  36. P2 = 1. 0. 0.;
  37. P3 = 1. 1. 0.;
  38. P4 = 0. 1. 0.;
  39. P5 = 0. 0. 1. ;
  40.  
  41. L1 = P1 DROIT 1 P2 ;
  42. L2 = P2 DROIT 1 P3 ;
  43. L3 = P3 DROIT 1 P4 ;
  44. L4 = P4 DROIT 1 P1 ;
  45.  
  46. LTOT = L1 ET L2 ET L3 ET L4 ;
  47. SURF1 = SURF LTOT PLANE;
  48. VOLTO =VOLU SURF1 1 TRANS P5;
  49. SURF2= FACE VOLTO 2;
  50.  
  51. VOLTOT = VOLTO;
  52.  
  53. *
  54. *------- Définition des conditions aux limites --------
  55. *----------- et des déplacements imposés --------------
  56. *
  57. CL = BLOQ SURF1 UZ;
  58. CLL = BLOQ P1 'DEPL';
  59. CLL = CLL ET (BLOQ UY P2);
  60. CL1 = BLOQ SURF2 Uz;
  61.  
  62. D1 = DEPI CL1 1;
  63.  
  64. *
  65. *----- Définition du modèle ---------------------------
  66. *
  67. SI (EGA nloc0 1);
  68. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  69. ENDOMMAGEMENT RICRAG
  70. 'NON_LOCAL' 'MOYE' 'V_MOYENNE' (MOTS 'EPTI') ;
  71. SINON;
  72. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  73. ENDOMMAGEMENT RICRAG;
  74. FINSI ;
  75. *
  76. *----- Paramètres matériaux ---------------------------
  77. *
  78.  
  79. * Module d'Young
  80. youngn = 36000E+6;
  81.  
  82. * Coefficient de Poisson
  83. nun = 0.2;
  84.  
  85. * Résistance en traction
  86. ftn = 3.6e6;
  87.  
  88. * Fragilité en traction
  89. aldin = 1.0e-2;
  90.  
  91. * Fragilité en compression
  92. alinn = 9.0e-5;
  93.  
  94. * Module d'écrouissage 1
  95. gam1n = 7.0e9;
  96.  
  97. * Moduke d'écrouissage 2
  98. a1n = 7.0e-7;
  99.  
  100. mat1 =MATE mod1 YOUN youngn NU nun
  101. FT ftn ALIN alinn
  102. GAM1 gam1n A1 a1n
  103. ALDI aldin;
  104.  
  105. *
  106. *----- Définition des cas de charge -------------------
  107. *
  108.  
  109. SI (EGA ncas 1) ;
  110. LI1 = PROG 0. 1.;
  111. LI2 = PROG 0. 4.0e-4;
  112. LIS1 = PROG 0. PAS 0.02 1.;
  113. FINSI;
  114.  
  115. SI (EGA ncas 2) ;
  116. LI1 = PROG 0. 1.;
  117. LI2 = PROG 0. -8.0e-3;
  118. LIS1 = PROG 0. PAS 0.02 1.;
  119. FINSI;
  120.  
  121. SI (EGA ncas 3) ;
  122. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  123. LI2 = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  124. LIS1 = PROG 0. PAS 0.02 5.;
  125. FINSI;
  126.  
  127. SI (EGA ncas 4) ;
  128. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  129. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  130. LIS1 = PROG 0. PAS 0.02 5.;
  131. FINSI;
  132.  
  133. SI (EGA ncas 5) ;
  134. LI1 = PROG 0. 1. 2. 3. 4. 5. 6.;
  135. LI2 = PROG 0. 1.3e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3;
  136. LIS1 = PROG 0. PAS 0.02 6;
  137. FINSI;
  138.  
  139. EV = EVOL MANU LI1 LI2 ;
  140. CHA1 = CHAR 'DIMP' D1 EV ;
  141.  
  142. *
  143. *----------- Calcul par l'operateur PASAPAS ------------
  144. *
  145. LC = 1.0e-10;
  146. CO1 = CONNEC mod1 LC NORMAL;
  147.  
  148. TAB1 = TABLE ;
  149. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  150. TAB1.'MODELE' = MOD1;
  151. TAB1.'MOVA' = 'D ';
  152. TAB1.'CHARGEMENT' = CHA1;
  153. TAB1.'TEMPS_CALCULES' = LIS1;
  154. TAB1.'MAXITERATION' = 10;
  155.  
  156. SI (EGA nloc0 1);
  157. TAB1.CONN = CO1;
  158. MAT1 = MAT1 ET (MATE MOD1 'LCAR' LC);
  159. FINSI;
  160.  
  161. TAB1.'CARACTERISTIQUES' = MAT1;
  162.  
  163. PASAPAS TAB1 ;
  164.  
  165. *
  166. *----------- Courbe effort-deplacement -----------------
  167. *
  168. ev2=@global tab1 CL1 EV fz;
  169. ee = extr ev2 ordo 1;
  170. aa = extr ee ( dime ee);
  171. list aa;
  172. err = abs (aa + 1.48500E+07 ) / 1.48500E+07 ;
  173. message ' erreur relative ' err;
  174. si (err > 1.e-3);
  175. erreur (5);
  176. finsi;
  177.  
  178. si ( ega graph 'O');
  179. DESS EV2;
  180. finsi;
  181. *@excel1 ev2 'cas_5.dat';
  182. list ev2;
  183. fin;
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  
  196.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales