Télécharger rayo-2D-1-trans.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : rayo-2D-1-trans.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. complet = faux;
  6. *
  7. *************************************************
  8. * pour calcul complet mettre complet à : vrai;
  9. ***************************************************
  10. ****************************************************************
  11. *
  12. * test 2D couplage conduction-rayonnement
  13. * REFERENCE: SPARROW CESS "Radiation Heat Transfer" 1978 p.189
  14. *
  15. * DONNEES
  16. * cas de 2 ailettes
  17. *
  18. * angle entre les ailettes : 45 degres
  19. * longueur : L=0.1m
  20. * emissivite : 0.75
  21. *
  22. * conductivite lineique : LAM=4.536 W/K
  23. * conditions aux limites base d ailette : TB= 2000 K
  24. * extremite ailette : flux nul
  25. * Nombre caracteristique rayonnemnent/conduction XC=1.
  26. *
  27. * RESULTATS
  28. * efficacite de l ailette 0.591
  29. * puissance rayonnee 41 kW
  30. * temperature en milieu d ailette 1820 K
  31. * temperature en extremite d ailette 1751 K
  32. *
  33. * Ce jeu de données est analogue au rayo-2D-1.dgibi sauf que
  34. * l'on obtient la solution par une simulation transitoire avec
  35. * un chargement constant (comme par une méthode de relaxation
  36. * en mécanique).
  37. *
  38. * on teste les 2 méthodes: 1/sans ou 2/avec calcul de la
  39. * matrice de rayonnement (cf. notice PASAPAS)
  40. ****************************************************************
  41.  
  42. *** Options ...
  43.  
  44. OPTION DIME 2 ELEM QUA4 ;
  45.  
  46. graph = faux ;
  47.  
  48. *** Paramètres ...
  49.  
  50. * AL angle entre les ailettes ...
  51. AL = 45. ;
  52.  
  53. L = 0.1; C = COS(AL) ; S = SIN(AL) ;
  54. A = SIN(AL/2.) ;
  55.  
  56. * Nombre de segments / ailette ...
  57. si complet;
  58. N = 20 ;
  59. sinon;
  60. N = 4;
  61. finsi;
  62.  
  63.  
  64. * Épaisseur des ailettes : 1mm
  65. dz = 0.001 ;
  66. dzp = dz ;
  67. dzn = -1 * dz ;
  68.  
  69. * Propriétés physiques ...
  70. sig=5.67E-8 ; l=0.1; tb=2000. ; emis = 0.75 ;
  71.  
  72. * Efficacite de l'ailette
  73. xc = 1.0 ;
  74.  
  75. *** Points ...
  76.  
  77. P1 = 0. 0. ; P2 = L 0. ;
  78. Q1 = 0. 0. ; Q2 = (L*C) (L*S) ;
  79.  
  80. *** Lignes ...
  81.  
  82. L1= D N P1 P2 ; L2 = D N Q2 Q1 ;
  83.  
  84. *** Surfaces ...
  85.  
  86. z1 = l1 tran 1 (0. dzn) ;
  87. z2 = l2 tran 1 ((dzn*s) (dzp*c)) ;
  88.  
  89. lim1 = cote 4 z1 ;
  90. lim2 = cote 2 z2 ;
  91.  
  92. cavite = l1 et l2 ;
  93. tout = z1 et z2 ;
  94. titr 'Le maillage d ailette' ;
  95. si(graph) ; trac tout ; finsi ;
  96.  
  97. *** Modélisation ...
  98.  
  99. * conduction
  100. * calcul de la conductivité lineique
  101. kr = sig*tb*tb*tb *l*l ;
  102. lam = kr/xc ;
  103. lamb = lam/dz ;
  104.  
  105. mcd1 = modeli z1 thermique ;
  106. mcd2 = modeli z2 thermique ;
  107. mcd = mcd1 et mcd2 ;
  108. k = mate mcd 'K' lamb 'RHO' 5000. 'C' 10. ;
  109. cnd = cond mcd k ;
  110.  
  111. mr1 = modeli l1 thermique rayonnement 'CAVITE' CONVEXE CONS 'CAV1';
  112. mr2 = modeli l2 thermique rayonnement 'CAVITE' CONVEXE CONS 'CAV1';
  113. mrt = mr1 et mr2 ;
  114.  
  115. e1 = mate mr1 'EMIS' emis ;
  116. e2 = mate mr2 'EMIS' emis ;
  117. e = e1 et e2 ;
  118.  
  119.  
  120. *** Conditions aux limites ...
  121.  
  122. c1 = bloq lim1 'T' ;
  123. tim1 = depi c1 tb ;
  124. c2 = bloq lim2 'T' ;
  125. tim2 = depi c2 tb ;
  126.  
  127. *--------------------------------------------------------------
  128. * méthode par défaut (avec calcul de la matrice de rayonnement)
  129.  
  130. *** Préparation à la simulation avec PASAPAS ...
  131.  
  132. tabnl = table ;
  133.  
  134. tabnl . 'MODELE' = mcd et mrt;
  135. tabnl . 'CARACTERISTIQUES' = k et e ;
  136.  
  137. listtemp = prog 0 5 100 ;
  138. listval = prog 1 1 1 ;
  139. evchar = evol manu 't' listtemp 'f(t)' listval ;
  140. tabnl . 'CHARGEMENT' = char 'TIMP' evchar (tim1 et tim2) ;
  141.  
  142. tabnl . 'BLOCAGES_THERMIQUES' = c1 et c2 ;
  143.  
  144. * tabnl . 'RAYONNEMENT' = table ;
  145. * tabnl . 'RAYONNEMENT' . 1 = table ;
  146. ** tabnl . 'RAYONNEMENT' . 1 . 'TYPE' = 'CAVITE' ;
  147. * tabnl . 'RAYONNEMENT' . 1 . 'MODELE' = mrt ;
  148. * tabnl . 'RAYONNEMENT' . 1 . 'CONVEXE' = vrai ;
  149. * tabnl . 'RAYONNEMENT' . 1 . 'FERME' = faux ;
  150.  
  151. tabnl . 'TEMPS_CALCULES' = prog 0 pas 0.5 10 ;
  152. * tabnl . 'TEMPS_SAUVES' = extr (tabnl . 'TEMPS_CALCULES')
  153. * (lect 1 pas 10 (dime (tabnl . 'TEMPS_CALCULES'))) ;
  154.  
  155. tabnl . 'PROCEDURE_THERMIQUE' = 'DUPONT' ;
  156.  
  157. *** Résolution (avec PASAPAS) ...
  158.  
  159. pasapas tabnl ;
  160.  
  161. *** Petit post-traitement ...
  162.  
  163. nbpas = dime (tabnl . TEMPS) ;
  164. listtime = prog ;
  165. listtemp = prog ;
  166. repeter surpas nbpas ;
  167. lindice = &surpas - 1 ;
  168. listtime = listtime et (prog (tabnl . TEMPS . lindice)) ;
  169. valtemp = extr (tabnl . TEMPERATURES . lindice) 'T' p2 ;
  170. listtemp = listtemp et (prog valtemp) ;
  171. fin surpas ;
  172.  
  173. titr 'Evolution de temperature a l extremite de l ailette' ;
  174. evtemp = evol manu 't' listtime 'T' listtemp ;
  175. si(graph) ; dess evtemp ; finsi ;
  176.  
  177.  
  178. valref = 1751. ;
  179. valobt = extr listtemp (dime listtemp) ;
  180. errre1 = 100 * (valobt - valref) / valref ;
  181.  
  182. opti echo 0 ;
  183. saut 1 lign ;
  184. mess 'Méthode avec calcul de la matrice de rayonnement' ;
  185. mess 'Solution exacte : ' valref ;
  186. mess 'Solution obtenue : ' valobt ;
  187. mess 'soit une erreur de ' errre1 ' %' ;
  188.  
  189.  
  190. *** Test de bon fonctionnement
  191.  
  192. si ((abs errre1) > 1.);
  193. mess ' méthode avec matrice de rayonnement';
  194. erre 5 ;
  195. sinon;
  196. erre 0;
  197. finsi ;
  198.  
  199. *--------------------------------------------------------------
  200. * méthode sans calcul de la matrice de rayonnement
  201. mrt2= model (l1 et l2) thermique 'RAYONNEMENT' 'CAVITE' FERME
  202. TRAYO ;
  203. e2 = mate mrt2 'EMIS' emis;
  204. tabnl = table ;
  205. tabnl . 'MODELE' = mcd et mrt2;
  206. tabnl . 'CARACTERISTIQUES' = k et e2 ;
  207.  
  208. listtemp = prog 0 5 100 ;
  209. listval = prog 1 1 1 ;
  210. evchar = evol manu 't' listtemp 'f(t)' listval ;
  211. tabnl . 'CHARGEMENT' = char 'TIMP' evchar (tim1 et tim2) ;
  212.  
  213. tabnl . 'BLOCAGES_THERMIQUES' = c1 et c2 ;
  214.  
  215. * tabnl . 'RAYONNEMENT' = table ;
  216. * tabnl . 'RAYONNEMENT' . 1 = table ;
  217. * tabnl . 'RAYONNEMENT' . 1 . 'TYPE' = 'CAVITE' ;
  218. * tabnl . 'RAYONNEMENT' . 1 . 'MODELE' = mrt ;
  219. ** tabnl . 'RAYONNEMENT' . 1 . 'CONVEXE' = vrai ;
  220. * tabnl . 'RAYONNEMENT' . 1 . 'FERME' = faux ;
  221. * tabnl . 'RAYONNEMENT' . 1 . 'TRAYO'= vrai;
  222.  
  223. tabnl . 'TEMPS_CALCULES' = prog 0 pas 0.5 10 ;
  224. * tabnl . 'TEMPS_SAUVES' = extr (tabnl . 'TEMPS_CALCULES')
  225. * (lect 1 pas 10 (dime (tabnl . 'TEMPS_CALCULES'))) ;
  226.  
  227. tabnl . 'PROCEDURE_THERMIQUE' = 'DUPONT' ;
  228.  
  229. *** Résolution (avec PASAPAS) ...
  230.  
  231. pasapas tabnl ;
  232.  
  233. *** Petit post-traitement ...
  234.  
  235. nbpas = dime (tabnl . TEMPS) ;
  236. listtime = prog ;
  237. listtemp = prog ;
  238. repeter surpas nbpas ;
  239. lindice = &surpas - 1 ;
  240. listtime = listtime et (prog (tabnl . TEMPS . lindice)) ;
  241. valtemp = extr (tabnl . TEMPERATURES . lindice) 'T' p2 ;
  242. listtemp = listtemp et (prog valtemp) ;
  243. fin surpas ;
  244.  
  245. titr 'Evolution de temperature a l extremite de l ailette' ;
  246. evtemp = evol manu 't' listtime 'T' listtemp ;
  247. si(graph) ; dess evtemp ; finsi ;
  248.  
  249.  
  250. valref = 1751. ;
  251. valobt = extr listtemp (dime listtemp) ;
  252. errre2 = 100 * (valobt - valref) / valref ;
  253.  
  254. opti echo 0 ;
  255. saut 1 lign ;
  256. mess 'Methode sans calcul de la matrice de rayonnement' ;
  257. mess 'Solution exacte : ' valref ;
  258. mess 'Solution obtenue : ' valobt ;
  259. mess 'soit une erreur de ' errre2 ' %' ;
  260.  
  261.  
  262.  
  263. *** Test de bon fonctionnement
  264.  
  265. si ((abs errre2) > 1.);
  266. mess ' méthode sans matrice de rayonnement';
  267. erre 5 ;
  268. sinon;
  269. erre 0;
  270. finsi ;
  271.  
  272. fin ;
  273.  
  274.  
  275.  
  276.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales