Télécharger plas6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas6.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. * CAS TEST DU 91/07/23 PROVENANCE : BIRET
  8.  
  9. *******************************************************
  10. * Test plas6.dgibi: Jeux de données *
  11. * --------------------------------- *
  12. *******************************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22. OPTI ECHO 1 ;
  23. OPTI TRAC PSC ;
  24. SINO ;
  25. OPTI ECHO 0 ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *******************************************************
  30. * *
  31. * TEST PLAS6 *
  32. * *
  33. * RECTANGLE EN FLEXION PURE (CONTRAINTES PLANES, *
  34. * PLASTICITE PARFAITE) *
  35. * *
  36. * Test V.P.C.S. numero SSNP11/89 *
  37. * *
  38. * References : R. Hill, Mathematical theory of *
  39. * plasticity, Oxford, Oxford Clavendon Press, 1950. *
  40. * *
  41. * Description : *
  42. * ----------- *
  43. * *
  44. * axe y *
  45. * D | A *
  46. * |----- ---- UA epaisseur a = 12.5 mm *
  47. * | | / hauteur b = 100.0 mm *
  48. * | | / *
  49. * | | / *
  50. * | |/ *
  51. * O |-----/-----> axe x *
  52. * | /| *
  53. * | / | *
  54. * | / | *
  55. * | / | *
  56. * ----- *
  57. * C UB B *
  58. * *
  59. * Chargement : Deplacement impose variant *
  60. * lineairement de UA a -UA entre A et B, *
  61. * UA croissant jusqu'a : UAmax = 0.5 mm . *
  62. * *
  63. * Conditions aux limites : *
  64. * sur CD : u = 0. *
  65. * au point O : v = 0. *
  66. * *
  67. * Proprietes des materiaux : *
  68. * Materiau elastique, parfaitement plastique *
  69. * E = 210 000 MPa , NU = 0.3 , SIGY = 483 MPa *
  70. * *
  71. *******************************************************
  72. OPTI MODE PLAN CONT;
  73. OPTI ELEM QUA4;
  74.  
  75. GRAPH2 = GRAPH;
  76.  
  77. TEMPS;
  78. *******************************************************
  79. * geometrie : maillage *
  80. *******************************************************
  81. PA = 12.5E-3 50.E-3;
  82. PB = 12.5E-3 -50.E-3;
  83. PC = 0. -50.E-3;
  84. PD = 0. 50.E-3;
  85.  
  86. NB1 = 32; NB2 = 4;
  87. D1 = PA DROI NB1 PB;
  88. D2 = PB DROI NB2 PC;
  89. D3 = PC DROI NB1 PD;
  90. D4 = PD DROI NB2 PA;
  91.  
  92. SUR1 = DALL D1 D2 D3 D4 PLAN;
  93.  
  94. SI (NEG GRAPH 'N');
  95. TITR 'PLAS6 : MAILLAGE';
  96. TRAC QUAL SUR1;
  97. FINSI;
  98.  
  99. NBNO1 = NBNO SUR1;
  100. NBEL1 = NBEL SUR1;
  101.  
  102. *******************************************************
  103. * calcul du modele,caracteristiques *
  104. *******************************************************
  105. MOD1 = MODE SUR1 MECANIQUE ELASTIQUE PLASTIQUE PARFAIT;
  106. MAT1 = MATE MOD1 YOUN 2.1E11 NU 0.3 SIGY 483.E6;
  107.  
  108. *******************************************************
  109. * conditions aux limites *
  110. *******************************************************
  111. CL1 = BLOQ UX D3;
  112. CL2 = BLOQ UY (SUR1 POIN PROC (0. 0.));
  113. CL3 = BLOQ UX D1;
  114. CL = CL1 ET CL2 ET CL3;
  115.  
  116. * Creation du chpoint de deplacement impose variable :
  117. * deplacement impose variant lineairement de u a -u
  118. * entre A et B, u croissant jusqu'a 0.5 mm .
  119. I = 0.;
  120. LISD1 = PROG 1.;
  121. REPETER BLOC10 NB1;
  122. I = I + 1.;
  123. YY = 1. - (2. * (I / NB1));
  124. LISD1 = LISD1 ET (PROG YY);
  125. FIN BLOC10;
  126.  
  127. LISD1 = LISD1 * 1.E-3;
  128. CHPO1 = MANU CHPO (CHAN 'POI1' D1) 1 UX LISD1;
  129.  
  130. CHA1 = DEPI CL3 CHPO1;
  131. *******************************************************
  132. * objets relatifs a la procedure PASAPAS *
  133. *******************************************************
  134. TAB1 = TABL ;
  135.  
  136. *On prend comme liste des pseudo-temps le deplacement u
  137. LREEL1= PROG 0.02875 0.05 0.1 0.15 0.2 0.3 0.4 0.5 1.0;
  138.  
  139. * Chargement
  140. EVOL1 = EVOL MANU UA LREEL1 COEFF LREEL1;
  141. CHAR1 = CHAR DIMP CHA1 EVOL1;
  142.  
  143. *******************************************************
  144. * resolution *
  145. *******************************************************
  146. TAB1.'CARACTERISTIQUES' = MAT1;
  147. TAB1.'CHARGEMENT' = CHAR1;
  148. TAB1.'MODELE' = MOD1;
  149. TAB1.'TEMPS_CALCULES' = LREEL1;
  150. TAB1.'BLOCAGES_MECANIQUES' = CL;
  151. PASAPAS TAB1;
  152.  
  153. *******************************************************
  154. * extraction des resultats *
  155. *******************************************************
  156.  
  157. * Initialisation
  158. MOM1 = TABL ;
  159. LISD2 = LISD1 * 50.;
  160. MOM2 = TABL ;
  161. ERG = TABL ;
  162.  
  163. MOM2.1 = 805.0; MOM2.2 = 1074.;
  164. MOM2.3 = 1174.; MOM2.4 = 1193.;
  165. MOM2.5 = 1199.; MOM2.6 = 1204.;
  166. MOM2.7 = 1205.; MOM2.8 = 1206.;
  167. MOM2.9 = 1207.5;
  168.  
  169. *Boucle pour chaque pas de chargement : fonction de UA.
  170. I = 0;
  171. REPETER BLOC1 9;
  172. I = I + 1;
  173. CONT1 = TAB1.CONTRAINTES.I;
  174. DEPL1 = TAB1.DEPLACEMENTS.I;
  175.  
  176. * Passage du champs de contrainte en chpoints
  177. * (utilisation des nouveaux chamelems)
  178. CHPO10 = CHAN CHPO MOD1 CONT1;
  179.  
  180. * Trace facultatif de la repartition
  181. * de la contrainte SMXX
  182. SI (I EGA 9);
  183. SI (NEG GRAPH2 'N');
  184. TITR 'PLAS6 : CONTRAINTE SMXX';
  185. BB = EXCO 'SMXX' CONT1;
  186. TRAC BB MOD1;
  187. FINSI;
  188. FINSI;
  189.  
  190. * Trace facultatif de la deformee
  191. * (verification du chargement)
  192. SI (I EGA 9);
  193. SI (NEG GRAPH2 'N');
  194. TITR 'PLAS6 : DEFORMEE';
  195. DEF0 = DEFO SUR1 DEPL1 0.;
  196. DEF1 = DEFO SUR1 DEPL1 2. VERT;
  197. TRAC SUR1 (DEF0 ET DEF1);
  198. FINSI;
  199. FINSI;
  200.  
  201. * Calcul du moment de flexion du aux contraintes
  202. * smxx s'exercant le long de AB.
  203. LIST2 = PROG;
  204. J = 0;
  205. NB = NB1 + 1;
  206. REPETER BLOC4 NB;
  207. J = J + 1;
  208. D = EXTR LISD2 J;
  209. POI1 = SUR1 POIN PROC (12.5E-3 D);
  210. SM = EXTR CHPO10 SMXX POI1;
  211. LIST2 = LIST2 ET (PROG SM);
  212. FIN BLOC4;
  213.  
  214. LIST3 = LIST2 * LISD2;
  215. TITR 'CONTRAINTE SMXX';
  216. ESMXX = EVOL MANU Y LISD2 SMXX LIST2;
  217. TITR 'PRODUIT Y * SMXX';
  218. EYSMXX = EVOL MANU Y LISD2 YSMXX LIST3;
  219.  
  220. SI (I EGA 9);
  221. SI (NEG GRAPH2 'N');
  222. DESS ESMXX;
  223. DESS EYSMXX;
  224. FINSI;
  225. FINSI;
  226. MOM1.I = INTG EYSMXX;
  227.  
  228. MOM1.I = -1.E-3 * MOM1.I;
  229. ERG.I = 100. * (ABS ((MOM1.I - MOM2.I) / MOM2.I));
  230.  
  231. FIN BLOC1;
  232.  
  233. *******************************************************
  234. * affichage des resultats *
  235. *******************************************************
  236. MESS 'RESULTATS : PLAS6';
  237. MESS '-------------------';
  238.  
  239. MESS 'Moment de flexion du aux contraintes SMXX le long de AB.';
  240. MESS '--------------------------------------------------------';
  241.  
  242. MESS ' UAmax = 0.02875 mm :';
  243. MESS ' ------------------';
  244. MESS ' Moment theorique :' MOM1.1 'N.m';
  245. MESS ' Moment calcule :' MOM2.1 'N.m';
  246. MESS ' Soit un ecart de :' ERG.1 '%';
  247.  
  248. MESS ' UAmax = 0.05 mm :';
  249. MESS ' --------------- ';
  250. MESS ' Moment theorique :' MOM1.2 'N.m';
  251. MESS ' Moment calcule :' MOM2.2 'N.m';
  252. MESS ' Soit un ecart de :' ERG.2 '%';
  253.  
  254. MESS ' UAmax = 0.1 mm :';
  255. MESS ' --------------';
  256. MESS ' Moment theorique :' MOM1.3 'N.m';
  257. MESS ' Moment calcule :' MOM2.3 'N.m';
  258. MESS ' Soit un ecart de :' ERG.3 '%';
  259.  
  260. MESS ' UAmax = 0.15 mm :';
  261. MESS ' ---------------';
  262. MESS ' Moment theorique :' MOM1.4 'N.m';
  263. MESS ' Moment calcule :' MOM2.4 'N.m';
  264. MESS ' Soit un ecart de :' ERG.4 '%';
  265.  
  266. MESS ' UAmax = 0.2 mm :';
  267. MESS ' --------------';
  268. MESS ' Moment theorique :' MOM1.5 'N.m';
  269. MESS ' Moment calcule :' MOM2.5 'N.m';
  270. MESS ' Soit un ecart de :' ERG.5 '%';
  271.  
  272. MESS ' UAmax = 0.3 mm :';
  273. MESS ' --------------';
  274. MESS ' Moment theorique :' MOM1.6 'N.m';
  275. MESS ' Moment calcule :' MOM2.6 'N.m';
  276. MESS ' Soit un ecart de :' ERG.6 '%';
  277.  
  278. MESS ' UAmax = 0.4 mm :';
  279. MESS ' --------------';
  280. MESS ' Moment theorique :' MOM1.7 'N.m';
  281. MESS ' Moment calcule :' MOM2.7 'N.m';
  282. MESS ' Soit un ecart de :' ERG.7 '%';
  283.  
  284. MESS ' UAmax = 0.5 mm :';
  285. MESS ' --------------';
  286. MESS ' Moment theorique :' MOM1.8 'N.m';
  287. MESS ' Moment calcule :' MOM2.8 'N.m';
  288. MESS ' Soit un ecart de :' ERG.8 '%';
  289.  
  290. MESS ' UAmax = 1.0 mm :';
  291. MESS ' --------------';
  292. MESS ' Moment theorique :' MOM1.9 'N.m';
  293. MESS ' Moment calcule :' MOM2.9 'N.m';
  294. MESS ' Soit un ecart de :' ERG.9 '%';
  295.  
  296. MESS 'Donnees sur le maillage';
  297. MESS '-----------------------';
  298. MESS ' Nombre d elements :' NBEL1 'QUA4';
  299. MESS ' Nombre de noeuds :' NBNO1 ;
  300.  
  301. *******************************************************
  302. * code fonctionnement *
  303. *******************************************************
  304. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5 ERG.6 ERG.7 ERG.8 ERG.9);
  305.  
  306. SI (ERGMAX <EG 0.5);
  307. ERRE 0;
  308. SINON;
  309. ERRE 5;
  310. FINSI;
  311.  
  312. TEMPS;
  313. FIN;
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales