Télécharger pore1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pore1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Pore1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. SAUT PAGE;
  8. *
  9. *******************************************************
  10. * *
  11. * TEST PORE1 *
  12. * *
  13. * CYLINDRE EPAIS EN MILIEU POREUX *
  14. * *
  15. * REFERENCE : Benchmark INTERCLAY 1.1 Variante 2 *
  16. * *
  17. * Le milieu est elastoplastique, modele *
  18. * Drucker-Prager non associe *
  19. * On decharge la contrainte a l'interieur du trou *
  20. * *
  21. * On se propose de caculer la convergence du trou *
  22. * valeur de reference : -0.266 m *
  23. * ainsi que la contrainte circonferentielle au *
  24. * bord du trou *
  25. * valeur de reference : -3.47E6 Pa *
  26. * Il s'agit de valeurs calculees par castem2000 *
  27. * et en accord avec les resultats de INTERCLAY *
  28. * *
  29. *******************************************************
  30. *
  31. OPTI ECHO 0;
  32. TITRE ' TEST PORE1 ' ;
  33. GRAPH = 'N';
  34. OPTIO DIME 2 MODEL AXIS ELEM QUA8 ;
  35. *
  36. *=====================================================*
  37. * geometrie : maillage *
  38. *=====================================================*
  39. *
  40. * Dimension en metres
  41. *
  42. DENS 0.5;
  43. P1 = 2.5 0. ; P2 = 25. 0. ; Q1 = 2.5 0.5 ;
  44. Q2 = 25. 0.5; PP1 = 5 0. ; QQ1 = 5 0.5 ;
  45. LI1 = P1 D P2 'DINI' 0.25 'DFIN' 2.5 ;
  46. LI2 = P2 D Q2 ;
  47. LI3 = INVE ( Q1 D Q2 'DINI' 0.25 'DFIN' 2.5 );
  48. LI4 = Q1 D P1 ;
  49. LI = LI1 ET LI2 ET LI3 ET LI4 ;
  50. CADRE = DALLER LI1 LI2 LI3 LI4 PLAN ;
  51. SI (NEG GRAPH 'N');
  52. TRAC CADRE ;
  53. FINSI;
  54. *
  55. *=====================================================*
  56. * modele - materiau - caracteristiques en Pa *
  57. * conditions aux limites *
  58. *=====================================================*
  59. *
  60. MO=MODE CADRE POREUX ELASTIQUE PLASTIQUE
  61. DRUCKER_PRAGER ;
  62. *
  63. MAT=MATE MO YOUNG 200.13E6 NU 0.25 MOB 7500E6 COB 1.
  64. PERM 4.E-12 VISCO 4.
  65. ALPH 0. KF 0. RHOF 0. ALPF 0. ALPM 0. RHO 0.
  66. ALFA 0.1270509 BETA 0.57735027 K 0.
  67. GAMM 0. DELT 0.57735027
  68. ETA 0.1270509 MU 0.57735027 KL 0. H 0. ;
  69. *
  70. * on bloque les faces superieure et inferieure
  71. *
  72. BL1=BLOQ UZ LI1 ;
  73. BL2=BLOQ UZ LI3 ;
  74. CL = BL1 ET BL2 ;
  75. *
  76. *=====================================================*
  77. * Chargement *
  78. *=====================================================*
  79. *
  80. * contraintes initiales
  81. *
  82. ZOZO = MANU CHML MO SMRZ 0.
  83. SMRR -5.E6 SMTT -5.E6 SMZZ -5.E6 MSR0 0.
  84. TYPE CONTRAINTES STRESSES ;
  85. ZUZU = MANU CHML MO GARZ 0.
  86. EPRR 0. EPTT 0. EPZZ 0. PRES 2.5E6
  87. TYPE DEFORMATIONS STRESSES ;
  88. FF = BSIGMA MO ZOZO;
  89. EVT1= EVOL MANU 'TEMPS' (PROG 0 14 )
  90. 'CHARGE' (PROG 1 1 );
  91. CHA1 = CHAR MECA FF EVT1 ;
  92. *
  93. * pression
  94. *
  95. FPI2 = PRESS MASS MO -1.E6 LI4 ;
  96. EVT2= EVOL MANU 'TEMPS' (PROG 0 PAS 1 14 )
  97. 'CHARGE' (PROG 0 PAS 0.25 3.5) ;
  98. CHA2 = CHAR MECA FPI2 EVT2 ;
  99. CHATT = CHA1 ET CHA2 ;
  100. *
  101. *=====================================================*
  102. * Initialisation de la table pour appel a PASAPAS *
  103. *=====================================================*
  104. *
  105. TAB1 = TABLE;
  106. TAB1 . 'CONTRAINTES' = TABLE;
  107. TAB1 . 'DEFORMATIONS' = TABLE;
  108. TAB1 . 'DEPLACEMENTS' = TABLE;
  109. TAB1.'CONTRAINTES' . 0 = ZOZO;
  110. TAB1.'DEFORMATIONS' . 0 = ZUZU;
  111. TAB1.'DEPLACEMENTS' . 0 = MANU CHPO CADRE 1 P 2.5E6 ;
  112. LREE = PROG 0 PAS 1 14;
  113. TAB1.'CARACTERISTIQUES' = MAT;
  114. TAB1.'CHARGEMENT' = CHATT;
  115. TAB1.'MODELE' = MO;
  116. TAB1.'TEMPS_CALCULES' = LREE;
  117. TAB1.'BLOCAGES_MECANIQUES' = CL;
  118. TAB1.'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  119. *
  120. PASAPAS TAB1;
  121. *=====================================================*
  122. * affichage des resultats *
  123. *=====================================================*
  124. *
  125. MESS ' RESULTATS TEST PORE1 ';
  126. MESS ' -------------------- ';
  127. ' On cherche la convergence du trou et la contrainte';
  128. ' circonferentielle ';
  129. ' Elles sont comparees a des valeurs de reference ';
  130. CONVTH = -0.266 ;
  131. SIGTTH = -3.47E6 ;
  132. LEDEP = PECHE TAB1 DEPLACEMENTS 14 ;
  133. SIGAA = PECHE TAB1 CONTRAINTES 14 ;
  134. SIGAB = CHAN 'CHPO' MO SIGAA ;
  135. CONVXX = EXTR LEDEP UR P1 ;
  136. SIGTXX = EXTR SIGAB SMTT P1 ;
  137. ERGXXA = ( CONVXX - CONVTH ) / CONVTH ;
  138. ERGXXA = ABS ERGXXA ;
  139. ERGXXB = ( SIGTXX - SIGTTH ) / SIGTTH ;
  140. ERGXXB = ABS ERGXXB ;
  141. *
  142. MESS ' Convergence de reference :' CONVTH 'm';
  143. MESS ' Convergence calculee :' CONVXX 'm';
  144. MESS ' Soit un ecart relatif de :' ERGXXA ;
  145. MESS ' Contrainte circonferentielle de reference :'
  146. SIGTTH 'Pa';
  147. MESS ' Contrainte circonferentielle calculee :'
  148. SIGTXX 'Pa';
  149. MESS ' Soit un ecart relatif de :' ERGXXB ;
  150. *
  151. *
  152. *=====================================================*
  153. * code fonctionnement *
  154. *=====================================================*
  155. *
  156. * L'ecart maximum entre valeur theorique et calculee
  157. * doit etre inferieure a 2%.
  158. *
  159. SAUT 2 LIGNE;
  160. SI (ERGXXA <EG 5) ;
  161. SI (ERGXXB <EG 5) ;
  162. ERRE 0;
  163. SINON;
  164. ERRE 5;
  165. FINSI;
  166. SINON;
  167. ERRE 5;
  168. FINSI;
  169. *
  170. *
  171. FIN;
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  
  180.  
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales