Télécharger pressutq2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressutq2.dgibi
  2. *
  3. * Containment pressurization (Phebus size)
  4. *
  5. * 3D mesh of about 14.5 m3 cylindrical containment with a 100oC vertical wall.
  6. * Initial pressure and temperature are 1.3bar and 123oC.
  7. * Steam is injected at a constant 10g/s mass flow rate and a temperature of 130oC.
  8. *
  9. * Transient is computed for 50s. We check the pressure, the averaged temperature,
  10. * the velocity and the condensation mass flow rate (that starts later) evolutions.
  11. *
  12. * This test case is similar as pressutq.dgibi except for the 'CORMAS'
  13. * and 'CORLIM' options set to vrai instead of faux.
  14. *
  15. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  16. *
  17. 'OPTI' 'DIME' 3 'ELEM' 'CU20' 'TRAC' 'PSC' ;
  18. 'DENS' 1. ;
  19. *
  20. COMPLET = FAUX ;
  21. GRAPH = FAUX ;
  22. 'SI' COMPLET ;
  23. nbit = 100 ;
  24. DT0 = 1. ;
  25. n1 = 1 ;
  26. n2 = 4 ;
  27. n3 = 4 ;
  28. nn = 2 ;
  29. 'SINO' ;
  30. nbit = 5 ;
  31. DT0 = 10. ;
  32. n1 = 1 ;
  33. n2 = 2 ;
  34. n3 = 4 ;
  35. nn = 1 ;
  36. 'FINS' ;
  37. epsi = 1.D-2 ;
  38. *
  39. *
  40. * Mesh
  41. *
  42. *
  43. * ri=cavity radius, h1=cavity height, sp=wall depth,
  44. * fg1=break to cavity radius ratio
  45. ri = 1.052 ;
  46. h1 = 4.163 ;
  47. sp = 0.10 ;
  48. fg1 = 0.25 ;
  49. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  50. *
  51. p0 = 0.000 0.000 0.000 ;
  52. p1 = (ri*fg1) 0.000 0.000 ;
  53. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  54. p3 = 0.000 (ri*fg1) 0.000 ;
  55. p4 = ri 0.000 0.000 ;
  56. p5 = 0.000 ri 0.000 ;
  57. p6 = (ri+sp) 0.000 0.000 ;
  58. p7 = 0.000 (ri+sp) 0.000 ;
  59. *
  60. * Fluid and structure basement surfaces
  61. * (built by symetry)
  62. l1 = 'DROI' p0 p1 n1 ;
  63. l2 = 'DROI' p1 p2 n1 ;
  64. l3 = 'DROI' p2 p3 n1 ;
  65. l4 = 'DROI' p3 p0 n1 ;
  66. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  67. basf0 = 'DALL' l1 l2 l3 l4 'PLAN' ;
  68. basf1 = ('REGL' (l2 'ET' l3) l5 n2) ;
  69. *
  70. l44 = 'COTE' 2 basf1;
  71. ax4 = ('INVE' l4) 'ET' l44 ;
  72. l11 = 'COTE' 4 basf1;
  73. ax1 = l11 'ET' ('INVE' l1) ;
  74. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  75. 'ELIM' basf epsi ;
  76. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  77. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' ('INVE' ax1) ;
  78. 'ELIM' basf epsi ;
  79. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  80. ax44 = ('INVE' ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  81. 'ELIM' basf epsi ;
  82. *
  83. * Fluid and structure volumes
  84. * (built by translation)
  85. nz1 = ('ENTI' (h1 '/' (ri '/' 2.))) '*' nn ;
  86. v1 = 0. 0. h1 ;
  87. mt = basf 'VOLU' nz1 'TRAN' v1 ;
  88. wall = ('DIFF' ('ENVE' mt) basf) 'COUL' 'ROUG' ;
  89. plan1 = ax11 'TRAN' nz1 v1 ;
  90. plan4 = ax44 'TRAN' nz1 v1 ;
  91. 'ELIM' (mt et wall 'ET' plan1 'ET' plan4) epsi ;
  92. *
  93. * Break at the basement if any
  94. pjg = 'POIN' basf 'PROC' (0. 0. 0.) ;
  95. breche = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  96. *
  97. *
  98. * Data for execrxt.procedur
  99. *
  100. *
  101. rxt = 'TABLE' ;
  102. rxt . 'VERSION' = 'V0' ;
  103. rxt . 'vtf' = mt ;
  104. rxt . 'epsi' = epsi ;
  105. rxt . 'pi' = 0. 0. 0.5 ;
  106. *
  107. rxt . 'DISCR' = 'MACRO';
  108. rxt . 'KPRE' = 'CENTRE';
  109. rxt . 'DT0' = DT0 ;
  110. *
  111. rxt . 'CORLIM' = vrai ;
  112. rxt . 'CORTEMP' = vrai ;
  113. *
  114. rxt . 'MODTURB' = 'NUTURB' ;
  115. rxt . 'NUT' = 1.D-2 ;
  116. *
  117. rxt . 'TIMP' = 'TABLE' ;
  118. rxt . 'TIMP' . 'TIMP1' = 'TABLE' ;
  119. rxt . 'TIMP' . 'TIMP1' .'MAILLAGE' = wall ;
  120. rxt . 'TIMP' . 'TIMP1' .'t' = 'PROG' 0.0 3000. ;
  121. rxt . 'TIMP' . 'TIMP1' .'TIMP' = 'PROG' 100. 100. ;
  122. rxt . 'TIMP' . 'TIMP1' .'ECHAN' = 10. ;
  123. *
  124. rxt . 'VAPEUR' = VRAI ;
  125. rxt . 'TF0' = 123.0 ;
  126. rxt . 'PT0' = 1.3e5 ;
  127. rxt . 'Yvap0' = 1.D-8 ;
  128. *
  129. rxt . 'Breches' = 'TABLE' ;
  130. rxt . 'Breches' . 'A' = 'TABLE' ;
  131. rxt . 'Breches' . 'A' . 'scenario' = 'TABLE' ;
  132. rxt . 'Breches' . 'A' . 'Maillage' = breche ;
  133. rxt . 'Breches' . 'A' . 'diru' = (0. 0. 1.) ;
  134. rxt . 'Breches' . 'A' . 'scenario' . 't' = 'PROG' 0.0 1000.0 ;
  135. rxt . 'Breches' . 'A' . 'scenario' . 'qeau' = 'PROG' 0.010 0.010 ;
  136. rxt . 'Breches' . 'A' . 'scenario' . 'qair' = 'PROG' 0.000 0.000 ;
  137. rxt . 'Breches' . 'A' . 'scenario' . 'tinj' = 'PROG' 130.0 130.0 ;
  138. *
  139. rxt . 'GRAPH' = GRAPH ;
  140. rxt . 'DETMAT' = VRAI ;
  141. rxt . 'FRPREC' = 5 ;
  142. rxt . 'RENU' = 'RIEN' ;
  143. *
  144. *
  145. * Transient (with restart after 2 time steps)
  146. *
  147. *
  148. EXECRXT 2 rxt ;
  149. EXECRXT (nbit - 2) rxt ;
  150. *
  151. *
  152. * Tests
  153. *
  154. *
  155. 'SI' ('NON' COMPLET) ;
  156. ERR1 = 0 ;
  157. 'LIST' rxt.TIC.'Tfm' ;
  158. 'LIST' rxt.TIC.'PT' ;
  159. 'LIST' rxt.TIC.'Qc' ;
  160. 'LIST' rxt.TIC.'LMAXU';
  161.  
  162. ltfm = 'PROG' 123.00 120.38 122.24 118.51 116.67 115.06 ;
  163.  
  164. lPT = 'PROG' 1.30000E+05 1.30840E+05 1.30301E+05 1.32429E+05
  165. 1.32769E+05 1.33224E+05 ;
  166.  
  167. Lqc = 'PROG' 0.0000 0.0000 0.0000 0.0000 0.0000 0.0000 ;
  168.  
  169. Lmaxu = 'PROG' 0.0000 0.11919 0.12541 1.5872 1.0398 1.9797 ;
  170.  
  171. tic = rxt . 'TIC' ;
  172. ERtf = 'SOMM' ('ABS'(ltfm - tic . 'Tfm')) '/' 80. ;
  173. ERPT = 'SOMM' ('ABS'(lPT - tic . 'PT' )) '/' 1.e5 ;
  174. ERQc = 'SOMM' ('ABS'(lqc - tic . 'Qc' )) ;
  175. ERum = 'SOMM' ('ABS'(Lmaxu - tic . 'LMAXU')) '/' 2. ;
  176. 'MESS' 'ERtf=' ERtf ' ' 'ERPT=' ERPT ' '
  177. 'ERQc=' ERQc ' ' 'ERum=' ERum ;
  178. 'SI' (ERtf '>' 2.e-4) ; err1 = err1 '+' 1 ; 'FINS' ;
  179. 'SI' (ERPT '>' 1.e-3) ; err1 = err1 '+' 1 ; 'FINS' ;
  180. 'SI' (ERQc '>' 1.e-4) ; err1 = err1 '+' 1 ; 'FINS' ;
  181. 'SI' (ERum '>' 1.e-2) ; err1 = err1 '+' 1 ; 'FINS' ;
  182. 'SI' ('NEG' ERR1 0) ;
  183. 'ERRE' 5 ;
  184. 'FINS' ;
  185. 'FINS' ;
  186. *
  187. *
  188. * Plots devoted to pressu... cases
  189. *
  190. *
  191. 'SI' GRAPH ;
  192. tbt = rxt . 'TBT' ;
  193. tic = rxt . 'TIC' ;
  194. *
  195. $vtf = rxt . 'GEO' . '$vtf' ;
  196. vtf = 'DOMA' $vtf 'MAILLAGE' ;
  197. *
  198. Mpl1 = 'CHAN' 'QUAF' plan1 ;
  199. Mpl4 = 'CHAN' 'QUAF' plan4 ;
  200. 'ELIM' (vtf 'ET' Mpl1 'ET' Mpl4) epsi ;
  201. $mpl1 = 'MODE' Mpl1 'NAVIER_STOKES' 'MACRO' ;
  202. $mpl4 = 'MODE' Mpl4 'NAVIER_STOKES' 'MACRO' ;
  203. plan1 = 'DOMA' $mpl1 'MAILLAGE' ;
  204. plan4 = 'DOMA' $mpl4 'MAILLAGE' ;
  205. plan = plan1 'ET' plan4 ;
  206. cplan = 'CONT' plan ;
  207. *
  208. 'SI' ('EXIS' tic 'TP') ;
  209. $vtp = rxt . 'GEO' . '$vtp' ;
  210. vtp = 'DOMA' $vtp 'MAILLAGE' ;
  211. 'FINS' ;
  212. paroif = rxt . 'TIMP' . 'TIMP1' . 'mtpi' ;
  213. cparoif = 'CONT' paroif ;
  214. *
  215. axe = p0 d nz1 (p0 plus v1) ;
  216. axe = 'CHAN' axe 'QUAF' ;
  217. 'ELIM' (axe 'ET' mt) epsi ;
  218. *
  219. un = tic . 'UN';
  220. unp = 'REDU' un plan ;
  221. ung = 'VECT' un 0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  222. ungp = 'VECT' unp 0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  223. tf = tic . 'TF' ;
  224. rho = tic . 'RHO' ;
  225. rair = tic . 'RAIR' ;
  226. 'SI' tbt . 'THE' ; rhe = tic . 'RHE' ; 'FINS' ;
  227. 'SI' tbt . 'TH2' ; rh2 = tic . 'RH2' ; 'FINS' ;
  228. 'SI' tbt . 'TCO' ; rco = tic . 'RCO' ; 'FINS' ;
  229. 'SI' tbt . 'TCO2' ; rco2 = tic . 'RCO2' ; 'FINS' ;
  230. 'SI' tbt . 'VAPEUR' ; rvp = tic . 'RVP' ; 'FINS' ;
  231. *
  232. evauz = 'EVOL' 'CHPO' ('EXCO' un 'UZ') axe ;
  233. 'DESS' evauz
  234. 'TITR' 'Velocity with the z axis' 'MIMA'
  235. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
  236. 'TRAC' ung plan ('CONT' plan) 'TITR' ' Velocity' ;
  237. *
  238. evatf = 'EVOL' 'CHPO' tf axe ;
  239. 'DESS' evatf
  240. 'TITR' 'Gas temperature with the z axis' 'MIMA'
  241. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  242. 'TRAC' tf plan cplan 'TITR' ' Temperature' ;
  243. 'TRAC' tf paroif cparoif 'TITR' ' Temperature' ;
  244. *
  245. evarh = 'EVOL' 'CHPO' rho axe ;
  246. 'DESS' evarh
  247. 'TITR' 'Gas density with the z axis' 'MIMA'
  248. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  249. 'TRAC' rho plan ('CONT' plan) ungp 'TITR' ' Density & velocity' ;
  250. 'TRAC' rho paroif cparoif 'TITR' ' Density' ;
  251. *
  252. evavap = 'EVOL' 'CHPO' rvp axe ;
  253. 'DESS' evavap
  254. 'TITR' 'Steam density with the z axis' 'MIMA'
  255. 'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  256. 'TRAC' rvp plan cplan 'TITR' ' Steam density' ;
  257. *
  258. Fcond = rxt . 'TIC' . 'Fcond11';
  259. 'TRAC' fcond paroif cparoif 'TITR' ' Fcond kg/m**2' ;
  260. *
  261. * Wall temperature
  262. 'SI' ('EXIS' tic 'TP') ;
  263. 'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  264. 'FINS' ;
  265. 'FINSI' ;
  266.  
  267. 'FIN' ;
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales