Télécharger plas2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas2.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test plas2.dgibi: Jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC PSC ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *******************************************************
  29. * TEST PLAS2
  30. *
  31. * Sortie du domaine élastique et phase plastique
  32. * (comportement élasto-plastique parfait)
  33. * Calcul axisymétrique avec prise en compte des
  34. * symétries.
  35. *
  36. * Une sphère de rayon extérieur égal à 2 mm et de rayon
  37. * intérieur égal à 1 mm (centre O et contour ABCD) est
  38. * soumise à une pression interne.
  39. *
  40. * La pression évolue en fonction du temps de 100 MPa à
  41. * 0 s jusqu'à 358.9 MPa à 1000 s.
  42. *
  43. * Cette évolution de la pression entraine un
  44. * comportement plastique jusqu'en R=1.5 mm.
  45. *
  46. * Les déplacements radiaux à 0 s et à 1000 s
  47. * sont comparés aux valeurs théoriques (0.4 microns
  48. * et 2.83 microns)
  49. *
  50. *******************************************************
  51. TITRE 'PLAS2 - SPHERE SOUS PRESSION INTERNE';
  52. OPTION DIME 2 ELEM QUA4 MODE AXIS ;
  53. TEMPS ;
  54. *
  55. *------------- Définition de la géométrie -------------
  56. *
  57. O = 0 0 ;
  58. A = 1E-3 0 ;
  59. B = 2E-3 0 ;
  60. C = 0 2E-3 ;
  61. D = 0 1E-3 ;
  62. *
  63. *------------------------------------------------------
  64. * La peau interne est maillée de façon plus fine pour
  65. * un meilleur calcul des contraintes radiales, les
  66. * points X et Y sont introduits à cet effet.
  67. *------------------------------------------------------
  68. *
  69. X = 1.1E-3 0 ;
  70. Y = 0 1.1E-3 ;
  71. *
  72. L1 = A DROI 5 X ;
  73. L2 = X DROI 9 B ;
  74. LR = L1 ET L2 ;
  75. CE = CERC 16 B O C ;
  76. L3 = C DROI 9 Y ;
  77. L4 = Y DROI 5 D ;
  78. LZ = L3 ET L4 ;
  79. CI = CERC 16 D O A ;
  80. *
  81. SU = LR CE LZ CI DALL PLAN ;
  82. *
  83. SI (NEG GRAPH 'N');
  84. TRAC 'QUAL' SU ;
  85. FINSI;
  86. *
  87. *------ Définition des conditions aux limites --------
  88. *----------- (conditions de symétrie) -----------------
  89. *
  90. CL1 = BLOQ LR UZ ;
  91. CL2 = BLOQ LZ UR ;
  92. CL = CL1 ET CL2 ;
  93. *
  94. *--------- Utilisation de la procedure PASAPAS --------
  95. *-- Les objets utilisés par la procédure PASAPAS sont -
  96. *--------- définis dans les lignes qui suivent --------
  97. *
  98. MO= MODE SU MECANIQUE ELASTIQUE PLASTIQUE PARFAIT QUA4;
  99. *
  100. *-----------------------------
  101. * SIGY est la limite élastique
  102. *-----------------------------
  103. *
  104. *------------- Définition du matériau -----------------
  105. *
  106. MAT1 = MATE MO YOUN 2E11 SIGY 300E6 NU 0.3;
  107. *
  108. *------ Définition en Pa de la pression unitaire ------
  109. *
  110. FO = PRES MASS MO 1E6 CI ;
  111. *
  112. *---------- au pas de temps T, la pression vaut F(T)*FO
  113. *
  114. LI1 = PROG 0. 1000. ;
  115. LI2 = PROG 0. 1000. ;
  116. EV = EVOL MANU T LI1 F(T) LI2 ;
  117. CHA1 = CHAR MECA FO EV ;
  118. *
  119. *-- Liste des pas de calcul, 100. MPa est la pression -
  120. *--- de début de plastification, 358.9 MPa engendre --
  121. *----- un comportement plastique jusqu'en R=1.5 mm ----
  122. *
  123. LIS1 = PROG 100. 358.9 ;
  124. TAB1 = TABLE ;
  125. TAB1.'BLOCAGES_MECANIQUES' = CL;
  126. TAB1.'MODELE' = MO;
  127. TAB1.'CARACTERISTIQUES' = MAT1;
  128. TAB1.'CHARGEMENT' = CHA1;
  129. TAB1.'TEMPS_CALCULES' = LIS1;
  130.  
  131. PASAPAS TAB1 ;
  132. *
  133. *-------- Calcul et impression des résultats ----------
  134. *
  135. RE1 = (TAB1.DEPLACEMENTS.1) ;
  136. RE2 = (TAB1.DEPLACEMENTS.2) ;
  137.  
  138.  
  139. SI (NEG GRAPH 'N');
  140. * Premier Increment
  141. TITR 'Deplacement Radial apres le premier increment' ;
  142. DEPR = EXCO RE1 'UR';
  143. DEPZ = EXCO RE1 'UZ';
  144. DEPRAD = (((DEPR**2) + (DEPZ**2))**0.5) * 1.e6;
  145. TRAC SU DEPRAD;
  146.  
  147. TITR 'Deplacement Radial apres le deuxieme increment' ;
  148. DEPR = EXCO RE2 'UR';
  149. DEPZ = EXCO RE2 'UZ';
  150. DEPRAD = (((DEPR**2) + (DEPZ**2))**0.5) * 1.e6;
  151. TRAC SU DEPRAD;
  152. FINSI;
  153.  
  154.  
  155. *
  156. V1 = EXTR RE1 UR A ;
  157. V1 = 1E6*V1 ;
  158. V2 = EXTR RE2 UR A ;
  159. V2 = 1E6*V2 ;
  160.  
  161. ERR1 = 100*(ABS(0.4 - V1)/0.4 );
  162. ERR2 = 100*(ABS(2.83 - V2)/2.83);
  163.  
  164. SAUT PAGE ; SAUT 2 LIGN ;
  165.  
  166. MESS 'EN R=1MM : DEPLACEMENT THEORIQUE ET CALCULE' ;
  167. MESS 'INCREMENT ELASTIQUE THEORIQUE UR= 0.40 MICRONS' ;
  168. MESS 'INCREMENT ELASTIQUE CALCULE UR= 'V1 'MICRONS' ;
  169. MESS ' SOIT UN ECART DE ' ERR1 '%' ;
  170. MESS 'INCREMENT PLASTIQUE THEORIQUE UR= 2.83 MICRONS' ;
  171. MESS 'INCREMENT PLASTIQUE CALCULE UR= 'V2 'MICRONS' ;
  172. MESS ' SOIT UN ECART DE ' ERR2 '%' ;
  173. TEMPS ;
  174. *------------ Code de fonctionnement ------------------
  175.  
  176. LIST1=PROG ERR1 ERR2;
  177.  
  178. ERRMAX=MAXI (PROG ERR1 ERR2);
  179.  
  180. SI (ERRMAX < 3.5);
  181. ERRE 0;
  182. SINON;
  183. ERRE 5;
  184. FINSI;
  185.  
  186. FIN;
  187.  
  188.  
  189.  
  190.  
  191.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales