Télécharger la plaquette Cast3M


fr en

Télécharger pressuhx2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : pressuhx2.dgibi
  2. *
  3. * Containment pressurization (Phebus size) with heat losses.
  4. * 3D mesh of a 14.5 m3 cylindrical containment with a 10cm in depth vertical wall.
  5. *
  6. * Initial pressure and temperature are 1bar and 40oC with the wall at 60oC.
  7. * Steam is injected at a constant 50g/s mass flow rate and a temperature of 150oC.
  8. *
  9. * Transient is computed for 1000s. We check the condensation mass flow
  10. * rate evolution (that starts at about 20s).  
  11. *
  12. * Compare to pressu.dgibi, hereafter heat losses are considered : the
  13. * containment is in contact with air or water. The water table elevation
  14. * is moving with time ; the convective heat transfer coefficient is
  15. * computed by the Mc Adams correlation  (by use of a personnel procedur) ;
  16. * air and water characteristic lenght and temperature are known with
  17. * time for both.   
  18. *
  19. * Auteurs : E. Studer, J.P. Magnaud    Novembre 1999
  20. *
  21. 'OPTI' 'DIME' 3 'ELEM' 'CU20' 'DENS' 1. 'TRAC' 'PSC' ;
  22. *
  23. COMPLET = FAUX ;
  24. GRAPH   = faux ;
  25. 'SI' COMPLET ;
  26.   nbit = 100 ;
  27.   DT0  = 1.  ;
  28.   n1   = 1  ;
  29.   n2   = 4  ;
  30.   n3   = 4  ;
  31.   nn   = 2  ;
  32. 'SINO' ;
  33.   nbit = 100 ;
  34.   DT0  = 10. ;
  35.   n1   = 1  ;
  36.   n2   = 2  ;
  37.   n3   = 4  ;
  38.   nn   = 1  ;
  39. 'FINS' ;
  40. epsi = 1.D-2 ;
  41. *
  42. *
  43. * Mesh
  44. *
  45. *
  46. * ri=cavity radius, h1=cavity height, sp=wall depth,
  47. * fg1=break to cavity radius ratio
  48. ri  = 1.052 ;
  49. h1  = 4.163 ;
  50. sp  = 0.10  ;
  51. fg1 = 0.25  ;
  52. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  53. *
  54. p0  = 0.000    0.000    0.000 ;
  55. p1  = (ri*fg1) 0.000    0.000 ;
  56. p2  = (ri*fg2) (ri*fg2) 0.000 ;
  57. p3  = 0.000    (ri*fg1) 0.000 ;
  58. p4  = ri       0.000    0.000 ;
  59. p5  = 0.000    ri       0.000 ;
  60. p6  = (ri+sp)  0.000    0.000 ;
  61. p7  = 0.000    (ri+sp)  0.000 ;
  62. *
  63. * Fluid and structure basement surfaces
  64. * (built by symetry)
  65. l1    = 'DROI' p0 p1 n1        ;
  66. l2    = 'DROI' p1 p2 n1        ;
  67. l3    = 'DROI' p2 p3 n1        ;
  68. l4    = 'DROI' p3 p0 n1        ;
  69. l5    = 'CERC' p4 p0 p5 (2*n1) ;
  70. l6    = 'CERC' p6 p0 p7 (2*n1) ;
  71. basf0 = 'DALL' l1 l2 l3 l4 'PLAN' ;
  72. basf1 = ('REGL' (l2 'ET' l3) l5 n2) ;
  73. *
  74. l44   = 'COTE' 2 basf1;
  75. ax4   = ('INVE' l4) 'ET' l44 ;
  76. l11   = 'COTE' 4 basf1;
  77. ax1   = l11 'ET' ('INVE' l1) ;
  78. basf  = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  79. 'ELIM' basf epsi ;
  80. basf  = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  81. ax11  = ('SYME' ax1 'DROI' p0 p3) 'ET' ('INVE' ax1) ;
  82. 'ELIM' basf epsi ;
  83. basf  = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  84. ax44  = ('INVE' ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  85. 'ELIM' basf epsi ;
  86. basm  =  'REGL' l5 l6 n3 ;
  87. basm  =  basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  88. 'ELIM' basm epsi ;
  89. basm  =  basm 'ET' ('SYME'  basm 'DROI' p0 p1) ;
  90. 'ELIM' basm epsi ;
  91. l5    = l5 'ET' ('SYME' l5 'DROI' p0 p1) ;                        
  92. l5    = l5 'ET' ('SYME' l5 'DROI' p0 p3) ;                        
  93. l6    = l6 'ET' ('SYME' l6 'DROI' p0 p1) ;                        
  94. l6    = l6 'ET' ('SYME' l6 'DROI' p0 p3) ;                        
  95. *
  96. * Fluid and structure volumes
  97. * (built by translation)
  98. nz1   = ('ENTI' (h1 '/' (ri '/' 2.))) '*' nn ;
  99. v1    = 0. 0. h1 ;
  100. mt    = basf 'VOLU' nz1 'TRAN' v1 ;
  101. wall  = (basm 'VOLU' nz1 'TRAN' v1) 'COUL' 'ROUG' ;
  102. *
  103. plan1 = ax11 'TRAN' nz1 v1 ;
  104. plan4 = ax44 'TRAN' nz1 v1 ;
  105. pari  = l5   'TRAN' nz1 v1 ;
  106. pare  = l6   'TRAN' nz1 v1 ;
  107. pti   = 'POIN' 1 l5 ;
  108. pte   = 'POIN' 1 l6 ;
  109. lzi   = pti d nz1 (pti 'PLUS' v1) ;
  110. lze   = pte d nz1 (pte 'PLUS' v1) ;
  111. *
  112. 'ELIM' (mt 'ET' wall 'ET' plan1 'ET' plan4 'ET'
  113.         pari 'ET' pare 'ET' lzi 'ET' lze) epsi ;
  114. *
  115. * Break at the basement if any
  116. pjg    =  'POIN' basf 'PROC' (0. 0. 0.) ;
  117. breche = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  118. *
  119. *
  120. * Data for execrxt.procedur
  121. *
  122. *
  123. rxt = 'TABLE' ;
  124. rxt . 'VERSION' = 'V0' ;
  125. rxt . 'vtf'     = mt ;
  126. rxt . 'epsi'    = epsi ;
  127. rxt . 'pi'      = 0. 0. 0.5 ;
  128. *
  129. rxt . 'DISCR' = 'MACRO';
  130. rxt . 'KPRE'  = 'CENTRE';
  131. rxt . 'DT0'   = DT0 ;
  132. *
  133. rxt . 'MODTURB' = 'NUTURB' ;
  134. rxt . 'NUT'     = 1.D-2    ;
  135. *
  136. rxt . 'THERMP'  = VRAI   ;
  137. rxt . 'vtp'     = wall   ;
  138. rxt . 'LAMBDA'  = 15.    ;
  139. rxt . 'ROCP'    = 3.9E6  ;
  140. rxt . 'Tp0'     = 60.    ;
  141. rxt . 'ECHAN'   = 10.    ;
  142. *
  143.  
  144. *
  145. rxt . 'VAPEUR' = VRAI   ;
  146. rxt . 'TF0'    = 40.0   ;
  147. rxt . 'PT0'    = 1.0e5  ;
  148. rxt . 'Yvap0'  = 0.0023 ;
  149. *
  150. rxt . 'Breches'                    = 'TABLE' ;
  151. rxt . 'Breches' . 'A'              = 'TABLE' ;
  152. rxt . 'Breches' . 'A' . 'scenario' = 'TABLE' ;
  153. rxt . 'Breches' . 'A' . 'Maillage' =  breche ;
  154. rxt . 'Breches' . 'A' . 'diru'     =  (0. 0. 1.) ;
  155. rxt . 'Breches' . 'A' . 'scenario' . 't'      = 'PROG' 0.0   1000.0 ;
  156. rxt . 'Breches' . 'A' . 'scenario' . 'qeau'   = 'PROG' 0.050  0.050 ;
  157. rxt . 'Breches' . 'A' . 'scenario' . 'qair'   = 'PROG' 0.000  0.000 ;
  158. rxt . 'Breches' . 'A' . 'scenario' . 'tinj'   = 'PROG' 150.0  150.0 ;
  159. *
  160. rxt . 'GRAPH'   = GRAPH ;
  161. rxt . 'DETMAT'  = VRAI ;
  162. rxt . 'FRPREC'  = 5 ;
  163. rxt . 'RENU'    = 'RIEN' ;
  164. *
  165. *===================================================================
  166. * Use of a personnal procedur to impose external temperature and heat
  167. * transfer coefficient
  168. *
  169. rxt . 'ECHEXT' = vrai ;           
  170. rxt . 'parext' = pare ;           
  171. rxt . 'HEXT'   = 0.   ;
  172. rxt . 'TPEXT'  = 0.   ;                                                                
  173. rxt . 'PERSO'    = vrai      ;
  174. rxt . 'PRCPERSO' = 'MAPROCX' ;
  175. rxt . 'TABPERSO' = 'TABLE'   ;
  176. *
  177. 'DEBPROC' MAPROCX TPS*'FLOTTANT' rxt*'TABLE' ;
  178. *
  179. * Heat transfer coeff given by Mc Adams correlation with h=hair if
  180. * z>z(t) and h=hwater otherwise (case KAS2 of the PROCHEXT procedur).
  181.    zt   = 'EVOL' 'MANU' ('PROG' 0. 1.e3) ('PROG'   2.   2.) ;
  182.    Lair = 3. ;
  183.    tair = 'EVOL' 'MANU' ('PROG' 0. 1.e3) ('PROG'  45.  45.) ;
  184.    Lmer = 2. ;
  185.    tmer = 'EVOL' 'MANU' ('PROG' 0. 1.e3) ('PROG'  25.  25.) ;
  186.    PROCHEXT TPS RXT 'KAS2' ZT TAIR LAIR TMER LMER ;
  187. 'FINP' ;
  188. *                                                                       
  189. *===================================================================
  190. *
  191. *
  192. * Transient (with restart after 2 time steps)
  193. *
  194. *
  195. EXECRXT  2    rxt       ;
  196. EXECRXT  (nbit - 2) rxt ;
  197. *
  198. *
  199. * Tests
  200. *
  201. *
  202. 'SI' ('NON' COMPLET) ;
  203.   ERR1 = 0 ;
  204.  
  205.   list rxt . 'TIC' . 'Qc' ;                                                    
  206.  
  207. lqc = 'PROG' 
  208.   0.0000      0.0000      0.0000      4.06187E-04 2.65273E-03
  209.   4.88913E-03 9.33217E-03 1.21696E-02 1.62809E-02 1.83569E-02
  210.   2.15760E-02 2.30394E-02 2.49146E-02 2.71021E-02 2.88218E-02
  211.   3.11268E-02 3.25368E-02 3.41987E-02 3.55088E-02 3.65889E-02
  212.   3.75529E-02 3.84019E-02 3.91586E-02 3.98414E-02 4.04639E-02
  213.   4.10347E-02 4.15599E-02 4.20449E-02 4.24941E-02 4.29111E-02
  214.   4.32985E-02 4.36591E-02 4.39950E-02 4.43082E-02 4.46005E-02 ;
  215. lqc = lqc 'ET' ('PROG' 
  216.   4.48734E-02 4.51285E-02 4.53669E-02 4.55900E-02 4.57989E-02
  217.   4.59945E-02 4.61778E-02 4.63498E-02 4.65111E-02 4.66625E-02
  218.   4.68047E-02 4.69383E-02 4.70639E-02 4.71820E-02 4.72932E-02
  219.   4.73978E-02 4.74964E-02 4.75892E-02 4.76767E-02 4.77591E-02
  220.   4.78369E-02 4.79102E-02 4.79795E-02 4.80448E-02 4.81065E-02
  221.   4.81648E-02 4.82198E-02 4.82719E-02 4.83210E-02 4.83675E-02
  222.   4.84115E-02 4.84531E-02 4.84924E-02 4.85296E-02 4.85648E-02) ;
  223. lqc = lqc 'ET' ('PROG' 
  224.   4.85982E-02 4.86297E-02 4.86596E-02 4.86879E-02 4.87147E-02
  225.   4.87400E-02 4.87640E-02 4.87868E-02 4.88084E-02 4.88288E-02
  226.   4.88481E-02 4.88664E-02 4.88838E-02 4.89003E-02 4.89158E-02
  227.   4.89306E-02 4.89446E-02 4.89578E-02 4.89704E-02 4.89822E-02
  228.   4.89935E-02 4.90041E-02 4.90142E-02 4.90237E-02 4.90327E-02
  229.   4.90413E-02 4.90493E-02 4.90569E-02 4.90641E-02 4.90709E-02
  230.   4.90774E-02) ;
  231.  
  232.   tic = rxt . 'TIC' ;
  233.   ERQc = 'SOMM' ('ABS'(lqc  - tic . 'Qc' ))  ;
  234.   'MESS' 'ERQc=' ERQc ;
  235.   'SI' (ERQc '>' 1.e-4) ; err1 = err1 '+' 1 ; 'FINS' ;
  236.   'SI' ('NEG' ERR1 0) ;
  237.     'ERRE' 5 ;
  238.   'FINS' ;
  239. 'FINS' ;
  240. *
  241. *
  242. * Plots devoted to pressu... cases
  243. *
  244. *
  245. 'SI' GRAPH ;
  246.   tbt = rxt . 'TBT' ;
  247.   tic = rxt . 'TIC' ;
  248. *
  249.   $vtf = rxt . 'GEO' . '$vtf' ;
  250.   vtf  = 'DOMA'  $vtf 'MAILLAGE' ;
  251. *
  252.   Mpl1 = 'CHAN' 'QUAF' plan1 ;
  253.   Mpl4 = 'CHAN' 'QUAF' plan4 ;
  254.   'ELIM' (vtf 'ET' Mpl1 'ET' Mpl4) epsi ;
  255.   $mpl1 = 'MODE' Mpl1 'NAVIER_STOKES' 'MACRO' ;
  256.   $mpl4 = 'MODE' Mpl4 'NAVIER_STOKES' 'MACRO' ;
  257.   plan1 = 'DOMA' $mpl1 'MAILLAGE' ;
  258.   plan4 = 'DOMA' $mpl4 'MAILLAGE' ;
  259.   plan  = plan1 'ET' plan4 ;
  260.   cplan = 'CONT' plan ;
  261. *
  262.   'SI' ('EXIS' tic 'TP') ;
  263.     $vtp = rxt . 'GEO' . '$vtp' ;
  264.     vtp  = 'DOMA'  $vtp 'MAILLAGE' ;    
  265.   'FINS' ;
  266.   paroif  = rxt . 'GEO' . 'paroif';
  267.   cparoif = 'CONT' paroif ;
  268. *
  269.   axe  = p0 d nz1 (p0 plus v1) ;
  270.   axe = 'CHAN' axe 'QUAF' ;
  271.   'ELIM' (axe 'ET' mt) epsi ;
  272. *   
  273.   un   = tic . 'UN';
  274.   unp  = 'REDU' un plan ;
  275.   ung  = 'VECT' un  0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  276.   ungp = 'VECT' unp 0.5 'UX' 'UY' 'UZ' 'JAUN' ;
  277.   tf   = tic . 'TF' ;
  278.   rho  = tic . 'RHO' ;
  279.   rair = tic . 'RAIR' ;
  280.   'SI' tbt . 'THE'    ; rhe  = tic . 'RHE'  ; 'FINS' ;
  281.   'SI' tbt . 'TH2'    ; rh2  = tic . 'RH2'  ; 'FINS' ;
  282.   'SI' tbt . 'TCO'    ; rco  = tic . 'RCO'  ; 'FINS' ;
  283.   'SI' tbt . 'TCO2'   ; rco2 = tic . 'RCO2' ; 'FINS' ;
  284.   'SI' tbt . 'VAPEUR' ; rvp  = tic . 'RVP'  ; 'FINS' ;
  285. *
  286.   evauz = 'EVOL' 'CHPO' ('EXCO' un 'UZ') axe ;
  287.   'DESS' evauz
  288.   'TITR' 'Velocity with the z axis' 'MIMA'
  289.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
  290.   'TRAC' ung plan ('CONT' plan) 'TITR' ' Velocity' ;
  291. *
  292.   evatf = 'EVOL' 'CHPO' tf  axe ;
  293.   'DESS' evatf
  294.   'TITR' 'Gas temperature with the z axis' 'MIMA'
  295.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  296.   'TRAC' tf plan cplan 'TITR' ' Temperature' ;
  297.   'TRAC' tf paroif cparoif 'TITR' ' Temperature' ;
  298. *
  299.   evarh = 'EVOL' 'CHPO' rho axe ;
  300.   'DESS' evarh
  301.   'TITR' 'Gas density with the z axis' 'MIMA'
  302.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  303.   'TRAC' rho plan ('CONT' plan) ungp 'TITR' ' Density & velocity' ;
  304.   'TRAC' rho paroif cparoif 'TITR' ' Density' ;
  305. *
  306.   evavap = 'EVOL' 'CHPO' rvp axe ;
  307.   'DESS' evavap
  308.   'TITR' 'Steam density with the z axis' 'MIMA'
  309.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  310.   'TRAC' rvp plan cplan 'TITR' ' Steam density' ;
  311. *
  312.   Fcond = rxt . 'TIC' . 'Fcondw';
  313.   'TRAC' fcond paroif cparoif 'TITR' ' Fcond kg/m**2' ;
  314. *
  315. * Wall temperature
  316.   'SI' ('EXIS' tic 'TP') ;
  317.      'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  318.   'FINS' ;
  319. *
  320. *
  321. * Specific plots
  322. *
  323. *
  324.   TAB1 = TABLE ;
  325.   TAB1 . 1 = 'MARQ LOSA REGU' ;
  326.   TAB1 . 2 = 'MARQ TRIU REGU' ;
  327.   TAB1 . 3 = 'MARQ PLUS TIRM' ;
  328.   TAB1 . 4 = 'MARQ CARR TIRM' ;
  329.   TAB1 . 'TITRE' = TABLE ;
  330. *
  331. *---------------------------------------> Hext, Text , ...
  332.  
  333.   TAB1 . 'TITRE' . 1 = 'MOT' 'TP int' ;
  334.   TAB1 . 'TITRE' . 2 = 'MOT' 'TP ext' ;
  335.   TAB1 . 'TITRE' . 3 = 'MOT' 'Text'   ;
  336.   TAB1 . 'TITRE' . 4 = 'MOT' 'TF int' ;
  337.  
  338.   evtpi  = ('EVOL' 'CHPO' tic . 'TP'    lzi) 'COUL' 'ROUG' ;
  339.   evtpe  = ('EVOL' 'CHPO' tic . 'TP'    lze) 'COUL' 'BLEU' ;
  340.   evtpxt = ('EVOL' 'CHPO' tic . 'TPEXT' lze) 'COUL' 'BLEU' ;
  341.   evtfi  = ('EVOL' 'CHPO' tic . 'TF'    lzi) 'COUL' 'ROUG' ;
  342.   'DESS' (evtpi 'ET' evtpe 'ET' evtpxt 'ET' evtfi)
  343.   'TITR' 'Gas, wall and external temperatures (KAS2)' 'MIMA'
  344.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z(m)' 'TITY' ' C'
  345.   'LEGE' tab1 ;
  346.  
  347.   TAB1 . 'TITRE' . 1 = 'MOT' 'Hext ' ;
  348.  
  349.   hext = 'ELNO' tic . 'HEXTc' rxt . 'GEO' . '$parext' ;
  350.   evhxt  = 'EVOL' 'CHPO' hext lze ;
  351.   'DESS'  evhxt
  352.   'TITR' 'Hext (KAS2)' 'MIMA'
  353.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z(m)' 'TITY' 'W/m^2/K'
  354.   'LEGE' tab1 ;
  355.   'TRAC' hext  pare 'TITR' 'Hext (KAS2)'         ;
  356.   'TRAC' tic . 'TPEXT' pare 'TITR' 'Text (KAS2)' ;
  357.  
  358. *
  359. *---------------------------------------> Pressure
  360. * Why TPi and not TFi for air ans steam ?
  361.  
  362.   TAB1 . 'TITRE' . 1 = 'MOT' 'PT' ;
  363.   TAB1 . 'TITRE' . 2 = 'MOT' 'Psat(TPi)' ;
  364.   TAB1 . 'TITRE' . 3 = 'MOT' 'Pair(TPi)' ;
  365.   TAB1 . 'TITRE' . 4 = 'MOT' 'Pvap(TPi)' ;
  366.  
  367.   Psattp = PSATT (tic . 'TP' + 273.15)  ;
  368.   PT     = 'EXTR' ('DIME' tic . 'PT') (tic . 'PT') ;
  369.   Pair   = ('EXTR' tic . 'Rhomn' 1) '*' 287.1 '*' tic . 'TP' ;
  370.   pvi    = PT - Pair ;
  371.  
  372.   evpsattpi = 'EVOL' 'CHPO' Psattp lzi ;
  373.   evpt     = 'EVOL' 'MANU' ('PROG' 0. h1) ('PROG' PT PT) ;
  374.   evpair   = 'EVOL' 'CHPO' pair lzi ;
  375.   evpvi    = 'EVOL' 'CHPO' pvi lzi ;
  376.   'DESS' (evPT et evpsattpi et evpair et evpvi)
  377.   'TITR'  'Pressure' 'MIMA'
  378.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z(m)' 'TITY' ' Pa'
  379.   'LEGE' tab1 ;
  380. *
  381. *---------------------------------------> Density
  382.  
  383.   TAB1 . 'TITRE' . 1 = 'MOT' 'Rho' ;
  384.   TAB1 . 'TITRE' . 2 = 'MOT' 'Rvp' ;
  385.   TAB1 . 'TITRE' . 3 = 'MOT' 'Rnc' ;
  386.   TAB1 . 'TITRE' . 4 = 'MOT' 'Rsat(TPi)' ;
  387.  
  388.   Rsattp   = Psattp '/' 461.73 '/' (tic . 'TP' '+' 273.15) ;
  389.  
  390.   evrhpi   = 'EVOL' 'CHPO' tic . 'RHO' lzi ;
  391.   evrvpi   = 'EVOL' 'CHPO' tic . 'RVP' lzi ;
  392.   evrinci  = 'EVOL' 'CHPO' (tic . 'RHO' '-' tic . 'RVP') lzi ;
  393.   evrsati  = 'EVOL' 'CHPO' Rsattp lzi ;
  394.   'DESS' (evrhpi 'ET' evrvpi 'ET' evrinci 'ET' evrsati)
  395.   'TITR' 'Density at the wall' 'MIMA'
  396.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z(m)' 'TITY' 'kg/m3'
  397.   'LEGE' tab1 ;
  398. *
  399. *---------------------------------------> Mass fraction
  400.  
  401.   TAB1 . 'TITRE' . 1 = 'MOT' 'Yvap' ;
  402.   TAB1 . 'TITRE' . 2 = 'MOT' 'Ysat(TPi)' ;
  403.   TAB1 . 'TITRE' . 3 = 'MOT' 'Yvap - Ysat(TPi)' ;
  404.  
  405.   yvi   = tic . 'RVP' '/' tic . 'RHO' ;
  406.   ysati = ('REDU' Rsattp lzi) '/' ('REDU' tic . 'RHO' lzi) ;
  407.  
  408.   evysati = 'EVOL' 'CHPO' ysati lzi ;
  409.   evyvi   = 'EVOL' 'CHPO' yvi lzi ;
  410.   evdyv   = evyvi '-' evysati ;
  411.   'DESS' (evyvi 'ET' evysati 'ET' evdyv)
  412.   'TITR' 'Steam mass fraction at wall' 'MIMA' 'YBOR' 0. 0.4
  413.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z(m)' 'TITY' ' Mass Fraction'
  414.   'LEGE' tab1 ;
  415. *
  416. *- Fin GRAPH
  417. *
  418. 'FINSI' ;
  419.  'FIN' ;
  420.  
  421.  
  422.  
  423.  
  424.  
  425.  
  426.  
  427.  
  428.  
  429.  
  430.  
  431.  
  432.  
  433.  
  434.  
  435.  
  436.  
  437.  
  438.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales